* [PATCH] gnu: services: Add dicod-service.
@ 2016-06-03 15:56 宋文武
2016-06-04 22:43 ` Ludovic Courtès
0 siblings, 1 reply; 4+ messages in thread
From: 宋文武 @ 2016-06-03 15:56 UTC (permalink / raw)
To: guix-devel; +Cc: 宋文武
* gnu/services/dict.scm: New file.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
* doc/guix.texi (Various Services): Document it.
---
doc/guix.texi | 8 ++++
gnu/local.mk | 1 +
gnu/services/dict.scm | 126 ++++++++++++++++++++++++++++++++++++++++++++++++++
3 files changed, 135 insertions(+)
create mode 100644 gnu/services/dict.scm
diff --git a/doc/guix.texi b/doc/guix.texi
index c8c7555..76579be 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -9388,6 +9388,14 @@ Finally, @var{extra-options} is a list of additional command-line options
passed to @command{lircd}.
@end deffn
+The @code{(gnu services dict)} module provides the following service:
+
+@deffn {Scheme Procedure} dicod-service [#:config (dicod-configuration)]
+Return a service that runs the dicod daemon, an implementation of
+DICT server. The optional CONFIG argument specifies the configuration
+for dicod, which should be a <dicod-configuration> object, by default
+it serving the GNU Collaborative International Dictonary of English.
+@end deffn
@node Setuid Programs
@subsection Setuid Programs
diff --git a/gnu/local.mk b/gnu/local.mk
index 59aaccc..ae82149 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -373,6 +373,7 @@ GNU_SYSTEM_MODULES = \
%D%/services/databases.scm \
%D%/services/dbus.scm \
%D%/services/desktop.scm \
+ %D%/services/dict.scm \
%D%/services/lirc.scm \
%D%/services/mail.scm \
%D%/services/networking.scm \
diff --git a/gnu/services/dict.scm b/gnu/services/dict.scm
new file mode 100644
index 0000000..eaba6cc
--- /dev/null
+++ b/gnu/services/dict.scm
@@ -0,0 +1,126 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2016 Sou Bunnbu <iyzsong@gmail.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+;;;
+;;; Some of the help text was taken from the default dovecot.conf files.
+
+(define-module (gnu services dict)
+ #:use-module (guix gexp)
+ #:use-module (guix records)
+ #:use-module (gnu services)
+ #:use-module (gnu services shepherd)
+ #:use-module (gnu system shadow)
+ #:use-module ((gnu packages admin) #:select (shadow))
+ #:use-module (gnu packages dico)
+ #:use-module (gnu packages dictionaries)
+ #:use-module (srfi srfi-1)
+ #:use-module (srfi srfi-26)
+ #:use-module (ice-9 match)
+ #:export (dicod-service
+ dicod-configuration
+ dicod-database
+ %dicod-database:gcide))
+
+\f
+;;;
+;;; GNU Dico.
+;;;
+
+(define-record-type* <dicod-configuration>
+ dicod-configuration make-dicod-configuration
+ dicod-configuration?
+ (dico dicod-configuration-dico (default dico))
+ (databases dicod-configuration-databases
+ ;; list of <dicod-database>
+ (default (list %dicod-database:gcide))))
+
+(define-record-type* <dicod-database>
+ dicod-database make-dicod-database
+ dicod-database?
+ (name dicod-database-name)
+ (module dicod-database-module)
+ (options dicod-database-options (default '())))
+
+(define %dicod-database:gcide
+ (dicod-database
+ (name "gcide")
+ (module "gcide")
+ (options (list #~(string-append "dbdir=" #$gcide "/share/gcide")
+ "idxdir=/var/run/dicod"))))
+
+(define %dicod-accounts
+ (list (user-group
+ (name "dicod")
+ (system? #t))
+ (user-account
+ (name "dicod")
+ (group "dicod")
+ (system? #t)
+ (home-directory "/var/empty")
+ (shell #~(string-append #$shadow "/sbin/nologin")))))
+
+(define (dicod-configuration-file config)
+ (define dicod-configuration->text
+ (match-lambda
+ (($ <dicod-configuration> dico databases)
+ (append-map (match-lambda
+ (($ <dicod-database> name module options)
+ `("
+load-module " ,module ";
+database {
+ name \"" ,name "\";
+ handler \"" ,module
+ ;; append the options list using space as separator before each element.
+ ,@(fold-right (cut cons* " " <> <>) '() options) "\";
+}\n")))
+ databases))))
+ (apply mixed-text-file "dicod.conf" (dicod-configuration->text config)))
+
+(define %dicod-activation
+ #~(begin
+ (use-modules (guix build utils))
+ (let ((user (getpwnam "dicod"))
+ (rundir "/var/run/dicod"))
+ (mkdir-p rundir)
+ (chown rundir (passwd:uid user) (passwd:gid user)))))
+
+(define (dicod-shepherd-service config)
+ (list (shepherd-service
+ (provision '(dicod))
+ (documentation "Run the dicod daemon.")
+ (start #~(make-forkexec-constructor
+ (list (string-append #$dico "/bin/dicod") "--foreground"
+ (string-append
+ "--config=" #$(dicod-configuration-file config)))
+ #:user "dicod" #:group "dicod"))
+ (stop #~(make-kill-destructor)))))
+
+(define dicod-service-type
+ (service-type
+ (name 'dict)
+ (extensions
+ (list (service-extension account-service-type
+ (const %dicod-accounts))
+ (service-extension activation-service-type
+ (const %dicod-activation))
+ (service-extension shepherd-root-service-type
+ dicod-shepherd-service)))))
+
+(define* (dicod-service #:key (config (dicod-configuration)))
+ "Return a service that runs the dicod daemon, an implementation of
+DICT server."
+ (service dicod-service-type config))
--
2.6.3
^ permalink raw reply related [flat|nested] 4+ messages in thread
* Re: [PATCH] gnu: services: Add dicod-service.
2016-06-03 15:56 [PATCH] gnu: services: Add dicod-service 宋文武
@ 2016-06-04 22:43 ` Ludovic Courtès
2016-06-05 5:51 ` 宋文武
0 siblings, 1 reply; 4+ messages in thread
From: Ludovic Courtès @ 2016-06-04 22:43 UTC (permalink / raw)
To: 宋文武; +Cc: guix-devel
宋文武 <iyzsong@gmail.com> skribis:
> * gnu/services/dict.scm: New file.
> * gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
> * doc/guix.texi (Various Services): Document it.
Nice! I’ve been wanting it for some time. :-)
> +@deffn {Scheme Procedure} dicod-service [#:config (dicod-configuration)]
> +Return a service that runs the dicod daemon, an implementation of
@command{dicod}
> +DICT server.
^
Add @pxref{Dicod,,, dico, GNU Dico Manual}
> The optional CONFIG argument specifies the configuration
@var{config}
> +for dicod, which should be a <dicod-configuration> object, by default
@command{dicod}, @code{<dicod-configuration>}
> +it serving the GNU Collaborative International Dictonary of English.
s/it serving/it serves/.
It would be nice to document ‘dicod-configuration’ with @deftp, as done
in some other places.
Also, maybe we should mention or cross-reference how to configure dico
to connect to localhost, since the default is to connect elsewhere;
WDYT?
> + (($ <dicod-database> name module options)
> + `("
> +load-module " ,module ";
> +database {
> + name \"" ,name "\";
> + handler \"" ,module
> + ;; append the options list using space as separator before each element.
> + ,@(fold-right (cut cons* " " <> <>) '() options) "\";
> +}\n")))
> + databases))))
Maybe (string-join (fold-right cons '() options)) instead.
> +(define* (dicod-service #:key (config (dicod-configuration)))
> + "Return a service that runs the dicod daemon, an implementation of
> +DICT server."
Use the guix.texi doc as a docstring.
Thank you!
Ludo’.
^ permalink raw reply [flat|nested] 4+ messages in thread
* Re: [PATCH] gnu: services: Add dicod-service.
2016-06-04 22:43 ` Ludovic Courtès
@ 2016-06-05 5:51 ` 宋文武
2016-06-05 12:48 ` Ludovic Courtès
0 siblings, 1 reply; 4+ messages in thread
From: 宋文武 @ 2016-06-05 5:51 UTC (permalink / raw)
To: Ludovic Courtès; +Cc: guix-devel
ludo@gnu.org (Ludovic Courtès) writes:
> 宋文武 <iyzsong@gmail.com> skribis:
>
>> * gnu/services/dict.scm: New file.
>> * gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
>> * doc/guix.texi (Various Services): Document it.
>
> Nice! I’ve been wanting it for some time. :-)
>
>> +@deffn {Scheme Procedure} dicod-service [#:config (dicod-configuration)]
>> +Return a service that runs the dicod daemon, an implementation of
>
> @command{dicod}
>
>> +DICT server.
> ^
> Add @pxref{Dicod,,, dico, GNU Dico Manual}
>
>> The optional CONFIG argument specifies the configuration
>
> @var{config}
>
>> +for dicod, which should be a <dicod-configuration> object, by default
>
> @command{dicod}, @code{<dicod-configuration>}
>
>> +it serving the GNU Collaborative International Dictonary of English.
>
> s/it serving/it serves/.
>
> It would be nice to document ‘dicod-configuration’ with @deftp, as done
> in some other places.
>
> Also, maybe we should mention or cross-reference how to configure dico
> to connect to localhost, since the default is to connect elsewhere;
> WDYT?
>
>> + (($ <dicod-database> name module options)
>> + `("
>> +load-module " ,module ";
>> +database {
>> + name \"" ,name "\";
>> + handler \"" ,module
>> + ;; append the options list using space as separator before each element.
>> + ,@(fold-right (cut cons* " " <> <>) '() options) "\";
>> +}\n")))
>> + databases))))
>
> Maybe (string-join (fold-right cons '() options)) instead.
>
>> +(define* (dicod-service #:key (config (dicod-configuration)))
>> + "Return a service that runs the dicod daemon, an implementation of
>> +DICT server."
>
> Use the guix.texi doc as a docstring.
All done, thanks for the review and guide!
^ permalink raw reply [flat|nested] 4+ messages in thread
* Re: [PATCH] gnu: services: Add dicod-service.
2016-06-05 5:51 ` 宋文武
@ 2016-06-05 12:48 ` Ludovic Courtès
0 siblings, 0 replies; 4+ messages in thread
From: Ludovic Courtès @ 2016-06-05 12:48 UTC (permalink / raw)
To: 宋文武; +Cc: guix-devel
iyzsong@member.fsf.org (宋文武) skribis:
> ludo@gnu.org (Ludovic Courtès) writes:
>
>> 宋文武 <iyzsong@gmail.com> skribis:
>>
>>> * gnu/services/dict.scm: New file.
>>> * gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
>>> * doc/guix.texi (Various Services): Document it.
>>
>> Nice! I’ve been wanting it for some time. :-)
>>
>>> +@deffn {Scheme Procedure} dicod-service [#:config (dicod-configuration)]
>>> +Return a service that runs the dicod daemon, an implementation of
>>
>> @command{dicod}
>>
>>> +DICT server.
>> ^
>> Add @pxref{Dicod,,, dico, GNU Dico Manual}
>>
>>> The optional CONFIG argument specifies the configuration
>>
>> @var{config}
>>
>>> +for dicod, which should be a <dicod-configuration> object, by default
>>
>> @command{dicod}, @code{<dicod-configuration>}
>>
>>> +it serving the GNU Collaborative International Dictonary of English.
>>
>> s/it serving/it serves/.
>>
>> It would be nice to document ‘dicod-configuration’ with @deftp, as done
>> in some other places.
>>
>> Also, maybe we should mention or cross-reference how to configure dico
>> to connect to localhost, since the default is to connect elsewhere;
>> WDYT?
>>
>>> + (($ <dicod-database> name module options)
>>> + `("
>>> +load-module " ,module ";
>>> +database {
>>> + name \"" ,name "\";
>>> + handler \"" ,module
>>> + ;; append the options list using space as separator before each element.
>>> + ,@(fold-right (cut cons* " " <> <>) '() options) "\";
>>> +}\n")))
>>> + databases))))
>>
>> Maybe (string-join (fold-right cons '() options)) instead.
>>
>>> +(define* (dicod-service #:key (config (dicod-configuration)))
>>> + "Return a service that runs the dicod daemon, an implementation of
>>> +DICT server."
>>
>> Use the guix.texi doc as a docstring.
>
> All done, thanks for the review and guide!
Awesome. :-)
Ludo’.
^ permalink raw reply [flat|nested] 4+ messages in thread
end of thread, other threads:[~2016-06-05 12:48 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2016-06-03 15:56 [PATCH] gnu: services: Add dicod-service 宋文武
2016-06-04 22:43 ` Ludovic Courtès
2016-06-05 5:51 ` 宋文武
2016-06-05 12:48 ` Ludovic Courtès
Code repositories for project(s) associated with this external index
https://git.savannah.gnu.org/cgit/guix.git
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.