;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2016 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services mcron)
  #:use-module (gnu services)
  #:use-module (gnu services base)
  #:use-module (gnu services shepherd)
  #:autoload   (gnu packages guile) (mcron)
  #:use-module (guix records)
  #:use-module (guix gexp)
  #:use-module (srfi srfi-1)
  #:use-module (ice-9 match)
  #:use-module (ice-9 vlist)
  #:export (mcron-configuration
            mcron-configuration?
            mcron-configuration-mcron
            mcron-configuration-jobs

            mcron-job
            mcron-job?
            mcron-job-user
            mcron-job-group
            mcron-job-specification
            mcron-job-imported-modules
            mcron-job-modules

            mcron-service-type
            mcron-service))

;;; Commentary:
;;;
;;; This module implements a service that to run instances of GNU mcron, a
;;; periodic job execution daemon.  Example of a service:
;;
;; (service mcron-service-type
;;          (mcron-configuration
;;           (jobs (list (mcron-job
;;                        (user "alice")
;;                        (specification
;;                         #~(job next-second-from
;;                                (lambda ()
;;                                  (call-with-output-file "/dev/console"
;;                                    (lambda (port)
;;                                      (display "hello!\n" port)))))))))))
;;;
;;; Code:

(define-record-type* <mcron-configuration> mcron-configuration
  make-mcron-configuration
  mcron-configuration?
  (mcron             mcron-configuration-mcron    ;package
                     (default mcron))
  (jobs              mcron-configuration-jobs     ;list of <mcron-job>
                     (default '())))

(define-record-type* <mcron-job> mcron-job make-mcron-job
  mcron-job?
  (user              mcron-job-user (default "root"))  ;string
  (group             mcron-job-group (default #f))     ;string | #f
  (specification     mcron-job-specification)          ;gexp
  (imported-modules  mcron-job-imported-modules        ;list
                     (default '()))
  (modules           mcron-job-modules                 ;list
                     (default '())))

(define (job-file job)
  (scheme-file "mcron-job"
               (mcron-job-specification job)))

(define (mcron-shepherd-service mcron jobs)
  (match jobs
    ((($ <mcron-job> user group) _ ...)
     (shepherd-service
      (provision (list (string->symbol
                        (string-append "mcron-" user
                                       (if group
                                           (string-append "-" group)
                                           "")))))
      (requirement '(user-processes))
      (start #~(make-forkexec-constructor
                (list (string-append #$mcron "/bin/mcron")
                      #$@(map job-file jobs))
                #:user #$user
                #:group #$(if user
                              (or group
                                  #~(group:name
                                     (getgrgid (passwd:gid (getpw #$user)))))
                              group)))
      (stop #~(make-kill-destructor))))))

(define mcron-shepherd-services
  (match-lambda
    (($ <mcron-configuration> mcron jobs)
     (define sorted-jobs
       (fold (lambda (job result)
               (match job
                 (($ <mcron-job> user group)
                  (vhash-cons (list user group) job result))))
             vlist-null
             jobs))

     (define users+groups
       (delete-duplicates
        (match jobs
          ((($ <mcron-job> users groups) ...)
           (zip users groups)))))

     (map (lambda (key)
            (mcron-shepherd-service mcron (vhash-fold* cons '() key sorted-jobs)))
          users+groups))))

(define mcron-service-type
  (service-type (name 'mcron)
                (extensions
                 (list (service-extension shepherd-root-service-type
                                          mcron-shepherd-services)))
                (compose concatenate)
                (extend (lambda (config jobs)
                          (mcron-configuration
                           (inherit config)
                           (jobs (append (mcron-configuration-jobs config)
                                         jobs)))))))

(define* (mcron-service #:optional (mcron mcron))
  (service mcron-service-type (mcron-configuration (mcron mcron))))

;;; mcron.scm ends here