[PATCH 1/5] gnu: Add efl.

[PATCH 1/5] gnu: Add efl.

[Tomáš Čech]

* gnu/packages/efl.scm: New file
* gnu-system.am (GNU_SYSTEM_MODULES): Add it.
---
 gnu-system.am        |   1 +
 gnu/packages/efl.scm | 115 +++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 116 insertions(+)
 create mode 100644 gnu/packages/efl.scm

diff --git a/gnu-system.am b/gnu-system.am
index 851068e..e559fd4 100644
--- a/gnu-system.am
+++ b/gnu-system.am
@@ -87,6 +87,7 @@ GNU_SYSTEM_MODULES =				\
   gnu/packages/dwm.scm				\
   gnu/packages/ebook.scm			\
   gnu/packages/ed.scm				\
+  gnu/packages/efl.scm				\
   gnu/packages/elf.scm				\
   gnu/packages/emacs.scm			\
   gnu/packages/enchant.scm			\
diff --git a/gnu/packages/efl.scm b/gnu/packages/efl.scm
new file mode 100644
index 0000000..5d15832
--- /dev/null
+++ b/gnu/packages/efl.scm
@@ -0,0 +1,115 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2015 Tomáš Čech <sleep_walker@suse.cz>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages efl)
+  #:use-module ((guix licenses) #:prefix license:)
+  #:use-module (guix packages)
+  #:use-module (guix download)
+  #:use-module (guix build-system gnu)
+  #:use-module (gnu packages)
+  #:use-module (gnu packages bash)
+  #:use-module (gnu packages curl)
+  #:use-module (gnu packages fontutils)
+  #:use-module (gnu packages fribidi)
+  #:use-module (gnu packages game-development)
+  #:use-module (gnu packages gl)
+  #:use-module (gnu packages glib)
+  #:use-module (gnu packages gnome)
+  #:use-module (gnu packages gstreamer)
+  #:use-module (gnu packages image)
+  #:use-module (gnu packages linux)
+  #:use-module (gnu packages lua)
+  #:use-module (gnu packages openssl)
+  #:use-module (gnu packages pulseaudio)
+  #:use-module (gnu packages photo)
+  #:use-module (gnu packages pkg-config)
+  #:use-module (gnu packages valgrind)
+  #:use-module (gnu packages xorg))
+
+(define-public efl
+  (package
+    (name "efl")
+    (version "1.13.0")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "http://download.enlightenment.org/rel/libs/efl/efl-" version ".tar.gz"))
+              (sha256
+               (base32 "0mwkxsfi5masiy6qfmdqy1j15cfz7nz8g8jq2bf3w501rpa9gxvz"))))
+    (build-system gnu-build-system)
+    (native-inputs
+     `(("pkg-config" ,pkg-config)))
+    (inputs
+     `(("alsa-lib" ,alsa-lib)
+       ("bash" ,bash)
+       ("compositeproto" ,compositeproto)
+       ("curl" ,curl)
+       ("giflib" ,giflib)
+       ("gstreamer" ,gstreamer)
+       ("gst-plugins-base" ,gst-plugins-base)
+       ("libexif" ,libexif)
+       ("libjpeg" ,libjpeg)
+       ("librsvg" ,librsvg)
+       ("libtiff" ,libtiff)
+       ("libx11" ,libx11)
+       ("libxcomposite" ,libxcomposite)
+       ("libxcursor" ,libxcursor)
+       ("libxdmcp" ,libxdmcp)
+       ("libxext" ,libxext)
+       ("libxi" ,libxi)
+       ("libxkbfile" ,libxkbfile)
+       ("libxinerama" ,libxinerama)
+       ("libxp" ,libxp)
+       ("libxrandr" ,libxrandr)
+       ("libxscrnsaver" ,libxscrnsaver)
+       ("libxtst" ,libxtst)
+       ("mesa" ,mesa)
+       ("printproto" ,printproto)
+       ("scrnsaverproto" ,scrnsaverproto)
+       ("valgrind" ,valgrind)
+       ("xextproto" ,xextproto)
+       ("xinput" ,xinput)
+       ("xpr" ,xpr)
+       ("xproto" ,xproto)))
+    (propagated-inputs
+     `(("bullet" ,bullet)
+       ("dbus" ,dbus)
+       ("eudev" ,eudev)
+       ("fontconfig" ,fontconfig)
+       ("freetype" ,freetype)
+       ("fribidi" ,fribidi)
+       ("glib" ,glib)
+       ("libpng" ,libpng)
+       ("libsndfile" ,libsndfile)
+       ("luajit" ,luajit)
+       ("openssl" ,openssl)
+       ("pulseaudio" ,pulseaudio)
+       ("util-linux" ,util-linux)))
+    (arguments
+     `(#:configure-flags '("--disable-silent-rules")
+       #:phases
+       (alist-cons-before
+        'configure 'patch-config-files
+        (lambda _
+          (substitute* "po/Makefile.in.in"
+            (("/bin/sh") (which "bash"))))
+        %standard-phases)))
+    (home-page "http://www.enlightenment.org")
+    (synopsis "Enlightenment Foundation Libraries")
+    (description
+     "EFL is toolkit used mainly for Enlightenment, but is used for more applications because it is resource friendly and energy efficient.")
+    (license (list license:bsd-2 license:lgpl2.1 license:zlib)))) ; different parts under different licenses
-- 
2.0.5

