[PATCH v2 0/2] Add dub and dub-build-system.

[PATCH v2 0/2] Add dub and dub-build-system.

[Danny Milosavljevic]

Danny Milosavljevic (2):
  gnu: Add dub.
  gnu: Add dub-build-system.

 Makefile.am                     |   2 +
 gnu/packages/ldc.scm            |  37 ++++++++++
 guix/build-system/dub.scm       | 153 ++++++++++++++++++++++++++++++++++++++++
 guix/build/dub-build-system.scm | 110 +++++++++++++++++++++++++++++
 4 files changed, 302 insertions(+)
 create mode 100644 guix/build-system/dub.scm
 create mode 100644 guix/build/dub-build-system.scm

[PATCH v2 1/2] gnu: Add dub.

[Danny Milosavljevic]

* gnu/packages/ldc.scm (dub): New variable.
---
 gnu/packages/ldc.scm | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

diff --git a/gnu/packages/ldc.scm b/gnu/packages/ldc.scm
index 6ea7f664b..163006247 100644
--- a/gnu/packages/ldc.scm
+++ b/gnu/packages/ldc.scm
@@ -27,6 +27,7 @@
   #:use-module (gnu packages)
   #:use-module (gnu packages base)
   #:use-module (gnu packages compression)
+  #:use-module (gnu packages curl)
   #:use-module (gnu packages libedit)
   #:use-module (gnu packages llvm)
   #:use-module (gnu packages python)
@@ -171,3 +172,39 @@ latest DMD frontend and uses LLVM as backend.")
     (license (list license:bsd-3
                    license:gpl2+
                    license:boost1.0))))
+
+(define-public dub
+  (package
+    (name "dub")
+    (version "1.2.0")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "https://github.com/dlang/dub/archive/"
+                                  "v" version ".tar.gz"))
+              (file-name (string-append name "-" version ".tar.gz"))
+              (sha256
+               (base32
+                "1sd8i1rvxc7y7kk0y6km5zyvaladc5zh56r6afj74ndd63dssv43"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:tests? #f ; it would have tested itself by installing some packages (vibe etc)
+       #:phases
+       (modify-phases %standard-phases
+         (delete 'configure)
+         (replace 'build
+           (lambda _
+             (zero? (system* "./build.sh"))))
+         (replace 'install
+           (lambda* (#:key outputs #:allow-other-keys)
+             (let* ((out (assoc-ref outputs "out"))
+                    (outbin (string-append out "/bin")))
+               (mkdir-p outbin)
+               (install-file "bin/dub" outbin)))))))
+    (inputs
+     `(("curl" ,curl)))
+    (native-inputs
+     `(("ldc" ,ldc)))
+    (home-page "https://code.dlang.org/getting_started")
+    (synopsis "DUB package manager")
+    (description "This package provides the D package manager.")
+    (license license:expat)))

[PATCH v2 2/2] gnu: Add dub-build-system.

[Danny Milosavljevic]

* guix/build-system/dub.scm: New file.
* guix/build/dub-build-system.scm: New file.
* Makefile.am (MODULES): Add them.
---
 Makefile.am                     |   2 +
 guix/build-system/dub.scm       | 153 ++++++++++++++++++++++++++++++++++++++++
 guix/build/dub-build-system.scm | 110 +++++++++++++++++++++++++++++
 3 files changed, 265 insertions(+)
 create mode 100644 guix/build-system/dub.scm
 create mode 100644 guix/build/dub-build-system.scm

diff --git a/Makefile.am b/Makefile.am
index c13d0df8a..15bafa224 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -63,6 +63,7 @@ MODULES =					\
   guix/build-system/ant.scm			\
   guix/build-system/cargo.scm			\
   guix/build-system/cmake.scm			\
+  guix/build-system/dub.scm			\
   guix/build-system/emacs.scm			\
   guix/build-system/asdf.scm			\
   guix/build-system/glib-or-gtk.scm		\
@@ -87,6 +88,7 @@ MODULES =					\
   guix/build/download.scm			\
   guix/build/cargo-build-system.scm		\
   guix/build/cmake-build-system.scm		\
+  guix/build/dub-build-system.scm		\
   guix/build/emacs-build-system.scm		\
   guix/build/asdf-build-system.scm		\
   guix/build/git.scm				\
