Re: Who has had success installing a Guix system on arm?

[Tobias Geerinckx-Rice <me@tobias.gr>]

[-- Attachment #1.1: Type: text/plain, Size: 1750 bytes --]

Jesse,

Jesse Gibbons 写道：
> Has anyone in this mailing list successfully used the Guix 
> system
> on an armhf or aarch64 computer? If so would you mind sharing 
> details, such as:
>
> -> Which board did you get working with guix system (banana pi 
> m2u,
>    novena, beaglebone black, pine64-plus, etc.)?

I'm not much of an ARM person but did have success installing Guix 
System onto two Overdrives 1000 currently part of the Berlin build 
farm.  They aren't ‘boards’ but proper computers using UEFI, so 
GRUB just works.

> -> Did you build natively or cross-build from a different 
> system?

Both machines came with OpenSUSE installed, and were briefly 
borged into Guix Systems simply by installing Guix (using the 
official installer script) and running ‘guix system init /’.

That worked but didn't last long.  I booted an aarch64 Fedora 
installer image, installed Guix into the live environment using 
the same installer script, wiped & repartitioned the drives, wrote 
a basic system configuration and ran ‘guix system init /mnt’. 
That's the system still running today.

It must have been easy or it would have been more memorable.  :-)

I never (cross-)built anything custom.

> -> What version of guix did you use? (what did guix describe 
> say?)

I don't remember.  Whatever was master soon before Jul 24 2019.

> -> If the board you got working can boot from an internal (emmc) 
> or
>    external (microsd) drive, which one did you get working?

These machines have a 1TB 3.5" SATA drive.

> -> Would you mind sharing the operating-system definition that 
> was
>    successful?

It's probably not useful for ‘boards’, but sure.

Kind regards,

T G-R


[-- Attachment #1.2: system.scm --]
[-- Type: application/octet-stream, Size: 2869 bytes --]

(use-modules (gnu)
	     (guix))
(use-service-modules mcron
                     networking
		     ssh)
(use-package-modules linux)

(define %accounts
  (list (user-account
	 (name "nckx")
	 (comment "Tobias Geerinckx-Rice")
	 (group "users")
	 (supplementary-groups (list "wheel" "kvm"))
	 (home-directory (string-append "/home/" name)))
        (user-account
         (name "hydra")
         (comment "Hydra user")
         (group "users")
         (home-directory (string-append "/home/" name)))))

(define gc-job
  ;; Run 'guix gc' at 3AM every day.
  #~(job '(next-hour '(3)) "guix gc -F 50G"))

(operating-system
  (host-name "dmitri")
  (timezone "Europe/Brussels")
  (locale "en_GB.utf8")

  (bootloader (bootloader-configuration
               (bootloader grub-efi-bootloader)
               (target "/boot/efi")
	       (timeout 3)))
  (initrd-modules (cons* "xhci-pci" "ahci_platform" "sd_mod"
                         %base-initrd-modules))
  (file-systems (cons* (file-system
                         (device (file-system-label "GNU"))
                         (mount-point "/")
                         (type "ext4"))
                       (file-system
			 (device (file-system-label "EFI"))
			 (mount-point "/boot/efi")
			 (type "vfat"))
                       %base-file-systems))
  (swap-devices '("/dev/sda2"))

  (users (append %accounts %base-user-accounts))
  (services (cons* (service openssh-service-type)
                   (service dhcp-client-service-type)
                   (service mcron-service-type
                            (mcron-configuration
                             (jobs (list gc-job))))
                   (service agetty-service-type
                            (agetty-configuration
                             (tty "ttyAMA0")
                             (keep-baud? #t)
                             (term "vt220")
                             (baud-rate "115200,38400,9600")))
                   (service openntpd-service-type
                            (openntpd-configuration
                             (servers (list "0.pool.ntp.org" "1.pool.ntp.org"))
                             (constraints-from (list "www.openbsd.org"))))
                   (modify-services %base-services
				    (guix-service-type
				     config => (guix-configuration
						(inherit config)
						(use-substitutes? #f)
						(max-silent-time 14400)
						(authorized-keys
						 (list (local-file "/etc/guix/maintenance/hydra/keys/guix/berlin.guixsd.org-export.pub")))
						(extra-options
						 '("--max-jobs=3" "--cores=2")))))))

  (packages
   (append
    (map specification->package+output
	 (list "dstat"
               "git"
               "htop"
               "picocom"                ; to debug sibling (/dev/ttyACM0*)
	       "mosh"
	       "ncurses"		; reset
	       "nss-certs"
	       "openssh"))
    %base-packages)))

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 247 bytes --]