;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2016 David Craven <david@craven.ch>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (guix import crate)
  #:use-module (gnu packages rust)
  #:use-module ((guix download) #:prefix download:)
  #:use-module (guix import utils)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix packages)
  #:use-module (guix upstream)
  #:use-module (guix utils)
  #:use-module (ice-9 match)
  #:use-module (json)
  #:use-module (srfi srfi-1)
  #:export (crate->guix-package
            guix-package->crate-name))

(define (crate-fetch name)
  "Return an alist representation of the crates.io metadata for the package NAME,
or #f on failure."
  ;; XXX: We want to silence the download progress report, which is especially
  ;; annoying for 'guix refresh', but we have to use a file port.
  (call-with-output-file "/dev/null"
    (lambda (null)
      (with-error-to-port null
        (lambda ()
          (json-fetch (string-append "https://crates.io/api/v1/crates/"
                                     name)))))))

;; TODO: Import inputs and native-inputs
(define (make-crate-sexp name version home-page synopsis description license)
  "Return the `package' s-expression for a rust package with the given NAME,
VERSION, SOURCE-URL, HOME-PAGE, SYNOPSIS, DESCRIPTION, and LICENSE."
  (call-with-temporary-output-file
   (lambda (temp port)
     (and (url-fetch (crate-uri name version) temp)
          `(package
             (name ,(crate-name->package-name name))
             (version ,version)
             (source (origin
                       (method url-fetch)
                       (uri (crate-uri ,name version))
                       (file-name (string-append name "-" version ".tar.gz"))
                       (sha256
                        (base32
                         ,(guix-hash-url temp)))))
             (build-system cargo-build-system)
             (home-page ,home-page)
             (synopsis ,synopsis)
             (description ,(beautify-description description))
             (license ,(match license
                         (() #f)
                         ((license) license)
                         (_ `(list ,@license)))))))))

(define (crate->guix-package crate-name)
  "Fetch the metadata for CRATE-NAME from crates.io, and return the
`package' s-expression corresponding to that package, or #f on failure."
  (let ((crate (crate-fetch crate-name)))
    (let ((name (assoc-ref* crate "crate" "name"))
          (version (assoc-ref* crate "crate" "max_version"))
          (home-page (assoc-ref* crate "crate" "homepage"))
          (synopsis (assoc-ref* crate "crate" "description"))
          (description (assoc-ref* crate "crate" "description"))
          (license (string->license (assoc-ref* crate "crate" "license"))))
      (make-crate-sexp name version home-page synopsis description license))))

(define (guix-package->crate-name package)
  "Return the crate NAME of a PACKAGE."
  (string-join (cdr (string-split (package-name package) #\-)) "-"))

(define (string->license string)
  (map spdx-string->license (string-split string #\/)))

(define (crate-name->package-name name)
  (string-append "rust-" name))