syntax check before commit and patch: net-perl-psyc

[ng0 <ng0@we.make.ritual.n0.is>]

[-- Attachment #1: Type: text/plain, Size: 3804 bytes --]

Hi,

the following is an insert minus the header etc of
net-perl-psyc. Before I commit and send in a patch, I'd
like to check if there's anything I can improve.

I have not yet set a synopsis and description, this
was just as a place holder.


;; highly optional dependencies: rxaudio (mp3 binary from 1996)
;; opt. perl: MP3::List (psycmp3), Curses (psycion), pwd.pl
;; (psyccmd), SGI::FAM module (psycfilemonitor); for full
;; functionality package all except MP3::List.
(define-public perl-net-psyc
  (let ((commit "4176f5236e73e99391c0877152d5596ab0a9b154"))
    (package
      (name "perl-net-psyc")
      (version (string-append "1.0" "-"
                              (string-take commit 7)))
      (source (origin
                (method git-fetch)
                (uri (git-reference
                      (url "git://git.psyced.org/git/perlpsyc")
                      (commit commit)))
                (file-name (string-append name "-" version))
                (sha256
                 (base32
                  "19msvr1kriqa6n8cnk8z96xd5i0v5cy2y52jsj08vaj79b4m7sph"))))
      (build-system perl-build-system)
      (arguments
       `(#:phases
         (modify-phases %standard-phases
           (delete 'configure)
           (delete 'build)
           (replace
            'install
            (lambda* (#:key outputs #:allow-other-keys)
              (let* ((out (assoc-ref outputs "out"))
                     (doc (string-append out "/share/doc/perl-net-psyc"))
                     (libpsyc (string-append out "/lib/psyc/ion"))
                     (libperl (string-append out "/lib/perl5/site_perl/"
                                             ,(package-version perl)))
                     (bin (string-append out "/bin")))
                (copy-recursively "lib/perl5" libperl)
                (copy-recursively "lib/psycion" libpsyc)
                (copy-recursively "bin" bin)
                (install-file "cgi/psycpager" (string-append doc "/cgi"))
                (copy-recursively "contrib" (string-append doc "/contrib"))
                (copy-recursively "hooks" (string-append doc "/hooks"))
                (copy-recursively "sdj" (string-append doc "/sdj"))
                (install-file "README.txt" doc)
                (install-file "TODO.txt" doc)
                #t)))
           (add-after 'install 'wrap-programs
                      (lambda* (#:key outputs #:allow-other-keys)
                        ;; Make sure all executables in "bin" find the Perl modules
                        ;; provided by this package at runtime.
                        (let* ((out  (assoc-ref outputs "out"))
                               (bin  (string-append out "/bin/"))
                               (path (string-append out "/lib/perl5/site_perl")))
                          (for-each (lambda (file)
                                      (wrap-program file
                                        `("PERL5LIB" ":" prefix (,path))))
                                    (find-files bin "\\.*$"))
                          ;; XXX: hooks/dpa2psyc,examples/{recvtest,sendtest},
                          ;; cgi/psycpager,contrib/{makenoise,keefchat
                          ;; contrib/MovableTypeBlog/plugins/psyc.pl
                          #t))))))
      (description
       "Perl implementation of PSYC protocol plus psycion, remotor, psycmp3 etc.")
      (synopsis
       "Perl implementation of PSYC protocol plus psycion, remotor, psycmp3 etc.")
      (home-page "http://perlpsyc.pages.de")
      ;;dual licensed: gpl2+ Artistic
      (license (list gpl2+ (package-license perl))))))



thanks,
--
♥Ⓐ ng0
For non-prism friendly talk find me on
psyced.org / loupsycedyglgamf.onion

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 195 bytes --]