From: Ekaitz Zarraga <ekaitz@elenq.tech>
To: 60889@debbugs.gnu.org
Cc: "Ludovic Courtès" <ludo@gnu.org>,
"efraim@flashner.co.il" <efraim@flashner.co.il>
Subject: [bug#60889] Add zig-build-system
Date: Tue, 17 Jan 2023 17:36:42 +0000 [thread overview]
Message-ID: <7NnZFxGvY0oj1TtDERAWi3dMBqoRv2AJoGBlaDPJA6vueGK91igAml6SLzMhNJyc1TssJW--OgezzmxLl5yv5MSgd7Wz6MRkORfOT62_f3w=@elenq.tech> (raw)
[-- Attachment #1: Type: text/plain, Size: 175 bytes --]
Hi,
This is tentative patch for a zig-build-system and a package that makes use of it as a testing.
Please, share your thoughts and feelings about it.
Cheers,
Ekaitz
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-build-system-Add-zig-build-system.patch --]
[-- Type: text/x-patch; name=0001-build-system-Add-zig-build-system.patch, Size: 12732 bytes --]
From 94ed99910b5092b60668b90a936f4c961b82f65b Mon Sep 17 00:00:00 2001
From: Ekaitz Zarraga <ekaitz@elenq.tech>
Date: Thu, 15 Dec 2022 13:01:23 +0100
Subject: [PATCH 1/2] build-system: Add zig-build-system.
* guix/build-system/zig.scm: New file.
* guix/build/zig-build-system.scm: New file.
* Makefile.am: Add them.
* doc/guix.texi: Document it.
* etc/snippets/yas/scheme-mode/guix-package (build-system): Add
zig-build-system.
---
Makefile.am | 2 +
doc/guix.texi | 22 ++++
etc/snippets/yas/scheme-mode/guix-package | 5 +-
guix/build-system/zig.scm | 124 ++++++++++++++++++++++
guix/build/zig-build-system.scm | 100 +++++++++++++++++
5 files changed, 251 insertions(+), 2 deletions(-)
create mode 100644 guix/build-system/zig.scm
create mode 100644 guix/build/zig-build-system.scm
diff --git a/Makefile.am b/Makefile.am
index b54288c0fc..4cc7c2e5cf 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -179,6 +179,7 @@ MODULES = \
guix/build-system/scons.scm \
guix/build-system/texlive.scm \
guix/build-system/trivial.scm \
+ guix/build-system/zig.scm \
guix/ftp-client.scm \
guix/http-client.scm \
guix/gnupg.scm \
@@ -263,6 +264,7 @@ MODULES = \
guix/build/graft.scm \
guix/build/bournish.scm \
guix/build/qt-utils.scm \
+ guix/build/zig-build-system.scm \
guix/build/make-bootstrap.scm \
guix/search-paths.scm \
guix/packages.scm \
diff --git a/doc/guix.texi b/doc/guix.texi
index aacf748838..c28dbf035a 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -9573,6 +9573,28 @@ Python package is used to run the script can be specified with the
@code{#:python} parameter.
@end defvr
+@defvr {Scheme Variable} zig-build-system This variable is exported by
+@code{(guix build-system zig)}. It implements the build procedure used by the
+Zig build system (@code{zig build} command).
+
+This build system adds @code{zig} to the package inputs, as well as the
+packages of @code{gnu-build-system}.
+
+There's no @code{configure} phase because zig packages typically don't need to
+be configured. The @code{#:zig-build-flags} parameter is taken as a list of
+flags passed to the @code{zig} command during the build. The
+@code{#:zig-test-flags} parameter is taken as a list of flags passed to the
+@code{zig test} command during the @code{check} phase. The default compiler
+package can be overriden using the @code{#:zig} argument.
+
+The @code{zig-release-type} parameter can be passed to define the type of
+release to make. Possible values are: @code{safe}, @code{fast}, @code{small}.
+It's default value is @code{#f}, which doesn't include the release flag in the
+@code{zig} command, resulting in a @code{debug} build.
+
+@end defvr
+
+
@defvr {Scheme Variable} scons-build-system
This variable is exported by @code{(guix build-system scons)}. It
implements the build procedure used by the SCons software construction
diff --git a/etc/snippets/yas/scheme-mode/guix-package b/etc/snippets/yas/scheme-mode/guix-package
index 724a392f81..3bb6307659 100644
--- a/etc/snippets/yas/scheme-mode/guix-package
+++ b/etc/snippets/yas/scheme-mode/guix-package
@@ -43,8 +43,9 @@
"scons-build-system"
"texlive-build-system"
"trivial-build-system"
- "waf-build-system")})
+ "waf-build-system"
+ "zig-build-system")})
(home-page "$4")
(synopsis "$5")
(description "$6")
- (license $7)))
\ No newline at end of file
+ (license $7)))
diff --git a/guix/build-system/zig.scm b/guix/build-system/zig.scm
new file mode 100644
index 0000000000..16b8a712cc
--- /dev/null
+++ b/guix/build-system/zig.scm
@@ -0,0 +1,124 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2023 Ekaitz Zarraga <ekaitz@elenq.tech>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build-system zig)
+ #:use-module (guix search-paths)
+ #:use-module (guix store)
+ #:use-module (guix utils)
+ #:use-module (guix gexp)
+ #:use-module (guix monads)
+ #:use-module (guix packages)
+ #:use-module (guix build-system)
+ #:use-module (guix build-system gnu)
+ #:use-module (ice-9 match)
+ #:use-module (srfi srfi-26)
+ #:export (zig-build-system))
+
+
+(define (default-zig)
+ "Return the default zig package."
+ ;; Lazily resolve the binding to avoid a circular dependency.
+ (let ((zig (resolve-interface '(gnu packages zig))))
+ (module-ref zig 'zig)))
+
+(define %zig-build-system-modules
+ ;; Build-side modules imported by default.
+ `((guix build zig-build-system)
+ (guix build syscalls)
+ ,@%gnu-build-system-modules))
+
+(define* (zig-build name inputs
+ #:key
+ source
+ (tests? #t)
+ (test-target #f)
+ (zig-build-flags ''())
+ (zig-test-flags ''())
+ (zig-release-type #f)
+ (phases '%standard-phases)
+ (outputs '("out"))
+ (search-paths '())
+ (system (%current-system))
+ (guile #f)
+ (imported-modules %zig-build-system-modules)
+ (modules '((guix build zig-build-system)
+ (guix build utils))))
+ "Build SOURCE using Zig, and with INPUTS."
+ (define builder
+ (with-imported-modules imported-modules
+ #~(begin
+ (use-modules #$@(sexp->gexp modules))
+ (zig-build #:name #$name
+ #:source #+source
+ #:system #$system
+ #:test-target #$test-target
+ #:zig-build-flags #$zig-build-flags
+ #:zig-test-flags #$zig-test-flags
+ #:zig-release-type #$zig-release-type
+ #:tests? #$tests?
+ #:phases #$phases
+ #:outputs #$(outputs->gexp outputs)
+ #:search-paths '#$(sexp->gexp
+ (map search-path-specification->sexp
+ search-paths))
+ #:inputs #$(input-tuples->gexp inputs)))))
+
+ (mlet %store-monad ((guile (package->derivation (or guile (default-guile))
+ system #:graft? #f)))
+ (gexp->derivation name builder
+ #:system system
+ #:guile-for-build guile)))
+
+(define* (lower name
+ #:key source inputs native-inputs outputs system target
+ (zig (default-zig))
+ #:allow-other-keys
+ #:rest arguments)
+ "Return a bag for NAME."
+
+ (define private-keywords
+ '(#:target #:zig #:inputs #:native-inputs #:outputs))
+
+ ;; TODO: support cross-compilation
+ ;; It's as simple as adding some build flags to `zig-build-flags`
+ ;; -Dtarget=aarch64-linux-musl, for example.
+ (and (not target)
+ (bag
+ (name name)
+ (system system)
+ (target target)
+ (host-inputs `(,@(if source
+ `(("source" ,source))
+ '())
+ ,@inputs
+
+ ;; Keep the standard inputs of 'gnu-build-system'
+ ;; TODO: do we need this?
+ ,@(standard-packages)))
+ (build-inputs `(("zig" ,zig)
+ ,@native-inputs))
+ (outputs outputs)
+ (build zig-build)
+ (arguments (strip-keyword-arguments private-keywords arguments)))))
+
+(define zig-build-system
+ (build-system
+ (name 'zig)
+ (description
+ "Zig build system, to build Zig packages")
+ (lower lower)))
diff --git a/guix/build/zig-build-system.scm b/guix/build/zig-build-system.scm
new file mode 100644
index 0000000000..d414ebfb17
--- /dev/null
+++ b/guix/build/zig-build-system.scm
@@ -0,0 +1,100 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2023 Ekaitz Zarraga <ekaitz@elenq.tech>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build zig-build-system)
+ #:use-module ((guix build gnu-build-system) #:prefix gnu:)
+ #:use-module (guix build utils)
+ #:use-module (ice-9 popen)
+ #:use-module (ice-9 rdelim)
+ #:use-module (ice-9 ftw)
+ #:use-module (ice-9 format)
+ #:use-module (ice-9 match)
+ #:use-module (rnrs io ports)
+ #:use-module (srfi srfi-1)
+ #:use-module (srfi srfi-26)
+ #:export (%standard-phases
+ zig-build))
+
+;; Interesting guide here:
+;; https://github.com/riverwm/river/blob/master/PACKAGING.md
+(define global-cache-dir "zig-cache")
+
+(define* (set-cc #:rest args)
+ ;; TODO: Zig needs the gcc-toolchain in order to find the libc.
+ ;; we need to think about how to solve this in the build system
+ ;; directly: --libc
+ (setenv "CC" "gcc"))
+
+(define* (set-zig-global-cache-dir #:rest args)
+ (setenv "ZIG_GLOBAL_CACHE_DIR" global-cache-dir))
+
+(define* (build #:key
+ zig-build-flags
+ zig-release-type ;; "safe", "fast" or "small" empty for a
+ ;; debug build"
+ #:allow-other-keys)
+ "Build a given Zig package."
+
+ (setenv "DESTDIR" "out")
+ (let ((call `("zig" "build"
+ "--prefix" "" ;; Don't add /usr
+ "--prefix-lib-dir" "lib"
+ "--prefix-exe-dir" "bin"
+ "--prefix-include-dir" "include"
+ ,@(if zig-release-type
+ (list (string-append "-Drelease-" zig-release-type))
+ '())
+ ,@zig-build-flags)))
+ (format #t "running: ~s~%" call)
+ (apply invoke call)))
+
+(define* (check #:key tests?
+ zig-test-flags
+ #:allow-other-keys)
+ "Run all the tests"
+ (when tests?
+ (let ((old-destdir (getenv "DESTDIR")))
+ (setenv "DESTDIR" "test-out") ;; Avoid colisions with the build output
+ (let ((call `("zig" "build" "test"
+ ,@zig-test-flags)))
+ (format #t "running: ~s~%" call)
+ (apply invoke call))
+ (if old-destdir
+ (setenv "DESTDIR" old-destdir)
+ (unsetenv "DESTDIR")))))
+
+(define* (install #:key inputs outputs #:allow-other-keys)
+ "Install a given Zig package."
+ (let ((out (assoc-ref outputs "out")))
+ (copy-recursively "out" out)))
+
+(define %standard-phases
+ (modify-phases gnu:%standard-phases
+ (delete 'bootstrap)
+ (delete 'configure)
+ (add-before 'build 'set-zig-global-cache-dir set-zig-global-cache-dir)
+ (add-before 'build 'set-cc set-cc)
+ (replace 'build build)
+ (replace 'check check)
+ (replace 'install install)))
+
+
+(define* (zig-build #:key inputs (phases %standard-phases)
+ #:allow-other-keys #:rest args)
+ "Build the given Zig package, applying all of PHASES in order."
+ (apply gnu:gnu-build #:inputs inputs #:phases phases args))
--
2.38.0
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #3: 0002-gnu-Add-tigerbeetle.patch --]
[-- Type: text/x-patch; name=0002-gnu-Add-tigerbeetle.patch, Size: 2047 bytes --]
From d492455090e97445cd0595ed1117bb564ad41640 Mon Sep 17 00:00:00 2001
From: Ekaitz Zarraga <ekaitz@elenq.tech>
Date: Thu, 15 Dec 2022 13:02:25 +0100
Subject: [PATCH 2/2] gnu: Add tigerbeetle.
* gnu/packages/zig.scm (tigerbeetle): New variable.
---
gnu/packages/zig.scm | 33 ++++++++++++++++++++++++++++++++-
1 file changed, 32 insertions(+), 1 deletion(-)
diff --git a/gnu/packages/zig.scm b/gnu/packages/zig.scm
index cda93bed2e..2ff65b3b1a 100644
--- a/gnu/packages/zig.scm
+++ b/gnu/packages/zig.scm
@@ -25,7 +25,8 @@ (define-module (gnu packages zig)
#:use-module ((guix licenses) #:prefix license:)
#:use-module (guix build-system cmake)
#:use-module (gnu packages)
- #:use-module (gnu packages llvm))
+ #:use-module (gnu packages llvm)
+ #:use-module (guix build-system zig))
(define-public zig
(package
@@ -104,3 +105,33 @@ (define-public zig
;; https://github.com/ziglang/zig/issues/6485
(supported-systems %64bit-supported-systems)
(license license:expat)))
+
+
+(define-public tigerbeetle
+ (let ((commit-id "2022-12-12-weekly")
+ (revision "0"))
+ (package
+ (name "tigerbeetle")
+ (version (string-append revision "-" commit-id))
+ (source
+ (origin
+ (method git-fetch)
+ (uri (git-reference
+ (url "https://github.com/tigerbeetledb/tigerbeetle.git")
+ (commit commit-id)))
+ (file-name (git-file-name name version))
+ (sha256
+ (base32 "18rawl8rhyplw8hpa3fzbq9fqg088x0calz688c7zdff6y6f6mcr"))))
+ (build-system zig-build-system)
+
+ (arguments
+ `(#:zig-release-type "safe"))
+
+ (synopsis "Distributed financial accounting database designed for mission
+critical safety and performance")
+
+ (description "Financial accounting database designed for mission critical
+safet y and performance to power the future of financial
+services.")
+ (home-page "https://github.com/tigerbeetledb/tigerbeetle.git")
+ (license license:asl2.0))))
--
2.38.0
next reply other threads:[~2023-01-17 17:38 UTC|newest]
Thread overview: 4+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-01-17 17:36 Ekaitz Zarraga [this message]
2023-01-20 14:30 ` [bug#60889] Tentative cross-compilation support Ekaitz Zarraga
2023-06-21 15:06 ` [bug#60889] [PATCH v2] build-system: Add zig-build-system Felix Lechner via Guix-patches via
2023-10-20 22:02 ` bug#60889: " Ludovic Courtès
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to='7NnZFxGvY0oj1TtDERAWi3dMBqoRv2AJoGBlaDPJA6vueGK91igAml6SLzMhNJyc1TssJW--OgezzmxLl5yv5MSgd7Wz6MRkORfOT62_f3w=@elenq.tech' \
--to=ekaitz@elenq.tech \
--cc=60889@debbugs.gnu.org \
--cc=efraim@flashner.co.il \
--cc=ludo@gnu.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this external index
https://git.savannah.gnu.org/cgit/guix.git
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.