[bug#51747] [PATCH]: gnu: nix: Update to 2.4.

[Maxime Devos <maximedevos@telenet.be>]

[-- Attachment #1.1: Type: text/plain, Size: 1403 bytes --]

Zhu Zihao schreef op za 15-01-2022 om 00:51 [+0800]:
> Patches updated.
> 
> The test is disabled by default, when I tried enable it test it fails,
> It looks like that the RPATH of test binary is not complete. Just leave
> it disabled.

I didn't see anyting RUNPATH (*) related.  It failed to run some python
script though with ‘file does not exist’ (which could maybe indicate
RUNPATH problems, but not in this case), it turned out that the shebang
wasn't patched.  Adding python to the native-inputs appears to fix
things

> I have no idea to gi.ve user a hint of differnce between cpuid and
> libcpuid. Maybe add a comment or add it to description. But I don't
> think user can find these hints in first sight.

See attachement for a variant of the 'libcpuid' package that builds for
me (--system=x86-64-linux, with tests) and cross-builds to
--target=i586-pc-gnu (tests automatically disabled because of cross-
compilation).  'kmod' only exists on Linux, so I modified the inputs
and 'absolutize' to only use it when building for Linux.

I don't think many users look at the description either, but it seems a
logical place to look in case of trouble.  I added a sentence.

I modified the package definition outside emacs and outside a git
checkout, so the indentation probably needs some fixing.

Greetings,
Maxime.

(*) IIRC Guix uses RUNPATH and not RPATH.

[-- Attachment #1.2: stuff.scm --]
[-- Type: text/x-scheme, Size: 2613 bytes --]


(use-modules (guix svn-download)
    ((guix licenses) #:prefix license:)
    (gnu packages linux)
    (gnu packages python)
    (guix packages)
    (guix gexp)
    (guix packages)
    (guix git-download)
    (guix build-system cmake)
    (guix utils)
    (srfi srfi-1))

(define-public libcpuid
  ;; We need to remove blobs from the source, first we have to isolate the blob
  ;; source in build system.
  ;; See <https://github.com/anrieff/libcpuid/pull/159>.
  (let ((commit "2e61160983f32ba840b2246d3c3850c44626ab0d")
        (revision "1"))
    (package
      (name "libcpuid")
      (version (git-version "0.5.1" revision commit))
      (source
       (origin
         (method git-fetch)
         (uri (git-reference
               (url "https://github.com/anrieff/libcpuid")
               (commit commit)))
         (sha256
          (base32 "1mphvkiqq6z33sq6i490fq27sbyylacwrf8bg7ccvpcjms208sww"))
         (modules '((guix build utils)))
         (snippet
          ;; Now remove blobs.
          #~(begin
              (delete-file "libcpuid/msrdriver.c")
              (delete-file-recursively "contrib/MSR Driver")))
         (file-name (git-file-name name version))))
      (build-system cmake-build-system)
      (arguments
       (list
        #:modules '((rnrs exceptions)
                    (guix build cmake-build-system)
                    (guix build utils))
        #:configure-flags #~'("-DLIBCPUID_TESTS=ON") 
        #:phases
        #~(modify-phases %standard-phases
            (add-after 'unpack 'absolutize
              (lambda* (#:key inputs #:allow-other-keys)
                ;; modprobe doesn't exist on the Hurd 
                (guard (c ((search-error? c) (values)))
                  (substitute* "libcpuid/rdmsr.c"
                    (("modprobe")
                     (search-input-file inputs "bin/modprobe")))))))))
      (inputs (if (target-linux?)
                  (list kmod) ; linux-only
                  '()))
      ;; a python from the 3. series is required by tests
      (native-inputs (list python-3))
      (supported-systems
       (filter (lambda (t) (or (target-x86-64? t) (target-x86-32? t)))
               %supported-systems))
      (home-page "https://libcpuid.sourceforge.net/")
      (synopsis "Small library for x86 CPU detection and feature extraction")
      (description "Libcpuid is a small C library to get vendor, model, branding
string, code name and other information from x86 CPU.  This library is not
to be confused with the @code{cpuid} command line utility fromm the
@code{cpuid} package.")
      (license license:bsd-2))))

libcpuid

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]