* [PATCH] Add (guix gnu-maintenance).
@ 2012-12-04 2:58 Nikita Karetnikov
2012-12-04 3:15 ` Nikita Karetnikov
0 siblings, 1 reply; 5+ messages in thread
From: Nikita Karetnikov @ 2012-12-04 2:58 UTC (permalink / raw)
To: bug-guix
[-- Attachment #1: Type: text/plain, Size: 224 bytes --]
Hi,
The following should return a list of GNU packages.
# ./pre-inst-env guile
scheme@(guile-user)> ,use (guix gnu-maintenance)
scheme@(guile-user)> (gnu-packages-womb %womb)
$1 = ("3dldf" "a2ps" "acct" "acm" ...)
Nikita
[-- Attachment #2: 0001-Add-guix-gnu-maintenance.patch --]
[-- Type: text/x-diff, Size: 3045 bytes --]
From d65bb961f8fc8628d07dbb5881390950eceac9bb Mon Sep 17 00:00:00 2001
From: Nikita Karetnikov <nikita@karetnikov.org>
Date: Tue, 4 Dec 2012 02:45:46 +0000
Subject: [PATCH] Add (guix gnu-maintenance).
* guix/gnu-maintenance.scm: New file.
* Makefile.am (MODULES): Add it.
---
Makefile.am | 1 +
guix/gnu-maintenance.scm | 56 ++++++++++++++++++++++++++++++++++++++++++++++
2 files changed, 57 insertions(+), 0 deletions(-)
create mode 100644 guix/gnu-maintenance.scm
diff --git a/Makefile.am b/Makefile.am
index 8bb3b55..0585b1e 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -27,6 +27,7 @@ MODULES = \
guix/utils.scm \
guix/derivations.scm \
guix/download.scm \
+ guix/gnu-maintenance.scm \
guix/build-system.scm \
guix/build-system/gnu.scm \
guix/build-system/trivial.scm \
diff --git a/guix/gnu-maintenance.scm b/guix/gnu-maintenance.scm
new file mode 100644
index 0000000..3cda545
--- /dev/null
+++ b/guix/gnu-maintenance.scm
@@ -0,0 +1,56 @@
+;;; Guix --- Nix package management from Guile. -*- coding: utf-8 -*-
+;;; Copyright (C) 2012 Nikita Karetnikov <nikita@karetnikov.org>
+;;;
+;;; This file is part of Guix.
+;;;
+;;; Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix gnu-maintenance)
+ #:use-module (web uri)
+ #:use-module (web client)
+ #:use-module (web response)
+ #:use-module (srfi srfi-11)
+ #:use-module (srfi srfi-26)
+ #:use-module (ice-9 regex))
+
+(define (http-fetch str)
+ "Fetch a file from STR, which should be a URI."
+ (let*-values (((resp data)
+ (http-get (string->uri str)))
+ ((code)
+ (response-code resp)))
+ (case code
+ ((200)
+ data)
+ (else
+ (error "download failed:" str code
+ (string-downcase (response-reason-phrase resp)))))))
+
+(define (rx-filter lst rx)
+ "Filter a list using a regexp."
+ (map (cut match:substring <>)
+ ((cut delete #f <>)
+ (map (cut regexp-exec rx <>)
+ lst))))
+
+(define-public %womb
+ (string-append "http://cvs.savannah.gnu.org/"
+ "viewvc/*checkout*/gnumaint/"
+ "gnupackages.txt?root=womb"))
+
+(define-public (gnu-packages-womb womb)
+ "Return a list of GNU packages."
+ (let ((lst (string-split (http-fetch womb) #\nl)))
+ (map (cut string-drop <> 9)
+ (rx-filter lst (make-regexp "^package: (.+)$")))))
--
1.7.5.4
^ permalink raw reply related [flat|nested] 5+ messages in thread
* Re: [PATCH] Add (guix gnu-maintenance).
2012-12-04 2:58 [PATCH] Add (guix gnu-maintenance) Nikita Karetnikov
@ 2012-12-04 3:15 ` Nikita Karetnikov
2012-12-04 18:42 ` Ludovic Courtès
0 siblings, 1 reply; 5+ messages in thread
From: Nikita Karetnikov @ 2012-12-04 3:15 UTC (permalink / raw)
To: bug-guix
[-- Attachment #1: Type: text/plain, Size: 26 bytes --]
I've slightly changed it.
[-- Attachment #2: 0001-Add-guix-gnu-maintenance.patch --]
[-- Type: text/x-diff, Size: 3034 bytes --]
From d07bf47caacc2bc71f5fea85a2963ee81bf29f9c Mon Sep 17 00:00:00 2001
From: Nikita Karetnikov <nikita@karetnikov.org>
Date: Tue, 4 Dec 2012 03:10:39 +0000
Subject: [PATCH] Add (guix gnu-maintenance).
* guix/gnu-maintenance.scm: New file.
* Makefile.am (MODULES): Add it.
---
Makefile.am | 1 +
guix/gnu-maintenance.scm | 56 ++++++++++++++++++++++++++++++++++++++++++++++
2 files changed, 57 insertions(+), 0 deletions(-)
create mode 100644 guix/gnu-maintenance.scm
diff --git a/Makefile.am b/Makefile.am
index 8bb3b55..0585b1e 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -27,6 +27,7 @@ MODULES = \
guix/utils.scm \
guix/derivations.scm \
guix/download.scm \
+ guix/gnu-maintenance.scm \
guix/build-system.scm \
guix/build-system/gnu.scm \
guix/build-system/trivial.scm \
diff --git a/guix/gnu-maintenance.scm b/guix/gnu-maintenance.scm
new file mode 100644
index 0000000..8ceb4e7
--- /dev/null
+++ b/guix/gnu-maintenance.scm
@@ -0,0 +1,56 @@
+;;; Guix --- Nix package management from Guile. -*- coding: utf-8 -*-
+;;; Copyright (C) 2012 Nikita Karetnikov <nikita@karetnikov.org>
+;;;
+;;; This file is part of Guix.
+;;;
+;;; Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix gnu-maintenance)
+ #:use-module (web uri)
+ #:use-module (web client)
+ #:use-module (web response)
+ #:use-module (srfi srfi-11)
+ #:use-module (srfi srfi-26)
+ #:use-module (ice-9 regex))
+
+(define (http-fetch str)
+ "Fetch a file from STR, which should be a URI."
+ (let*-values (((resp data)
+ (http-get (string->uri str)))
+ ((code)
+ (response-code resp)))
+ (case code
+ ((200)
+ data)
+ (else
+ (error "download failed:" str code
+ (string-downcase (response-reason-phrase resp)))))))
+
+(define (rx-filter lst rx)
+ "Filter a list using a regexp."
+ (map (cut match:substring <>)
+ ((cut delete #f <>)
+ (map (cut regexp-exec rx <>)
+ lst))))
+
+(define %womb
+ (string-append "http://cvs.savannah.gnu.org/"
+ "viewvc/*checkout*/gnumaint/"
+ "gnupackages.txt?root=womb"))
+
+(define-public (gnu-packages-womb)
+ "Return a list of GNU packages."
+ (let ((lst (string-split (http-fetch %womb) #\nl)))
+ (map (cut string-drop <> 9)
+ (rx-filter lst (make-regexp "^package: (.+)$")))))
--
1.7.5.4
^ permalink raw reply related [flat|nested] 5+ messages in thread
* Re: [PATCH] Add (guix gnu-maintenance).
2012-12-04 3:15 ` Nikita Karetnikov
@ 2012-12-04 18:42 ` Ludovic Courtès
2012-12-04 23:15 ` Nikita Karetnikov
0 siblings, 1 reply; 5+ messages in thread
From: Ludovic Courtès @ 2012-12-04 18:42 UTC (permalink / raw)
To: Nikita Karetnikov; +Cc: bug-guix
Hi,
Nikita Karetnikov <nikita.karetnikov@gmail.com> skribis:
> +(define (http-fetch str)
> + "Fetch a file from STR, which should be a URI."
Rather:
(define (http-fetch uri)
"Return a string containing the textual data at URI, a string."
...)
> + (error "download failed:" str code
> + (string-downcase (response-reason-phrase resp)))))))
Please remove ‘string-downcase’.
> +(define %womb
Rather ‘%package-list-url’.
> + (string-append "http://cvs.savannah.gnu.org/"
> + "viewvc/*checkout*/gnumaint/"
> + "gnupackages.txt?root=womb"))
> +
> +(define-public (gnu-packages-womb)
What about ‘official-gnu-packages’ instead? Seems more descriptive to me.
Also, please use #:export instead of ‘define-public’ (I try to avoid the
latter, and use it only in (distro packages ...) where it matters to
increase locality.)
> + "Return a list of GNU packages."
"Return the list of system identifiers of official GNU packages."
> + (let ((lst (string-split (http-fetch %womb) #\nl)))
> + (map (cut string-drop <> 9)
> + (rx-filter lst (make-regexp "^package: (.+)$")))))
Rather:
(define %package-line-rx
(make-regexp "^package: (.+)$"))
(let ((lst (string-split (http-fetch %package-list-url) #\nl)))
(filter-map (lambda (line)
(and=> (regexp-exec %package-line-rx line)
(cut match:substring <> 1)))
lst)
Can you post an updated patch?
Thanks,
Ludo’.
^ permalink raw reply [flat|nested] 5+ messages in thread
* Re: [PATCH] Add (guix gnu-maintenance).
2012-12-04 18:42 ` Ludovic Courtès
@ 2012-12-04 23:15 ` Nikita Karetnikov
2012-12-05 13:59 ` Ludovic Courtès
0 siblings, 1 reply; 5+ messages in thread
From: Nikita Karetnikov @ 2012-12-04 23:15 UTC (permalink / raw)
To: bug-guix
[-- Attachment #1: Type: text/plain, Size: 111 bytes --]
> Can you post an updated patch?
Attached.
Where can I read about 'and=>'? I haven't found it in the manual.
[-- Attachment #2: 0001-Add-guix-gnu-maintenance.patch --]
[-- Type: text/x-diff, Size: 3136 bytes --]
From 8aad5e89632e311a5ea45a4fe2cc97c28c205f80 Mon Sep 17 00:00:00 2001
From: Nikita Karetnikov <nikita@karetnikov.org>
Date: Tue, 4 Dec 2012 23:02:22 +0000
Subject: [PATCH] Add (guix gnu-maintenance).
* guix/gnu-maintenance.scm: New file.
* Makefile.am (MODULES): Add it.
---
Makefile.am | 1 +
guix/gnu-maintenance.scm | 57 ++++++++++++++++++++++++++++++++++++++++++++++
2 files changed, 58 insertions(+), 0 deletions(-)
create mode 100644 guix/gnu-maintenance.scm
diff --git a/Makefile.am b/Makefile.am
index 2500c0e..fab85ae 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -27,6 +27,7 @@ MODULES = \
guix/utils.scm \
guix/derivations.scm \
guix/download.scm \
+ guix/gnu-maintenance.scm \
guix/build-system.scm \
guix/build-system/gnu.scm \
guix/build-system/trivial.scm \
diff --git a/guix/gnu-maintenance.scm b/guix/gnu-maintenance.scm
new file mode 100644
index 0000000..2035e44
--- /dev/null
+++ b/guix/gnu-maintenance.scm
@@ -0,0 +1,57 @@
+;;; Guix --- Nix package management from Guile. -*- coding: utf-8 -*-
+;;; Copyright (C) 2012 Nikita Karetnikov <nikita@karetnikov.org>
+;;; Copyright (C) 2012 Ludovic Courtès <ludo@gnu.org>
+;;;
+;;; This file is part of Guix.
+;;;
+;;; Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix gnu-maintenance)
+ #:use-module (web uri)
+ #:use-module (web client)
+ #:use-module (web response)
+ #:use-module (ice-9 regex)
+ #:use-module (srfi srfi-1)
+ #:use-module (srfi srfi-11)
+ #:use-module (srfi srfi-26)
+ #:export (official-gnu-packages))
+
+(define (http-fetch uri)
+ "Return a string containing the textual data at URI, a string."
+ (let*-values (((resp data)
+ (http-get (string->uri uri)))
+ ((code)
+ (response-code resp)))
+ (case code
+ ((200)
+ data)
+ (else
+ (error "download failed:" uri code
+ (response-reason-phrase resp))))))
+
+(define %package-list-url
+ (string-append "http://cvs.savannah.gnu.org/"
+ "viewvc/*checkout*/gnumaint/"
+ "gnupackages.txt?root=womb"))
+
+(define (official-gnu-packages)
+ "Return a list of GNU packages."
+ (define %package-line-rx
+ (make-regexp "^package: (.+)$"))
+
+ (let ((lst (string-split (http-fetch %package-list-url) #\nl)))
+ (filter-map (lambda (line)
+ (and=> (regexp-exec %package-line-rx line)
+ (cut match:substring <> 1)))
+ lst)))
--
1.7.5.4
^ permalink raw reply related [flat|nested] 5+ messages in thread
* Re: [PATCH] Add (guix gnu-maintenance).
2012-12-04 23:15 ` Nikita Karetnikov
@ 2012-12-05 13:59 ` Ludovic Courtès
0 siblings, 0 replies; 5+ messages in thread
From: Ludovic Courtès @ 2012-12-05 13:59 UTC (permalink / raw)
To: Nikita Karetnikov; +Cc: bug-guix
Nikita Karetnikov <nikita.karetnikov@gmail.com> skribis:
>> Can you post an updated patch?
>
> Attached.
Applied, thanks!
In the future, we may want to use GNU recutils to parse all of the file.
> Where can I read about 'and=>'? I haven't found it in the manual.
It’s missing from the manual, indeed. Patch welcome. :-)
Ludo’.
^ permalink raw reply [flat|nested] 5+ messages in thread
end of thread, other threads:[~2012-12-05 13:59 UTC | newest]
Thread overview: 5+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-12-04 2:58 [PATCH] Add (guix gnu-maintenance) Nikita Karetnikov
2012-12-04 3:15 ` Nikita Karetnikov
2012-12-04 18:42 ` Ludovic Courtès
2012-12-04 23:15 ` Nikita Karetnikov
2012-12-05 13:59 ` Ludovic Courtès
Code repositories for project(s) associated with this external index
https://git.savannah.gnu.org/cgit/guix.git
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.