[PATCH 2/5] gnu: Add elementary.

[Tomáš Čech]

* gnu/packages/efl (elementary): New variable.
---
 gnu/packages/efl.scm | 20 ++++++++++++++++++++
 1 file changed, 20 insertions(+)

diff --git a/gnu/packages/efl.scm b/gnu/packages/efl.scm
index 5d15832..687137e 100644
--- a/gnu/packages/efl.scm
+++ b/gnu/packages/efl.scm
@@ -113,3 +113,23 @@
     (description
      "EFL is toolkit used mainly for Enlightenment, but is used for more applications because it is resource friendly and energy efficient.")
     (license (list license:bsd-2 license:lgpl2.1 license:zlib)))) ; different parts under different licenses
+
+(define-public elementary
+  (package
+    (name "elementary")
+    (version "1.13.0")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "http://download.enlightenment.org/rel/libs/elementary/elementary-" version ".tar.gz"))
+              (sha256
+               (base32 "133p4yaynmy37yhk2gxwlc8a2n2wy7cbh4rd7nsnl5929wqb9waj"))))
+    (build-system gnu-build-system)
+    (native-inputs
+     `(("pkg-config" ,pkg-config)))
+    (inputs
+     `(("efl" ,efl)))
+    (home-page "http://www.enlightenment.org")
+    (synopsis "Widget library of Enlightenment world")
+    (description
+     "Widget library/toolkit for EFL based applications.")
+    (license license:lgpl2.1)))
-- 
2.0.5

[PATCH 3/5] gnu: Add evas-generic-loaders

[Tomáš Čech]

* gnu/packages/efl.scm (evas-generic-loaders): New variable.
---
 gnu/packages/efl.scm | 28 ++++++++++++++++++++++++++++
 1 file changed, 28 insertions(+)

diff --git a/gnu/packages/efl.scm b/gnu/packages/efl.scm
index 687137e..3d5ed74 100644
--- a/gnu/packages/efl.scm
+++ b/gnu/packages/efl.scm
@@ -27,6 +27,7 @@
   #:use-module (gnu packages fontutils)
   #:use-module (gnu packages fribidi)
   #:use-module (gnu packages game-development)
+  #:use-module (gnu packages ghostscript)
   #:use-module (gnu packages gl)
   #:use-module (gnu packages glib)
   #:use-module (gnu packages gnome)
@@ -35,6 +36,7 @@
   #:use-module (gnu packages linux)
   #:use-module (gnu packages lua)
   #:use-module (gnu packages openssl)
+  #:use-module (gnu packages pdf)
   #:use-module (gnu packages pulseaudio)
   #:use-module (gnu packages photo)
   #:use-module (gnu packages pkg-config)
@@ -133,3 +135,29 @@
     (description
      "Widget library/toolkit for EFL based applications.")
     (license license:lgpl2.1)))
+
+(define-public evas-generic-loaders
+  (package
+    (name "evas-generic-loaders")
+    (version "1.13.0")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "http://download.enlightenment.org/rel/libs/evas_generic_loaders/evas_generic_loaders-" version ".tar.gz"))
+              (sha256
+               (base32 "16yzjk58bxsd0rlnpzrr8as9fxjjiq01swzhpadsgkmq33abgg63"))))
+    (build-system gnu-build-system)
+    (native-inputs
+     `(("pkg-config" ,pkg-config)))
+    (inputs
+     `(("gstreamer" ,gstreamer)
+       ("gst-plugins-base" ,gst-plugins-base)
+       ("efl" ,efl)
+       ("librsvg" ,librsvg)
+       ("libspectre" ,libspectre)
+       ("poppler" ,poppler)
+       ))
+    (home-page "http://www.enlightenment.org")
+    (synopsis "Plugins for integration of various file types into Evas")
+    (description
+     "Set of generic loaders allowing to open pictures, documents and media files into Evas (EFL canvas library)")
+    (license license:gpl2+)))
-- 
2.0.5

[PATCH 4/5] gnu: Add emotion-generic-players

[Tomáš Čech]

* gnu/packages/efl.scm (emotion-generic-players): New variable.
---
 gnu/packages/efl.scm | 22 ++++++++++++++++++++++
 1 file changed, 22 insertions(+)

diff --git a/gnu/packages/efl.scm b/gnu/packages/efl.scm
index 3d5ed74..d69cb5c 100644
--- a/gnu/packages/efl.scm
+++ b/gnu/packages/efl.scm
@@ -41,6 +41,7 @@
   #:use-module (gnu packages photo)
   #:use-module (gnu packages pkg-config)
   #:use-module (gnu packages valgrind)
+  #:use-module (gnu packages video)
   #:use-module (gnu packages xorg))
 
 (define-public efl
@@ -161,3 +162,24 @@
     (description
      "Set of generic loaders allowing to open pictures, documents and media files into Evas (EFL canvas library)")
     (license license:gpl2+)))
