[PATCH] guix: Add downloader for Mercurial repositories.

[PATCH] guix: Add downloader for Mercurial repositories.

[Ricardo Wurmus]

* guix/build/hg.scm: New file.
* guix/hg-download.scm: New file.
* Makefile.am (MODULES): Add them.
---
 Makefile.am          |  2 ++
 guix/build/hg.scm    | 51 +++++++++++++++++++++++++++++++
 guix/hg-download.scm | 85 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 138 insertions(+)
 create mode 100644 guix/build/hg.scm
 create mode 100644 guix/hg-download.scm

diff --git a/Makefile.am b/Makefile.am
index 50cde52..8fd1c1b 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -43,6 +43,7 @@ MODULES =					\
   guix/sets.scm					\
   guix/download.scm				\
   guix/git-download.scm				\
+  guix/hg-download.scm				\
   guix/monads.scm				\
   guix/monad-repl.scm				\
   guix/gexp.scm					\
@@ -82,6 +83,7 @@ MODULES =					\
   guix/build/cmake-build-system.scm		\
   guix/build/emacs-build-system.scm		\
   guix/build/git.scm				\
+  guix/build/hg.scm				\
   guix/build/glib-or-gtk-build-system.scm	\
   guix/build/gnu-build-system.scm		\
   guix/build/gnu-dist.scm			\
diff --git a/guix/build/hg.scm b/guix/build/hg.scm
new file mode 100644
index 0000000..ae4574d
--- /dev/null
+++ b/guix/build/hg.scm
@@ -0,0 +1,51 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2016 Ricardo Wurmus <rekado@elephly.net>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build hg)
+  #:use-module (guix build utils)
+  #:export (hg-fetch))
+
+;;; Commentary:
+;;;
+;;; This is the build-side support code of (guix hg-download).  It allows a
+;;; Mercurial repository to be cloned and checked out at a specific changeset
+;;; identifier.
+;;;
+;;; Code:
+
+(define* (hg-fetch url changeset directory
+                   #:key (hg-command "hg"))
+  "Fetch CHANGESET from URL into DIRECTORY.  CHANGESET must be a valid
+Mercurial changeset identifier.  Return #t on success, #f otherwise."
+
+  (and (zero? (system* hg-command
+                       "clone" url
+                       "--rev" changeset
+                       ;; Disable TLS certificate verification.  The hash of
+                       ;; the checkout is known in advance anyway.
+                       "--insecure"
+                       directory))
+       (with-directory-excursion directory
+         (begin
+           ;; The contents of '.hg' vary as a function of the current
+           ;; status of the Mercurial repo.  Since we want a fixed
+           ;; output, this directory needs to be taken out.
+           (delete-file-recursively ".hg")
+           #t))))
+
+;;; hg.scm ends here
diff --git a/guix/hg-download.scm b/guix/hg-download.scm
new file mode 100644
index 0000000..bcc45ef
--- /dev/null
+++ b/guix/hg-download.scm
@@ -0,0 +1,85 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2014, 2015 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2016 Ricardo Wurmus <rekado@elephly.net>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix hg-download)
+  #:use-module (guix gexp)
+  #:use-module (guix store)
+  #:use-module (guix monads)
+  #:use-module (guix records)
+  #:use-module (guix packages)
+  #:autoload   (guix build-system gnu) (standard-packages)
+  #:use-module (ice-9 match)
+  #:export (hg-reference
+            hg-reference?
+            hg-reference-url
+            hg-reference-changeset
+            hg-reference-recursive?
+
+            hg-fetch))
+
+;;; Commentary:
+;;;
+;;; An <origin> method that fetches a specific changeset from a Mercurial
+;;; repository.  The repository URL and changeset ID are specified with a
+;;; <hg-reference> object.
+;;;
+;;; Code:
+
+(define-record-type* <hg-reference>
+  hg-reference make-hg-reference
+  hg-reference?
+  (url        hg-reference-url)
+  (changeset  hg-reference-changeset))
+
+(define (hg-package)
+  "Return the default Mercurial package."
+  (let ((distro (resolve-interface '(gnu packages version-control))))
+    (module-ref distro 'mercurial)))
+
+(define* (hg-fetch ref hash-algo hash
+                   #:optional name
+                   #:key (system (%current-system)) (guile (default-guile))
+                   (hg (hg-package)))
+  "Return a fixed-output derivation that fetches REF, a <hg-reference>
+object.  The output is expected to have recursive hash HASH of type
+HASH-ALGO (a symbol).  Use NAME as the file name, or a generic name if #f."
+  (define build
+    #~(begin
+        (use-modules (guix build hg)
+                     (guix build utils)
+                     (ice-9 match))
+
+        (hg-fetch '#$(hg-reference-url ref)
+                  '#$(hg-reference-changeset ref)
+                  #$output
+                  #:hg-command (string-append #+hg "/bin/hg"))))
+
+  (mlet %store-monad ((guile (package->derivation guile system)))
+    (gexp->derivation (or name "hg-checkout") build
+                      #:system system
+                      #:local-build? #t           ;don't offload repo cloning
+                      #:hash-algo hash-algo
+                      #:hash hash
+                      #:recursive? #t
+                      #:modules '((guix build hg)
+                                  (guix build utils))
+                      #:guile-for-build guile
+                      #:local-build? #t)))
+
+;;; hg-download.scm ends here
-- 
2.8.4

Re: [PATCH] guix: Add downloader for Mercurial repositories.

[Ludovic Courtès]

Ricardo Wurmus <ricardo.wurmus@mdc-berlin.de> skribis:

> * guix/build/hg.scm: New file.
> * guix/hg-download.scm: New file.
> * Makefile.am (MODULES): Add them.

[...]

> +    (gexp->derivation (or name "hg-checkout") build
> +                      #:system system
> +                      #:local-build? #t           ;don't offload repo cloning
> +                      #:hash-algo hash-algo
> +                      #:hash hash
> +                      #:recursive? #t
> +                      #:modules '((guix build hg)
> +                                  (guix build utils))
> +                      #:guile-for-build guile
> +                      #:local-build? #t)))

Apart from the duplicate #:local-build? that Efraim reported on IRC,
this looks all good!

Danke,
Ludo’.

Re: [PATCH] guix: Add downloader for Mercurial repositories.

[Ricardo Wurmus]

Ludovic Courtès <ludo@gnu.org> writes:

> Ricardo Wurmus <ricardo.wurmus@mdc-berlin.de> skribis:
>
>> * guix/build/hg.scm: New file.
>> * guix/hg-download.scm: New file.
>> * Makefile.am (MODULES): Add them.
>
> [...]
>
>> +    (gexp->derivation (or name "hg-checkout") build
>> +                      #:system system
>> +                      #:local-build? #t           ;don't offload repo cloning
>> +                      #:hash-algo hash-algo
>> +                      #:hash hash
>> +                      #:recursive? #t
>> +                      #:modules '((guix build hg)
>> +                                  (guix build utils))
>> +                      #:guile-for-build guile
>> +                      #:local-build? #t)))
>
> Apart from the duplicate #:local-build? that Efraim reported on IRC,
> this looks all good!

Thanks.  I removed the second “#:local-build?” (someone™ should also
remove it from “git-download.scm” which served as a template) and pushed
to master.

~~ Ricardo