;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2014, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (guix build git)
  #:use-module (web uri)
  #:use-module (web client)
  #:use-module (web response)
  #:use-module (guix serialization)
  #:use-module (guix build utils)
  #:use-module (srfi srfi-11)
  #:use-module (ice-9 format)
  #:use-module (ice-9 match)
  #:export (git-fetch))

;;; Commentary:
;;;
;;; This is the build-side support code of (guix git-download).  It allows a
;;; Git repository to be cloned and checked out at a specific commit.
;;;
;;; Code:

(define (urls-for-item item)
  "Return the fallback nar URL for ITEM--e.g., \"cabbag3…-foo-1.2-checkout\"."
  ;; TODO: Use the /gzip URLs, make it configurable, and use TLS.
  (list (string-append "http://mirror.hydra.gnu.org/guix/nar/" item)
        (string-append "http://berlin.guixsd.org/nar/" item)))

(define (download-nar item directory)
  "Download Git checkout ITEM to DIRECTORY as a nar."
  (setvbuf (current-output-port) _IONBF)
  (setvbuf (current-error-port) _IONBF)

  (let loop ((urls (urls-for-item item)))
    (match urls
      ((url rest ...)
       (format #t "Trying content-addressed mirror at ~a...~%"
               (uri-host (string->uri url)))
       (let-values (((response port)
                     (http-get url #:streaming? #t)))
         (if (= 200 (response-code response))
             (let ((size (response-content-length response)))
               (if size
                   (format #t "Downloading from ~a (~,2h MiB)...~%"
                           url (/ size (expt 2 20.)))
                   (format #t "Downloading from ~a...~%" url))
               (restore-file port directory)
               (close-port port)
               #t)
             (loop rest))))
      (()
       #f))))

(define* (git-fetch url commit directory
                    #:key (git-command "git") recursive?)
  "Fetch COMMIT from URL into DIRECTORY.  COMMIT must be a valid Git commit
identifier.  When RECURSIVE? is true, all the sub-modules of URL are fetched,
recursively.  Return #t on success, #f otherwise."

  ;; Disable TLS certificate verification.  The hash of the checkout is known
  ;; in advance anyway.
  (setenv "GIT_SSL_NO_VERIFY" "true")

  ;; We cannot use "git clone --recursive" since the following "git checkout"
  ;; effectively removes sub-module checkouts as of Git 2.6.3.
  (if (zero? (system* git-command "clone" url directory))
      (with-directory-excursion directory
        (system* git-command "tag" "-l")
        (and (zero? (system* git-command "checkout" commit))
             (begin
               (when recursive?
                 ;; Now is the time to fetch sub-modules.
                 (unless (zero? (system* git-command "submodule" "update"
                                         "--init" "--recursive"))
                   (error "failed to fetch sub-modules" url))

                 ;; In sub-modules, '.git' is a flat file, not a directory,
                 ;; so we can use 'find-files' here.
                 (for-each delete-file-recursively
                           (find-files directory "^\\.git$")))

               ;; The contents of '.git' vary as a function of the current
               ;; status of the Git repo.  Since we want a fixed output, this
               ;; directory needs to be taken out.
               (delete-file-recursively ".git")
               #t)))
      (download-nar (basename directory) directory)))

;;; git.scm ends here