all messages for Guix-related lists mirrored at yhetil.org
 help / color / mirror / code / Atom feed
From: Ricardo Wurmus <ricardo.wurmus@mdc-berlin.de>
To: ng0@n0.is
Cc: 30385@debbugs.gnu.org
Subject: [bug#30385] Add vim-build-system
Date: Thu, 21 Jun 2018 15:20:52 +0200	[thread overview]
Message-ID: <871sd0tgwb.fsf@mdc-berlin.de> (raw)
In-Reply-To: <87a7wkv3eh.fsf@abyayala.i-did-not-set--mail-host-address--so-tickle-me>

[-- Attachment #1: Type: text/plain, Size: 1003 bytes --]


> This adds a first version of a functional vim-build-system.

Thank you.

Sorry for the delay.  I just went through this but found a couple of
defects.

I fixed the regular expressions in %default-exclude, removed unused
module imports, and fixed minor indentation problems, but then I noticed
a few more fundamental problems.

* %default-exclude is not used.  The “install” phase unconditionally
   installs everything

* The build system does not support an #:exclude argument that would
  allow a user to override the behaviour.  (Compare this to the
  ant-build-system, which supports excluding tests, for example.)

* The build system allows users to specify a test-target and disable
  tests (they default to #t), but there is no check phase anyway.  It
  also supports configure-flags, but it would not use them.

Attached is the patch with my minor changes.

Could you please send an updated patch where these problems are
addressed?

Thanks!

--
Ricardo


[-- Attachment #2: 0001-build-system-Add-vim-build-system.patch --]
[-- Type: text/x-patch, Size: 10709 bytes --]

From 7decc6cd27af54994abfc396beaeae68a6acd69a Mon Sep 17 00:00:00 2001
From: ng0 <ng0@infotropique.org>
Date: Sun, 2 Jul 2017 16:07:48 +0000
Subject: [PATCH] build-system: Add vim-build-system.

* Makefile.am (MODULES): Add guix/build-system/vim.scm and
guix/build/vim-build-system.scm.
* guix/build-system/vim.scm: New file.
* guix/build/vim-build-system.scm: New file.

Signed-off-by: Ricardo Wurmus <rekado@elephly.net>
---
 Makefile.am                     |   2 +
 guix/build-system/vim.scm       | 129 ++++++++++++++++++++++++++++++++
 guix/build/vim-build-system.scm |  91 ++++++++++++++++++++++
 3 files changed, 222 insertions(+)
 create mode 100644 guix/build-system/vim.scm
 create mode 100644 guix/build/vim-build-system.scm

diff --git a/Makefile.am b/Makefile.am
index ab145065d..b5d910139 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -114,6 +114,7 @@ MODULES =					\
   guix/build-system/perl.scm			\
   guix/build-system/python.scm			\
   guix/build-system/ocaml.scm			\
+  guix/build-system/vim.scm			\
   guix/build-system/waf.scm			\
   guix/build-system/r.scm			\
   guix/build-system/ruby.scm			\
@@ -143,6 +144,7 @@ MODULES =					\
   guix/build/font-build-system.scm		\
   guix/build/go-build-system.scm		\
   guix/build/asdf-build-system.scm		\
+  guix/build/vim-build-system.scm		\
   guix/build/git.scm				\
   guix/build/hg.scm				\
   guix/build/glib-or-gtk-build-system.scm	\
diff --git a/guix/build-system/vim.scm b/guix/build-system/vim.scm
new file mode 100644
index 000000000..9bd44e077
--- /dev/null
+++ b/guix/build-system/vim.scm
@@ -0,0 +1,129 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2018 ng0 <ng0@crash.cx>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build-system vim)
+  #:use-module (guix utils)
+  #:use-module (guix packages)
+  #:use-module (guix derivations)
+  #:use-module (guix store)
+  #:use-module (guix search-paths)
+  #:use-module (guix build-system)
+  #:use-module (guix build-system gnu)
+  #:use-module (ice-9 match)
+  #:export (%vim-build-system-modules
+            vim-build
+            vim-build-system))
+
+;; Commentary:
+;;
+;; Standard build procedure for vim packages.  This is
+;; implemented as an extension of 'gnu-build-system'.
+;;
+;; Code:
+
+(define %vim-build-system-modules
+  ;; Build-side modules imported by default.
+  `((guix build vim-build-system)
+    ,@%gnu-build-system-modules))
+
+(define* (lower name
+                #:key source inputs native-inputs outputs system target
+                #:allow-other-keys
+                #:rest arguments)
+  "Return a bag for NAME."
+  (define private-keywords
+    '(#:target #:inputs #:exclude #:native-inputs))
+
+  (bag
+    (name name)
+    (system system)
+    (host-inputs `(,@(if source
+                         `(("source" ,source))
+                         '())
+                   ,@inputs
+                   ,(list "tar" (module-ref (resolve-interface '(gnu packages base)) 'tar))
+                   ,@(let ((compression (resolve-interface '(gnu packages compression))))
+                       (map (match-lambda
+                              ((name package)
+                               (list name (module-ref compression package))))
+                            `(("gzip" gzip)
+                              ("bzip2" bzip2)
+                              ("unzip" unzip)
+                              ("xz" xz))))))
+    (build-inputs native-inputs)
+    (outputs outputs)
+    (build vim-build)
+    (arguments (strip-keyword-arguments private-keywords arguments))))
+
+(define* (vim-build store name inputs
+                     #:key source
+                     (tests? #t)
+                     (test-target "test")
+                     (configure-flags ''())
+                     (phases '(@ (guix build vim-build-system)
+                                 %standard-phases))
+                     (outputs '("out"))
+                     (search-paths '())
+                     (system (%current-system))
+                     (guile #f)
+                     (imported-modules %vim-build-system-modules)
+                     (modules '((guix build vim-build-system)
+                                (guix build utils))))
+  "Build SOURCE with INPUTS."
+  (define builder
+    `(begin
+       (use-modules ,@modules)
+       (vim-build #:name ,name
+                   #:source ,(match (assoc-ref inputs "source")
+                               (((? derivation? source))
+                                (derivation->output-path source))
+                               ((source)
+                                source)
+                               (source
+                                source))
+                   #:configure-flags ,configure-flags
+                   #:system ,system
+                   #:test-target ,test-target
+                   #:tests? ,tests?
+                   #:phases ,phases
+                   #:outputs %outputs
+                   #:search-paths ',(map search-path-specification->sexp
+                                         search-paths)
+                   #:inputs %build-inputs)))
+
+  (define guile-for-build
+    (match guile
+      ((? package?)
+       (package-derivation store guile system #:graft? #f))
+      (#f                                         ; the default
+       (let* ((distro (resolve-interface '(gnu packages commencement)))
+              (guile  (module-ref distro 'guile-final)))
+         (package-derivation store guile system #:graft? #f)))))
+
+  (build-expression->derivation store name builder
+                                #:inputs inputs
+                                #:system system
+                                #:modules imported-modules
+                                #:outputs outputs
+                                #:guile-for-build guile-for-build))
+
+(define vim-build-system
+  (build-system
+    (name 'vim)
+    (description "The build system for vim packages")
+    (lower lower)))
diff --git a/guix/build/vim-build-system.scm b/guix/build/vim-build-system.scm
new file mode 100644
index 000000000..a8a6221e9
--- /dev/null
+++ b/guix/build/vim-build-system.scm
@@ -0,0 +1,91 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2018 ng0 <ng0@crash.cx>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build vim-build-system)
+  #:use-module ((guix build gnu-build-system) #:prefix gnu:)
+  #:use-module (guix build utils)
+  #:use-module (srfi srfi-11)
+  #:export (%standard-phases
+            %default-exclude
+            vim-build))
+
+;; Commentary:
+;;
+;; Builder-side code of the build procedure for vim packages.
+;;
+;; Code:
+
+;; These are the default inclusion/exclusion regexps for the install phase.
+(define %default-exclude '("^.github$" "^.*\\.md$" "LICENSE" "COPYING"
+                           "^.*README.*$" "^\\.travis\\.yml$"
+                           "^.*Makefile.*$"))
+
+(define gnu:unpack (assoc-ref gnu:%standard-phases 'unpack))
+
+(define (store-file->vim-source-file file)
+  "Convert FILE, a store file name for an Vim source file, into a file
+name that has been stripped of the hash and version number."
+  (let ((suffix ".vim"))
+    (let-values (((name version)
+                  (package-name->name+version
+                   (basename
+                    (strip-store-file-name file) suffix))))
+      (string-append name suffix))))
+
+(define* (unpack #:key source #:allow-other-keys)
+  "Unpack SOURCE into the build directory.  SOURCE may be a compressed
+archive, a directory or a '.vim' file."
+  (if (string-suffix? ".vim" source)
+      (begin
+        (mkdir "source")
+        (chdir "source")
+        (copy-file source (store-file->vim-source-file source))
+        #t)
+      (gnu:unpack #:source source)))
+
+;; FIXME: Files like README.md and other, more unpredictable file names,
+;; are currently being installed. Because there is no concept of a
+;; standardized build-system in Vim extensions, we have to find a long-term
+;; solution to exclusion of files that are not used at runtime.
+(define* (install #:key outputs
+                  (exclude %default-exclude)
+                  #:allow-other-keys)
+  "Install the package contents."
+  (let* ((out (assoc-ref outputs "out"))
+         (source (getcwd))
+         (vimfiles (string-append out "/share/vim/vimfiles")))
+    (for-each delete-file-recursively
+              (find-files source "^\\.git$"))
+    (for-each delete-file-recursively
+              (find-files source "^\\.gitignore$"))
+    (mkdir out)
+    (copy-recursively "." vimfiles)
+    #t))
+
+(define %standard-phases
+  (modify-phases gnu:%standard-phases
+    (replace 'unpack unpack)
+    (delete 'configure)
+    (delete 'check)
+    (delete 'build)
+    (replace 'install install)))
+
+(define* (vim-build #:key inputs (phases %standard-phases)
+                    #:allow-other-keys #:rest args)
+  "Build the given vim package, applying all of PHASES in order."
+  (apply gnu:gnu-build #:inputs inputs #:phases phases args))
-- 
2.17.1


  parent reply	other threads:[~2018-06-21 13:22 UTC|newest]

Thread overview: 11+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2018-02-07 22:30 [bug#30385] Add vim-build-system ng0
2018-02-28  8:54 ` ng0
2018-02-28 22:08   ` Ludovic Courtès
2018-06-21 13:20 ` Ricardo Wurmus [this message]
2018-06-26 14:47   ` Nils Gillmann
  -- strict thread matches above, loose matches on Subject: below --
2018-06-27 20:04 [bug#31989] vim-build-system Efraim Flashner
2018-06-28  4:56 ` Nils Gillmann
2021-11-24 23:45 ` zimoun
2021-11-26 11:13   ` [bug#30385] " Efraim Flashner
2021-11-28  9:23     ` Foo Chuan Wei
2021-11-28  9:28       ` Efraim Flashner

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=871sd0tgwb.fsf@mdc-berlin.de \
    --to=ricardo.wurmus@mdc-berlin.de \
    --cc=30385@debbugs.gnu.org \
    --cc=ng0@n0.is \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
Code repositories for project(s) associated with this external index

	https://git.savannah.gnu.org/cgit/guix.git

This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.