+
+(define-public emotion-generic-players
+  (package
+    (name "emotion-generic-players")
+    (version "1.13.0")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "http://download.enlightenment.org/rel/libs/emotion_generic_players/emotion_generic_players-" version ".tar.gz"))
+              (sha256
+               (base32 "0gin3cjhfj75v0gjsvv7harbj4fs4r7r1sfi74ncxzna71nrd8r3"))))
+    (build-system gnu-build-system)
+    (native-inputs
+     `(("pkg-config" ,pkg-config)))
+    (inputs
+     `(("efl" ,efl)
+       ("vlc" ,vlc)))
+    (home-page "http://www.enlightenment.org")
+    (synopsis "Plugins for integrating media players in EFL based applications")
+    (description
+     "Set of generic media players allowing to open video files through emotion. Useful only for emotion library based applications.")
+    (license license:bsd-2)))
-- 
2.0.5

[PATCH 5/5] gnu: Add terminology.

[Tomáš Čech]

* gnu/packages/efl.scm (terminology): New variable.
---
 gnu/packages/efl.scm | 21 +++++++++++++++++++++
 1 file changed, 21 insertions(+)

diff --git a/gnu/packages/efl.scm b/gnu/packages/efl.scm
index d69cb5c..61bc22b 100644
--- a/gnu/packages/efl.scm
+++ b/gnu/packages/efl.scm
@@ -183,3 +183,24 @@
     (description
      "Set of generic media players allowing to open video files through emotion. Useful only for emotion library based applications.")
     (license license:bsd-2)))
+
+(define-public terminology
+  (package
+    (name "terminology")
+    (version "0.8.0")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "http://download.enlightenment.org/rel/apps/terminology/terminology-" version ".tar.gz"))
+              (sha256
+               (base32 "0a767ixackzmhb2awrhjy7q6vsivsd54wc434i617xiw095x843s"))))
+    (build-system gnu-build-system)
+    (native-inputs
+     `(("pkg-config" ,pkg-config)))
+    (inputs
+     `(("efl" ,efl)
+       ("elementary" ,elementary)))
+    (home-page "http://www.enlightenment.org")
+    (synopsis "Powerful terminal emulator based on EFL")
+    (description
+     "Fast but advanced terminal emulator running in X or framebuffer")
+    (license license:bsd-2)))
-- 
2.0.5

Re: [PATCH 4/5] gnu: Add emotion-generic-players

[Andreas Enge]

Hello,

just a quick comment on the descriptions. It would be good to write full 
sentences, for instance:

On Thu, Feb 26, 2015 at 01:31:12AM +0100, Tomáš Čech wrote:
> +     "Set of generic media players allowing to open video files through emotion. Useful only for emotion library based applications.")

"Emotion Generic Players provides/consists of/is a set of generic ...
It is useful only for ...".

I think it would also be good to expand a bit where possible, and to introduce
the word "enlightenment" in each of these packages (by replacing "EFL" with
"Enlightenment Foundation Libraries", for instance, or adding a sentence like
"It is part of the Enlightenment desktop environment").

Maybe call the file enlightenment.scm?

Andreas

Re: [PATCH 4/5] gnu: Add emotion-generic-players

[Tomáš Čech]

[-- Attachment #1: Type: text/plain, Size: 1692 bytes --]

Hello,

thanks for review.

On Thu, Feb 26, 2015 at 11:23:27AM +0100, Andreas Enge wrote:
>Hello,
>
>just a quick comment on the descriptions. It would be good to write full
>sentences, for instance:
>
>On Thu, Feb 26, 2015 at 01:31:12AM +0100, Tomáš Čech wrote:
>> +     "Set of generic media players allowing to open video files through emotion. Useful only for emotion library based applications.")
>
>"Emotion Generic Players provides/consists of/is a set of generic ...
>It is useful only for ...".

I agree that sentences may be better, I only suck at it. I'll try
to improvide it  or I can accept any recommendations in the meantime.

>I think it would also be good to expand a bit where possible, and to introduce
>the word "enlightenment" in each of these packages (by replacing "EFL" with
>"Enlightenment Foundation Libraries",

I do agree that use of "Enlightenment Foundation Libraries" instead of
"EFL" could make it more enjoyable to read, but we could expand also
Gimp toolkit, Tool Command Language, ...

Those who would need such these packages will know and it won't help
to others anyway.

Synopsis of efl package will show you "Enlightenment Foundation Libraries".

>for instance, or adding a sentence like
>"It is part of the Enlightenment desktop environment").

Enlightenment is using the same libraries (they were developed for
Enlightenment) but the libraries are much more generic. It's like
relationship between Qt and KDE, only with reversed history order.

>Maybe call the file enlightenment.scm?

I believe efl.scm is more accurate as the packages there would be EFL
based but not necessarily Enlightenment related.