diff --git a/guix/build-system/dub.scm b/guix/build-system/dub.scm
new file mode 100644
index 000000000..cecdba843
--- /dev/null
+++ b/guix/build-system/dub.scm
@@ -0,0 +1,153 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2013, 2014, 2015, 2016 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
+;;; Copyright © 2013 Nikita Karetnikov <nikita@karetnikov.org>
+;;; Copyright © 2016 David Craven <david@craven.ch>
+;;; Copyright © 2016 Danny Milosavljevic <dannym@scratchpost.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build-system dub)
+  #:use-module (guix search-paths)
+  #:use-module (guix store)
+  #:use-module (guix utils)
+  #:use-module (guix derivations)
+  #:use-module (guix packages)
+  #:use-module (guix build-system)
+  #:use-module (guix build-system gnu)
+  #:use-module (ice-9 match)
+  #:use-module (srfi srfi-26)
+  #:export (dub-build-system
+            package-url
+            package-url?
+            package-uri))
+
+(define package-url "https://packages.io/api/v1/packages/")
+(define package-url? (cut string-prefix? package-url <>))
+
+(define (package-uri name version)
+  "Return a URI string for the package package hosted at packages.io corresponding
+to NAME and VERSION."
+  (string-append package-url name "/" version "/download"))
+
+(define (default-ldc)
+  "Return the default Rustc package."
+  ;; Lazily resolve the binding to avoid a circular dependency.
+  (let ((ldc (resolve-interface '(gnu packages ldc))))
+    (module-ref ldc 'ldc)))
+
+(define (default-dub)
+  "Return the default Rustc package."
+  ;; Lazily resolve the binding to avoid a circular dependency.
+  (let ((ldc (resolve-interface '(gnu packages ldc))))
+    (module-ref ldc 'dub)))
+
+(define %dub-build-system-modules
+  ;; Build-side modules imported by default.
+  `((guix build dub-build-system)
+    (guix build syscalls)
+    ,@%gnu-build-system-modules))
+
+(define* (dub-build store name inputs
+                      #:key
+                      (tests? #t)
+                      (test-target #f)
+                      (configure-flags #f) ; XXX unused
+                      (dub-build-flags ''())
+                      (phases '(@ (guix build dub-build-system)
+                                  %standard-phases))
+                      (outputs '("out"))
+                      (search-paths '())
+                      (system (%current-system))
+                      (guile #f)
+                      (imported-modules %dub-build-system-modules)
+                      (modules '((guix build dub-build-system)
+                                 (guix build utils))))
+  "Build SOURCE using DUB, and with INPUTS."
+
+  (define builder
+    `(begin
+       (use-modules ,@modules)
+       (dub-build #:name ,name
+                    #:source ,(match (assoc-ref inputs "source")
+                                (((? derivation? source))
+                                 (derivation->output-path source))
+                                ((source)
+                                 source)
+                                (source
+                                 source))
+                    #:system ,system
+                    #:test-target ,test-target
+                    #:dub-build-flags ,dub-build-flags
+                    #:tests? ,tests?
+                    #:phases ,phases
+                    #:outputs %outputs
+                    #:search-paths ',(map search-path-specification->sexp
+                                          search-paths)
+                    #:inputs %build-inputs)))
+
+  (define guile-for-build
+    (match guile
+      ((? package?)
+       (package-derivation store guile system #:graft? #f))
+      (#f                                         ; the default
+       (let* ((distro (resolve-interface '(gnu packages commencement)))
+              (guile  (module-ref distro 'guile-final)))
+         (package-derivation store guile system #:graft? #f)))))
+
+  (build-expression->derivation store name builder
+                                #:inputs inputs
+                                #:system system
+                                #:modules imported-modules
+                                #:outputs (cons "src" outputs)
+                                #:guile-for-build guile-for-build))
+
+(define* (lower name
+                #:key source inputs native-inputs outputs system target
+                (ldc (default-ldc))
+                (dub (default-dub))
+                #:allow-other-keys
+                #:rest arguments)
+  "Return a bag for NAME."
+
+  (define private-keywords
+    '(#:source #:target #:ldc #:dub #:inputs #:native-inputs #:outputs))
+
+  (and (not target) ;; TODO: support cross-compilation
+       (bag
+         (name name)
+         (system system)
+         (target target)
+         (host-inputs `(,@(if source
+                              `(("source" ,source))
+                              '())
+                        ,@inputs
+
+                        ;; Keep the standard inputs of 'gnu-build-system'
+                        ,@(standard-packages)))
+         (build-inputs `(("ldc" ,ldc)
+                         ("dub" ,dub)
+                         ,@native-inputs))
+         (outputs outputs)
+         (build dub-build)
+         (arguments (strip-keyword-arguments private-keywords arguments)))))
+
+(define dub-build-system
+  (build-system
+    (name 'dub)
+    (description
+     "DUB build system, to build Rust packages")
+    (lower lower)))
diff --git a/guix/build/dub-build-system.scm b/guix/build/dub-build-system.scm
new file mode 100644
index 000000000..e58d2e343
--- /dev/null
+++ b/guix/build/dub-build-system.scm
@@ -0,0 +1,110 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2016 David Craven <david@craven.ch>
+;;; Copyright © 2017 Danny Milosavljevic <dannym@scratchpost.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build dub-build-system)
+  #:use-module ((guix build gnu-build-system) #:prefix gnu:)
+  #:use-module (guix build syscalls)
+  #:use-module (guix build utils)
+  #:use-module (ice-9 popen)
+  #:use-module (ice-9 rdelim)
+  #:use-module (ice-9 ftw)
+  #:use-module (ice-9 format)
+  #:use-module (ice-9 match)
+  #:use-module (srfi srfi-1)
+  #:use-module (srfi srfi-26)
+  #:export (%standard-phases
+            dub-build))
+
+;; Commentary:
+;;
+;; Builder-side code of the standard Rust package build procedure.
+;;
+;; Code:
+
+;; FIXME: Needs to be parsed from url not package name.
+(define (package-name->d-package-name name)
+  "Return the package name of NAME."
+  (match (string-split name #\-)
+    (("d" rest ...)
+     (string-join rest "-"))
+    (_ #f)))
+
+(define* (configure #:key inputs #:allow-other-keys)
+  "Replace argo.toml [dependencies] section with guix inputs."
+  (system* "chmod" "+w" ".")
+  (mkdir "vendor")
+  (for-each
+    (match-lambda
+      ((name . path)
+       (let ((d-package (package-name->d-package-name name)))
+         (when (and d-package path)
+           (match (string-split (basename path) #\-)
+             ((_ ... version)
+              (symlink (string-append path "/lib/d") (string-append "vendor/" (basename path)))))))))
+    inputs)
+  ;(setenv "CC" (string-append (assoc-ref inputs "gcc") "/bin/gcc"))
+  (let* ((dir (mkdtemp! "/tmp/dub.XXXXXX")))
+    (setenv "HOME" dir)
+    (zero? (system* "dub" "add-path" (string-append (getcwd) "/vendor")))))
+
+(define* (build #:key (dub-build-flags '())
+                #:allow-other-keys)
+  "Build a given DUB package."
+  (if (or (zero? (system* "grep" "-q" "sourceLibrary" "package.json"))
+          (zero? (system* "grep" "-q" "sourceLibrary" "dub.sdl"))
+          (zero? (system* "grep" "-q" "sourceLibrary" "dub.json"))) ; note: format is different!
+    #t
+    (let ((status (zero? (apply system* `("dub" "build" ,@dub-build-flags)))))
+      ; TODO "targetType": "sourceLibrary"
+      (system* "dub" "run") ; might fail for "targetType": "library"
+      status)))
+
+(define* (check #:key tests? #:allow-other-keys)
+  (if tests?
+    (zero? (system* "dub" "test"))
+    #t))
+
+(define* (install #:key inputs outputs #:allow-other-keys)
+  "Install a given DUB package (as source)."
+  (let* ((out (assoc-ref outputs "out"))
+         (outbin (string-append out "/bin"))
+         (src (assoc-ref inputs "source"))
+         (rsrc (string-append (assoc-ref outputs "src")
+                              "/lib/d")))
+    (mkdir-p outbin)
+    ;; TODO remove "-test-application"
+    (copy-recursively "bin" outbin)
+    (mkdir-p rsrc)
+    (delete-file-recursively "vendor") ; contains timestamps
+    (copy-recursively "." (string-append rsrc))
+    #t))
+
+(define %standard-phases
+  (modify-phases gnu:%standard-phases
+    (replace 'configure configure)
+    (replace 'build build)
+    (replace 'check check)
+    (replace 'install install)))
+
+(define* (dub-build #:key inputs (phases %standard-phases)
+                      #:allow-other-keys #:rest args)
+  "Build the given DUB package, applying all of PHASES in order."
+  (apply gnu:gnu-build #:inputs inputs #:phases phases args))
+
+;;; dub-build-system.scm ends here

Re: [PATCH v2 1/2] gnu: Add dub.

[Ludovic Courtès]

Danny Milosavljevic <dannym@scratchpost.org> skribis:

> * gnu/packages/ldc.scm (dub): New variable.

[...]

> +       (modify-phases %standard-phases
> +         (delete 'configure)
> +         (replace 'build
> +           (lambda _
> +             (zero? (system* "./build.sh"))))
> +         (replace 'install
> +           (lambda* (#:key outputs #:allow-other-keys)
> +             (let* ((out (assoc-ref outputs "out"))
> +                    (outbin (string-append out "/bin")))
> +               (mkdir-p outbin)
> +               (install-file "bin/dub" outbin)))))))

Please add #t at the end of this lambda, to denote success.

Otherwise LGTM, thanks!

Ludo’.

Re: [PATCH v2 1/2] gnu: Add dub.

[Pjotr Prins]

Great work!

On Mon, Jan 23, 2017 at 11:46:25PM +0100, Ludovic Courtès wrote:
> Danny Milosavljevic <dannym@scratchpost.org> skribis:
> 
> > * gnu/packages/ldc.scm (dub): New variable.
> 
> [...]
> 
> > +       (modify-phases %standard-phases
> > +         (delete 'configure)
> > +         (replace 'build
> > +           (lambda _
> > +             (zero? (system* "./build.sh"))))
> > +         (replace 'install
> > +           (lambda* (#:key outputs #:allow-other-keys)
> > +             (let* ((out (assoc-ref outputs "out"))
> > +                    (outbin (string-append out "/bin")))
> > +               (mkdir-p outbin)
> > +               (install-file "bin/dub" outbin)))))))
> 
> Please add #t at the end of this lambda, to denote success.
> 
> Otherwise LGTM, thanks!
> 
> Ludo’.
> 

-- 

Re: [PATCH v2 1/2] gnu: Add dub.

[Danny Milosavljevic]

Pushed, commit 4fdcc5026fb6a1fe007363eb32af891f35704e28.