[bug#40622] new package 'flowee'.

[bug#40622] new package 'flowee'.

[Tom Zander via Guix-patches via]

[-- Attachment #1: Type: text/plain, Size: 29 bytes --]

Please merge.

-- 
Tom Zander

[-- Attachment #2: 0001-gnu-Add-flowee.patch --]
[-- Type: text/x-patch, Size: 3738 bytes --]

From 0d5cd3f28daed7320fcd879fa4e0d1351856127a Mon Sep 17 00:00:00 2001
From: TomZ <tomz@freedommail.ch>
Date: Sat, 11 Apr 2020 14:56:49 +0200
Subject: [PATCH] gnu: Add flowee.

* gnu/packages/finance.scm (flowee): New variable.
---
 gnu/packages/finance.scm | 66 +++++++++++++++++++++++++++++++++++++++-
 1 file changed, 65 insertions(+), 1 deletion(-)

diff --git a/gnu/packages/finance.scm b/gnu/packages/finance.scm
index aa71335040..4449781463 100644
--- a/gnu/packages/finance.scm
+++ b/gnu/packages/finance.scm
@@ -1412,7 +1412,7 @@ a Qt GUI.")
        (uri (string-append "https://gitlab.com/FloweeTheHub/fulcrum/-/archive/v"
                            version "/fulcrum-v" version ".tar.gz"))
        (sha256
-        (base32 "1c1hkik8avill8ha33g76rk4b03j5ac8wiml69q4jav7a63ywgfy"))))
+        (base32 "1ajd5axv9zyhh6njrvamm11zn52j1q4j3mwn2nfv7cjd4lhnhlsr"))))
     (build-system gnu-build-system)
     (arguments
      `(#:phases
@@ -1440,6 +1440,70 @@ walets in a fast and small server.  The full data is stored in a full node,
 like Flowee the Hub, which Fulcrum connects to over RPC.")
     (license license:gpl3+)))
 
+(package
+  (name "flowee")
+  (version "2020.03.1")
+  (source (origin
+         (method url-fetch)
+         (uri (string-append "https://gitlab.com/FloweeTheHub/thehub/-/archive/"
+                             version "/thehub-" version ".tar.gz"))
+          (sha256
+            (base32
+             "1w20haldxlnppi2lkn5xsmw8cnxpcc92yradhb823d2ih66ybp0l"))))
+  (build-system cmake-build-system)
+  (arguments
+   `(#:configure-flags '("-Dbuild_tests=ON" "-Denable_gui=OFF")
+     #:phases
+      (modify-phases %standard-phases
+        (add-before 'configure 'make-qt-deterministic
+          (lambda _
+            ; Make Qt deterministic.
+            (setenv "QT_RCC_SOURCE_DATE_OVERRIDE" "1")
+           #t))
+        (add-before 'configure 'disable-black-box
+          ; the black-box testing runs full hubs and lets them interact.
+          ; this is more fragile and a slow machine, or low memory machine, may
+          ; make the tests timeout and fail.  We just disable them here.
+          (lambda _
+            (substitute* "testing/CMakeLists.txt"
+              (("test_api") ""))
+            #t))
+        (add-after 'configure 'set-build-info
+          ; Their genbuild.sh to generate a build.h fails in guix (no .git dir) .
+          ; Its purpose is to write the tag name in the build.h file. We do that
+          ; here instead.
+          (lambda _
+            (with-output-to-file "include/build.h"
+              (lambda _
+                (display
+                  (string-append "#define BUILD_DESC " "\"", version "\""))))))
+        (add-before 'check 'set-home
+          (lambda _
+            (setenv "HOME" (getenv "TMPDIR")) ; tests write to $HOME
+            #t))
+        (replace 'check
+          (lambda _
+            (invoke "make" "check" "-C" "testing"))))))
+  (inputs
+   `(("boost" ,boost)
+     ("libevent" ,libevent)
+     ("miniupnpc" ,miniupnpc)
+     ("qtbase" ,qtbase)
+     ("gmp" ,gmp)
+     ("openssl" ,openssl)))
+  (native-inputs
+   `(("pkg-config" ,pkg-config)
+     ("util-linux" ,util-linux)       ; provides the hexdump command for tests
+     ("qttools" ,qttools)))
+  (home-page "https://flowee.org")
+  (synopsis "Flowee infrastructure tools and services")
+  (description
+   "Flowee packages all tier-1 applications and services from the Flowee group.
+This includes components like The Hub and Indexer which and various others
+that allows you to run services and through them access the Bitcoin Cash networks.")
+  (license license:gpl3+))
+
+
 (define-public beancount
   (package
     (name "beancount")
-- 
2.25.1

[bug#40622] new package 'flowee'.

[Nicolas Goaziou]

Hello,

Tom Zander via Guix-patches via <guix-patches@gnu.org> writes:

> Please merge.

Thank you. I have some comments first. :)

>         (sha256
> -        (base32 "1c1hkik8avill8ha33g76rk4b03j5ac8wiml69q4jav7a63ywgfy"))))
> +        (base32 "1ajd5axv9zyhh6njrvamm11zn52j1q4j3mwn2nfv7cjd4lhnhlsr"))))

This change is unrelated.

>      (build-system gnu-build-system)
>      (arguments
>       `(#:phases
> @@ -1440,6 +1440,70 @@ walets in a fast and small server.  The full data is stored in a full node,
>  like Flowee the Hub, which Fulcrum connects to over RPC.")
>      (license license:gpl3+)))
>  
> +(package
> +  (name "flowee")
> +  (version "2020.03.1")

You forgot to define a variable for this package.

> +  (source (origin
> +         (method url-fetch)
> +         (uri (string-append "https://gitlab.com/FloweeTheHub/thehub/-/archive/"
> +                             version "/thehub-" version ".tar.gz"))
> +          (sha256
> +            (base32
> +             "1w20haldxlnppi2lkn5xsmw8cnxpcc92yradhb823d2ih66ybp0l"))))

Nitpick: I would move `origin' under `source' and `base32' on the same
line as the string.

> +  (build-system cmake-build-system)
> +  (arguments
> +   `(#:configure-flags '("-Dbuild_tests=ON" "-Denable_gui=OFF")
> +     #:phases
> +      (modify-phases %standard-phases
> +        (add-before 'configure 'make-qt-deterministic
> +          (lambda _
> +            ; Make Qt deterministic.

Comments on a full line need two semicolons.

> +            (setenv "QT_RCC_SOURCE_DATE_OVERRIDE" "1")
> +           #t))
> +        (add-before 'configure 'disable-black-box
> +          ; the black-box testing runs full hubs and lets them interact.
> +          ; this is more fragile and a slow machine, or low memory machine, may
> +          ; make the tests timeout and fail.  We just disable them here.

Ditto.
> +          (lambda _
> +            (substitute* "testing/CMakeLists.txt"
> +              (("test_api") ""))
> +            #t))
> +        (add-after 'configure 'set-build-info
> +          ; Their genbuild.sh to generate a build.h fails in guix (no .git dir) .
> +          ; Its purpose is to write the tag name in the build.h file. We do that
> +          ; here instead.

See above.

> +  (inputs
> +   `(("boost" ,boost)
> +     ("libevent" ,libevent)
> +     ("miniupnpc" ,miniupnpc)
> +     ("qtbase" ,qtbase)
> +     ("gmp" ,gmp)
> +     ("openssl" ,openssl)))
> +  (native-inputs
> +   `(("pkg-config" ,pkg-config)
> +     ("util-linux" ,util-linux)       ; provides the hexdump command for tests
> +     ("qttools" ,qttools)))

Could you re-order inputs alphabetically?

Could you send an updated patch?

Regards,

-- 
Nicolas Goaziou

[bug#40622] new package 'flowee'.

[Tom Zander via Guix-patches via]

[-- Attachment #1: Type: text/plain, Size: 211 bytes --]

On dinsdag 14 april 2020 10:09:36 CEST Nicolas Goaziou wrote:
> Could you send an updated patch?

Thanks for your comments!

I applied all requested changes and please find a new patch attached.


-- 
Tom Zander

[-- Attachment #2: 0001-gnu-Add-flowee.patch --]
[-- Type: text/x-patch, Size: 3420 bytes --]

From fef3d46b594050960ceb19a7172e4e0bbff421c4 Mon Sep 17 00:00:00 2001
From: TomZ <tomz@freedommail.ch>
Date: Sat, 11 Apr 2020 14:56:49 +0200
Subject: [PATCH] gnu: Add flowee.

* gnu/packages/finance.scm (flowee): New variable.
---
 gnu/packages/finance.scm | 65 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/gnu/packages/finance.scm b/gnu/packages/finance.scm
index aa71335040..c5f9066fd7 100644
--- a/gnu/packages/finance.scm
+++ b/gnu/packages/finance.scm
@@ -1440,6 +1440,71 @@ walets in a fast and small server.  The full data is stored in a full node,
 like Flowee the Hub, which Fulcrum connects to over RPC.")
     (license license:gpl3+)))
 
+(define-public flowee
+  (package
+    (name "flowee")
+    (version "2020.03.1")
+    (source
+     (origin
+       (method url-fetch)
+       (uri (string-append "https://gitlab.com/FloweeTheHub/thehub/-/archive/"
+                            version "/thehub-" version ".tar.gz"))
+       (sha256
+         (base32 "1ajd5axv9zyhh6njrvamm11zn52j1q4j3mwn2nfv7cjd4lhnhlsr"))))
+    (build-system cmake-build-system)
+    (arguments
+     `(#:configure-flags '("-Dbuild_tests=ON" "-Denable_gui=OFF")
+       #:phases
+        (modify-phases %standard-phases
+          (add-before 'configure 'make-qt-deterministic
+            (lambda _
+              ;; Make Qt deterministic.
+              (setenv "QT_RCC_SOURCE_DATE_OVERRIDE" "1")
+             #t))
+          (add-before 'configure 'disable-black-box
+            ;; the black-box testing runs full hubs and lets them interact.
+            ;; this is more fragile and a slow machine, or low memory machine, may
+            ;; make the tests timeout and fail.  We just disable them here.
+            (lambda _
+              (substitute* "testing/CMakeLists.txt"
+                (("test_api") ""))
+              #t))
+          (add-after 'configure 'set-build-info
+            ;; Their genbuild.sh to generate a build.h fails in guix (no .git dir) .
+            ;; Its purpose is to write the tag name in the build.h file. We do that
+            ;; here instead.
+            (lambda _
+              (with-output-to-file "include/build.h"
+                (lambda _
+                  (display
+                    (string-append "#define BUILD_DESC " "\"", version "\""))))))
+          (add-before 'check 'set-home
+            (lambda _
+              (setenv "HOME" (getenv "TMPDIR")) ; tests write to $HOME
+              #t))
+          (replace 'check
+            (lambda _
+              (invoke "make" "check" "-C" "testing"))))))
+    (inputs
+     `(("boost" ,boost)
+       ("gmp" ,gmp)
+       ("libevent" ,libevent)
+       ("miniupnpc" ,miniupnpc)
+       ("openssl" ,openssl)
+       ("qtbase" ,qtbase)))
+    (native-inputs
+     `(("pkg-config" ,pkg-config)
+       ("qttools" ,qttools)
+       ("util-linux" ,util-linux)))       ; provides the hexdump command for tests
+    (home-page "https://flowee.org")
+    (synopsis "Flowee infrastructure tools and services")
+    (description
+     "Flowee packages all tier-1 applications and services from the Flowee group.
+This includes components like The Hub and Indexer which and various others
+that allows you to run services and through them access the Bitcoin Cash networks.")
+    (license license:gpl3+)))
+
+
 (define-public beancount
   (package
     (name "beancount")
-- 
2.25.1

bug#40622: new package 'flowee'.

[Nicolas Goaziou]

Hello,

Tom Zander <tomz@freedommail.ch> writes:

> I applied all requested changes and please find a new patch attached.

Thank you! I applied it as 87b343f7539fe9e5b4cb3814d1607855b8e7bde9.

Regards,

-- 
Nicolas Goaziou