all messages for Guix-related lists mirrored at yhetil.org
 help / color / mirror / code / Atom feed
From: Raghav Gururajan via Guix-patches via <guix-patches@gnu.org>
To: Leo Prikler <leo.prikler@student.tugraz.at>, 45889@debbugs.gnu.org
Subject: [bug#45889] Nextcloud Client (v13)
Date: Mon, 22 Feb 2021 12:29:13 -0500	[thread overview]
Message-ID: <12599035-d671-b417-d70c-89d694f3ccd9@raghavgururajan.name> (raw)
In-Reply-To: <f8fc183a9f28096a1f587860828ca4c30db337ab.camel@student.tugraz.at>


[-- Attachment #1.1.1: Type: text/plain, Size: 681 bytes --]

Hi Leo!

> Still seems pretty sync to me, especially since it's just the client
> for now.

Circular-dependency when putting it in sync.scm. So we'll keep it as is 
I guess.

> (X) Doubt
> 
> It appears the Nextcloud variant has an added namespace layer, that one
> should easily be able to strip via substitute*.  I do wonder where that
> comes from, though, it seems to have been there "forever".

No idea! Thanks for fixing the build errors.

Also, I cannot package them separately because the build script is not 
viable. No libraries gets built, except for .o files. Also, INSTALL.txt 
deals with Windows and MacOS.

I have attached v13.

Regards,
RG.

[-- Attachment #1.1.2: 0001-gnu-Add-appstream.patch --]
[-- Type: text/x-patch, Size: 5614 bytes --]

From d4b271d3fcff56c27e6ee0222e688aad4b78a8eb Mon Sep 17 00:00:00 2001
From: Raghav Gururajan <rg@raghavgururajan.name>
Date: Thu, 14 Jan 2021 23:32:27 -0500
Subject: [PATCH 1/2] gnu: Add appstream.

* gnu/packages/freedesktop.scm (appstream): New variable.
---
 gnu/packages/freedesktop.scm | 96 ++++++++++++++++++++++++++++++++++++
 1 file changed, 96 insertions(+)

diff --git a/gnu/packages/freedesktop.scm b/gnu/packages/freedesktop.scm
index e00454f7b3..bccd8e9b00 100644
--- a/gnu/packages/freedesktop.scm
+++ b/gnu/packages/freedesktop.scm
@@ -58,8 +58,10 @@
   #:use-module (gnu packages bash)
   #:use-module (gnu packages boost)
   #:use-module (gnu packages check)
+  #:use-module (gnu packages cmake)
   #:use-module (gnu packages compression)
   #:use-module (gnu packages cryptsetup)
+  #:use-module (gnu packages databases)
   #:use-module (gnu packages disk)
   #:use-module (gnu packages docbook)
   #:use-module (gnu packages documentation)
@@ -75,6 +77,7 @@
   #:use-module (gnu packages gstreamer)
   #:use-module (gnu packages gtk)
   #:use-module (gnu packages image)
+  #:use-module (gnu packages language)
   #:use-module (gnu packages libffi)
   #:use-module (gnu packages libunwind)
   #:use-module (gnu packages libusb)
@@ -101,6 +104,99 @@
   #:use-module (gnu packages xorg)
   #:use-module (srfi srfi-1))
 
+(define-public appstream
+  (package
+    (name "appstream")
+    (version "0.13.1")
+    (source
+     (origin
+       (method url-fetch)
+       (uri
+        (string-append "https://www.freedesktop.org/software/"
+                       "appstream/releases/"
+                       "AppStream-" version ".tar.xz"))
+       (sha256
+        (base32 "09l6ixz1w29pi0nb0flz14m4r3f2hpqpp1fq8y66v9xa4c9fczds"))))
+    (build-system meson-build-system)
+    (arguments
+     `(#:glib-or-gtk? #t
+       #:phases
+       (modify-phases %standard-phases
+         (add-after 'unpack 'patch-libstemmer
+           (lambda* (#:key inputs #:allow-other-keys)
+             (substitute* "meson.build"
+               (("/usr/include")
+                (string-append (assoc-ref inputs "libstemmer")
+                               "/include")))
+             #t))
+         (add-after 'patch-libstemmer 'patch-docbook-xml
+           (lambda* (#:key inputs #:allow-other-keys)
+             (with-directory-excursion "docs/api"
+               (substitute* "appstream-docs.xml"
+                 (("http://www.oasis-open.org/docbook/xml/4.3/")
+                  (string-append (assoc-ref inputs "docbook-xml-4.3")
+                                 "/xml/dtd/docbook/"))))
+             (for-each (lambda (file)
+                         (substitute* file
+                           (("http://www.oasis-open.org/docbook/xml/4.5/")
+                            (string-append (assoc-ref inputs "docbook-xml")
+                                           "/xml/dtd/docbook/"))))
+                       (find-files "scripts/desc" "\\.xml$"))
+             #t))
+         (add-after 'patch-docbook-xml 'disable-failing-tests
+           (lambda _
+             (substitute* "tests/test-pool.c"
+               (("	g_test_add_func \\(\"/AppStream/PoolRead\", test_pool_read\\);")
+                "")
+               (("	g_test_add_func \\(\"/AppStream/PoolReadAsync\", test_pool_read_async\\);")
+                "")
+               (("	g_test_add_func \\(\"/AppStream/PoolEmpty\", test_pool_empty\\);")
+                "")
+               (("	g_test_add_func \\(\"/AppStream/Cache\", test_cache\\);")
+                "")
+               (("	g_test_add_func \\(\"/AppStream/Merges\", test_merge_components\\);")
+                ""))
+             #t))
+         (add-after 'disable-failing-tests 'patch-install-dir
+           (lambda* (#:key outputs #:allow-other-keys)
+             (substitute* "data/meson.build"
+               (("/etc")
+                (string-append (assoc-ref outputs "out")
+                               "/etc")))
+             #t)))))
+    (native-inputs
+     `(("cmake" ,cmake)
+       ("docbook-xml-4.3" ,docbook-xml-4.3)
+       ("docbook-xml" ,docbook-xml)
+       ("docbook-xsl" ,docbook-xsl)
+       ("gettext" ,gettext-minimal)
+       ("glib:bin" ,glib "bin")
+       ("gobject-introspection" ,gobject-introspection)
+       ("gperf" ,gperf)
+       ("gtk-doc" ,gtk-doc)
+       ("pkg-config" ,pkg-config)
+       ("python" ,python-wrapper)
+       ("xsltproc" ,libxslt)))
+    (inputs
+     `(("libsoup" ,libsoup)
+       ("libstemmer" ,libstemmer)
+       ("libxml2" ,libxml2)
+       ("libyaml" ,libyaml)
+       ("lmdb" ,lmdb)))
+    (propagated-inputs
+     `(("glib" ,glib)))
+    (synopsis "Tools and libraries to work with AppStream metadata")
+    (description "AppStream is a cross-distribution effort for enhancing the way
+we interact with the software repositories provided by distributions by
+standardizing software component metadata.  It provides the foundation to build
+software-center applications, by providing metadata necessary for an
+application-centric view on package repositories.  It additionally provides
+specifications for things like an unified software metadata database, screenshot
+services and various other things needed to create user-friendly
+application-centers for distributions.")
+    (home-page "https://www.freedesktop.org/wiki/Distributions/AppStream/")
+    (license license:gpl2+)))
+
 (define-public farstream
   (package
     (name "farstream")
-- 
2.30.1


[-- Attachment #1.1.3: 0002-gnu-Add-nextcloud-client.patch --]
[-- Type: text/x-patch, Size: 8908 bytes --]

From dd9028ea1babf23ad23c08d19c8146c77e937479 Mon Sep 17 00:00:00 2001
From: Raghav Gururajan <rg@raghavgururajan.name>
Date: Fri, 15 Jan 2021 05:04:31 -0500
Subject: [PATCH 2/2] gnu: Add nextcloud-client.

* gnu/packages/nextcloud.scm: New module.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
* gnu/packages/nextcloud.scm (nextcloud-client): New variable.
---
 gnu/local.mk               |   1 +
 gnu/packages/nextcloud.scm | 190 +++++++++++++++++++++++++++++++++++++
 2 files changed, 191 insertions(+)
 create mode 100644 gnu/packages/nextcloud.scm

diff --git a/gnu/local.mk b/gnu/local.mk
index c3398c62fd..a9e0abe225 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -398,6 +398,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/packages/netpbm.scm			\
   %D%/packages/nettle.scm			\
   %D%/packages/networking.scm			\
+  %D%/packages/nextcloud.scm              \
   %D%/packages/nfs.scm                          \
   %D%/packages/nickle.scm                       \
   %D%/packages/nicotine.scm                     \
diff --git a/gnu/packages/nextcloud.scm b/gnu/packages/nextcloud.scm
new file mode 100644
index 0000000000..d172f3214f
--- /dev/null
+++ b/gnu/packages/nextcloud.scm
@@ -0,0 +1,190 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2021 Raghav Gururajan <rg@raghavgururajan.name>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages nextcloud)
+  #:use-module (gnu packages)
+  #:use-module (gnu packages check)
+  #:use-module (gnu packages compression)
+  #:use-module (gnu packages documentation)
+  #:use-module (gnu packages freedesktop)
+  #:use-module (gnu packages glib)
+  #:use-module (gnu packages gnome)
+  #:use-module (gnu packages graphviz)
+  #:use-module (gnu packages kde-frameworks)
+  #:use-module (gnu packages perl)
+  #:use-module (gnu packages pkg-config)
+  #:use-module (gnu packages python)
+  #:use-module (gnu packages python-xyz)
+  #:use-module (gnu packages qt)
+  #:use-module (gnu packages ruby)
+  #:use-module (gnu packages sphinx)
+  #:use-module (gnu packages sqlite)
+  #:use-module (gnu packages tls)
+  #:use-module ((guix licenses) #:prefix license:)
+  #:use-module (guix packages)
+  #:use-module (guix git-download)
+  #:use-module (guix build-system glib-or-gtk)
+  #:use-module (guix build-system qt))
+
+(define-public nextcloud-client
+  (package
+    (name "nextcloud-client")
+    (version "3.1.3")
+    (source
+     (origin
+       (method git-fetch)
+       (uri
+        (git-reference
+         (url "https://github.com/nextcloud/desktop")
+         (commit
+          (string-append "v" version))))
+       (file-name
+        (git-file-name name version))
+       (sha256
+        (base32 "15ymk3gvfmgwzmqbhlw7jjy9y65ib3391h1dlmpll65iaj2miajk"))
+       (modules '((guix build utils)
+                  (ice-9 ftw)
+                  (srfi srfi-1)))
+       (snippet
+        `(begin
+           (let ((keep '( ;; Not available in Guix.
+                         "QProgressIndicator"
+                         "kmessagewidget" "qtokenizer")))
+             (with-directory-excursion "src/3rdparty"
+               (for-each delete-file-recursively
+                         (lset-difference string=?
+                                          (scandir ".")
+                                          (cons* "." ".." keep))))
+             #t)))))
+    (build-system qt-build-system)
+    (arguments
+     `(#:configure-flags
+       (list
+        "-DUNIT_TESTING=ON"
+        ;; Upstream Bug: https://github.com/nextcloud/desktop/issues/2885
+        "-DNO_SHIBBOLETH=ON")
+       #:imported-modules
+       ((guix build glib-or-gtk-build-system)
+        ,@%qt-build-system-modules)
+       #:modules
+       (((guix build glib-or-gtk-build-system)
+         #:prefix glib-or-gtk:)
+        (guix build qt-build-system)
+        (guix build utils))
+       #:phases
+       (modify-phases %standard-phases
+         (add-after 'unpack 'patch-source
+           (lambda* (#:key inputs outputs #:allow-other-keys)
+             (let* ((qtsolutions (assoc-ref inputs "qtsolutions")))
+               (for-each
+                (lambda (dir)
+                  (copy-recursively
+                   (string-append qtsolutions "/" dir "/src")
+                   (string-append "src/3rdparty/" dir)))
+                '("qtlockedfile" "qtsingleapplication")))
+             (with-directory-excursion "src/gui"
+               (substitute* `("application.h" "application.cpp")
+                 (("SharedTools::QtSingleApplication") "QtSingleApplication")
+                 (("slotParseMessage\\(const QString &(msg)?.*\\)")
+                  "slotParseMessage(const QString &msg)")))
+             #t))
+         (add-after 'unpack 'patch-cmake
+           (lambda* (#:key outputs #:allow-other-keys)
+             ;; Patch install directory for dbus service files.
+             (substitute* "shell_integration/libcloudproviders/CMakeLists.txt"
+               (("PKGCONFIG_GETVAR\\(.+ _install_dir\\)")
+                "set(_install_dir \"${CMAKE_INSTALL_PREFIX}/share/dbus-1/services\")"))
+             ;; Make sure, that Qt modules are installed under $prefix.
+             (substitute* "shell_integration/dolphin/CMakeLists.txt"
+               (("ON CACHE")
+                "OFF CACHE"))
+             #t))
+         (add-after 'patch-plugin-dirs 'fix-build
+           (lambda _
+             (with-directory-excursion "src/gui"
+               (substitute* `("application.h" "application.cpp")
+                 (("SharedTools::")
+                  "")))
+             #t))
+         (add-before 'check 'pre-check
+           (lambda _
+             ;; Tests write to $HOME.
+             (setenv "HOME" (getcwd))
+             #t))
+         (add-after 'install 'glib-or-gtk-compile-schemas
+           (assoc-ref glib-or-gtk:%standard-phases 'glib-or-gtk-compile-schemas))
+         (add-after 'glib-or-gtk-compile-schemas 'glib-or-gtk-wrap
+           (assoc-ref glib-or-gtk:%standard-phases 'glib-or-gtk-wrap)))))
+    (native-inputs
+     `(("cmocka" ,cmocka)
+       ("dot" ,graphviz)
+       ("doxygen" ,doxygen)
+       ("extra-cmake-modules" ,extra-cmake-modules)
+       ("glib:bin" ,glib "bin")
+       ("perl" ,perl)
+       ("pkg-config" ,pkg-config)
+       ("python" ,python-wrapper)
+       ("qtsolutions"
+        ,(origin
+           (method git-fetch)
+           (uri
+            (git-reference
+             (url "https://github.com/qtproject/qt-solutions")
+             (commit "9568abd142d581b67b86a5f63d823a34b0612702")))
+           (file-name
+            (git-file-name "qtsolutions" "9568abd"))
+           (sha256
+            (base32 "17fnmassflm3vxi0krpr6fff368jy38cby31a48rban4nqqmgx7n"))))
+       ("qttools" ,qttools)
+       ("ruby" ,ruby)))
+    (inputs
+     `(("appstream" ,appstream)
+       ("glib" ,glib)
+       ("kconfig" ,kconfig)
+       ("kcoreaddons" ,kcoreaddons)
+       ("kio" ,kio)
+       ("kjs" ,kjs)
+       ("libcloudproviders" ,libcloudproviders)
+       ("libzip" ,libzip)
+       ("openssl" ,openssl)
+       ("python-nautilus" ,python-nautilus)
+       ("qtbase" ,qtbase)
+       ("qtdeclarative" ,qtdeclarative)
+       ("qtgraphicaleffects" ,qtgraphicaleffects)
+       ("qtkeychain" ,qtkeychain)
+       ("qtquickcontrols2" ,qtquickcontrols2)
+       ("qtsvg" ,qtsvg)
+       ("qtwebchannel" ,qtwebchannel)
+       ("qtwebsockets" ,qtwebsockets)
+       ("qtwebkit" ,qtwebkit)
+       ("sqlite" ,sqlite)
+       ("zlib" ,zlib)))
+    (propagated-inputs
+     `(("qtwebengine" ,qtwebengine)))
+    (synopsis "Desktop sync client for Nextcloud")
+    (description "Nextcloud-Desktop is a tool to synchronize files from
+Nextcloud Server with your computer.")
+    (home-page "https://nextcloud.com/install/#install-clients")
+    (license
+     (list
+      ;; QtProgressIndicator
+      license:expat
+      ;; All ThirdParty (except QtProgressIndicator)
+      license:lgpl2.1+
+      ;; Others
+      license:gpl2+))))
-- 
2.30.1


[-- Attachment #2: OpenPGP digital signature --]
[-- Type: application/pgp-signature, Size: 236 bytes --]

  reply	other threads:[~2021-02-22 17:42 UTC|newest]

Thread overview: 44+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2021-01-15 10:09 [bug#45889] Nextcloud Desktop Raghav Gururajan
2021-01-16  6:40 ` [bug#45889] Nextcloud Desktop (v2) Raghav Gururajan
2021-01-16  8:33 ` [bug#45889] Nextcloud Desktop (v3) Raghav Gururajan
2021-01-16 10:09 ` [bug#45889] Nextcloud Desktop (v4) Raghav Gururajan
2021-01-16 10:48   ` Nicolò Balzarotti
2021-01-16 14:42     ` Raghav Gururajan
2021-01-16 14:34 ` [bug#45889] Nextcloud Desktop (v5) Raghav Gururajan
2021-01-17 14:44 ` [bug#45889] Nextcloud Client (v6) Raghav Gururajan
2021-01-24 18:45   ` david larsson
2021-02-01 15:07     ` Raghav Gururajan
2021-02-01 15:13 ` [bug#45889] Nextcloud Client (v7) Raghav Gururajan
2021-02-09 10:22   ` Leo Prikler
2021-02-13 20:36     ` [bug#45889] Nextcloud Client (v8) Raghav Gururajan
2021-02-13 21:47       ` Leo Prikler
2021-02-13 23:54         ` Raghav Gururajan
2021-02-14  0:47           ` [bug#45889] Nextcloud Client (v9) Raghav Gururajan
2021-02-14 10:53           ` [bug#45889] Nextcloud Client (v8) Leo Prikler
2021-02-18 20:23             ` [bug#45889] Nextcloud Client (v10) Raghav Gururajan via Guix-patches via
2021-02-18 22:26               ` Leo Prikler
2021-02-21 17:04                 ` Raghav Gururajan via Guix-patches via
2021-02-21 17:45                   ` Leo Prikler
2021-02-21 18:09                     ` [bug#45889] Nextcloud Client (v11) Raghav Gururajan via Guix-patches via
2021-02-21 18:22                       ` Leo Prikler
2021-02-21 18:50                         ` [bug#45889] Nextcloud Client (v12) Raghav Gururajan via Guix-patches via
2021-02-21 19:37                           ` Leo Prikler
2021-02-22 17:29                             ` Raghav Gururajan via Guix-patches via [this message]
2021-02-23 14:27                               ` [bug#45889] Nextcloud Client (v14) Raghav Gururajan via Guix-patches via
2021-02-23 17:58                                 ` Leo Prikler
2021-03-09  6:00                                   ` [bug#45889] Nextcloud Client (v15) Raghav Gururajan via Guix-patches via
2021-03-09  7:03                                     ` Leo Prikler
2021-03-09 10:50                                       ` [bug#45889] Nextcloud Client (v16) Raghav Gururajan via Guix-patches via
2021-03-09 11:39                                         ` Leo Prikler
2021-03-09 12:29                                           ` Raghav Gururajan via Guix-patches via
2021-03-09 12:43                                             ` [bug#45889] Nextcloud Client (v17) Leo Prikler
2021-03-09 15:16                                               ` [bug#45889] Nextcloud Client (v18) Raghav Gururajan via Guix-patches via
2021-03-09 23:24                                                 ` bug#45889: " Leo Prikler
2021-03-10  3:46                                                   ` [bug#45889] " Raghav Gururajan via Guix-patches via
2021-03-11  6:45                                                     ` Raghav Gururajan via Guix-patches via
2021-03-11  6:49                                                       ` Leo Prikler
2021-03-11  7:44                                                         ` Raghav Gururajan via Guix-patches via
2021-03-12  9:25                                                   ` david larsson
2021-03-12  9:47                                                     ` Raghav Gururajan via Guix-patches via
2021-02-21 18:22                       ` [bug#45889] Nextcloud Client (v11) Raghav Gururajan via Guix-patches via
2021-02-09 12:53   ` [bug#45889] Nextcloud Client (v7) Leo Prikler

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=12599035-d671-b417-d70c-89d694f3ccd9@raghavgururajan.name \
    --to=guix-patches@gnu.org \
    --cc=45889@debbugs.gnu.org \
    --cc=leo.prikler@student.tugraz.at \
    --cc=rg@raghavgururajan.name \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
Code repositories for project(s) associated with this external index

	https://git.savannah.gnu.org/cgit/guix.git

This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.