[bug#31297] [PATCH] gnu: Add sound service.

[bug#31297] [PATCH] gnu: Add sound service.

[Oleg Pykhalov]

* gnu/services/sound.scm: New file.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add this.
* doc/guix.texi (Sound Services): New chapter.
---
 doc/guix.texi          | 33 +++++++++++++++
 gnu/local.mk           |  1 +
 gnu/services/sound.scm | 95 ++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 129 insertions(+)
 create mode 100644 gnu/services/sound.scm

diff --git a/doc/guix.texi b/doc/guix.texi
index 75886e94b..b057f67cb 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -235,6 +235,7 @@ Services
 * X Window::                    Graphical display.
 * Printing Services::           Local and remote printer support.
 * Desktop Services::            D-Bus and desktop services.
+* Sound Services::              ALSA and Pulseaudio services.
 * Database Services::           SQL databases, key-value stores, etc.
 * Mail Services::               IMAP, POP3, SMTP, and all that.
 * Messaging Services::          Messaging services.
@@ -9697,6 +9698,7 @@ declaration.
 * X Window::                    Graphical display.
 * Printing Services::           Local and remote printer support.
 * Desktop Services::            D-Bus and desktop services.
+* Sound Services::              ALSA and Pulseaudio services.
 * Database Services::           SQL databases, key-value stores, etc.
 * Mail Services::               IMAP, POP3, SMTP, and all that.
 * Messaging Services::          Messaging services.
@@ -12804,6 +12806,37 @@ bluetooth keyboard or mouse.
 Users need to be in the @code{lp} group to access the D-Bus service.
 @end deffn
 
+@node Sound Services
+@subsubsection Sound Services
+
+The @code{(gnu services alsa)} module provides an
+@code{alsa-service-type} service to generate an ALSA
+@file{/etc/asound.conf} configuration file.
+
+@deffn {Scheme Variable} alsa-service-type
+This is the type for the @uref{https://alsa-project.org/, alsa},
+@command{alsa-configuration} record as in this example:
+
+@example
+(service alsa-service-type)
+@end example
+
+See below for details about @code{alsa-configuration}.
+@end deffn
+
+@deftp {Data Type} alsa-configuration
+Data type representing the configuration for @code{alsa-service}.
+
+@table @asis
+@item @code{pulseaudio?} (default: @var{#t})
+Whether to use Pulseaudio for configuring ALSA to use PulseAudio.
+
+@item @code{extra-options} (default: @var{#f})
+Extra options is a string which will be appended to asound.conf file.
+
+@end table
+@end deftp
+
 @node Database Services
 @subsubsection Database Services
 
diff --git a/gnu/local.mk b/gnu/local.mk
index cbf2c6f1b..b649ae008 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -480,6 +480,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/services/networking.scm			\
   %D%/services/nfs.scm			\
   %D%/services/shepherd.scm			\
+  %D%/services/sound.scm			\
   %D%/services/herd.scm				\
   %D%/services/pm.scm				\
   %D%/services/rsync.scm			\
diff --git a/gnu/services/sound.scm b/gnu/services/sound.scm
new file mode 100644
index 000000000..b34e0efc1
--- /dev/null
+++ b/gnu/services/sound.scm
@@ -0,0 +1,95 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2018 Oleg Pykhalov <go.wigust@gmail.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu services sound)
+  #:use-module (gnu services base)
+  #:use-module (gnu services configuration)
+  #:use-module (gnu services shepherd)
+  #:use-module (gnu services web)
+  #:use-module (gnu services)
+  #:use-module (gnu system shadow)
+  #:use-module (guix gexp)
+  #:use-module (guix packages)
+  #:use-module (guix records)
+  #:use-module (guix store)
+  #:use-module (gnu packages pulseaudio)
+  #:use-module (ice-9 match)
+  #:export (alsa-configuration
+            alsa-service-type))
+
+;;; Commentary:
+;;;
+;;; Sound services.
+;;;
+;;; Code:
+
+\f
+;;;
+;;; ALSA
+;;;
+
+(define-record-type* <alsa-configuration>
+  alsa-configuration make-alsa-configuration alsa-configuration?
+  (pulseaudio?   alsa-configuration-pulseaudio? ;boolean
+                 (default #t))
+  (extra-options alsa-configuration-extra-options ;string
+                 (default #f)))
+
+(define (alsa-config-file config)
+  "Return the ALSA configuration file corresponding to CONFIG."
+  (computed-file
+   "asound.conf"
+   #~(call-with-output-file #$output
+       (lambda (port)
+         (display "# Generated by 'alsa-service'.\n\n" port)
+         (when #$(alsa-configuration-pulseaudio? config)
+           (display "# Use PulseAudio by default
+pcm.!default {
+  type pulse
+  fallback \"sysdefault\"
+  hint {
+    show on
+    description \"Default ALSA Output (currently PulseAudio Sound Server)\"
+  }
+}
+
+ctl.!default {
+  type pulse
+  fallback \"sysdefault\"
+}
+"
+                    port))
+         (let ((extra-options #$(alsa-configuration-extra-options config)))
+           (when extra-options (display extra-options port)))))))
+
+(define (alsa-activation config)
+  "Return the activation GEXP for CONFIG."
+  (with-imported-modules '((guix build utils))
+    #~(begin
+        (use-modules (guix build utils))
+        (copy-file #$(alsa-config-file config) "/etc/asound.conf"))))
+
+(define alsa-service-type
+  (service-type
+   (name 'alsa)
+   (extensions
+    (list (service-extension activation-service-type alsa-activation)))
+   (default-value (alsa-configuration))
+   (description "Configure the alsa.")))
+
+;;; alsa.scm ends here
-- 
2.17.0

[bug#31297] [PATCH] gnu: Add sound service.

[Ludovic Courtès]

Hello,

Oleg Pykhalov <go.wigust@gmail.com> skribis:

> * gnu/services/sound.scm: New file.
> * gnu/local.mk (GNU_SYSTEM_MODULES): Add this.
> * doc/guix.texi (Sound Services): New chapter.

[...]

> +@node Sound Services
> +@subsubsection Sound Services
> +
> +The @code{(gnu services alsa)} module provides an
> +@code{alsa-service-type} service to generate an ALSA
> +@file{/etc/asound.conf} configuration file.

Is this file required to get PulseAudio support?  I realize I have
~/.asoundrc that’s similar to what this new service does, so it may be
that I simply forgot that things wouldn’t work well without it.

> +@deffn {Scheme Variable} alsa-service-type
> +This is the type for the @uref{https://alsa-project.org/, alsa},

s/alsa/ALSA/


> +(define-record-type* <alsa-configuration>
> +  alsa-configuration make-alsa-configuration alsa-configuration?
> +  (pulseaudio?   alsa-configuration-pulseaudio? ;boolean
> +                 (default #t))
> +  (extra-options alsa-configuration-extra-options ;string
> +                 (default #f)))

s/#f/""/ since it’s a string.

> +(define (alsa-config-file config)
> +  "Return the ALSA configuration file corresponding to CONFIG."
> +  (computed-file
> +   "asound.conf"
> +   #~(call-with-output-file #$output
> +       (lambda (port)
> +         (display "# Generated by 'alsa-service'.\n\n" port)
> +         (when #$(alsa-configuration-pulseaudio? config)
> +           (display "# Use PulseAudio by default
> +pcm.!default {
> +  type pulse
> +  fallback \"sysdefault\"
> +  hint {
> +    show on
> +    description \"Default ALSA Output (currently PulseAudio Sound Server)\"
> +  }
> +}
> +
> +ctl.!default {
> +  type pulse
> +  fallback \"sysdefault\"
> +}
> +"
> +                    port))
> +         (let ((extra-options #$(alsa-configuration-extra-options config)))
> +           (when extra-options (display extra-options port)))))))

I think you could instead write:

  (if (alsa-configuration-pulseaudio? config)
      (plain-file "asound.conf" (string-append "# Generated by…" extra-options))
      (plain-file "asound.conf" extra-options))

> +(define (alsa-activation config)
> +  "Return the activation GEXP for CONFIG."
> +  (with-imported-modules '((guix build utils))
> +    #~(begin
> +        (use-modules (guix build utils))
> +        (copy-file #$(alsa-config-file config) "/etc/asound.conf"))))

Please extend ‘etc-service-type’ instead.

> +(define alsa-service-type
> +  (service-type
> +   (name 'alsa)
> +   (extensions
> +    (list (service-extension activation-service-type alsa-activation)))
> +   (default-value (alsa-configuration))
> +   (description "Configure the alsa.")))

“Configure low-level Linux sound support, ALSA.”

Thanks,
Ludo’.

[bug#31297] [PATCH] gnu: Add sound service.

[Oleg Pykhalov]

[-- Attachment #1.1: Type: text/plain, Size: 1089 bytes --]

Hello Ludovic,

Thank you for review!

ludo@gnu.org (Ludovic Courtès) writes:

> Oleg Pykhalov <go.wigust@gmail.com> skribis:
>
>> * gnu/services/sound.scm: New file.
>> * gnu/local.mk (GNU_SYSTEM_MODULES): Add this.
>> * doc/guix.texi (Sound Services): New chapter.
>
> [...]
>
>> +@node Sound Services
>> +@subsubsection Sound Services
>> +
>> +The @code{(gnu services alsa)} module provides an
>> +@code{alsa-service-type} service to generate an ALSA
>> +@file{/etc/asound.conf} configuration file.
>
> Is this file required to get PulseAudio support?  I realize I have
> ~/.asoundrc that’s similar to what this new service does, so it may be
> that I simply forgot that things wouldn’t work well without it.

In case of existing ‘~/.asoundrc’ it's not required.  But I spent some
time to find a ‘asoundrc’ config and be glad if it was in a Guix manual.

[…]

I also replaced “to” with “by” in
“Whether to use Pulseaudio by configuring ALSA to use PulseAudio.”
                           ^^
sentence in Guix documentation.


[-- Attachment #1.2: gnu: Add sound service. --]
[-- Type: text/x-patch, Size: 6153 bytes --]

From 460fa678823a7cf3d2869a3e4beafb22e5a313fa Mon Sep 17 00:00:00 2001
From: Oleg Pykhalov <go.wigust@gmail.com>
Date: Sat, 28 Apr 2018 13:30:20 +0300
Subject: [PATCH] gnu: Add sound service.

* gnu/services/sound.scm: New file.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add this.
* doc/guix.texi (Sound Services): New chapter.
---
 doc/guix.texi          | 33 ++++++++++++++++
 gnu/local.mk           |  1 +
 gnu/services/sound.scm | 86 ++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 120 insertions(+)
 create mode 100644 gnu/services/sound.scm

diff --git a/doc/guix.texi b/doc/guix.texi
index 75886e94b..46855d945 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -235,6 +235,7 @@ Services
 * X Window::                    Graphical display.
 * Printing Services::           Local and remote printer support.
 * Desktop Services::            D-Bus and desktop services.
+* Sound Services::              ALSA and Pulseaudio services.
 * Database Services::           SQL databases, key-value stores, etc.
 * Mail Services::               IMAP, POP3, SMTP, and all that.
 * Messaging Services::          Messaging services.
@@ -9697,6 +9698,7 @@ declaration.
 * X Window::                    Graphical display.
 * Printing Services::           Local and remote printer support.
 * Desktop Services::            D-Bus and desktop services.
+* Sound Services::              ALSA and Pulseaudio services.
 * Database Services::           SQL databases, key-value stores, etc.
 * Mail Services::               IMAP, POP3, SMTP, and all that.
 * Messaging Services::          Messaging services.
@@ -12804,6 +12806,37 @@ bluetooth keyboard or mouse.
 Users need to be in the @code{lp} group to access the D-Bus service.
 @end deffn
 
+@node Sound Services
+@subsubsection Sound Services
+
+The @code{(gnu services alsa)} module provides an
+@code{alsa-service-type} service to generate an ALSA
+@file{/etc/asound.conf} configuration file.
+
+@deffn {Scheme Variable} alsa-service-type
+This is the type for the @uref{https://alsa-project.org/, ALSA},
+@command{alsa-configuration} record as in this example:
+
+@example
+(service alsa-service-type)
+@end example
+
+See below for details about @code{alsa-configuration}.
+@end deffn
+
+@deftp {Data Type} alsa-configuration
+Data type representing the configuration for @code{alsa-service}.
+
+@table @asis
+@item @code{pulseaudio?} (default: @var{#t})
+Whether to use Pulseaudio by configuring ALSA to use PulseAudio.
+
+@item @code{extra-options} (default: @var{#f})
+Extra options is a string which will be appended to asound.conf file.
+
+@end table
+@end deftp
+
 @node Database Services
 @subsubsection Database Services
 
diff --git a/gnu/local.mk b/gnu/local.mk
index cbf2c6f1b..b649ae008 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -480,6 +480,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/services/networking.scm			\
   %D%/services/nfs.scm			\
   %D%/services/shepherd.scm			\
+  %D%/services/sound.scm			\
   %D%/services/herd.scm				\
   %D%/services/pm.scm				\
   %D%/services/rsync.scm			\
diff --git a/gnu/services/sound.scm b/gnu/services/sound.scm
new file mode 100644
index 000000000..5fe555e8b
--- /dev/null
+++ b/gnu/services/sound.scm
@@ -0,0 +1,86 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2018 Oleg Pykhalov <go.wigust@gmail.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu services sound)
+  #:use-module (gnu services base)
+  #:use-module (gnu services configuration)
+  #:use-module (gnu services shepherd)
+  #:use-module (gnu services)
+  #:use-module (gnu system shadow)
+  #:use-module (guix gexp)
+  #:use-module (guix packages)
+  #:use-module (guix records)
+  #:use-module (guix store)
+  #:use-module (gnu packages pulseaudio)
+  #:use-module (ice-9 match)
+  #:export (alsa-configuration
+            alsa-service-type))
+
+;;; Commentary:
+;;;
+;;; Sound services.
+;;;
+;;; Code:
+
+\f
+;;;
+;;; ALSA
+;;;
+
+(define-record-type* <alsa-configuration>
+  alsa-configuration make-alsa-configuration alsa-configuration?
+  (pulseaudio?   alsa-configuration-pulseaudio? ;boolean
+                 (default #t))
+  (extra-options alsa-configuration-extra-options ;string
+                 (default "")))
+
+(define (alsa-config-file config)
+  "Return the ALSA configuration file corresponding to CONFIG."
+  (plain-file "asound.conf"
+              (string-append "# Generated by 'alsa-service'.\n\n"
+                             (if (alsa-configuration-pulseaudio? config)
+                                 "# Use PulseAudio by default
+pcm.!default {
+  type pulse
+  fallback \"sysdefault\"
+  hint {
+    show on
+    description \"Default ALSA Output (currently PulseAudio Sound Server)\"
+  }
+}
+
+ctl.!default {
+  type pulse
+  fallback \"sysdefault\"
+}
+"
+                                 "")
+                             (alsa-configuration-extra-options config))))
+
+(define (alsa-etc-service config)
+  (list `("asound.conf" ,(alsa-config-file config))))
+
+(define alsa-service-type
+  (service-type
+   (name 'alsa)
+   (extensions
+    (list (service-extension etc-service-type alsa-etc-service)))
+   (default-value (alsa-configuration))
+   (description "Configure low-level Linux sound support, ALSA.")))
+
+;;; sound.scm ends here
-- 
2.17.0


[-- Attachment #1.3: Type: text/plain, Size: 7 bytes --]


Oleg.

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 832 bytes --]

[bug#31297] [PATCH] gnu: Add sound service.

[Ludovic Courtès]

Hello Oleg,

Oleg Pykhalov <go.wigust@gmail.com> skribis:

> ludo@gnu.org (Ludovic Courtès) writes:
>
>> Oleg Pykhalov <go.wigust@gmail.com> skribis:
>>
>>> * gnu/services/sound.scm: New file.
>>> * gnu/local.mk (GNU_SYSTEM_MODULES): Add this.
>>> * doc/guix.texi (Sound Services): New chapter.
>>
>> [...]
>>
>>> +@node Sound Services
>>> +@subsubsection Sound Services
>>> +
>>> +The @code{(gnu services alsa)} module provides an
>>> +@code{alsa-service-type} service to generate an ALSA
>>> +@file{/etc/asound.conf} configuration file.
>>
>> Is this file required to get PulseAudio support?  I realize I have
>> ~/.asoundrc that’s similar to what this new service does, so it may be
>> that I simply forgot that things wouldn’t work well without it.
>
> In case of existing ‘~/.asoundrc’ it's not required.  But I spent some
> time to find a ‘asoundrc’ config and be glad if it was in a Guix manual.

Right, I agree.

> From 460fa678823a7cf3d2869a3e4beafb22e5a313fa Mon Sep 17 00:00:00 2001
> From: Oleg Pykhalov <go.wigust@gmail.com>
> Date: Sat, 28 Apr 2018 13:30:20 +0300
> Subject: [PATCH] gnu: Add sound service.
>
> * gnu/services/sound.scm: New file.
> * gnu/local.mk (GNU_SYSTEM_MODULES): Add this.
> * doc/guix.texi (Sound Services): New chapter.

[...]

> +@node Sound Services
> +@subsubsection Sound Services
> +

Maybe add “@cindex sound support”, “@cindex ALSA”, and
“@cindex PulseAudio, sound support”.

> +The @code{(gnu services alsa)} module provides an
                           ^^
“sound”

> +@code{alsa-service-type} service to generate an ALSA
> +@file{/etc/asound.conf} configuration file.

Perhaps add a sentence like: “This configuration file is what allows
applications that produce sound using ALSA to be correctly handled.”

> +@deftp {Data Type} alsa-configuration
> +Data type representing the configuration for @code{alsa-service}.
> +
> +@table @asis
> +@item @code{pulseaudio?} (default: @var{#t})
> +Whether to use Pulseaudio by configuring ALSA to use PulseAudio.

“Whether ALSA applications should transparently be made to use the
@uref{http://www.pulseaudio.org/, PulseAudio} sound server.

Using PulseAudio allows you to run several sound-producing applications
at the same time and to individual control them @i{via}
@command{pavucontrol}, among other things.”

> +@item @code{extra-options} (default: @var{#f})

default: @code{""}

> +Extra options is a string which will be appended to asound.conf file.

Just: “String to append to the @file{asound.conf} file.”

Apologies for not catching those earlier!

You can push with changes along these lines.

Thank you!

Ludo’.

[bug#31297] [PATCH] gnu: Add sound service.

[Ludovic Courtès]

Also, in a separate patch, it may be useful to add (service
alsa-service-type) to %desktop-services.

What do people think?

Thanks,
Ludo’.

[bug#31297] [PATCH] gnu: Add sound service.

[Marius Bakke]

[-- Attachment #1: Type: text/plain, Size: 334 bytes --]

Ludovic Courtès <ludo@gnu.org> writes:

> Also, in a separate patch, it may be useful to add (service
> alsa-service-type) to %desktop-services.
>
> What do people think?

I also had a ~/.asoundrc since forever that is very similar to the one
added by this service.  So it makes sense to provide it with
%desktop-services.

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 487 bytes --]

[bug#31297] [PATCH] gnu: Add sound service.

[Oleg Pykhalov]

[-- Attachment #1.1: Type: text/plain, Size: 288 bytes --]

“gnu: Add sound service.” pushed as
8cd1e8e84926dc6ed1012a17609dea2d20ac41b4

ludo@gnu.org (Ludovic Courtès) writes:

> Also, in a separate patch, it may be useful to add (service
> alsa-service-type) to %desktop-services.
>
> What do people think?

[…]

I'm agree.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.2: service: desktop: Add alsa-service-type. --]
[-- Type: text/x-patch, Size: 1057 bytes --]

From 47b00837a8109f4b18e1de28d6f1b72524af18a9 Mon Sep 17 00:00:00 2001
From: Oleg Pykhalov <go.wigust@gmail.com>
Date: Wed, 2 May 2018 15:01:37 +0300
Subject: [PATCH] services: desktop: Add alsa-service-type.

* gnu/services/desktop.scm (%desktop-services): Add 'alsa-service-type'.
---
 gnu/services/desktop.scm | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/gnu/services/desktop.scm b/gnu/services/desktop.scm
index 517d5d3ef..0dada8273 100644
--- a/gnu/services/desktop.scm
+++ b/gnu/services/desktop.scm
@@ -29,6 +29,7 @@
   #:use-module (gnu services avahi)
   #:use-module (gnu services xorg)
   #:use-module (gnu services networking)
+  #:use-module (gnu services sound)
   #:use-module ((gnu system file-systems)
                 #:select (%elogind-file-systems))
   #:use-module (gnu system shadow)
@@ -934,6 +935,8 @@ with the administrator's password."
 
          x11-socket-directory-service
 
+         (service alsa-service-type)
+
          %base-services))
 
 ;;; desktop.scm ends here
-- 
2.17.0


[-- Attachment #1.3: Type: text/plain, Size: 7 bytes --]


Oleg.

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 832 bytes --]

[bug#31297] [PATCH] gnu: Add sound service.

[Ludovic Courtès]

Oleg Pykhalov <go.wigust@gmail.com> skribis:

> From 47b00837a8109f4b18e1de28d6f1b72524af18a9 Mon Sep 17 00:00:00 2001
> From: Oleg Pykhalov <go.wigust@gmail.com>
> Date: Wed, 2 May 2018 15:01:37 +0300
> Subject: [PATCH] services: desktop: Add alsa-service-type.
>
> * gnu/services/desktop.scm (%desktop-services): Add 'alsa-service-type'.

LGTM, thank you!

Ludo’.

bug#31297: [PATCH] gnu: Add sound service.

[Oleg Pykhalov]

[-- Attachment #1: Type: text/plain, Size: 516 bytes --]

ludo@gnu.org (Ludovic Courtès) writes:

> Oleg Pykhalov <go.wigust@gmail.com> skribis:
>
>> From 47b00837a8109f4b18e1de28d6f1b72524af18a9 Mon Sep 17 00:00:00 2001
>> From: Oleg Pykhalov <go.wigust@gmail.com>
>> Date: Wed, 2 May 2018 15:01:37 +0300
>> Subject: [PATCH] services: desktop: Add alsa-service-type.
>>
>> * gnu/services/desktop.scm (%desktop-services): Add 'alsa-service-type'.
>
> LGTM, thank you!

Pushed as ef6a484475e7473131efd9a41473c1f25a6b0d0c

I'll close the bug report.

Oleg.

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 832 bytes --]