Problem using multiple manifest files

Problem using multiple manifest files

[Thaddäus Töppen]

[-- Attachment #1: Type: text/plain, Size: 899 bytes --]

Hello Guix community,

I am new to Guix, and I am having trouble, using multiple manifest files.
For example, I have a file "emacs.scm", containing:

(specifications->manifest
  '("emacs" "emacs-evil"))

…and then other similar files, bundling different things, like programming
languages / xorg stuff etc.

When I use "guix package -m emacs.scm" it installs the packages and they
are available. When I then install the next manifest file's packages, the
"emacs.scm" packages are no longer available – the links in
"~/.guix-profile/bin" have been removed.

Am I correct in assuming, that only one manifest file can be installed at a
time, thus all package definitions have to be in one file (or at least
imported into a main-package-file)?

Also: If I have more (beginner) questions, should I drop them all in one
mail or create separate threads

Best Regards
Thaddäus

[-- Attachment #2: Type: text/html, Size: 1820 bytes --]

Re: Problem using multiple manifest files

[Ricardo Wurmus]

Hello Thaddäus,

> Hello Guix community,

welcome!

> When I use "guix package -m emacs.scm" it installs the packages and they
> are available. When I then install the next manifest file's packages, the
> "emacs.scm" packages are no longer available – the links in
> "~/.guix-profile/bin" have been removed.
>
> Am I correct in assuming, that only one manifest file can be installed at a
> time, thus all package definitions have to be in one file (or at least
> imported into a main-package-file)?

Yes, this is correct.  A manifest declares the contents of a single
profile.  By passing a manifest file to “guix package -m” you tell it to
only install the declared packages and remove everything else.

You can instantiate different manifest to different profiles by also
passing “-p /path/to/other/profile”.  You can combine them in a session
by source-ing each of the profiles’ “etc/profile” files.

> Also: If I have more (beginner) questions, should I drop them all in one
> mail or create separate threads

It’s better to send separate emails.

--
Ricardo

Re: Problem using multiple manifest files

[Mikhail Kryshen]

[-- Attachment #1: Type: text/plain, Size: 1303 bytes --]

Thaddäus Töppen <thaddaeus.toeppen@gmail.com> writes:
> Am I correct in assuming, that only one manifest file can be installed at a
> time, thus all package definitions have to be in one file (or at least
> imported into a main-package-file)?

Yes, but since manifest file is a Guile program, you can implement any
custom logic for constructing the manifest there.

Here is an example of a manifest file that loads multiple manifests and
composes them into one:

----------------------------------------------------------------------
(use-modules (srfi srfi-1)
             ((guix ui) #:select (make-user-module)))

(define (load-manifest file)
  ;; Load manifest file in a fresh module with necessary imports.
  (let ((module (make-user-module '((guix profiles) (gnu)))))
    (save-module-excursion
     (lambda _
       (set-current-module module)
       (load (canonicalize-path file))))))

(define (combined-manifest-from-files . files)
  (fold (lambda (file combined)
          (manifest-add combined
                        (manifest-entries (load-manifest file))))
        (manifest '())
        files))

(combined-manifest-from-files
 "emacs.scm"
 "xorg.scm"
 "etc.scm")
----------------------------------------------------------------------

-- 
Mikhail

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 658 bytes --]

Re: Problem using multiple manifest files

[Ludovic Courtès]

Hello,

Mikhail Kryshen <mikhail@kryshen.net> skribis:

> Here is an example of a manifest file that loads multiple manifests and
> composes them into one:
>
> ----------------------------------------------------------------------
> (use-modules (srfi srfi-1)
>              ((guix ui) #:select (make-user-module)))
>
> (define (load-manifest file)
>   ;; Load manifest file in a fresh module with necessary imports.
>   (let ((module (make-user-module '((guix profiles) (gnu)))))
>     (save-module-excursion
>      (lambda _
>        (set-current-module module)
>        (load (canonicalize-path file))))))
>
> (define (combined-manifest-from-files . files)
>   (fold (lambda (file combined)
>           (manifest-add combined
>                         (manifest-entries (load-manifest file))))
>         (manifest '())
>         files))
>
> (combined-manifest-from-files
>  "emacs.scm"
>  "xorg.scm"
>  "etc.scm")
> ----------------------------------------------------------------------

Nice example!

Ludo’.

Re: Problem using multiple manifest files

[Chris Marusich]

[-- Attachment #1: Type: text/plain, Size: 1052 bytes --]

Mikhail Kryshen <mikhail@kryshen.net> writes:

> (use-modules (srfi srfi-1)
>              ((guix ui) #:select (make-user-module)))
>
> (define (load-manifest file)
>   ;; Load manifest file in a fresh module with necessary imports.
>   (let ((module (make-user-module '((guix profiles) (gnu)))))
>     (save-module-excursion
>      (lambda _
>        (set-current-module module)
>        (load (canonicalize-path file))))))

Neat example!  But what is make-user-module doing, and is it necessary?

I checked in the Guix source and found that this procedure uses the
procedure make-fresh-user-module, which comes from the (ice-9 boot)
module and is not documented in the Guile Reference manual.  I stopped
investigating when I checked the ice-9 source code and found that it did
not contain an immediately helpful docstring or comment.  It feels like
maybe make-fresh-user-module ought to be documented in "(guile) Module
System Reflection", but it isn't.  Unfortunately, I don't have time
right now to dig deeper.

-- 
Chris

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 832 bytes --]

Re: Problem using multiple manifest files

[Mikhail Kryshen]

[-- Attachment #1: Type: text/plain, Size: 972 bytes --]

Chris Marusich <cmmarusich@gmail.com> writes:

> Mikhail Kryshen <mikhail@kryshen.net> writes:
>
>> (use-modules (srfi srfi-1)
>>              ((guix ui) #:select (make-user-module)))
>>
>> (define (load-manifest file)
>>   ;; Load manifest file in a fresh module with necessary imports.
>>   (let ((module (make-user-module '((guix profiles) (gnu)))))
>>     (save-module-excursion
>>      (lambda _
>>        (set-current-module module)
>>        (load (canonicalize-path file))))))
>
> Neat example!

Thanks! 

> But what is make-user-module doing, and is it necessary?

I looked into the Guix source and reproduced what "guix package -m" does
to load a manifest file.  Make-user-module procedure appear to be used
in Guix to dynamically create modules for running user code.  I could
have simply used "load" here, but then all the files would be loaded in
the same environment and could potentially interfere with each other.

-- 
Mikhail

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 658 bytes --]

Re: Problem using multiple manifest files

[Chris Marusich]

[-- Attachment #1: Type: text/plain, Size: 1136 bytes --]

Mikhail Kryshen <mikhail@kryshen.net> writes:

> Chris Marusich <cmmarusich@gmail.com> writes:
>
>> Mikhail Kryshen <mikhail@kryshen.net> writes:
>>
>>> (use-modules (srfi srfi-1)
>>>              ((guix ui) #:select (make-user-module)))
>>>
>>> (define (load-manifest file)
>>>   ;; Load manifest file in a fresh module with necessary imports.
>>>   (let ((module (make-user-module '((guix profiles) (gnu)))))
>>>     (save-module-excursion
>>>      (lambda _
>>>        (set-current-module module)
>>>        (load (canonicalize-path file))))))
>>
>> Neat example!
>
> Thanks! 
>
>> But what is make-user-module doing, and is it necessary?
>
> I looked into the Guix source and reproduced what "guix package -m" does
> to load a manifest file.  Make-user-module procedure appear to be used
> in Guix to dynamically create modules for running user code.  I could
> have simply used "load" here, but then all the files would be loaded in
> the same environment and could potentially interfere with each other.

I see.  Thank you for the explanation!  That does indeed seem to be the
intent.

-- 
Chris

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 832 bytes --]