[PATCH] gnu: Add OCaml. licenses: Add QPL.

[PATCH] gnu: Add OCaml. licenses: Add QPL.

[Cyril Roelandt]

* gnu/packages/ocaml.scm: New file.
* Makefile.am (MODULES): Add it.
* guix/licenses.scm: New variable.
---
Hey !

This patch is a first attempt at packaging OCaml. I'm getting a few
error messages when building:

"patch-shebang: ./otherlibs/labltk/examples_labltk/hello.tcl: warning: no binary for interpreter `wish' found in $PATH"

wish is provided by tk, and seems to require X, so I don't think it's
too bad.

"patch-shebang: ./boot/ocamlc: warning: no binary for interpreter `ocamlrun' found in $PATH"

ocamlrun is installed by ocaml, so it's OK.

Finally, a bunch of tests fail, and some of them cannot even be
launched:

"/nix/store/wqvmn0mmk68iwy88ljgqn57vjf15nf74-ocaml-4.00.1/bin/ocamlrun: bad interpreter: No such file or directory"

This is because OCaml assumes that "make install" has been run before
launching the tests. I'm not sure whether there's a clean solution to
this problem. WDYT ?

WBR,
Cyril Roelandt.


 Makefile.am            |    1 +
 gnu/packages/ocaml.scm |   70 ++++++++++++++++++++++++++++++++++++++++++++++++
 guix/licenses.scm      |    6 +++++
 3 files changed, 77 insertions(+)
 create mode 100644 gnu/packages/ocaml.scm

diff --git a/Makefile.am b/Makefile.am
index 5e3114d..d96ecc0 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -106,6 +106,7 @@ MODULES =					\
   gnu/packages/nano.scm				\
   gnu/packages/ncurses.scm			\
   gnu/packages/nettle.scm			\
+  gnu/packages/ocaml.scm 			\
   gnu/packages/openssl.scm			\
   gnu/packages/oggvorbis.scm			\
   gnu/packages/perl.scm				\
