Guile snippet to get latest "guix pull" commit with prebuilt binaries

Guile snippet to get latest "guix pull" commit with prebuilt binaries

[Pierre Neidhardt]

[-- Attachment #1: Type: text/plain, Size: 337 bytes --]

Hi,

Ludo told me he had a Guile snippet to find the last Guix commits  with
enough(?) pre-built binaries.  (Which is quite useful for a "guix pull".)

Ludo, anyone, would you like to share? :)

@Ludo: Seems like I cannot send you emails directly, maybe I'm being
marked as spam?

-- 
Pierre Neidhardt
https://ambrevar.xyz/

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 487 bytes --]

Re: Guile snippet to get latest "guix pull" commit with prebuilt binaries

[swedebugia]

Pierre Neidhardt <mail@ambrevar.xyz> skrev: (5 februari 2019 00:09:46 CET)
>
>@Ludo: Seems like I cannot send you emails directly, maybe I'm being
>marked as spam?

I also could not send to ludo at gnu dot org about a week ago and ended up sending a notice to his work email instead. 
don't know if that worked better but it was not rejected by the postmaster.


-- 
Sent from my k-9 mail for Android.

Re: Guile snippet to get latest "guix pull" commit with prebuilt binaries

[Ludovic Courtès]

[-- Attachment #1: Type: text/plain, Size: 386 bytes --]

Hello!

Pierre Neidhardt <mail@ambrevar.xyz> skribis:

> Ludo told me he had a Guile snippet to find the last Guix commits  with
> enough(?) pre-built binaries.  (Which is quite useful for a "guix pull".)
>
> Ludo, anyone, would you like to share? :)

Here’s the file you’d drop as ~/.config/guix/channels.scm or pass to
‘guix pull -C’ (it expects Guile-JSON 1.x):


[-- Attachment #2: the file --]
[-- Type: text/plain, Size: 1894 bytes --]

(use-modules (guix http-client)
             (json)
             (srfi srfi-1)
             (ice-9 match))

(define (latest-evaluations jobset)
  "Return the latest evaluations of JOBSET."
  (filter (lambda (json)
            (string=? (hash-ref json "specification") jobset))
          (json->scm
           (http-fetch
            "https://berlin.guixsd.org/api/evaluations?nr=30"))))

(define (evaluation-complete? number)
  "Return true if evaluation NUMBER completed and all its builds were
successful."
  (let ((builds (json->scm
                 (http-fetch
                  (string-append
                   "https://berlin.guixsd.org/api/latestbuilds?nr=30&evaluation="
                   (number->string number))))))
    (every (lambda (build)
             ;; Zero means build success.
             (= (hash-ref build "buildstatus") 0))
           builds)))

(define (latest-commit-successfully-built)
  "Return the latest commit for which substitutes are (potentially)
available."
  (let* ((evaluations (latest-evaluations "guix-modular-master"))
         (candidates  (filter-map (lambda (json)
                                    (match (hash-ref json "checkouts")
                                      ((checkout)
                                       (cons (hash-ref json "id")
                                             (hash-ref checkout "commit")))
                                      (_ #f)))
                                  evaluations)))
    (any (match-lambda
            ((evaluation . commit)
             (and (evaluation-complete? evaluation)
                  commit)))
          candidates)))

;; Pull the latest commit fully built on berlin.guixsd.org.
;; WARNING: This could downgrade your system!
(list (channel
       (name 'guix)
       (url "https://git.savannah.gnu.org/git/guix.git")
       (commit (pk 'commit (latest-commit-successfully-built)))))

[-- Attachment #3: Type: text/plain, Size: 143 bytes --]


It looks for a commit for which Guix itself is built.

Use with care as this could prevent you from getting security updates!

Ludo’.

Re: Guile snippet to get latest "guix pull" commit with prebuilt binaries

[Pierre Neidhardt]

[-- Attachment #1: Type: text/plain, Size: 84 bytes --]

This is great, thanks for sharing!

-- 
Pierre Neidhardt
https://ambrevar.xyz/

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 487 bytes --]