[bug#27474] [PATCH] services: Add 'sysctl-service-type'.

[bug#27474] [PATCH] services: Add 'sysctl-service-type'.

[宋文武]

* gnu/services/sysctl.scm: New file.
* doc/guix.texi (Miscellaneous Services): Document it.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
---
 doc/guix.texi           | 29 +++++++++++++++++++
 gnu/local.mk            |  1 +
 gnu/services/sysctl.scm | 77 +++++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 107 insertions(+)
 create mode 100644 gnu/services/sysctl.scm

diff --git a/doc/guix.texi b/doc/guix.texi
index 729ec081b..c2652a61c 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -15277,6 +15277,35 @@ Package object of thermald.
 @node Miscellaneous Services
 @subsubsection Miscellaneous Services
 
+@cindex sysctl
+@subsubheading System Control Service
+
+The @code{(gnu services sysctl)} provides a service to configure kernel
+parameters at boot.
+
+@defvr {Scheme Variable} sysctl-service-type
+The service type for @command{sysctl}, which modifies kernel parameters
+under @file{/proc/sys/}.  To enable IPv4 forwarding, it can be
+instantiated as:
+
+@example
+(service sysctl-service-type
+         (sysctl-configuration
+           (settings '(("net.ipv4.ip_forward" . "1")))))
+@end example
+@end defvr
+
+@deftp {Data Type} sysctl-configuration
+The data type representing the configuration of @command{sysctl}.
+
+@table @asis
+@item @code{sysctl} (default: @code{(file-append procps "/sbin/sysctl"})
+The @command{sysctl} executable to use.
+
+@item @code{settings} (default: @code{'()})
+An association list specifies kernel parameters and their values.
+@end table
+@end deftp
 
 @cindex lirc
 @subsubheading Lirc Service
diff --git a/gnu/local.mk b/gnu/local.mk
index a4b29d5fd..ee63f0f20 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -442,6 +442,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/services/sddm.scm				\
   %D%/services/spice.scm				\
   %D%/services/ssh.scm				\
+  %D%/services/sysctl.scm			\
   %D%/services/version-control.scm              \
   %D%/services/vpn.scm				\
   %D%/services/web.scm				\
diff --git a/gnu/services/sysctl.scm b/gnu/services/sysctl.scm
new file mode 100644
index 000000000..be5be59a0
--- /dev/null
+++ b/gnu/services/sysctl.scm
@@ -0,0 +1,77 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2017 Sou Bunnbu <iyzsong@member.fsf.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu services sysctl)
+  #:use-module (gnu services)
+  #:use-module (gnu services shepherd)
+  #:use-module (gnu packages linux)
+  #:use-module (guix gexp)
+  #:use-module (guix records)
+  #:use-module (srfi srfi-1)
+  #:use-module (ice-9 match)
+  #:export (sysctl-configuration
+            sysctl-service-type))
+
+\f
+;;;
+;;; System Control Service.
+;;;
+
+(define-record-type* <sysctl-configuration>
+  sysctl-configuration make-sysctl-configuration?
+  sysctl-configuration?
+  (sysctl   sysctl-configuration-sysctl    ; path of the 'sysctl' command
+            (default (file-append procps "/sbin/sysctl")))
+  (settings sysctl-configuration-settings  ; alist of string pairs
+            (default '())))
+
+(define (sysctl-configuration-settings->sysctl.conf settings)
+  "Return a file for @command{sysctl} to set kernel parameters as specified by
+@var{settings}."
+  (apply mixed-text-file "sysctl.conf"
+         (append-map (match-lambda
+                       ((key . value)
+                        (list key "=" value "\n")))
+                     settings)))
+
+(define sysctl-shepherd-service
+  (match-lambda
+    (($ <sysctl-configuration> sysctl settings)
+     (let ((sysctl.conf
+            (sysctl-configuration-settings->sysctl.conf settings)))
+       (shepherd-service
+        (documentation "Configure kernel parameters at boot.")
+        (provision '(sysctl))
+        (start #~(lambda _
+                   (zero? (system* #$sysctl "--load" #$sysctl.conf))))
+        (stop #~(const #t))
+        (respawn? #f))))))
+
+(define sysctl-service-type
+  (service-type
+   (name 'sysctl)
+   (extensions
+    (list (service-extension shepherd-root-service-type
+                             (compose list sysctl-shepherd-service))))
+   (compose concatenate)
+   (extend (lambda (config settings)
+             (sysctl-configuration
+              (inherit config)
+              (settings (append (sysctl-configuration-settings config)
+                                settings)))))
+   (default-value (sysctl-configuration))))
-- 
2.12.2

bug#27474: pushed

[宋文武]

Pushed as 296bf4d5ab1cf7822956205b6d266c2c67ce056c.