[-- Attachment #2: Type: application/pgp-signature, Size: 181 bytes --]

Re: [PATCH 4/5] gnu: Add emotion-generic-players

[Andreas Enge]

On Thu, Feb 26, 2015 at 12:14:43PM +0100, Tomáš Čech wrote:
> I do agree that use of "Enlightenment Foundation Libraries" instead of
> "EFL" could make it more enjoyable to read, but we could expand also
> Gimp toolkit, Tool Command Language, ...
> Those who would need such these packages will know and it won't help
> to others anyway.

Here it is not a question of enjoyment; personally, I have heard of
Enlightenment, but would not be able to understand EFL immediately.

> I believe efl.scm is more accurate as the packages there would be EFL
> based but not necessarily Enlightenment related.

Okay, I see.

Andreas

Re: [PATCH 5/5] gnu: Add terminology.

[宋文武]

Tomáš Čech <sleep_walker@suse.cz> writes:

> * gnu/packages/efl.scm (terminology): New variable.
I'll call this file 'enlightenment.scm', since you
plan to add applications and wm of E19 to this file right?

> ---
>  gnu/packages/efl.scm | 21 +++++++++++++++++++++
>  1 file changed, 21 insertions(+)
>
> diff --git a/gnu/packages/efl.scm b/gnu/packages/efl.scm
> index d69cb5c..61bc22b 100644
> --- a/gnu/packages/efl.scm
> +++ b/gnu/packages/efl.scm
> @@ -183,3 +183,24 @@
>      (description
>       "Set of generic media players allowing to open video files through emotion. Useful only for emotion library based applications.")
>      (license license:bsd-2)))
> +
> +(define-public terminology
> +  (package
> +    (name "terminology")
> +    (version "0.8.0")
> +    (source (origin
> +              (method url-fetch)
> +              (uri (string-append "http://download.enlightenment.org/rel/apps/terminology/terminology-" version ".tar.gz"))
> +              (sha256
> +               (base32 "0a767ixackzmhb2awrhjy7q6vsivsd54wc434i617xiw095x843s"))))
> +    (build-system gnu-build-system)
> +    (native-inputs
> +     `(("pkg-config" ,pkg-config)))
> +    (inputs
> +     `(("efl" ,efl)
> +       ("elementary" ,elementary)))
> +    (home-page "http://www.enlightenment.org")
> +    (synopsis "Powerful terminal emulator based on EFL")
> +    (description
> +     "Fast but advanced terminal emulator running in X or framebuffer")
> +    (license license:bsd-2)))
> -- 
> 2.0.5
And please wrap long line to 80 characters,
I think './pre-inst-env guix lint efl' should complain this ;-)

Great work!
I'm very excite to use terminology on GuixSD.

Re: [PATCH 4/5] gnu: Add emotion-generic-players

[宋文武]

Tomáš Čech <sleep_walker@suse.cz> writes:

> Hello,
>
> thanks for review.
>
> On Thu, Feb 26, 2015 at 11:23:27AM +0100, Andreas Enge wrote:
>>Hello,
>>
>>just a quick comment on the descriptions. It would be good to write full
>>sentences, for instance:
>>
>>On Thu, Feb 26, 2015 at 01:31:12AM +0100, Tomáš Čech wrote:
>>> +     "Set of generic media players allowing to open video files through emotion. Useful only for emotion library based applications.")
>>
>>"Emotion Generic Players provides/consists of/is a set of generic ...
>>It is useful only for ...".
>
> I agree that sentences may be better, I only suck at it. I'll try
> to improvide it  or I can accept any recommendations in the meantime.
>
>>I think it would also be good to expand a bit where possible, and to introduce
>>the word "enlightenment" in each of these packages (by replacing "EFL" with
>>"Enlightenment Foundation Libraries",
>
> I do agree that use of "Enlightenment Foundation Libraries" instead of
> "EFL" could make it more enjoyable to read, but we could expand also
> Gimp toolkit, Tool Command Language, ...
>
> Those who would need such these packages will know and it won't help
> to others anyway.
>
> Synopsis of efl package will show you "Enlightenment Foundation Libraries".
>
>>for instance, or adding a sentence like
>>"It is part of the Enlightenment desktop environment").
>
> Enlightenment is using the same libraries (they were developed for
> Enlightenment) but the libraries are much more generic. It's like
> relationship between Qt and KDE, only with reversed history order.
>
>>Maybe call the file enlightenment.scm?
>
> I believe efl.scm is more accurate as the packages there would be EFL
> based but not necessarily Enlightenment related.
Sorry, I didn't notice this line. (for my comment about terminology).

Yes, this make sense.  But I think it's more clear to make packages
from enlightenment.org go into enlightenment.scm, while packages not
from enlightenment.org but based on EFL into seperated files.

Re: [PATCH 4/5] gnu: Add emotion-generic-players

[Tomáš Čech]

[-- Attachment #1: Type: text/plain, Size: 2451 bytes --]

On Thu, Feb 26, 2015 at 08:47:20PM +0800, 宋文武 wrote:
>Tomáš Čech <sleep_walker@suse.cz> writes:
>
>> Hello,
>>
>> thanks for review.
>>
>> On Thu, Feb 26, 2015 at 11:23:27AM +0100, Andreas Enge wrote:
>>>Hello,
>>>
>>>just a quick comment on the descriptions. It would be good to write full
>>>sentences, for instance:
>>>
>>>On Thu, Feb 26, 2015 at 01:31:12AM +0100, Tomáš Čech wrote:
>>>> +     "Set of generic media players allowing to open video files through emotion. Useful only for emotion library based applications.")
>>>
>>>"Emotion Generic Players provides/consists of/is a set of generic ...
>>>It is useful only for ...".
>>
>> I agree that sentences may be better, I only suck at it. I'll try
>> to improvide it  or I can accept any recommendations in the meantime.
>>
>>>I think it would also be good to expand a bit where possible, and to introduce
>>>the word "enlightenment" in each of these packages (by replacing "EFL" with
>>>"Enlightenment Foundation Libraries",
>>
>> I do agree that use of "Enlightenment Foundation Libraries" instead of
>> "EFL" could make it more enjoyable to read, but we could expand also
>> Gimp toolkit, Tool Command Language, ...
>>
>> Those who would need such these packages will know and it won't help
>> to others anyway.
>>
>> Synopsis of efl package will show you "Enlightenment Foundation Libraries".
>>
>>>for instance, or adding a sentence like
>>>"It is part of the Enlightenment desktop environment").
>>
>> Enlightenment is using the same libraries (they were developed for
>> Enlightenment) but the libraries are much more generic. It's like
>> relationship between Qt and KDE, only with reversed history order.
>>
>>>Maybe call the file enlightenment.scm?
>>
>> I believe efl.scm is more accurate as the packages there would be EFL
>> based but not necessarily Enlightenment related.
>Sorry, I didn't notice this line. (for my comment about terminology).
>
>Yes, this make sense.  But I think it's more clear to make packages
>from enlightenment.org go into enlightenment.scm, while packages not
>from enlightenment.org but based on EFL into seperated files.