diff --git a/gnu/packages/ocaml.scm b/gnu/packages/ocaml.scm
new file mode 100644
index 0000000..871c98f
--- /dev/null
+++ b/gnu/packages/ocaml.scm
@@ -0,0 +1,70 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2013 Cyril Roelandt <tipecaml@gmail.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages ocaml)
+  #:use-module (guix licenses)
+  #:use-module (guix packages)
+  #:use-module (guix download)
+  #:use-module (guix build-system gnu)
+  #:use-module (gnu packages)
+  #:use-module (gnu packages perl))
+
+(define-public ocaml
+  (package
+    (name "ocaml")
+    (version "4.00.1")
+    (source (origin
+             (method url-fetch)
+             (uri (string-append
+                   "http://caml.inria.fr/pub/distrib/ocaml-4.00/ocaml-"
+                   version ".tar.gz"))
+             (sha256
+              (base32
+               "0yp86napnvbi2jgxr6bk1235bmjdclgzrzgq4mhwv87l7dymr3dl"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:phases (alist-replace
+                 'configure
+                 (lambda* (#:key outputs #:allow-other-keys)
+                   ;; OCaml uses "-prefix <prefix>" rather than the usual
+                   ;; "--prefix=<prefix>".
+                   (let ((out (assoc-ref outputs "out")))
+                     (zero? (system* "./configure" "-prefix" out))))
+                 (alist-replace
+                  'build
+                  (lambda* (#:key outputs #:allow-other-keys)
+                    ;; "make" does not do anything, we must use
+                    ;; "make world.opt".
+                    (zero? (system* "make" "world.opt")))
+                  (alist-replace
+                   'check
+                   (lambda* (#:key outputs #:allow-other-keys)
+                     ;; There does not seem to be a "check" or "test" target.
+                     (zero? (system "cd testsuite && make all")))
+                   %standard-phases)))))
+    (inputs
+     `(("perl", perl)
+      ))
+    (home-page "http://www.ocaml.org/")
+    (synopsis "The OCaml programming language")
+    (description
+     "OCaml is a general purpose industrial-strength programming language with
+an emphasis on expressiveness and safety. Developed for more than 20 years at
+Inria it benefits from one of the most advanced type systems and supports
+functional, imperative and object-oriented styles of programming.")
+    (license '(qpl gpl2))))
diff --git a/guix/licenses.scm b/guix/licenses.scm
index 93af865..c636cc5 100644
--- a/guix/licenses.scm
+++ b/guix/licenses.scm
@@ -36,6 +36,7 @@
             mpl2.0
             openldap2.8 openssl
             psfl public-domain
+            qpl
             vim
             x11
             zlib))
@@ -213,6 +214,11 @@ which may be a file:// URI pointing the package's tree."
            "http://directory.fsf.org/wiki/License:PublicDomain"
            "https://www.gnu.org/licenses/license-list#PublicDomain"))
 
+(define qpl
+  (license "QPL"
+           "http://directory.fsf.org/wiki/License:QPLv1.0"
+           "http://www.gnu.org/licenses/license-list.html#QPL"))
+
 (define vim
   (license "Vim"
            "http://directory.fsf.org/wiki/License:Vim7.2"
-- 
1.7.10.4

Re: [PATCH] gnu: Add OCaml. licenses: Add QPL.

[Andreas Enge]

[-- Attachment #1: Type: text/plain, Size: 810 bytes --]

Am Montag, 21. Januar 2013 schrieb Cyril Roelandt:
> "patch-shebang: ./otherlibs/labltk/examples_labltk/hello.tcl: warning:
> no binary for interpreter `wish' found in $PATH"
> 
> wish is provided by tk, and seems to require X, so I don't think it's
> too bad.

Hopefully, this is detected during configure, so that this does not get 
run.

> Finally, a bunch of tests fail, and some of them cannot even be
> launched:
> "/nix/store/wqvmn0mmk68iwy88ljgqn57vjf15nf74-ocaml-4.00.1/bin/ocamlrun:
> bad interpreter: No such file or directory"
> 
> This is because OCaml assumes that "make install" has been run before
> launching the tests. I'm not sure whether there's a clean solution to
> this problem. WDYT ?

Maybe you could patch the files to point to the location of the binary in 
the build tree?

Andreas

[-- Attachment #2: Type: text/html, Size: 4378 bytes --]

Re: [PATCH] gnu: Add OCaml. licenses: Add QPL.

[Ludovic Courtès]

Andreas Enge <andreas@enge.fr> skribis:

> Am Montag, 21. Januar 2013 schrieb Cyril Roelandt:

[...]

>> Finally, a bunch of tests fail, and some of them cannot even be
>> launched:
>> "/nix/store/wqvmn0mmk68iwy88ljgqn57vjf15nf74-ocaml-4.00.1/bin/ocamlrun:
>> bad interpreter: No such file or directory"
>> 
>> This is because OCaml assumes that "make install" has been run before
>> launching the tests. I'm not sure whether there's a clean solution to
>> this problem. WDYT ?
>
> Maybe you could patch the files to point to the location of the binary in 
> the build tree?

Alternately, you could move the ‘check’ phase after the install phase,
like this (untested):

  (arguments
   '(#:phases
     (let ((check (assq-ref %standard-phases 'check)))
       (alist-cons-after
         'install 'check-after-install
         check
         (alist-remove 'check %standard-phases)))))

HTH,
Ludo’.

Re: [PATCH] gnu: Add OCaml. licenses: Add QPL.

[Andreas Enge]

[-- Attachment #1: Type: text/plain, Size: 412 bytes --]

Am Montag, 21. Januar 2013 schrieb Ludovic Courtès:
> Alternately, you could move the ‘check’ phase after the install phase,
> like this (untested):

But then, if the check fails, the /nix/store would contain an "invalid" 
package, no? I think it would be desirable to install only packages for 
which the check succeeds (granted, installation itself may fail, but this 
is less likely).

Andreas

[-- Attachment #2: Type: text/html, Size: 1925 bytes --]

Re: [PATCH] gnu: Add OCaml. licenses: Add QPL.

[Ludovic Courtès]

Andreas Enge <andreas@enge.fr> skribis:

> Am Montag, 21. Januar 2013 schrieb Ludovic Courtès:
>> Alternately, you could move the ‘check’ phase after the install phase,
>> like this (untested):
>
> But then, if the check fails, the /nix/store would contain an "invalid" 
> package, no?

No: if ‘check’ fails (or ‘install’, or ‘patch-shebangs’), then the whole
process fails, and the store path is marked as invalid.

That is, /nix/store/*-ocaml* exists and may even be populated, but
‘valid-path?’ returns #f for that directory.  Thus, the daemon considers
that it has to rebuild it, as if it did not exist at all.

Thanks,
Ludo’.

[PATCH v2] gnu: Add OCaml. licenses: Add QPL.

[Cyril Roelandt]

* gnu/packages/ocaml.scm: New file.
* Makefile.am (MODULES): Add it.
* guix/licenses.scm: New variable.
---
On 01/21/2013 09:18 PM, Ludovic Courtès wrote:
> Alternately, you could move the ‘check’ phase after the install phase,
> like this (untested):

Thanks, that worked. Here is a second version of the patch, which seems to work.

WBR,
Cyril Roelandt.

 Makefile.am            |    1 +
 gnu/packages/ocaml.scm |   79 ++++++++++++++++++++++++++++++++++++++++++++++++
 guix/licenses.scm      |    6 ++++
 3 files changed, 86 insertions(+)
 create mode 100644 gnu/packages/ocaml.scm

diff --git a/Makefile.am b/Makefile.am
index 54e80cc..f80f166 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -108,6 +108,7 @@ MODULES =					\
   gnu/packages/ncurses.scm			\
   gnu/packages/netpbm.scm			\
   gnu/packages/nettle.scm			\
+  gnu/packages/ocaml.scm 			\
   gnu/packages/openssl.scm			\
   gnu/packages/oggvorbis.scm			\
   gnu/packages/perl.scm				\
diff --git a/gnu/packages/ocaml.scm b/gnu/packages/ocaml.scm
new file mode 100644
index 0000000..71974e2
--- /dev/null
+++ b/gnu/packages/ocaml.scm
@@ -0,0 +1,79 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2013 Cyril Roelandt <tipecaml@gmail.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages ocaml)
+  #:use-module (guix licenses)
+  #:use-module (guix packages)
+  #:use-module (guix download)
+  #:use-module (guix build-system gnu)
+  #:use-module (gnu packages)
+  #:use-module (gnu packages perl))
+
+(define-public ocaml
+  (package
+    (name "ocaml")
+    (version "4.00.1")
+    (source (origin
+             (method url-fetch)
+             (uri (string-append
+                   "http://caml.inria.fr/pub/distrib/ocaml-4.00/ocaml-"
+                   version ".tar.gz"))
+             (sha256
+              (base32
+               "0yp86napnvbi2jgxr6bk1235bmjdclgzrzgq4mhwv87l7dymr3dl"))))
+    (build-system gnu-build-system)
+    (arguments
+       `(#:modules ((guix build gnu-build-system)
+                    (guix build utils)
+                    (srfi srfi-1))
+         #:phases (alist-replace
+                   'configure
+                   (lambda* (#:key outputs #:allow-other-keys)
+                     ;; OCaml uses "-prefix <prefix>" rather than the usual
+                     ;; "--prefix=<prefix>".
+                     (let ((out (assoc-ref outputs "out")))
+                      (zero? (system* "./configure" "-prefix" out))))
+                   (alist-replace
+                    'build
+                    (lambda* (#:key outputs #:allow-other-keys)
+                      ;; "make" does not do anything, we must use
+                      ;; "make world.opt".
+                      (zero? (system* "make" "world.opt")))
+                    (alist-replace
+                     'check-after-install
+                     (lambda* (#:key outputs #:allow-other-keys)
+                       ;; There does not seem to be a "check" or "test" target.
+                       (zero? (system "cd testsuite && make all")))
+                     (let ((check (assq-ref %standard-phases 'check)))
+                      ;; OCaml assumes that "make install" is run before
+                      ;; launching the tests.
+                      (alist-cons-after
+                       'install 'check-after-install
+                       check
+                       (alist-delete 'check %standard-phases))))))))
+    (inputs
+     `(("perl", perl)
+      ))
+    (home-page "http://www.ocaml.org/")
+    (synopsis "The OCaml programming language")
+    (description
+     "OCaml is a general purpose industrial-strength programming language with
+an emphasis on expressiveness and safety. Developed for more than 20 years at
+Inria it benefits from one of the most advanced type systems and supports
+functional, imperative and object-oriented styles of programming.")
+    (license '(qpl gpl2))))
diff --git a/guix/licenses.scm b/guix/licenses.scm
index 93af865..c636cc5 100644
--- a/guix/licenses.scm
+++ b/guix/licenses.scm
@@ -36,6 +36,7 @@
             mpl2.0
             openldap2.8 openssl
             psfl public-domain
+            qpl
             vim
             x11
             zlib))
@@ -213,6 +214,11 @@ which may be a file:// URI pointing the package's tree."
            "http://directory.fsf.org/wiki/License:PublicDomain"
            "https://www.gnu.org/licenses/license-list#PublicDomain"))
 
+(define qpl
+  (license "QPL"
+           "http://directory.fsf.org/wiki/License:QPLv1.0"
+           "http://www.gnu.org/licenses/license-list.html#QPL"))
+
 (define vim
   (license "Vim"
            "http://directory.fsf.org/wiki/License:Vim7.2"
-- 
1.7.10.4

Re: [PATCH v2] gnu: Add OCaml. licenses: Add QPL.

[Ludovic Courtès]

> Thanks, that worked. Here is a second version of the patch, which seems to work.

Applied, thanks!

I took the liberty to change the following:

> +    (inputs
> +     `(("perl", perl)
> +      ))

No hanging parenthesis, and comma right before ‘perl’.

> +    (home-page "http://www.ocaml.org/")

Changed to caml.inria.fr, which is the Really Official web site, AIUI.

Ludo’.