;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2018 Danny Milosavljevic <dannym@scratchpost.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (wip batik)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix utils)
  #:use-module (guix download)
  #:use-module (guix git-download)
  #:use-module (guix packages)
  #:use-module (guix build-system ant)
  #:use-module (gnu packages)
  #:use-module (gnu packages compression)
  #:use-module (gnu packages java)
  #:use-module (gnu packages textutils))

;;; TODO: Use maven.
;;; TODO: Remove bundled jar files (I guess our ant-build-system ought to
;;; do that).

(define java-batik
  (package
    (name "java-batik")
    (version "1.10")
    (source
      (origin
        (method url-fetch)
        (uri (string-append
              "mirror://apache/xmlgraphics/batik/source/batik-src-" version
              ".tar.gz"))
        (sha256
         (base32
          "05nipxvm940m2dgzmrvflr2r72a5mmqbl25pvqr0xn73a5lygi6z"))
        (file-name (string-append name "-" version))))
    (build-system ant-build-system)
    (native-inputs
     `(("java-junit" ,java-junit)))
    (home-page "https://xmlgraphics.apache.org/batik/")
    (synopsis "SVG toolkit for Java")
    (description "This package provides an SVG toolkit for Java.")
    (license license:asl2.0)))

(define (java-batik-package subdir inputs)
  (package
    (inherit java-batik)
    (name (string-append "java-" subdir))
    (propagated-inputs
     inputs)
    (arguments
     `(#:jar-name (string-append ,subdir ".jar")
       #:tests? #t
       #:phases
       (modify-phases %standard-phases
         (add-after 'unpack 'chdir
           (lambda _
             ;; FIXME: Be nicer.
             (delete-file-recursively "batik-util/src/test")
             (chdir ,subdir)
             #t)))))))

(define (java-batik-disable-tests base-package)
  (package
    (inherit base-package)
    (arguments
     (substitute-keyword-arguments (package-arguments base-package)
      ((#:tests? _)
       #f)))))

(define-public java-batik-i18n
  ;; No tests exist.
  (java-batik-disable-tests (java-batik-package "batik-i18n" '())))

(define-public java-batik-constants
  ;; No tests exist.
  (java-batik-disable-tests (java-batik-package "batik-constants" '())))

(define-public java-batik-util
  ;; batik-util tests require batik-test.  batik-test requires batik-util.
  (java-batik-disable-tests
   (java-batik-package "batik-util"
    `(("java-batik-constants" ,java-batik-constants)
      ("java-batik-i18n" ,java-batik-i18n)))))

(define-public java-batik-xml
  (java-batik-package "batik-xml"
   `(("java-batik-i18n" ,java-batik-i18n)
     ("java-batik-util" ,java-batik-util))))

(define-public java-batik-ext
  (java-batik-package "batik-ext"
   `()))

(define-public java-w3c-smil-3.0
  (package
    (name "java-w3c-smil")
    (version "3.0")
    (source #f)
    (build-system ant-build-system)
    (arguments
     `(#:jar-name "w3c-smil.jar"
       #:source-dir "."
       #:tests? #f ; No tests exist.
       #:phases
       (modify-phases %standard-phases
         (replace 'unpack
           (lambda* (#:key source #:allow-other-keys)
             ;; https://www.w3.org/TR/SMIL3/smil-timing.html#q142
             (mkdir-p "org/w3c/dom/smil")
             (call-with-output-file "org/w3c/dom/smil/ElementTimeControl.java"
               (lambda (port)
                 (format port "
package org.w3c.dom.smil;

import org.w3c.dom.DOMException;

public interface ElementTimeControl {
    public boolean  beginElement();

    public boolean  beginElementAt(float offset);

    public boolean endElement();

    public boolean endElementAt(float offset);
}
")))
             (call-with-output-file "org/w3c/dom/smil/TimeEvent.java"
               (lambda (port)
                 (format port "
package org.w3c.dom.smil;

import org.w3c.dom.events.Event;
import org.w3c.dom.views.AbstractView;

public interface TimeEvent extends Event {
    public AbstractView getView();

    public int getDetail();

    public void initTimeEvent(String typeArg,
                              AbstractView viewArg,
                              int detailArg);

}
")))
             #t)))))
    (native-inputs
     `(("unzip" ,unzip)))
    (home-page "https://www.w3.org/Style/CSS/SAC/")
    (synopsis "W3C SAC interface for CSS parsers in Java")
    (description "This package provides a SAC interface by the W3C.
SAC is an interface for CSS parsers.")
    (license license:w3c)))

(define-public java-w3c-sac
  (package
    (name "java-w3c-sac")
    (version "1.3")
    (source
      (origin
        (method url-fetch)
        (uri (string-append "https://www.w3.org/2002/06/sacjava-" version
                            ".zip"))
        (sha256
         (base32
          "1djp2nnzf8jchnwz1ij9i5jfx4cg1ryf3lbw133yzjy0wkhcla52"))))
    (build-system ant-build-system)
    (arguments
     `(#:jar-name "w3c-sac.jar"
       #:source-dir "sac-1.3"
       #:tests? #f ; No tests exist.
       #:phases
       (modify-phases %standard-phases
         (replace 'unpack
           (lambda* (#:key source #:allow-other-keys)
             (invoke "unzip" source))))))
    (native-inputs
     `(("unzip" ,unzip)))
    (home-page "https://www.w3.org/Style/CSS/SAC/")
    (synopsis "W3C SAC interface for CSS parsers in Java")
    (description "This package provides a SAC interface by the W3C.
SAC is an interface for CSS parsers.")
    (license license:w3c)))

(define-public java-w3c-svg-1.0
  (package
    (name "java-w3c-svg")
    (version "20010904")
    (source
      (origin
        (method url-fetch)
        (uri (string-append "http://www.w3.org/TR/2001/REC-SVG-" version
                            "/java-binding.zip"))
        (sha256
         (base32
          "0gnxvx51bg6ijplf6l2q0i1m07101f7fickawshfygnsdjqfdnbp"))))
    (build-system ant-build-system)
    (arguments
     `(#:jar-name "w3c-svg.jar"
       #:source-dir "."
       #:tests? #f ; No tests exist.
       #:phases
       (modify-phases %standard-phases
         (replace 'unpack
           (lambda* (#:key source #:allow-other-keys)
             (invoke "unzip" source)))
         (add-after 'unpack 'patch-interface
           (lambda _
             ;; Make it compatible with batik.
             ;; This is equivalent to usingxml commons externals'
             ;; "externals" part from https://xerces.apache.org/mirrors.cgi
             (substitute* "SVGFEConvolveMatrixElement.java"
              (("public SVGAnimatedLength[ ]*getKernelUnitLength")
               "public SVGAnimatedNumber getKernelUnitLength"))
             (substitute* "SVGFEMorphologyElement.java"
              (("public SVGAnimatedLength[ ]*getRadius")
               "public SVGAnimatedNumber getRadius"))
             (call-with-output-file "EventListenerInitializer.java"
               (lambda (port)
                 (format port "
// License: http://www.apache.org/licenses/LICENSE-2.0
package org.w3c.dom.svg;
public interface EventListenerInitializer {
    public void initializeEventListeners(SVGDocument doc);
}

")))
             #t)))))
    (propagated-inputs
     `(("java-w3c-smil" ,java-w3c-smil-3.0)))
    (native-inputs
     `(("unzip" ,unzip)))
    (home-page "https://www.w3.org/Style/CSS/SAC/")
    (synopsis "W3C SVG interface")
    (description "This package provides a SVG interface.")
    (license license:w3c)))

(define-public java-w3c-svg
  (package
    (inherit java-w3c-svg-1.0)
    (version "20110816")
    (source
      (origin
        (method url-fetch)
        (uri (string-append "http://www.w3.org/TR/2011/REC-SVG11-" version
                            "/java-binding.zip"))
        (sha256
         (base32
          "0jicqcrxav8ggs37amgvvwgc2f0qp1c5wns4rb2i3si83s2m09ns"))))
    (propagated-inputs
     `())))

(define java-xmlgraphics-commons
  (package
    (name "java-xmlgraphics-commons")
    (version "2.3")
    (source
      (origin
        (method url-fetch)
        (uri (string-append "mirror://apache/xmlgraphics/commons/source/xmlgraphics-commons-"
                            version "-src.tar.gz"))
        (sha256
         (base32
          "0a432a4ca3vgnbada5cy9mlmfzmq6hi4i176drfxrp17q2d43w23"))))
    (build-system ant-build-system)
    (arguments
     `(#:build-target "jar-main"
       #:test-target "junit-basic"
       #:phases
       (modify-phases %standard-phases
         (add-after 'unpack 'make-reproducible
           (lambda _
             (substitute* "build.xml"
              (("<attribute name=\"Build-Id\" value=\"[^\"]*\"")
               "<attribute name=\"Build-Id\" value=\"\""))
             #t))
         (replace 'install
           (lambda* (#:key outputs #:allow-other-keys)
             (let* ((out (assoc-ref outputs "out"))
                    (out-share (string-append out "/share/java")))
             (install-file "build/xmlgraphics-commons-2.3.jar" out-share)
             #t))))))
    (home-page "https://xmlgraphics.apache.org/commons/")
    (synopsis "XMLGraphics constants.")
    (description "This package provides XMLGraphics constants (originally
from @code{batik}).")
    (license license:asl2.0)))

(define-public java-batik-css
  (java-batik-package "batik-css"
   `(("java-batik-constants" ,java-batik-constants)
     ("java-batik-i18n" ,java-batik-i18n)
     ("java-batik-util" ,java-batik-util)
     ("java-w3c-sac" ,java-w3c-sac)
     ("java-w3c-svg" ,java-w3c-svg-1.0)
     ("java-xmlgraphics-commons" ,java-xmlgraphics-commons))))

(define-public java-batik-dom
  (java-batik-package "batik-dom"
   `(("java-batik-constants" ,java-batik-constants)
     ("java-batik-css" ,java-batik-css)
     ("java-batik-ext" ,java-batik-ext)
     ("java-batik-i18n" ,java-batik-i18n)
     ("java-batik-util" ,java-batik-util)
     ("java-batik-xml" ,java-batik-xml)
     ("java-w3c-sac" ,java-w3c-sac)
     ("java-w3c-smil" ,java-w3c-smil-3.0)
     ("java-xalan" ,java-xalan))))

(define-public java-batik-awt-util
  (java-batik-package "batik-awt-util"
   `(("java-batik-i18n" ,java-batik-i18n)
     ("java-batik-util" ,java-batik-util)
     ("java-xmlgraphics-commons" ,java-xmlgraphics-commons))))

(define-public java-batik-parser
  (java-batik-package "batik-parser"
   `(("java-batik-awt-util" ,java-batik-awt-util)
     ("java-batik-i18n" ,java-batik-i18n)
     ("java-batik-util" ,java-batik-util)
     ("java-batik-xml" ,java-batik-xml)
     ("java-w3c-svg" ,java-w3c-svg-1.0))))