[bug#54529] [PATCH] Added orca-lang package

[bug#54529] [PATCH] Added orca-lang package

[Christopher Rodriguez]

---
 gnu/packages/music.scm | 60 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/gnu/packages/music.scm b/gnu/packages/music.scm
index 9c8203aa80..32ab263f84 100644
--- a/gnu/packages/music.scm
+++ b/gnu/packages/music.scm
@@ -6879,3 +6879,63 @@ (define-public musikcube
 streaming audio server.")
     (home-page "https://musikcube.com/")
     (license license:bsd-3)))
+(define-public orca-lang
+  (let ((commit "5ba56ca67baae3db140f8b7a2b2fc46bbac5602f")
+        (revision "4"))
+    (package
+     (name "orca-lang")
+     (version (git-version "git" revision commit))
+     (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://git.sr.ht/~rabbits/orca")
+                    (commit commit)))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1mnhk68slc6g5y5348vj86pmnz90a385jxvm3463fic79k90gckd"))))
+     (build-system gnu-build-system)
+     (arguments
+      `(#:tests?
+        #f
+        #:phases
+        (modify-phases
+         %standard-phases
+         (delete 'configure)
+         (delete 'check)
+         (delete 'patch-shebangs)
+         (delete 'validate-documentation-location)
+         (delete 'delete-info-dir-file)
+         (delete 'patch-dot-desktop-files)
+         (delete 'reset-gzip-timestamps)
+         (replace 'build
+                  (lambda* (#:key inputs outputs #:allow-other-keys)
+                           (setenv "CC" "gcc")
+                           (invoke "make" "release")))
+         (replace 'install
+                  (lambda* (#:key outputs #:allow-other-keys)
+                           (let* ((out
+                                   (assoc-ref outputs "out"))
+                                  (dest-bin
+                                   (string-append out "/bin"))
+                                  (dest-lib
+                                   (string-append out "/share"))
+                                  (dest-exa
+                                   (string-append dest-lib "/examples"))
+                                  (dest-doc
+                                   (string-append dest-lib "/doc")))
+                             (install-file "./build/orca" dest-bin)
+                             (copy-recursively "./examples" dest-exa)
+                             (install-file "./README.md" dest-doc)
+                             #t))))))
+     (inputs `(("ncurses" ,ncurses)
+               ("portmidi" ,portmidi)))
+     (native-inputs `(("pkg-config" ,pkg-config)))
+     (synopsis "Musical Esoteric Programming Language")
+     (description
+      "Orca is an esoteric programming language and live editor designed to
+quickly create procedural sequencers.  Every letter of the alphabet is an
+operation, lowercase letters execute on *bang*, and uppercase letters execute
+each frame.")
+     (home-page "https://wiki.xxiivv.com/site/uxn.html")
+     (license license:agpl3))))
-- 
2.34.0

[bug#54529] [PATCH v2] Added orca-lang package

[Christopher Rodriguez]

---

Added the alsa-plugins package (out and pulseaudio outputs) as
propogated inputs because MIDI output depends on being able to use
libasound_module_conf_pulse.so.

 gnu/packages/music.scm | 62 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/gnu/packages/music.scm b/gnu/packages/music.scm
index 9c8203aa80..9e1b078436 100644
--- a/gnu/packages/music.scm
+++ b/gnu/packages/music.scm
@@ -6879,3 +6879,65 @@ (define-public musikcube
 streaming audio server.")
     (home-page "https://musikcube.com/")
     (license license:bsd-3)))
+(define-public orca-lang
+  (let ((commit "5ba56ca67baae3db140f8b7a2b2fc46bbac5602f")
+        (revision "5"))
+    (package
+     (name "orca-lang")
+     (version (git-version "git" revision commit))
+     (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://git.sr.ht/~rabbits/orca")
+                    (commit commit)))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1mnhk68slc6g5y5348vj86pmnz90a385jxvm3463fic79k90gckd"))))
+     (build-system gnu-build-system)
+     (arguments
+      `(#:tests?
+        #f
+        #:phases
+        (modify-phases
+         %standard-phases
+         (delete 'configure)
+         (delete 'check)
+         (delete 'patch-shebangs)
+         (delete 'validate-documentation-location)
+         (delete 'delete-info-dir-file)
+         (delete 'patch-dot-desktop-files)
+         (delete 'reset-gzip-timestamps)
+         (replace 'build
+                  (lambda* (#:key inputs outputs #:allow-other-keys)
+                           (setenv "CC" "gcc")
+                           (invoke "make" "release")))
+         (replace 'install
+                  (lambda* (#:key outputs #:allow-other-keys)
+                           (let* ((out
+                                   (assoc-ref outputs "out"))
+                                  (dest-bin
+                                   (string-append out "/bin"))
+                                  (dest-lib
+                                   (string-append out "/share"))
+                                  (dest-exa
+                                   (string-append dest-lib "/examples"))
+                                  (dest-doc
+                                   (string-append dest-lib "/doc")))
+                             (install-file "./build/orca" dest-bin)
+                             (copy-recursively "./examples" dest-exa)
+                             (install-file "./README.md" dest-doc)
+                             #t))))))
+     (inputs `(("ncurses" ,ncurses)
+               ("portmidi" ,portmidi)))
+     (native-inputs `(("pkg-config" ,pkg-config)))
+     (propagated-inputs `(("alsa-plugins" ,alsa-plugins)
+                          ("alsa-plugins:pulseaudio" ,alsa-plugins "pulseaudio")))
+     (synopsis "Musical Esoteric Programming Language")
+     (description
+      "Orca is an esoteric programming language and live editor designed to
+quickly create procedural sequencers.  Every letter of the alphabet is an
+operation, lowercase letters execute on *bang*, and uppercase letters execute
+each frame.")
+     (home-page "https://100r.co/site/orca.html")
+     (license license:agpl3))))
-- 
2.34.0

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 364 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +                  (lambda* (#:key inputs outputs #:allow-other-keys)
> +                           (setenv "CC" "gcc")

This is broken when cross-compiling, try 'cc-for-target'.
Additionally, 'outputs' and 'inputs' are unused here.

Greetings,
Maxime.


[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 117 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +      `(#:tests?
> +        #f

Why?

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 436 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +         (delete 'configure)
> +         (delete 'check)
> +         (delete 'patch-shebangs)
> +         (delete 'validate-documentation-location)
> +         (delete 'delete-info-dir-file)
> +         (delete 'patch-dot-desktop-files)
> +         (delete 'reset-gzip-timestamps)

Why are these phases deleted?

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 242 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +     (inputs `(("ncurses" ,ncurses)
> +               ("portmidi" ,portmidi)))

Preferably use the new inputs style: (inputs (list ncurses portmidi)).

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 267 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +     (propagated-inputs `(("alsa-plugins" ,alsa-plugins)
> +                          ("alsa-plugins:pulseaudio" ,alsa-plugins "pulseaudio")))

Why are these propagated?

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 367 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +     (synopsis "Musical Esoteric Programming Language")

Why the capital letters? And why mention ‘Esoteric’ in the synopsis and
description?  Also, it is not actually a programming language, it is
more an implementation of a language for producing music.

Greetings,
Maxime.




[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 107 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> *bang*

This is not texinfo markup.

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 135 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +(define-public orca-lang

Personally I'd go with "orca-music".

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 250 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +  (let ((commit "5ba56ca67baae3db140f8b7a2b2fc46bbac5602f")
> +        (revision "5"))

Where does this revision come from?  This is the first version of orca
in Guix.

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 283 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +     (version (git-version "git" revision commit))

"git" is not a version numberr, I suggest "0" instead.
Also, why is a ‘random’ git commit used instead of an upstream version?

Greetings,
Maxime.

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 336 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +                                  (dest-exa
> +                                   (string-append dest-lib "/examples"))

I don't think that abbreviations are necessary here, these's enough
space here.

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 267 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +         (replace 'install
> +                  (lambda* (#:key outputs #:allow-other-keys)

Spacing went wrong here, try running "./pre-inst-env guix style" on the
package.

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 137 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +     (license license:agpl3))))

Is it agpl3-only or agpl3+?

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 390 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +                                  (dest-lib
> +                                   (string-append out "/share"))

This seems rather confusing naming.  Libraries are put in [...]/lib,
not [...]/share.  Alsso, I think you could drop the 'dest-' prefix
here.

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 176 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +                             #t))))))

Phases do not need to return #f anymore.

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v2] Added orca-lang package

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 275 bytes --]

Christopher Rodriguez schreef op di 22-03-2022 om 22:30 [-0400]:
> +     (inputs `(("ncurses" ,ncurses)

If you do this, you'll have to add the native-search-paths of ncurses
to orca-lang, because of <https://issues.guix.gnu.org/issue/22138>.

Greetings,
Maxime.

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#54529] [PATCH v3] Added orca-lang package

[Christopher Rodriguez]

---

> This is broken when cross-compiling, try 'cc-for-target'.
> Additionally, 'outputs' and 'inputs' are unused here.

> Why?

> Why the capital letters? And why mention ‘Esoteric’ in the synopsis and
> description?  Also, it is not actually a programming language, it is
> more an implementation of a language for producing music.

> This is not texinfo markup.

> Personally I'd go with "orca-music".

> I don't think that abbreviations are necessary here, these's enough
> space here.

> Spacing went wrong here, try running "./pre-inst-env guix style" on the
> package.

> This seems rather confusing naming.  Libraries are put in [...]/lib,
> not [...]/share.  Alsso, I think you could drop the 'dest-' prefix
> here.

> Phases do not need to return #f anymore.

All of the above were amended as written in this version of the patch.

> Why are these phases deleted?

Went back and audited the phases I initially deleted; Two remain
deleted in this patch: configure, and check. This is due to the
package not using a configure script, nor having any 'check' defined
for make.

> Why are these propagated?

I've propagated both alsa-plugins and alsa-plugins:pulseaudio because
this package using portmidi for midi output, and needs to load the
`libasound_module_conf_pulse.so` shared library to interface with MIDI
when using `pulseaudio`. Is there another way to do this without
propagating these?

> Where does this revision come from?  This is the first version of orca
> in Guix.

The revision was in my personal channel; I kept bumping the revision
number because I needed to recompile the package, and `guix build -f`
would assume the package was already compiled. I've reverted it to
revision 1.

> "git" is not a version numberr, I suggest "0" instead.
> Also, why is a ‘random’ git commit used instead of an upstream version?

The upstream package at https://git.sr.ht/~rabbits/orca does not have
any tags, let alone version tags. And as near as I can tell, it does
not use semantic versioning at all. I used "git" because of my
experience with rpm packaging; I have changed this to 0 here, to align
with Guix conventions.

> Is it agpl3-only or agpl3+?

It is actually expat; apparently I neglected to update this field when
defining this package. I have fixed this here.

> If you do this, you'll have to add the native-search-paths of ncurses
> to orca-lang, because of https://issues.guix.gnu.org/issue/22138.

Discussed this with maximed on #guix. When I tried to apply
`(package-native-search-paths ncurses)` it introduced a bunch of
undefined variable errors. This may be due to cyclic imports; either
way, it seems to be an issue outside the scope of this package.

I've chosen to instead explicitly define the same native search path
(namely, for TERMINFO_DIRS) as ncurses in this package, to work around
this bug.

Here's the patch. Let me know what else can be improved.

Particularly, I am worried about the name of the binary. It is
currently installed as `orca`, which is (I believe) the same name
given to the binary for the orca screen reader.

Should I change this? And if so, how?

 gnu/packages/music.scm | 57 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/gnu/packages/music.scm b/gnu/packages/music.scm
index 9c8203aa80..1240027050 100644
--- a/gnu/packages/music.scm
+++ b/gnu/packages/music.scm
@@ -6879,3 +6879,60 @@ (define-public musikcube
 streaming audio server.")
     (home-page "https://musikcube.com/")
     (license license:bsd-3)))
+(define-public orca-music
+  (let ((commit "5ba56ca67baae3db140f8b7a2b2fc46bbac5602f") (revision "1"))
+    (package
+      (name "orca-music")
+      ;; No upstream version numbers; Using commit instead.
+      (version (git-version "0" revision commit))
+      (source (origin
+                (method git-fetch)
+                (uri (git-reference
+                      (url "https://git.sr.ht/~rabbits/orca")
+                      (commit commit)))
+                (file-name (git-file-name name version))
+                (sha256
+                 (base32
+                  "1mnhk68slc6g5y5348vj86pmnz90a385jxvm3463fic79k90gckd"))))
+      (build-system gnu-build-system)
+      (arguments
+       `(#:phases (modify-phases %standard-phases
+                    (delete 'configure) ;; No autoconf
+                    (delete 'check) ;; No make check
+                    (replace 'build
+                      (lambda* (#:key inputs outputs #:allow-other-keys)
+                        (setenv "CC"
+                                ,(cc-for-target))
+                        (invoke "make" "release")))
+                    (replace 'install
+                      (lambda* (#:key outputs #:allow-other-keys)
+                        (let* ((out (assoc-ref outputs "out")) (dest-bin (string-append
+                                                                          out
+                                                                          "/bin"))
+                               (share (string-append out "/share"))
+                               (dest-examples (string-append share "/examples"))
+                               (dest-doc (string-append share "/doc")))
+                          (install-file "./build/orca" dest-bin)
+                          (copy-recursively "./examples" dest-examples)
+                          (install-file "./README.md" dest-doc)))))))
+      (inputs (list ncurses portmidi))
+      (native-inputs (list pkg-config))
+      ;; The below are needed as propagated inputs to let orca interact with
+      ;; alsa/pulse MIDI.
+      (propagated-inputs `(("alsa-plugins" ,alsa-plugins) ("alsa-plugins:pulseaudio" ,alsa-plugins
+                                                           "pulseaudio")))
+      (native-search-paths (list
+                             (search-path-specification
+                              (variable "TERMINFO_DIRS")
+                              (files '("share/terminfo")))))
+      (synopsis "musical live-coding environment")
+      (description
+       "This is the C implementation of the ORCΛ language and terminal
+livecoding environment. It's designed to be power efficient. It can handle
+large files, even if your terminal is small.
+
+Orca is not a synthesizer, but a flexible livecoding environment capable of
+sending MIDI, OSC, and UDP to your audio/visual interfaces like Ableton,
+Renoise, VCV Rack, or SuperCollider.")
+      (home-page "https://100r.co/site/orca.html")
+      (license license:expat))))
-- 
2.34.0

[bug#54529] [PATCH v3] Added orca-lang package

[Christine Lemmer-Webber]

First: this is awesome.  Second...

Christopher Rodriguez <yewscion@gmail.com> writes:

> Here's the patch. Let me know what else can be improved.
>
> Particularly, I am worried about the name of the binary. It is
> currently installed as `orca`, which is (I believe) the same name
> given to the binary for the orca screen reader.
>
> Should I change this? And if so, how?

I think you could probably just add a post-install phase that moves the
binary file in its output directory from "orca" to "orca-music"?

Why not give it a try anyway? :)

>  gnu/packages/music.scm | 57 ++++++++++++++++++++++++++++++++++++++++++
>  1 file changed, 57 insertions(+)
>
> diff --git a/gnu/packages/music.scm b/gnu/packages/music.scm
> index 9c8203aa80..1240027050 100644
> --- a/gnu/packages/music.scm
> +++ b/gnu/packages/music.scm
> @@ -6879,3 +6879,60 @@ (define-public musikcube
>  streaming audio server.")
>      (home-page "https://musikcube.com/")
>      (license license:bsd-3)))
> +(define-public orca-music
> +  (let ((commit "5ba56ca67baae3db140f8b7a2b2fc46bbac5602f") (revision "1"))
> +    (package
> +      (name "orca-music")
> +      ;; No upstream version numbers; Using commit instead.
> +      (version (git-version "0" revision commit))
> +      (source (origin
> +                (method git-fetch)
> +                (uri (git-reference
> +                      (url "https://git.sr.ht/~rabbits/orca")
> +                      (commit commit)))
> +                (file-name (git-file-name name version))
> +                (sha256
> +                 (base32
> +                  "1mnhk68slc6g5y5348vj86pmnz90a385jxvm3463fic79k90gckd"))))
> +      (build-system gnu-build-system)
> +      (arguments
> +       `(#:phases (modify-phases %standard-phases
> +                    (delete 'configure) ;; No autoconf
> +                    (delete 'check) ;; No make check
> +                    (replace 'build
> +                      (lambda* (#:key inputs outputs #:allow-other-keys)
> +                        (setenv "CC"
> +                                ,(cc-for-target))
> +                        (invoke "make" "release")))
> +                    (replace 'install
> +                      (lambda* (#:key outputs #:allow-other-keys)
> +                        (let* ((out (assoc-ref outputs "out")) (dest-bin (string-append
> +                                                                          out
> +                                                                          "/bin"))
> +                               (share (string-append out "/share"))
> +                               (dest-examples (string-append share "/examples"))
> +                               (dest-doc (string-append share "/doc")))
> +                          (install-file "./build/orca" dest-bin)
> +                          (copy-recursively "./examples" dest-examples)
> +                          (install-file "./README.md" dest-doc)))))))
> +      (inputs (list ncurses portmidi))
> +      (native-inputs (list pkg-config))
> +      ;; The below are needed as propagated inputs to let orca interact with
> +      ;; alsa/pulse MIDI.
> +      (propagated-inputs `(("alsa-plugins" ,alsa-plugins) ("alsa-plugins:pulseaudio" ,alsa-plugins
> +                                                           "pulseaudio")))
> +      (native-search-paths (list
> +                             (search-path-specification
> +                              (variable "TERMINFO_DIRS")
> +                              (files '("share/terminfo")))))
> +      (synopsis "musical live-coding environment")
> +      (description
> +       "This is the C implementation of the ORCΛ language and terminal
> +livecoding environment. It's designed to be power efficient. It can handle
> +large files, even if your terminal is small.
> +
> +Orca is not a synthesizer, but a flexible livecoding environment capable of
> +sending MIDI, OSC, and UDP to your audio/visual interfaces like Ableton,
> +Renoise, VCV Rack, or SuperCollider.")
> +      (home-page "https://100r.co/site/orca.html")
> +      (license license:expat))))

[bug#54529] [PATCH v4] Added orca-lang package

[Christopher Rodriguez]

---

> I think you could probably just add a post-install phase that moves the
> binary file in its output directory from "orca" to "orca-music"?
>
> Why not give it a try anyway? :)

Done! I actually made it a post-build, because I was manually selecting the
files to install anyway.

Updated patch below. Should be ready for merge, aside from unmentioned issues
and/or the propagated inputs (if those must be fixed). If that's the case, let
me know.

Otherwise, I look forward to contributing my first (of hopefully many!) bits of
code to Guix! Thank You all for Your help!

 gnu/packages/music.scm | 81 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)

diff --git a/gnu/packages/music.scm b/gnu/packages/music.scm
index 9c8203aa80..04b3cd4b4b 100644
--- a/gnu/packages/music.scm
+++ b/gnu/packages/music.scm
@@ -6879,3 +6879,84 @@ (define-public musikcube
 streaming audio server.")
     (home-page "https://musikcube.com/")
     (license license:bsd-3)))
+(define-public orca-music
+  (let ((commit "5ba56ca67baae3db140f8b7a2b2fc46bbac5602f") (revision "1"))
+    (package
+      (name "orca-music")
+      ;; No upstream version numbers; Using commit instead.
+      (version (git-version "0" revision commit))
+      (source (origin
+                (method git-fetch)
+                (uri (git-reference
+                      (url "https://git.sr.ht/~rabbits/orca")
+                      (commit commit)))
+                (file-name (git-file-name name version))
+                (sha256
+                 (base32
+                  "1mnhk68slc6g5y5348vj86pmnz90a385jxvm3463fic79k90gckd"))))
+      (build-system gnu-build-system)
+      (arguments
+       `(#:tests? #f
+         #:phases (modify-phases %standard-phases
+                    (delete 'configure) ;; No autoconf
+                    ;; (add-after 'wrap 'wrap-program
+                    ;;   (lambda* (#:key inputs outputs #:allow-other-keys)
+                    ;;     (let ((out (assoc-ref outputs "out"))
+                    ;;           (pulseaudio-plugins
+                    ;;            (assoc-ref inputs "alsa-plugins:pulseaudio")))
+                    ;;       (with-directory-excursion (string-append out "/bin")
+                    ;;         (for-each
+                    ;;          (lambda (binary)
+                    ;;            (wrap-program binary
+                    ;;              ;; Make QtWebEngineProcess available
+                    ;;              `("QTWEBENGINEPROCESS_PATH" ":" =
+                    ;;                ,(list (string-append
+                    ;;                        qtwebengine
+                    ;;                        "/lib/qt5/libexec/QtWebEngineProcess")))))
+                    ;;          ;; wrap all the binaries shipping with the package, except
+                    ;;          ;; for the wrappings created during the 'wrap standard phase.
+                    ;;          ;; This extends existing .calibre-real wrappers rather than
+                    ;;          ;; create ..calibre-real-real-s.
+                    ;;          ;; For more information see: https://issues.guix.gnu.org/43249
+                    ;;          (find-files "." (lambda (file stat)
+                    ;;                            (not (wrapper? file)))))))))                      
+                    (replace 'build
+                      (lambda* (#:key inputs outputs #:allow-other-keys)
+                        (setenv "CC"
+                                ,(cc-for-target))
+                        (invoke "make" "release")))
+                    (add-after 'build 'rename-orca
+                      (lambda* _
+                        (invoke "mv" "-v" "./build/orca" "./build/orca-music")))
+                    (replace 'install
+                      (lambda* (#:key outputs #:allow-other-keys)
+                        (let* ((out (assoc-ref outputs "out")) (dest-bin (string-append
+                                                                          out
+                                                                          "/bin"))
+                               (share (string-append out "/share"))
+                               (dest-examples (string-append share "/examples"))
+                               (dest-doc (string-append share "/doc")))
+                          (install-file "./build/orca-music" dest-bin)
+                          (copy-recursively "./examples" dest-examples)
+                          (install-file "./README.md" dest-doc)))))))
+      (inputs (list ncurses portmidi alsa-plugins `(,alsa-plugins "pulseaudio")))
+      (native-inputs (list pkg-config))
+      ;; The below are needed as propagated inputs to let orca interact with
+      ;; alsa/pulse MIDI.
+      ;; (propagated-inputs `(("alsa-plugins" ,alsa-plugins) ("alsa-plugins:pulseaudio" ,alsa-plugins
+      ;;                                                      "pulseaudio")))
+      (native-search-paths (list
+                             (search-path-specification
+                              (variable "TERMINFO_DIRS")
+                              (files '("share/terminfo")))))
+      (synopsis "musical live-coding environment")
+      (description
+       "This is the C implementation of the ORCΛ language and terminal
+livecoding environment. It's designed to be power efficient. It can handle
+large files, even if your terminal is small.
+
+Orca is not a synthesizer, but a flexible livecoding environment capable of
+sending MIDI, OSC, and UDP to your audio/visual interfaces like Ableton,
+Renoise, VCV Rack, or SuperCollider.")
+      (home-page "https://100r.co/site/orca.html")
+      (license license:expat))))
-- 
2.34.0

[bug#54529] Checking In

[Christopher Rodriguez]

[-- Attachment #1: Type: text/plain, Size: 355 bytes --]

Hello all,

Just want to confirm if this is waiting on me for anything. Trying to stay on
top of the issues I'm opening, as I'm planning to open more soon and don't want
to pollute the queue with a bunch of forgotten issues.

Is there anything else that needs done from my end concerning the above patch?

Thanks for Your time!

--

Christopher Rodriguez

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 832 bytes --]

[bug#54529] Checking In

[Christine Lemmer-Webber]

Christopher Rodriguez <yewscion@gmail.com> writes:

> [[PGP Signed Part:Undecided]]
> Hello all,
>
> Just want to confirm if this is waiting on me for anything. Trying to stay on
> top of the issues I'm opening, as I'm planning to open more soon and don't want
> to pollute the queue with a bunch of forgotten issues.
>
> Is there anything else that needs done from my end concerning the above patch?
>
> Thanks for Your time!

I've been overwhelmed with other things, but I did try the patch out and
it did work great.  Then I got overwhelmed again.  ;P

I think I made a suggestion about the moving the binary name after
install bit.  Did you / could you give that a try?

[bug#54529] Checking In

[Christopher Rodriguez]

[-- Attachment #1: Type: text/plain, Size: 1226 bytes --]


Christine Lemmer-Webber <cwebber@dustycloud.org> writes:

> Christopher Rodriguez <yewscion@gmail.com> writes:
>
>> [[PGP Signed Part:Undecided]]
>> Hello all,
>>
>> Just want to confirm if this is waiting on me for anything. Trying to stay on
>> top of the issues I'm opening, as I'm planning to open more soon and don't want
>> to pollute the queue with a bunch of forgotten issues.
>>
>> Is there anything else that needs done from my end concerning the above patch?
>>
>> Thanks for Your time!
>
> I've been overwhelmed with other things, but I did try the patch out and
> it did work great.  Then I got overwhelmed again.  ;P
>
> I think I made a suggestion about the moving the binary name after
> install bit.  Did you / could you give that a try?

Hi Christine!

I did give it a try, and it worked! I actually decided to do it after
the build step, before the install.

The above patch should have the updated version, though I do notice now
(upon reading through it again) that it includes a rather large section
I had commented out during debugging.

I'll remove that and send a revised patch tonight; With the package name issue
out of the way I believe this /should/ be ready to merge.

--

Christopher Rodriguez

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 832 bytes --]

[bug#54529] Checking In

[Christine Lemmer-Webber]

Hello!  Checking in on this again.  If you give an updated version of
the patch, it can be merged I think.  With the commented out part, I'm
uncertain whether or not it was commented out because it's no longer
needed or because it was but you were debugging, based on what you've
said so that's the main concern I have.

Could you also use git format-patch for the next version you send?
That'll make it easy to apply!

Thanks!  Sorry for the delays on this review cycle!  It's busy here.
 - Christine

Christopher Rodriguez <yewscion@gmail.com> writes:

> [[PGP Signed Part:Undecided]]
>
> Christine Lemmer-Webber <cwebber@dustycloud.org> writes:
>
>> Christopher Rodriguez <yewscion@gmail.com> writes:
>>
>>> [[PGP Signed Part:Undecided]]
>>> Hello all,
>>>
>>> Just want to confirm if this is waiting on me for anything. Trying to stay on
>>> top of the issues I'm opening, as I'm planning to open more soon and don't want
>>> to pollute the queue with a bunch of forgotten issues.
>>>
>>> Is there anything else that needs done from my end concerning the above patch?
>>>
>>> Thanks for Your time!
>>
>> I've been overwhelmed with other things, but I did try the patch out and
>> it did work great.  Then I got overwhelmed again.  ;P
>>
>> I think I made a suggestion about the moving the binary name after
>> install bit.  Did you / could you give that a try?
>
> Hi Christine!
>
> I did give it a try, and it worked! I actually decided to do it after
> the build step, before the install.
>
> The above patch should have the updated version, though I do notice now
> (upon reading through it again) that it includes a rather large section
> I had commented out during debugging.
>
> I'll remove that and send a revised patch tonight; With the package name issue
> out of the way I believe this /should/ be ready to merge.

[bug#54529] Checking In

[Christopher Rodriguez]

[-- Attachment #1: Type: text/plain, Size: 1291 bytes --]


Christine Lemmer-Webber <cwebber@dustycloud.org> writes:

> Hello!  Checking in on this again.

Hi Christine!

> If you give an updated version of the patch, it can be merged I think.
> With the commented out part, I'm uncertain whether or not it was
> commented out because it's no longer needed or because it was but you
> were debugging, based on what you've said so that's the main concern I
> have.

I will rebase the patch on a new pull of guix from git, clean it up, and
send it here within the next hour or so. That way, I'll be sure that it
still works with all of the changes since then and now.

> Could you also use git format-patch for the next version you send?
> That'll make it easy to apply!

Between my last comment and now I've become used to the `git send-email`
style workflow. Is that what You are asking for? If not, let me know and
I will send a patch in the preferred format ASAP.

> Thanks!  Sorry for the delays on this review cycle!  It's busy here.

No worries! Frankly, looking at the number and depth of the commits that
GNU Guix gets on a daily basis, I'm very impressed with the speed with
which our maintainers work! Thank You all for Your efforts; they are
very appreciated!

>  - Christine

-- 

Christopher Rodriguez

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 832 bytes --]

[bug#54529] Checking In

[Christine Lemmer-Webber]

Christopher Rodriguez <yewscion@gmail.com> writes:

> [[PGP Signed Part:Undecided]]
>
> Christine Lemmer-Webber <cwebber@dustycloud.org> writes:
>
>> Hello!  Checking in on this again.
>
> Hi Christine!
>
>> If you give an updated version of the patch, it can be merged I think.
>> With the commented out part, I'm uncertain whether or not it was
>> commented out because it's no longer needed or because it was but you
>> were debugging, based on what you've said so that's the main concern I
>> have.
>
> I will rebase the patch on a new pull of guix from git, clean it up, and
> send it here within the next hour or so. That way, I'll be sure that it
> still works with all of the changes since then and now.

Awesome!

>> Could you also use git format-patch for the next version you send?
>> That'll make it easy to apply!
>
> Between my last comment and now I've become used to the `git send-email`
> style workflow. Is that what You are asking for? If not, let me know and
> I will send a patch in the preferred format ASAP.

Yep, that's what i mean :)

>> Thanks!  Sorry for the delays on this review cycle!  It's busy here.
>
> No worries! Frankly, looking at the number and depth of the commits that
> GNU Guix gets on a daily basis, I'm very impressed with the speed with
> which our maintainers work! Thank You all for Your efforts; they are
> very appreciated!
>
>>  - Christine

I'm not a maintainer, and not nearly often enough a reviewer (or
contributor), but I agree :)

[bug#54529] [PATCH v5] Added orca-music package.

[Christopher Rodriguez]

[Ticket: 54529]
---
 gnu/packages/music.scm | 58 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/gnu/packages/music.scm b/gnu/packages/music.scm
index 1c34ae621c..765e8440df 100644
--- a/gnu/packages/music.scm
+++ b/gnu/packages/music.scm
@@ -6770,3 +6770,61 @@ (define-public quodlibet
 a tag editor, which can also be invoked as a standalone program, and further
 supports streaming audio and feeds (such as podcasts).")
     (license license:gpl2+)))
+
+(define-public orca-music
+  (let ((commit "e55b8fdc3606341345938d5b24b2d9d9326afdb5") (revision "1"))
+    (package
+      (name "orca-music")
+      ;; No upstream version numbers; Using commit instead.
+      (version (git-version "0" revision commit))
+      (source (origin
+                (method git-fetch)
+                (uri (git-reference
+                      (url "https://git.sr.ht/~rabbits/orca")
+                      (commit commit)))
+                (file-name (git-file-name name version))
+                (sha256
+                 (base32
+                  "0xf5i9vd2wyrhvfp68j5gvd40iqm9rf6g1p74jan7d875g6kpppq"))))
+      (build-system gnu-build-system)
+      (arguments
+       `(#:tests? #f
+         #:phases
+         (modify-phases %standard-phases
+           (delete 'configure) ;No autoconf
+           (replace 'build
+             (lambda* (#:key inputs outputs #:allow-other-keys)
+               (setenv "CC"
+                       ,(cc-for-target))
+               (invoke "make" "release")))
+           (add-after 'build 'rename-orca
+             (lambda* _
+               (invoke "mv" "-v" "./build/orca" "./build/orca-music")))
+           (replace 'install
+             (lambda* (#:key outputs #:allow-other-keys)
+               (let* ((out (assoc-ref outputs "out")) (dest-bin (string-append
+                                                                 out "/bin"))
+                      (share (string-append out "/share"))
+                      (dest-examples (string-append share "/examples"))
+                      (dest-doc (string-append share "/doc")))
+                 (install-file "./build/orca-music" dest-bin)
+                 (copy-recursively "./examples" dest-examples)
+                 (install-file "./README.md" dest-doc)))))))
+      (inputs (list ncurses portmidi alsa-plugins
+                    `(,alsa-plugins "pulseaudio")))
+      (native-inputs (list pkg-config))
+      (native-search-paths
+       (list (search-path-specification
+              (variable "TERMINFO_DIRS")
+              (files '("share/terminfo")))))
+      (synopsis "Musical live-coding environment")
+      (description
+       "This is the C implementation of the ORCΛ language and terminal
+livecoding environment.  It's designed to be power efficient.  It can handle
+large files, even if your terminal is small.
+
+Orca is not a synthesizer, but a flexible livecoding environment capable of
+sending MIDI, OSC, and UDP to your audio/visual interfaces like Ableton,
+Renoise, VCV Rack, or SuperCollider.")
+      (home-page "https://100r.co/site/orca.html")
+      (license license:expat))))

base-commit: d4482e9a9ebe61197a0756ce9048fcb895e6f552
-- 
2.36.1

[bug#54529] [PATCH v5] Added orca-music package.

[Christine Lemmer-Webber]

Cool, I pushed it upstream.

This last version was good, the only thing missing which would be good
in future versions is that it would be good to include the Guix-style
(ie, changelog entry type) commit message within the email you send... I
filled it in, but it looks like so:

> gnu: Add orca-music.
> 
> * gnu/packages/music.scm (orca-music): New variable.

With that, it's good enough to push, so I did!  Congrats and thanks,
I look forward to playing with this myself in my (ha ha) downtime
(ha ha ha ha). :)

 - Christine

Christopher Rodriguez <yewscion@gmail.com> writes:

> [Ticket: 54529]
> ---
>  gnu/packages/music.scm | 58 ++++++++++++++++++++++++++++++++++++++++++
>  1 file changed, 58 insertions(+)
>
> diff --git a/gnu/packages/music.scm b/gnu/packages/music.scm
> index 1c34ae621c..765e8440df 100644
> --- a/gnu/packages/music.scm
> +++ b/gnu/packages/music.scm
> @@ -6770,3 +6770,61 @@ (define-public quodlibet
>  a tag editor, which can also be invoked as a standalone program, and further
>  supports streaming audio and feeds (such as podcasts).")
>      (license license:gpl2+)))
> +
> +(define-public orca-music
> +  (let ((commit "e55b8fdc3606341345938d5b24b2d9d9326afdb5") (revision "1"))
> +    (package
> +      (name "orca-music")
> +      ;; No upstream version numbers; Using commit instead.
> +      (version (git-version "0" revision commit))
> +      (source (origin
> +                (method git-fetch)
> +                (uri (git-reference
> +                      (url "https://git.sr.ht/~rabbits/orca")
> +                      (commit commit)))
> +                (file-name (git-file-name name version))
> +                (sha256
> +                 (base32
> +                  "0xf5i9vd2wyrhvfp68j5gvd40iqm9rf6g1p74jan7d875g6kpppq"))))
> +      (build-system gnu-build-system)
> +      (arguments
> +       `(#:tests? #f
> +         #:phases
> +         (modify-phases %standard-phases
> +           (delete 'configure) ;No autoconf
> +           (replace 'build
> +             (lambda* (#:key inputs outputs #:allow-other-keys)
> +               (setenv "CC"
> +                       ,(cc-for-target))
> +               (invoke "make" "release")))
> +           (add-after 'build 'rename-orca
> +             (lambda* _
> +               (invoke "mv" "-v" "./build/orca" "./build/orca-music")))
> +           (replace 'install
> +             (lambda* (#:key outputs #:allow-other-keys)
> +               (let* ((out (assoc-ref outputs "out")) (dest-bin (string-append
> +                                                                 out "/bin"))
> +                      (share (string-append out "/share"))
> +                      (dest-examples (string-append share "/examples"))
> +                      (dest-doc (string-append share "/doc")))
> +                 (install-file "./build/orca-music" dest-bin)
> +                 (copy-recursively "./examples" dest-examples)
> +                 (install-file "./README.md" dest-doc)))))))
> +      (inputs (list ncurses portmidi alsa-plugins
> +                    `(,alsa-plugins "pulseaudio")))
> +      (native-inputs (list pkg-config))
> +      (native-search-paths
> +       (list (search-path-specification
> +              (variable "TERMINFO_DIRS")
> +              (files '("share/terminfo")))))
> +      (synopsis "Musical live-coding environment")
> +      (description
> +       "This is the C implementation of the ORCΛ language and terminal
> +livecoding environment.  It's designed to be power efficient.  It can handle
> +large files, even if your terminal is small.
> +
> +Orca is not a synthesizer, but a flexible livecoding environment capable of
> +sending MIDI, OSC, and UDP to your audio/visual interfaces like Ableton,
> +Renoise, VCV Rack, or SuperCollider.")
> +      (home-page "https://100r.co/site/orca.html")
> +      (license license:expat))))
>
> base-commit: d4482e9a9ebe61197a0756ce9048fcb895e6f552