I'm afraid it is still quite optimistic POV, there is not that big
number of EFL based applications worth of packaging.

http://edevel.tumblr.com/post/98156942204

But it seems that the filename is really important to you all so I'll
change the name.

S_W

[-- Attachment #2: Type: application/pgp-signature, Size: 181 bytes --]

Re: [PATCH 4/5] gnu: Add emotion-generic-players

[Andreas Enge]

On Thu, Feb 26, 2015 at 07:09:08PM +0100, Tomáš Čech wrote:
> But it seems that the filename is really important to you all so I'll
> change the name.

Not really, I care a lot about package names and little about file names :-)
It was just a suggestion to think about, whatever you prefer.

Andreas

Re: [PATCH 1/5] gnu: Add efl.

[Andreas Enge]

Hello,

so here are suggestions for possible descriptions. No particular quality
is guaranteed :-) Feel free to use or modify them.

On Thu, Feb 26, 2015 at 01:31:09AM +0100, Tomáš Čech wrote:
> +(define-public efl
The Enlightenment Foundation Libraries (EFL) provide a graphics toolkit
which is used mainly, but not exclusively, for the Enlightenment desktop.

elementary
Elementary is a widget toolkit based on the Enlightenment Foundation
Libraries (EFL).

evas-generic-loaders
Evas Generic Loaders provides image decoders to place pictures, documents
and media files into Evas, the Enlightenment Foundation Libraries (EFL)
canvas library.

emotion-generic-players
Emotion Generic Players is a set of video decoders allowing to open video files
through Emotion, a library among  the Enlightenment Foundation Libraries (EFL).

terminology
Terminology is the terminal emulator from the Enlightenment project.

Andreas

Re: [PATCH 1/5] gnu: Add efl.

[Andreas Enge]

Hello,

a few more comments:

On Thu, Feb 26, 2015 at 01:31:09AM +0100, Tomáš Čech wrote:
> +    (propagated-inputs
> +     `(("bullet" ,bullet)
> +       ("dbus" ,dbus)
> +       ("eudev" ,eudev)
> +       ("fontconfig" ,fontconfig)
> +       ("freetype" ,freetype)
> +       ("fribidi" ,fribidi)
> +       ("glib" ,glib)
> +       ("libpng" ,libpng)
> +       ("libsndfile" ,libsndfile)
> +       ("luajit" ,luajit)
> +       ("openssl" ,openssl)
> +       ("pulseaudio" ,pulseaudio)
> +       ("util-linux" ,util-linux)))

Why do all these need to be propagated? Are the all dlopenend? If they are
linked normally into executables and libraries, are ld-wrapper should take
care of them. If all or some of them need to be propagated, it would be good
to add a comment.

> * gnu/packages/efl (elementary): New variable.

This one looks safe (except for the line length of 80 characters already
mentioned by 宋文武).

> * gnu/packages/efl.scm (evas-generic-loaders): New variable.
> +       ("poppler" ,poppler)
> +       ))

The "))" should be at the end of the previous line. Apart from that,
it looks good.

> * gnu/packages/efl.scm (emotion-generic-players): New variable.

Looks good.

> * gnu/packages/efl.scm (terminology): New variable.

Looks good, too!

Andreas

Re: [PATCH 1/5] gnu: Add efl.

[Ludovic Courtès]

Tomáš Čech <sleep_walker@suse.cz> skribis:

> * gnu/packages/efl.scm: New file
> * gnu-system.am (GNU_SYSTEM_MODULES): Add it.

Nice work!

> +              (uri (string-append "http://download.enlightenment.org/rel/libs/efl/efl-" version ".tar.gz"))

Please keep lines below 80 chars.

> +    (inputs
> +     `(("alsa-lib" ,alsa-lib)
> +       ("bash" ,bash)

Adding Bash is most likely unnecessary, or if it is, you’ll have to add
a comment to justify it.  :-)

> +    (propagated-inputs
> +     `(("bullet" ,bullet)
> +       ("dbus" ,dbus)
> +       ("eudev" ,eudev)
> +       ("fontconfig" ,fontconfig)
> +       ("freetype" ,freetype)
> +       ("fribidi" ,fribidi)
> +       ("glib" ,glib)
> +       ("libpng" ,libpng)
> +       ("libsndfile" ,libsndfile)
> +       ("luajit" ,luajit)
> +       ("openssl" ,openssl)
> +       ("pulseaudio" ,pulseaudio)
> +       ("util-linux" ,util-linux)))

That’s a lot!  Normally we put a comment to justify why an input is
propagated.  The usual reasons are: installed headers include headers of
a propagated input, or .pc file refers to one of them.

Could you double-check whether all these are needed, and add comments?

> +       #:phases
> +       (alist-cons-before
> +        'configure 'patch-config-files
> +        (lambda _
> +          (substitute* "po/Makefile.in.in"
> +            (("/bin/sh") (which "bash"))))
> +        %standard-phases)))

po/Makefile.in.in is not used, so I believe this phase is not needed.

> +    (home-page "http://www.enlightenment.org")
> +    (synopsis "Enlightenment Foundation Libraries")
> +    (description
> +     "EFL is toolkit used mainly for Enlightenment, but is used for more applications because it is resource friendly and energy efficient.")

“Toolkit” is vague; could you say a couple of words about what it
provides?  My understanding is that it’s partly a graphical toolkit, but
also partly a library of data structures, file system convenience
functions, and such, right?

Also, s/Enlightenment/the Enlightenment desktop environment/ or
something like that.

> +    (license (list license:bsd-2 license:lgpl2.1 license:zlib)))) ; different parts under different licenses

Please move the comment above to keep the lines below 80 chars.

Thanks!

Ludo’.

Re: [PATCH 4/5] gnu: Add emotion-generic-players

[Ludovic Courtès]

Tomáš Čech <sleep_walker@suse.cz> skribis:

> * gnu/packages/efl.scm (emotion-generic-players): New variable.

I agree with Andreas.  Other than that LGTM, except for lines too long.

Thanks,
Ludo’.

Re: [PATCH 2/5] gnu: Add elementary.

[Ludovic Courtès]

Tomáš Čech <sleep_walker@suse.cz> skribis:

> * gnu/packages/efl (elementary): New variable.

[...]

> +    (synopsis "Widget library of Enlightenment world")

“from the Enlightenment world” maybe?

> +    (description
> +     "Widget library/toolkit for EFL based applications.")

Please expound a bit.

Thanks,
Ludo’.

Re: [PATCH 3/5] gnu: Add evas-generic-loaders

[Ludovic Courtès]

Tomáš Čech <sleep_walker@suse.cz> skribis:

> * gnu/packages/efl.scm (evas-generic-loaders): New variable.

[...]

> +              (uri (string-append "http://download.enlightenment.org/rel/libs/evas_generic_loaders/evas_generic_loaders-" version ".tar.gz"))

Line too long.

> +       ("poppler" ,poppler)
> +       ))

Move the parens to the previous line please.

> +    (home-page "http://www.enlightenment.org")
> +    (synopsis "Plugins for integration of various file types into Evas")
> +    (description
> +     "Set of generic loaders allowing to open pictures, documents and media files into Evas (EFL canvas library)")

Line too long + what Andreas wrote before.

Thanks,
Ludo’.

Re: [PATCH 5/5] gnu: Add terminology.

[Ludovic Courtès]

Tomáš Čech <sleep_walker@suse.cz> skribis:

> * gnu/packages/efl.scm (terminology): New variable.

[...]

> +              (uri (string-append "http://download.enlightenment.org/rel/apps/terminology/terminology-" version ".tar.gz"))

Too long.

> +    (description
> +     "Fast but advanced terminal emulator running in X or framebuffer")

Could you expound a bit (features, etc.)?  Also make sure the
description contains punctuated sentences.

Thanks!

Ludo’.

[PATCH 1/5] gnu: Add efl.

[Tomáš Čech]

* gnu/packages/enlightenment.scm: New file
* gnu/packages/enlightenment.scm (efl): New variable.
* gnu-system.am (GNU_SYSTEM_MODULES): Add it.
---
 gnu-system.am                  |   1 +
 gnu/packages/enlightenment.scm | 140 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 141 insertions(+)
 create mode 100644 gnu/packages/enlightenment.scm

diff --git a/gnu-system.am b/gnu-system.am
index e42e89a..21847cc 100644
--- a/gnu-system.am
+++ b/gnu-system.am
@@ -90,6 +90,7 @@ GNU_SYSTEM_MODULES =				\
   gnu/packages/elf.scm				\
   gnu/packages/emacs.scm			\
   gnu/packages/enchant.scm			\
+  gnu/packages/enligtenment.scm			\
   gnu/packages/feh.scm                          \
   gnu/packages/file.scm				\
   gnu/packages/firmware.scm			\
diff --git a/gnu/packages/enlightenment.scm b/gnu/packages/enlightenment.scm
new file mode 100644
index 0000000..6ea0dd5
--- /dev/null
+++ b/gnu/packages/enlightenment.scm
@@ -0,0 +1,140 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2015 Tomáš Čech <sleep_walker@suse.cz>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages efl)
+  #:use-module ((guix licenses) #:prefix license:)
+  #:use-module (guix packages)
+  #:use-module (guix download)
+  #:use-module (guix build-system gnu)
+  #:use-module (gnu packages)
+  #:use-module (gnu packages bash)
+  #:use-module (gnu packages compression)
+  #:use-module (gnu packages curl)
+  #:use-module (gnu packages fontutils)
+  #:use-module (gnu packages fribidi)
+  #:use-module (gnu packages game-development)
+  #:use-module (gnu packages gl)
+  #:use-module (gnu packages glib)
+  #:use-module (gnu packages gnome)
+  #:use-module (gnu packages gstreamer)
+  #:use-module (gnu packages image)
+  #:use-module (gnu packages linux)
+  #:use-module (gnu packages lua)
+  #:use-module (gnu packages openssl)
+  #:use-module (gnu packages pulseaudio)
+  #:use-module (gnu packages photo)
+  #:use-module (gnu packages pkg-config)
+  #:use-module (gnu packages valgrind)
+  #:use-module (gnu packages xorg))
+
+(define-public efl
+  (package
+    (name "efl")
+    (version "1.13.0")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append
+                    "http://download.enlightenment.org/rel/libs/efl/efl-"
+                    version ".tar.gz"))
+              (sha256
+               (base32 "0mwkxsfi5masiy6qfmdqy1j15cfz7nz8g8jq2bf3w501rpa9gxvz"))))
+    (build-system gnu-build-system)
+    (native-inputs
+     `(("pkg-config" ,pkg-config)))
+    (inputs
+     `(("alsa-lib" ,alsa-lib)
+       ("compositeproto" ,compositeproto)
+       ("curl" ,curl)
+       ("giflib" ,giflib)
+       ("gstreamer" ,gstreamer)
+       ("gst-plugins-base" ,gst-plugins-base)
+       ("harfbuzz" ,harfbuzz)
+       ("libexif" ,libexif)
+       ("libjpeg" ,libjpeg)
+       ("librsvg" ,librsvg)
+       ("libtiff" ,libtiff)
+       ("libx11" ,libx11)
+       ("libxcomposite" ,libxcomposite)
+       ("libxcursor" ,libxcursor)
+       ("libxdmcp" ,libxdmcp)
+       ("libxext" ,libxext)
+       ("libxi" ,libxi)
+       ("libxkbfile" ,libxkbfile)
+       ("libxinerama" ,libxinerama)
+       ("libxp" ,libxp)
+       ("libxrandr" ,libxrandr)
+       ("libxscrnsaver" ,libxscrnsaver)
+       ("libxtst" ,libxtst)
+       ("mesa" ,mesa)
+       ("printproto" ,printproto)
+       ("scrnsaverproto" ,scrnsaverproto)
+       ("valgrind" ,valgrind)
+       ("xextproto" ,xextproto)
+       ("xinput" ,xinput)
+       ("xpr" ,xpr)
+       ("xproto" ,xproto)))
+    (propagated-inputs
+     ; all these inputs are in package config files in section
+     ; Require.private
+     `(("bullet" ,bullet) ; ephysics.pc
+       ("dbus" ,dbus) ; eldbus.pc
+       ("eudev" ,eudev) ; eeze.pc
+       ("fontconfig" ,fontconfig) ; evas.pc
+       ("freetype" ,freetype) ; evas.pc
+       ("fribidi" ,fribidi) ; evas.pc
+       ("glib" ,glib) ; ecore.pc
+       ("libpng" ,libpng) ; evas.pc, evas-cxx.pc
+       ("libsndfile" ,libsndfile) ; ecore-audio.pc, ecore-audio-cxx.pc
+       ("luajit" ,luajit) ; evas.pc, edje.pc
+       ("openssl" ,openssl) ; eet.pc, ecore-con.pc
+       ("pulseaudio" ,pulseaudio) ; ecore-audio.pc, ecore-audio-cxx.pc
+       ("util-linux" ,util-linux) ; eeze.pc
+       ("zlib" ,zlib))) ; eet.pc
+    (arguments
+     `(#:configure-flags '("--disable-silent-rules")
+       #:phases
+       (alist-cons-before
+        'configure 'patch-config-files
+        (lambda _
+          (substitute* "po/Makefile.in.in"
+            (("/bin/sh") (which "bash"))))
+        %standard-phases)))
+    (home-page "http://www.enlightenment.org")
+    (synopsis "Enlightenment Foundation Libraries")
+    (description
+     "Enlightenment Foundation Libraries is set of libraries developed
+for Enlightenment, but is used for more applications because it is resource
+friendly, energy efficient and good looking.  It consists of:
+
+ * Eina - defining data types and low level abstractions
+ * Eo - generic object concept for EFL
+ * Eet - binary data parser and serializer
+ * Evas - canvas library
+ * Ecore - abstraction to operating system
+ * Embryo - script engine
+ * Escape - Playstation portability layer
+ * Evil - Microsoft Windows portability layer
+ * Eio - library for asynchronous input/output
+ * Eldbus - DBus integration
+ * Efreet - support for Freedesktop.org standards
+ * Eeze - hardware interface
+ * EPhysics - integration of physics engine
+ * Edje - UI layout library, themes support
+ * Emotion - multimedia integration
+ * Ethumb - image thumbnail support")
+    (license (list license:bsd-2 license:lgpl2.1 license:zlib)))) ; different parts under different licenses
-- 
2.0.5

Re: [PATCH 1/5] gnu: Add efl.

[Andreas Enge]

Hello,

On Sat, Feb 28, 2015 at 11:11:02PM +0100, Tomáš Čech wrote:
> +    (propagated-inputs
> +     ; all these inputs are in package config files in section
> +     ; Require.private

I was under the impression that only libraries given as "Require" needed
to be propagated, and not "Require.private" ones. Maybe someone else can
comment?

You could also try to move them to normal inputs and see whether another
package depending on efl still compiles.

Andreas

Re: [PATCH 1/5] gnu: Add efl.

[tcech]

[-- Attachment #1: Type: text/plain, Size: 970 bytes --]

Hello,

On Sun, Mar 01, 2015 at 08:24:54PM +0100, Andreas Enge wrote:
>Hello,
>
>On Sat, Feb 28, 2015 at 11:11:02PM +0100, Tomáš Čech wrote:
>> +    (propagated-inputs
>> +     ; all these inputs are in package config files in section
>> +     ; Require.private
>
>I was under the impression that only libraries given as "Require" needed
>to be propagated, and not "Require.private" ones. Maybe someone else can
>comment?

I don't know pkgconfig much, but when in later packages in configure
tests presence with

$PKG_CONFIG --exists --print-errors "somepackage >= version"

Missing libraries from Require.private leads to failure of configure.

>You could also try to move them to normal inputs and see whether another
>package depending on efl still compiles.

I'm afraid that I found what propagated-input is thanks to this. I'm
sure that elementary or others won't build without that.

Maybe I misunderstand the problem though.

S_W

[-- Attachment #2: Type: application/pgp-signature, Size: 181 bytes --]

Re: [PATCH 1/5] gnu: Add efl.

[Andreas Enge]

On Sun, Mar 01, 2015 at 08:43:09PM +0100, tcech@suse.cz wrote:
> On Sun, Mar 01, 2015 at 08:24:54PM +0100, Andreas Enge wrote:
> >You could also try to move them to normal inputs and see whether another
> >package depending on efl still compiles.
> I'm afraid that I found what propagated-input is thanks to this. I'm
> sure that elementary or others won't build without that.

Sorry, what I suggested as a test actually does not work. The question is:
Does everything built with efl requires the additional libraries, or may
there be packages building with efl, but without these additional libraries?
Of course, no finite number of examples constitutes a proof...

I found the following:
   http://people.freedesktop.org/~dbn/pkg-config-guide.html
Requires: A list of packages required by this package. The versions of these packages may be specified using the comparison operators =, <, >, <= or >=.
Requires.private: A list of private packages required by this package but not exposed to applications. The version specific rules from the Requires field also apply here.

This sounds as if only "Requires" libraries need to be propagated, whereas
"Requires.private" libraries are already handled by our ld wrapper.

The page above links to the following:
   https://wiki.openmandriva.org/en/Overlinking_issues_in_packaging

This seems to confirm my opinion, but it would be good if someone more
knowledgeable on pkg-config could comment on the issue.

Andreas

Re: [PATCH 1/5] gnu: Add efl.

[Ludovic Courtès]

Andreas Enge <andreas@enge.fr> skribis:

> I was under the impression that only libraries given as "Require" needed
> to be propagated, and not "Require.private" ones. Maybe someone else can
> comment?

It’s worth propagating in both cases.  “Require.private” is used for
static linking only, as in ‘pkg-config foo --libs --static’.

Ludo’.

Re: [PATCH 1/5] gnu: Add efl.

[Ludovic Courtès]

Tomáš Čech <sleep_walker@suse.cz> skribis:

> * gnu/packages/enlightenment.scm: New file
> * gnu/packages/enlightenment.scm (efl): New variable.
> * gnu-system.am (GNU_SYSTEM_MODULES): Add it.

[...]

> +    (propagated-inputs
> +     ; all these inputs are in package config files in section
> +     ; Require.private

Please use two semicolons for comments like this one.  Capitalize
sentences and add a period at the end.

> +       (alist-cons-before
> +        'configure 'patch-config-files
> +        (lambda _
> +          (substitute* "po/Makefile.in.in"
> +            (("/bin/sh") (which "bash"))))

I persist to think that this is not needed, is it?  If not, please
remove it.

> +    (description
> +     "Enlightenment Foundation Libraries is set of libraries developed
> +for Enlightenment, but is used for more applications because it is resource
> +friendly, energy efficient and good looking.  It consists of:
> +
> + * Eina - defining data types and low level abstractions
> + * Eo - generic object concept for EFL
> + * Eet - binary data parser and serializer
> + * Evas - canvas library
> + * Ecore - abstraction to operating system
> + * Embryo - script engine
> + * Escape - Playstation portability layer
> + * Evil - Microsoft Windows portability layer
> + * Eio - library for asynchronous input/output
> + * Eldbus - DBus integration
> + * Efreet - support for Freedesktop.org standards
> + * Eeze - hardware interface
> + * EPhysics - integration of physics engine
> + * Edje - UI layout library, themes support
> + * Emotion - multimedia integration
> + * Ethumb - image thumbnail support")

You’ll hate me for saying that ;-) but please make it just a plain
paragraph: the UIs may reformat the paragraph to their without caring
for the bullet list.

The text probably doesn’t need to be exhaustive, just to list some of
the main functionality.

> +    (license (list license:bsd-2 license:lgpl2.1 license:zlib)))) ; different parts under different licenses

Line too long.

OK to push with these changes.

Thanks!

Ludo’.