;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2013, 2014, 2015 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2014, 2015 Mark H Weaver <mhw@netris.org>
;;; Copyright © 2016, 2017, 2018, 2020 Efraim Flashner <efraim@flashner.co.il>
;;; Copyright © 2016, 2017 Nikita <nikita@n0.is>
;;; Copyright © 2017, 2018, 2019, 2020 Tobias Geerinckx-Rice <me@tobias.gr>
;;; Copyright © 2017, 2018, 2019 Eric Bavier <bavier@member.fsf.org>
;;; Copyright © 2017 Rutger Helling <rhelling@mykolab.com>
;;; Copyright © 2018 Ricardo Wurmus <rekado@elephly.net>
;;; Copyright © 2020 Vincent Legoll <vincent.legoll@gmail.com>
;;; Copyright © 2020 Brice Waegeneire <brice@waegenei.re>
;;; Copyright © 2020 André Batista <nandre@riseup.net>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu packages tor)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix packages)
  #:use-module (guix utils)
  #:use-module (guix download)
  #:use-module (guix git-download)
  #:use-module (guix build-system cargo)
  #:use-module (guix build-system gnu)
  #:use-module (guix build-system go)
  #:use-module (guix build-system python)
  #:use-module (guix build-system trivial)
  #:use-module (gnu packages)
  #:use-module (gnu packages admin)
  #:use-module (gnu packages assembly)
  #:use-module (gnu packages audio)
  #:use-module (gnu packages autotools)
  #:use-module (gnu packages base)
  #:use-module (gnu packages bash)
  #:use-module (gnu packages check)
  #:use-module (gnu packages compression)
  #:use-module (gnu packages cups)
  #:use-module (gnu packages databases)
  #:use-module (gnu packages fontutils)
  #:use-module (gnu packages gl)
  #:use-module (gnu packages glib)
  #:use-module (gnu packages gnome)
  #:use-module (gnu packages golang)
  #:use-module (gnu packages gtk)
  #:use-module (gnu packages icu4c)
  #:use-module (gnu packages image)
  #:use-module (gnu packages kerberos)
  #:use-module (gnu packages libcanberra)
  #:use-module (gnu packages libevent)
  #:use-module (gnu packages libffi)
  #:use-module (gnu packages linux)
  #:use-module (gnu packages llvm)
  #:use-module (gnu packages node)
  #:use-module (gnu packages nss)
  #:use-module (gnu packages pcre)
  #:use-module (gnu packages perl)
  #:use-module (gnu packages pkg-config)
  #:use-module (gnu packages pulseaudio)
  #:use-module (gnu packages python)
  #:use-module (gnu packages python-crypto)
  #:use-module (gnu packages python-web)
  #:use-module (gnu packages python-xyz)
  #:use-module (gnu packages qt)
  #:use-module (gnu packages readline)
  #:use-module (gnu packages rsync) ; for httpse
  #:use-module (gnu packages rust)
  #:use-module (gnu packages rust-apps)
  #:use-module (gnu packages sqlite)
  #:use-module (gnu packages tls)
  #:use-module (gnu packages version-control)
  #:use-module (gnu packages video)
  #:use-module (gnu packages vim) ; for xxd
  #:use-module (gnu packages w3m)
  #:use-module (gnu packages xdisorg)
  #:use-module (gnu packages xiph)
  #:use-module (gnu packages xorg)
  #:use-module (gnu packages xml) ; for httpse
  #:use-module (ice-9 match)
  #:use-module ((srfi srfi-1) #:hide (zip)))

(define-public tor
  (package
    (name "tor")
    (version "0.4.3.6")
    (source (origin
             (method url-fetch)
             (uri (string-append "https://dist.torproject.org/tor-"
                                 version ".tar.gz"))
             (sha256
              (base32
               "0qmcrkjip0ywq77232m73pjwqiaj0q2klwklqlpbw575shvhcbba"))))
    (build-system gnu-build-system)
    (arguments
     `(#:configure-flags
       (list "--enable-lzma"
             "--enable-zstd")))
    (native-inputs
     `(("pkg-config" ,pkg-config)
       ("python" ,python)))             ; for tests
    (inputs
     `(("libevent" ,libevent)
       ("libseccomp" ,libseccomp)
       ("openssl" ,openssl)
       ("xz" ,xz)
       ("zlib" ,zlib)
       ("zstd" ,zstd "lib")))
    (home-page "https://www.torproject.org/")
    (synopsis "Anonymous network router to improve privacy on the Internet")
    (description
     "Tor protects you by bouncing your communications around a distributed
network of relays run by volunteers all around the world: it prevents
somebody watching your Internet connection from learning what sites you
visit, and it prevents the sites you visit from learning your physical
location.  Tor works with many of your existing applications, including
web browsers, instant messaging clients, remote login, and other
applications based on the TCP protocol.

This package is the full featured @code{tor} which is needed for running
relays, bridges or directory authorities. If you just want to access the Tor
network or to setup an onion service you may install @code{tor-client}
instead.")
    (license license:bsd-3)))

(define-public tor-client
  (package
    (inherit tor)
    (name "tor-client")
    (arguments
     (substitute-keyword-arguments (package-arguments tor)
       ((#:configure-flags flags)
        (append flags
                '("--disable-module-relay")))))
    (synopsis "Client to the anonymous Tor network")
    (description
     "Tor protects you by bouncing your communications around a distributed
network of relays run by volunteers all around the world: it prevents
somebody watching your Internet connection from learning what sites you
visit, and it prevents the sites you visit from learning your physical
location.  Tor works with many of your existing applications, including
web browsers, instant messaging clients, remote login, and other
applications based on the TCP protocol.

To @code{torify} applications (to take measures to ensure that an application,
which has not been designed for use with Tor such as ssh, will use only Tor for
internet connectivity, and also ensures that there are no leaks from DNS, UDP or
the application layer) you need to install @code{torsocks}.

This package only provides a client to the Tor Network.")))

(define-public torsocks
  (package
    (name "torsocks")
    (version "2.3.0")
    (source (origin
              (method url-fetch)
              (uri (string-append "https://people.torproject.org/~dgoulet/"
                                  "torsocks/torsocks-" version ".tar.xz"))
              (sha256
               (base32
                "08inrkap29gikb6sdmb58z43hw4abwrfw7ny40c4xzdkss0vkwdr"))))
    (build-system gnu-build-system)
    (inputs
     `(("libcap" ,libcap)))
    (arguments
     `(#:phases (modify-phases %standard-phases
                  (add-after 'build 'absolutize
                    (lambda* (#:key inputs #:allow-other-keys)
                      (substitute* "src/bin/torsocks"
                        (("getcap=.*")
                         (string-append "getcap=" (which "getcap") "\n")))
                      #t)))))
    (home-page "https://www.torproject.org/")
    (synopsis "Use socks-friendly applications with Tor")
    (description
     "Torsocks allows you to use most socks-friendly applications in a safe
way with Tor.  It ensures that DNS requests are handled safely and explicitly
rejects UDP traffic from the application you're using.")

    ;; All the files explicitly say "version 2 only".
    (license license:gpl2)))

(define-public privoxy
  (package
    (name "privoxy")
    (version "3.0.28")
    (source (origin
             (method url-fetch)
             (uri (string-append "mirror://sourceforge/ijbswa/Sources/"
                                 version "%20%28stable%29/privoxy-"
                                 version "-stable-src.tar.gz"))
             (sha256
              (base32
               "0jl2yav1qzqnaqnnx8i6i53ayckkimcrs3l6ryvv7bda6v08rmxm"))))
    (build-system gnu-build-system)
    (arguments
     '(;; The default 'sysconfdir' is $out/etc; change that to
       ;; $out/etc/privoxy.
       #:configure-flags (list (string-append "--sysconfdir="
                                              (assoc-ref %outputs "out")
                                              "/etc/privoxy")
                               "--localstatedir=/var")
       #:tests? #f                      ; no test suite
       #:phases
       (modify-phases %standard-phases
         (add-after 'unpack 'patch-default-logging
           (lambda _
             (with-fluids ((%default-port-encoding "ISO-8859-1"))
               ;; Do not create /var/run nor /var/log/privoxy/logfile.
               (substitute* "GNUmakefile.in"
                 (("(logfile \\|\\| exit )1" _ match)
                  (string-append match "0"))
                 (("(\\$\\(DESTDIR\\)\\$\\(SHARE_DEST\\)) \\\\" _ match)
                  match)
                 ((".*\\$\\(LOG_DEST\\) \\$\\(DESTDIR\\)\\$\\(PID_DEST\\).*")
                  ""))
               ;; Disable logging in the default configuration to allow for
               ;; non-root users using it as is.
               (substitute* "config"
                 (("^logdir") "#logdir")
                 (("^logfile") "#logfile")))
             #t)))))
    (inputs
     `(("w3m" ,w3m)
       ("pcre" ,pcre)
       ("zlib" ,zlib)))
    (native-inputs
     `(("autoconf" ,autoconf)
       ("automake" ,automake)))
    (home-page "https://www.privoxy.org")
    (synopsis "Web proxy with advanced filtering capabilities for enhancing privacy")
    (description
     "Privoxy is a non-caching web proxy with advanced filtering capabilities
for enhancing privacy, modifying web page data and HTTP headers, controlling
access, and removing ads and other obnoxious Internet junk.  Privoxy has a
flexible configuration and can be customized to suit individual needs and
tastes.  It has application for both stand-alone systems and multi-user
networks.")
    (license license:gpl2+)))

(define-public onionshare
  (package
    (name "onionshare")
    (version "2.2")
    (source
      (origin
        (method git-fetch)
        (uri (git-reference
              (url "https://github.com/micahflee/onionshare")
              (commit (string-append "v" version))))
        (file-name (git-file-name name version))
        (sha256
         (base32 "0m8ygxcyp3nfzzhxs2dfnpqwh1vx0aws44lszpnnczz4fks3a5j4"))))
    (build-system python-build-system)
    (arguments
     `(#:phases
       (modify-phases %standard-phases
         (add-after 'unpack 'fix-install-path
           (lambda* (#:key outputs #:allow-other-keys)
             (let* ((out        (assoc-ref outputs "out"))
                    (onionshare (string-append out "/share/onionshare")))
               (substitute* '("setup.py" "onionshare/common.py")
                 (("sys.prefix,") (string-append "'" out "',")))
               (substitute* "setup.py"
                 ;; For the nautilus plugin.
                 (("/usr/share/nautilus") "share/nautilus"))
               (substitute* "install/org.onionshare.OnionShare.desktop"
                 (("/usr") out))
               #t)))
         (delete 'check)
         (add-before 'strip 'check
           ;; After all the patching we run the tests after installing.
           (lambda _
             (setenv "HOME" "/tmp")     ; Some tests need a writable homedir
             (invoke "pytest" "tests/")
             #t)))))
    (native-inputs
     `(("python-pytest" ,python-pytest)))
    (inputs
     `(("python-pycrypto" ,python-pycrypto)
       ("python-flask" ,python-flask)
       ("python-flask-httpauth" ,python-flask-httpauth)
       ("python-nautilus" ,python-nautilus)
       ("python-sip" ,python-sip)
       ("python-stem" ,python-stem)
       ("python-pysocks" ,python-pysocks)
       ("python-pyqt" ,python-pyqt)))
    (home-page "https://onionshare.org/")
    (synopsis "Securely and anonymously share files")
    (description "OnionShare is a tool for securely and anonymously sending
and receiving files using Tor onion services.  It works by starting a web
server directly on your computer and making it accessible as an unguessable
Tor web address that others can load in a Tor-enabled web browser to download
files from you, or upload files to you.  It doesn't require setting up a
separate server, using a third party file-sharing service, or even logging
into an account.")
    ;; Bundled, minified jquery is expat licensed.
    (license (list license:gpl3+ license:expat))))

(define-public nyx
  (package
    (name "nyx")
    (version "2.1.0")
    (source
     (origin
       (method url-fetch)
       (uri (pypi-uri name version))
       (sha256
        (base32
         "02rrlllz2ci6i6cs3iddyfns7ang9a54jrlygd2jw1f9s6418ll8"))))
    (build-system python-build-system)
    (inputs
     `(("python-stem" ,python-stem)))
    (arguments
     `(#:phases
       (modify-phases %standard-phases
         (add-after 'install 'install-man-page
           (lambda* (#:key outputs #:allow-other-keys)
             (let* ((out (assoc-ref outputs "out"))
                    (man (string-append out "/share/man")))
               (install-file "nyx.1" (string-append man "/man1"))
               #t)))
         (add-after 'install 'install-sample-configuration
           (lambda* (#:key outputs #:allow-other-keys)
             (let* ((out (assoc-ref outputs "out"))
                    (doc (string-append out "/share/doc/" ,name "-" ,version)))
               (install-file "web/nyxrc.sample" doc)
               #t))))
       ;; XXX The tests seem to require more of a real terminal than the build
       ;; environment provides:
       ;;   _curses.error: setupterm: could not find terminal
       ;; With TERM=linux, the tests try to move the cursor and still fail:
       ;;   _curses.error: cbreak() returned ERR
       #:tests? #f))
    (home-page "https://nyx.torproject.org/")
    (synopsis "Tor relay status monitor")
    (description
     "Nyx monitors the performance of relays participating in the
@uref{https://www.torproject.org/, Tor anonymity network}.  It displays this
information visually and in real time, using a curses-based terminal interface.
This makes Nyx well-suited for remote shell connections and servers without a
graphical display.  It's like @command{top} for Tor, providing detailed
statistics and status reports on:

@enumerate
@item connections (with IP address, hostname, fingerprint, and consensus data),
@item bandwidth, processor, and memory usage,
@item the relay's current configuration,
@item logged events,
@item and much more.
@end enumerate

Potential client and exit connections are scrubbed of sensitive information.")
    (license license:gpl3+)))

(define-public obfs4
  (package
   (name "obfs4")
   (version "0.0.11")
   (source
    (origin
     (method git-fetch)
     (uri (git-reference
           (url "https://git.torproject.org/pluggable-transports/obfs4.git")
           (commit (string-append "obfs4proxy-" version))))
     (file-name (git-file-name name version))
     (sha256
      (base32
       "1y2kjwrk64l1h8b87m4iqsanib5rn68gzkdri1vd132qrlypycjn"))))
   (build-system go-build-system)
   (arguments
    '(#:import-path "git.torproject.org/pluggable-transports/obfs4.git"
      #:tests? #f ;; No test files
      #:phases
      (modify-phases %standard-phases
        (replace 'build
          (lambda* (#:key outputs configure-flags #:allow-other-keys)
            (let ((out (assoc-ref outputs "out")))
              (copy-recursively
               "src/git.torproject.org/pluggable-transports/obfs4.git"
               "src/gitlab.com/yawning/obfs4.git"
               #:log (%make-void-port "w"))
              (with-directory-excursion
               "src/git.torproject.org/pluggable-transports/obfs4.git/obfs4proxy"
               (invoke "go" "build" "-ldflags" "-s"))
            #t)))
        (replace 'install
          (lambda* (#:key outputs #:allow-other-keys)
            (let* ((out (assoc-ref outputs "out"))
                   (src "src/git.torproject.org/pluggable-transports/obfs4.git")
                   (bin (string-append out "/bin"))
                   (share (string-append out "/share"))
                   (doc (string-append share "/doc"))
                   (man (string-append share "/man/man1")))
              (mkdir-p man)
              (mkdir bin)
              (mkdir doc)
              (with-directory-excursion
               (string-append src "/obfs4proxy")
               (copy-file "obfs4proxy"
                          (string-append bin "/obfs4proxy")))
              (with-directory-excursion
               (string-append src "/doc")
               (copy-file "obfs4proxy.1"
                          (string-append man "/obfs4proxy.1"))
               (copy-file "obfs4-spec.txt"
                          (string-append doc "/obfs4-spec.txt")))
            #t))))))
   (propagated-inputs
    `(("go-torproject-org-ptlib" ,go-torproject-org-ptlib)
      ("go-github-com-agl-ed25519" ,go-github-com-agl-ed25519)
      ("go-github-com-dchest-siphash" ,go-github-com-dchest-siphash)
      ("go-github-com-dchest-uniuri" ,go-github-com-dchest-uniuri)
      ("go-github-com-dsnet-compress" ,go-github-com-dsnet-compress)
      ("go-schwanenlied-me-yawning-bsaes" ,go-schwanenlied-me-yawning-bsaes)
      ("go-gitlab-com-yawning-utls" ,go-gitlab-com-yawning-utls)
      ("go-golang-org-x-net" ,go-golang-org-x-net)
      ("go-golang-org-x-crypto" ,go-golang-org-x-crypto)
      ("go-golang-org-x-text" ,go-golang-org-x-text)))
   (home-page "https://git.torproject.org/pluggable-transports/obfs4.git")
   (synopsis "Obfs4 implements an obfuscation protocol")
   (description "This is a look-like nothing obfuscation protocol that
incorporates ideas and concepts from Philipp Winter's ScrambleSuit protocol.
The obfs naming was chosen primarily because it was shorter, in terms of
protocol ancestery obfs4 is much closer to ScrambleSuit than obfs2/obfs3.")
   (license license:gpl3+)))

;; Upstream does not seem to keep tor-browser and tor-browser-build versions
;; in sync
(define %torbrowser-version "68.12.0esr-9.5-1")
(define %torbrowser-build-version "9.5.4")
(define %torbrowser-build "build1")
(define %torbrowser-build-id "20200729000000");must be of the form YYYYMMDDhhmmss

;; Fonts for Tor Browser. Avoid downloading 4Gb+ git repo on
;; https://github.com/googlei18n/noto-fonts.git to use just a handful.
;; Use the fonts on Tor Browser release tarball.
(define torbrowser-fonts
  (package
   (name "torbrowser-fonts")
   ; Tor Browser fonts did not change since last release and were not available
   ; when this version was built, the previous version were kept.
   ;(version %torbrowser-build-version)
   (version "9.5.3")
   (source
    (origin
     (method url-fetch)
     (uri (string-append "https://dist.torproject.org/torbrowser/"
                         version "/tor-browser-linux64-"
                         version "_en-US.tar.xz"))
     (sha256
      (base32
       "1kqvr0sag94xdkq85k426qq1hz2b52m315yz51w6hvc87d8332b4"))))
   (build-system trivial-build-system)
   (native-inputs
    `(("tar" ,tar)
      ("xz" ,xz)))
   (arguments
    `(#:modules ((guix build utils))
      #:builder (begin
                  (use-modules (guix build utils))
                  (let ((src (assoc-ref %build-inputs "source"))
                        (src-dir "tor-browser_en-US/Browser/fonts")
                        (fonts (string-append %output "/share/fonts"))
                        (tar (assoc-ref %build-inputs "tar"))
                        (xz (assoc-ref %build-inputs "xz")))
                    (mkdir-p fonts)
                    (format #t "Untaring torbrowser ball ...~%")
                    (invoke (string-append tar "/bin/tar") "-xf" src
                            "-C" fonts "--strip-components=3"
                            (string-append "--use-compress-program=" xz "/bin/xz")
                            src-dir)
                    #t))))
   (home-page "https://github.com/googlei18n/noto-fonts")
   (synopsis "Tor Browser bundled fonts")
   (description "Free fonts bundled with Tor Browser.  Includes a subset of Noto,
Arimo, Cousine, Tinos and STIX fonts.")
   (license license:silofl1.1)))

(define tor-browser-build
  (let ((commit (string-append "tbb-" %torbrowser-build-version
                               "-" %torbrowser-build)))
    (package
     (name "tor-browser-build")
     (version %torbrowser-build-version)
     (source
      (origin
       (method git-fetch)
       (uri (git-reference
             (url "https://git.torproject.org/builders/tor-browser-build.git")
             (commit commit)))
       (file-name (git-file-name name version))
       (sha256
        (base32
         "0mq9ml8p0l2nnwjgr6dqn00pzk7h5zpi3hhr093hq99bapxs3wcs"))))
     (build-system trivial-build-system)
     (arguments
      `(#:modules ((guix build utils))
        #:builder (begin
                    (use-modules (guix build utils))
                    (format #t "Copying build scripts ...~%")
                    (copy-recursively (string-append
                                       (assoc-ref %build-inputs "source")
                                       "/projects/tor-browser")
                                      %output
                                      #:log (%make-void-port "w")))))
     (home-page "https://www.torproject.org")
     (synopsis "Tor Browser Builder scripts")
     (description "Tor Browser build and runtime scripts.")
     (license (license:non-copyleft "file://LICENSE")))))

(define torbutton
  (let ((commit "ebe2bedab44e38f18c7968bd327d99eef7660f34"))
    (package
     (name "torbutton")
     (version %torbrowser-build-version)
     (source
      (origin
       (method git-fetch)
       (uri (git-reference
             (url "https://git.torproject.org/torbutton.git")
             (commit commit)))
       (file-name (git-file-name name version))
       (sha256
        (base32
         "03xdyszab1a8j98xv6440v4lq58jkfqgmhxc2a62qz8q085d2x83"))))
     (build-system trivial-build-system)
     (arguments
      `(#:modules ((guix build utils))
        #:builder (begin
                    (use-modules (guix build utils))
                    (format #t "Copying source ...~%")
                    (copy-recursively (assoc-ref %build-inputs "source")
                                      %output
                                      #:log (%make-void-port "w")))))
     (home-page "https://www.torproject.org")
     (synopsis "Tor Browser built-in extension")
     (description "Browser extension needed to build and run Tor Browser.")
     (license (license:non-copyleft "file://LICENSE")))))

(define tor-launcher
  (package
   (name "tor-launcher")
   (version "0.2.21.8")
   (source
    (origin
     (method git-fetch)
     (uri (git-reference
           (url "https://git.torproject.org/tor-launcher.git")
           (commit version)))
     (file-name (git-file-name name version))
     (sha256
      (base32
       "1mm1z7gv9dv6ymbr3vsg0lsnhnn84zrb6qsa164hmaxcfrwfhz5d"))))
   (build-system trivial-build-system)
   (arguments
    `(#:modules ((guix build utils))
      #:builder (begin
                  (use-modules (guix build utils))
                  (format #t "Copying source ...~%")
                  (copy-recursively (assoc-ref %build-inputs "source")
                                    %output
                                    #:log (%make-void-port "w")))))
   (home-page "https://www.torproject.org")
   (synopsis "Tor Browser built-in controler extension")
   (description "Browser extension that starts the tor process (which
connects the browser and other applications to the Tor Network), and
which helps people configure and use @code{tor}. The first window that
you see when you start Tor Browser is displayed by this extension.")
   (license (license:non-copyleft "file://src/LICENSE"))))

;; This package is actually a cargo crate, so it should be moved to
;; crates-io.scm and made public once the cross building to wasm32 is
;; successful.
(define https-everywhere-lib-wasm
  (let ((commit "af199004083ce200f285735f68a5a57c47eed0e6"))
  (package
   (name "https-everywhere-lib-wasm")
   (version "2020.08.13")
   (source
    (origin
     (method git-fetch)
      (uri (git-reference
            (url "https://github.com/EFForg/https-everywhere-lib-wasm")
            (commit commit)))
      (file-name (git-file-name name version))
      (sha256
       (base32
        "14xv637hf9kzdyr2w0cvx0g5if9nrzflf29p1spdl228yqlv9d5r"))))
   (build-system trivial-build-system)
   (arguments
    `(#:modules ((guix build utils))
      #:builder (begin
                  (use-modules (guix build utils))
                  (format #t "Copying source ...~%")
                  (copy-recursively (assoc-ref %build-inputs "source")
                                    %output
                                    #:log (%make-void-port "w")))))
   (home-page "https://github.com/EFForg/https-everywhere-lib-wasm")
   (synopsis "Rust library for https-everywhere browser extension")
   (description "Rust library for https-everywhere browser
extension.")
   (license license:gpl2+))))

;; This should probably go elsewhere on the file system and made
;; public in order to be shared between Tor Browser and IceCat once
;; lib-wasm gets fixed.
(define https-everywhere
  (package
   (name "https-everywhere")
   (version "2020.8.13")
   (source
    (origin
     (method url-fetch)
     (uri (string-append "https://github.com/EFForg/" name
                         "/archive/" version ".tar.gz"))
     (sha256
      (base32
       "0xb8q7izlyq80zzvj2j7wqp3srxxmi0wgwrb47lc5w38r7yzqjjd"))))
   (build-system trivial-build-system)
   (native-inputs
    `(("bash" ,bash)
      ("coreutils" ,coreutils)
      ("findutils" ,findutils)
      ("git" ,git)
      ("grep" ,grep)
      ("gzip" ,gzip)
      ("https-everywhere-lib-wasm"
       ,https-everywhere-lib-wasm)
      ("libxml2" ,libxml2)
      ("libxslt" ,libxslt)
      ("openssl" ,openssl)
      ("python" ,python)
      ("rsync" ,rsync)
      ("sed" ,sed)
      ("tar" ,tar)
      ("util-linux" ,util-linux) ; for getopt
      ("which" ,which)
      ("xxd" ,xxd)
      ("zip" ,zip)))
   (arguments
    `(#:modules ((guix build utils))
      #:builder (begin
                  (use-modules (guix build utils))
                  (let ((src (assoc-ref %build-inputs "source"))
                        (httpse-libwasm (assoc-ref %build-inputs
                                                   "https-everywhere-lib-wasm"))
                        (bash (assoc-ref %build-inputs "bash"))
                        (coreutils (assoc-ref %build-inputs "coreutils"))
                        (findutils (assoc-ref %build-inputs "findutils"))
                        ;; Might be worth patching make.sh and remove this.
                        (git (assoc-ref %build-inputs "git"))
                        (grep (assoc-ref %build-inputs "grep"))
                        (gzip (assoc-ref %build-inputs "gzip"))
                        (libxml2 (assoc-ref %build-inputs "libxml2"))
                        (libxslt (assoc-ref %build-inputs "libxslt"))
                        (openssl (assoc-ref %build-inputs "openssl"))
                        (python (assoc-ref %build-inputs "python"))
                        ;; Possibly not needed and used to update rules at
                        ;; build time.
                        (rsync (assoc-ref %build-inputs "rsync"))
                        (sed (assoc-ref %build-inputs "sed"))
                        (tar (assoc-ref %build-inputs "tar"))
                        (util-linux (assoc-ref %build-inputs "util-linux"))
                        (which (assoc-ref %build-inputs "which"))
                        (xxd (assoc-ref %build-inputs "xxd"))
                        (zip (assoc-ref %build-inputs "zip")))
                    (setenv "SHELL" (string-append bash "/bin/bash"))
                    (set-path-environment-variable
                     "PATH" '("bin")
                     (list bash sed findutils which git python tar openssl rsync
                           libxml2 libxslt util-linux grep xxd gzip zip coreutils))
                    (set-path-environment-variable
                     "LIBRARY_PATH" '("lib")
                     (list bash sed findutils which git python tar openssl rsync
                           libxml2 libxslt util-linux grep xxd gzip zip coreutils))
                    (format #t "Untaring source tarball ...~%")
                    (invoke "tar" "-xf" src "--strip-components=1")
                    ;; Python3.6 is hardcoded on these scripts. Using v3.8 appears
                    ;; to be harmless.
                    (substitute*
                     '("install-dev-dependencies.sh"
                       "make.sh"
                       "hooks/precommit"
                       "test/firefox.sh"
                       "test/manual.sh"
                       "test/rules/src/https_everywhere_checker/check_rules.py"
                       "test/script.py"
                       "test/validations.sh"
                       "test/validations/filename/run.py"
                       "test/validations/relaxng/run.py"
                       "test/validations/securecookie/run.py"
                       "test/validations/special/run.py"
                       "utils/create_zip.py"
                       "utils/chromium-translations.py"
                       "utils/create-platform-certs/split_combined_cert_file.py"
                       "utils/mk-client-whitelist/dbconnect.py"
                       "utils/mk-client-whitelist/run.py"
                       "utils/merge-rulesets.py"
                       "utils/setversion.py"
                       "utils/zipfile_deterministic.py")
                     (("python3.6") "python3"))
                    (make-file-writable "lib-wasm")
                    (copy-recursively httpse-libwasm
                                      "lib-wasm"
                                      #:log (%make-void-port "w"))
                    ;; Remove precompiled binaries from source. This breaks
                    ;; http-everywhere at runtime, but building is successful.
                    ;; Once lib-wasm is successfuly cross-compiled to wasm,
                    ;; remove this.
                    (with-directory-excursion "lib-wasm/pkg"
                      (for-each (lambda (file)
                        (if (file-exists? file)
                            (delete-file file)
                            (display (string-append
                             "Warning: file " file
                             " not found! Skipping...\n"))))
                        '("https_everywhere_lib_wasm.js"
                          "https_everywhere_lib_wasm_bg.wasm")))
                    (for-each patch-shebang
                              (find-files "."
                                          (lambda (file stat)
                                            ;; Filter out symlinks.
                                            (eq? 'regular (stat:type stat)))
                                          #:stat lstat))
                    ;; Failing to generate the xpi, but copy-dir appears to be
                    ;; enough.
                    (invoke "./make.sh")
                    (copy-recursively "pkg/xpi-eff" %output
                                      #:log (%make-void-port "w"))
                    #t))))
   (home-page "https://www.eff.org/https-everywhere")
   (synopsis "Browser extension for automatic HTTPS usage")
   (description "Browser extension that automatically makes the browser to
use HTTPS instead of plain HTTP when the remote destination makes it
available to users.")
   (license license:gpl2+)))

;; Currently there seems to be no binaries on this package, but in
;; order to avoid the possibility of one getting silently added,
;; this needs reworking to make it build from source.
(define noscript
  (package
   (name "noscript")
   (version "11.0.38")
   (source
    (origin
     (method url-fetch)
     (uri (string-append "https://secure.informaction.com/download/releases/"
                         name "-" version ".xpi"))
     (sha256
      (base32
       "0f77dh1qj02ayrxiz98px0kl0dlza65fpjzq56nsmhrxmmyrby4c"))))
   (build-system trivial-build-system)
   (arguments
    `(#:modules ((guix build utils))
      #:builder (begin
                  (format #t "Copying source ...~%")
                  (copy-file (assoc-ref %build-inputs "source")
                             %output))))
   (home-page "https://noscript.net")
   (synopsis "Browser extension for protection against known attacks")
   (description "Browser extension that protects users from a range of
known attacks on web browsing activity such as Cross-site scripting, clickjack
and makes possible for the users to block or choose on a per site basis which
remote javascript to run while browsing the web.")
   (license license:gpl2+)))

;; (Un)fortunatly Tor Browser has it's own reproducible build system - RBM -
;; which automates the build process for them and compiles Tor Browser from a
;; range of repositories and produces a range of tarballs for different
;; architectures and locales. So we need to cherry-pick what is needed for
;; guix and produce our own tarball. See
;; https://gitweb.torproject.org/builders/tor-browser-build.git/projects/\
;; {tor-browser,firefox}/{build,config} for the rationale applied here. See
;; also the Hacking on Tor Browser document for a high level introduction at
;; https://trac.torproject.org/projects/tor/wiki/doc/Tor Browser/Hacking.
;;
;; TODO: Import langpacks.
(define-public torbrowser-unbundle
  (let ((commit (string-append "tor-browser-" %torbrowser-version
                               "-" %torbrowser-build)))
    (package
     (name "torbrowser-unbundle")
     (version %torbrowser-build-version)
     (source
      (origin
       (method git-fetch)
       (uri (git-reference
             (url "https://git.torproject.org/tor-browser.git")
             (commit commit)))
       (file-name (git-file-name name version))
       (sha256
        (base32
         "02pxbhv64l575p2s2i365v53qyqynn272f64b6gqfrcvhn920g09"))))
     (build-system gnu-build-system)
     (inputs
      `(("alsa-lib" ,alsa-lib)
        ("bzip2" ,bzip2)
        ("cups" ,cups)
        ("dbus-glib" ,dbus-glib)
        ("ffmpeg" ,ffmpeg)
        ("freetype" ,freetype)
        ("gdk-pixbuf" ,gdk-pixbuf)
        ("glib" ,glib)
        ("gtk+" ,gtk+)
        ("gtk+-2" ,gtk+-2)
        ("graphite2" ,graphite2)
        ("harfbuzz" ,harfbuzz)
        ("icu4c" ,icu4c)
        ("libcanberra" ,libcanberra)
        ("libgnome" ,libgnome)
        ("libjpeg-turbo" ,libjpeg-turbo)
        ("libogg" ,libogg)
        ;; ("libtheora" ,libtheora) ; wants theora-1.2, not yet released
        ("libvorbis" ,libvorbis)
        ("libxft" ,libxft)
        ("libevent" ,libevent)
        ("libxinerama" ,libxinerama)
        ("libxscrnsaver" ,libxscrnsaver)
        ("libxcomposite" ,libxcomposite)
        ("libxt" ,libxt)
        ("libffi" ,libffi)
        ("libvpx" ,libvpx)
        ("mesa" ,mesa)
        ("mit-krb5" ,mit-krb5)
        ;; See <https://bugs.gnu.org/32833>
        ;;   and related comments in the 'remove-bundled-libraries' phase.
        ;; UNBUNDLE-ME! ("nspr" ,nspr)
        ;; UNBUNDLE-ME! ("nss" ,nss)
        ("obfs4" ,obfs4)
        ("pango" ,pango)
        ("pixman" ,pixman)
        ("pulseaudio" ,pulseaudio)
        ("shared-mime-info" ,shared-mime-info)
        ("sqlite" ,sqlite)
        ("startup-notification" ,startup-notification)
        ("tor" ,tor-client)
        ("unzip" ,unzip)
        ("zip" ,zip)
        ("zlib" ,zlib)))
     (native-inputs
      `(("autoconf" ,autoconf-2.13)
        ("bash" ,bash)
        ("cargo" ,rust "cargo")
        ("clang" ,clang)
        ("https-everywhere" ,https-everywhere)
        ("llvm" ,llvm)
        ("patch" ,(canonical-package patch))
        ("torbrowser-start-tor-browser.patch"
         ,(search-patch "torbrowser-start-tor-browser.patch"))
        ("torbrowser-start-tor-browser.desktop.patch"
         ,(search-patch "torbrowser-start-tor-browser.desktop.patch"))
        ("perl" ,perl)
        ("pkg-config" ,pkg-config)
        ("python" ,python)
        ("python2" ,python-2.7)
        ("python2-pysqlite" ,python2-pysqlite)
        ("nasm" ,nasm)  ; XXX FIXME: only needed on x86_64 and i686
        ("node" ,node)
        ("noscript" ,noscript)
        ("rust" ,rust)
        ("rust-cbindgen" ,rust-cbindgen)
        ("tor-browser-build" ,tor-browser-build)
        ("torbrowser-fonts" ,torbrowser-fonts)
        ("tor-launcher" ,tor-launcher)
        ("torbutton" ,torbutton)
        ("which" ,which)
        ("yasm" ,yasm)))
     (arguments
      `(#:tests? #f ; Some tests are autodone by mach on build fase.

        ;; XXX: There are RUNPATH issues such as
        ;; $prefix/lib/icecat-31.6.0/plugin-container NEEDing libmozalloc.so,
        ;; which is not in its RUNPATH, but they appear to be harmless in
        ;; practice somehow.  See <http://hydra.gnu.org/build/378133>.
        #:validate-runpath? #f
        #:imported-modules ,%cargo-utils-modules ;for `generate-all-checksums'
        ;; This modules where copied from IceCat package definition and some
        ;; of them are probably not needed anymore. TODO: verify if/which
        ;; are still needed.
        #:modules ((ice-9 ftw)
                   (ice-9 rdelim)
                   (ice-9 regex)
                   (ice-9 match)
                   (srfi srfi-34)
                   (srfi srfi-35)
                   (rnrs bytevectors)
                   (rnrs io ports)
                   (guix elf)
                   (guix build gremlin)
                   (guix build utils)
                   (sxml simple)
                   ,@%gnu-build-system-modules)
        #:phases
        (modify-phases %standard-phases
          (add-after 'unpack 'make-bundle
            (lambda* (#:key inputs native-inputs #:allow-other-keys)
              (let ((torbutton (assoc-ref inputs "torbutton"))
                    (torbutton-dir "toolkit/torproject/torbutton")
                    (tor-launcher (assoc-ref inputs "tor-launcher"))
                    (tor-launcher-dir "browser/extensions/tor-launcher")
                    (tbb (assoc-ref inputs "tor-browser-build"))
                    (tbb-scripts-dir "tbb-scripts"))
                (format #t "Copying torbutton source to default path ...~%")
                (make-file-writable torbutton-dir)
                (copy-recursively torbutton torbutton-dir
                                  #:log (%make-void-port "w"))
                (format #t "Copying tor-launcher ...~%")
                (copy-recursively tor-launcher tor-launcher-dir
                                  #:log (%make-void-port "w"))
                (format #t "Copying tor-browser-build ...~%")
                (mkdir tbb-scripts-dir)
                (copy-recursively tbb tbb-scripts-dir
                                  #:log (%make-void-port "w"))
                (make-file-writable (string-append
                                     tbb-scripts-dir
                                     "/RelativeLink/start-tor-browser"))
                (make-file-writable (string-append
                                     tbb-scripts-dir
                                     "/RelativeLink/start-tor-browser.desktop")))
              #t))

          (add-after 'make-bundle 'apply-guix-specific-patches
            (lambda* (#:key inputs native-inputs #:allow-other-keys)
              (let ((patch (string-append (assoc-ref (or native-inputs inputs)
                                                     "patch")
                                          "/bin/patch")))
                (for-each (match-lambda
                  ((label . file)
                     (when (and (string-prefix? "torbrowser-" label)
                       (string-suffix? ".patch" label))
                       (format #t "applying '~a'...~%" file)
                       (invoke patch "--force" "--no-backup-if-mismatch"
                                     "-p1" "--input" file))))
                  (or native-inputs inputs)))
              #t))

          ;; On mach build system this is done on configure.
          (delete 'bootstrap)

          (add-after 'patch-source-shebangs 'patch-cargo-checksums
            (lambda _
              (use-modules (guix build cargo-utils))
              (let ((null-hash
                     "e3b0c44298fc1c149afbf4c8996fb92427ae41e4649b934ca495991b7852b855"))
                (substitute* '("Cargo.lock" "gfx/wr/Cargo.lock")
                  (("(\"checksum .* = )\".*\"" all name)
                   (string-append name "\"" null-hash "\"")))
                (generate-all-checksums "third_party/rust"))
              #t))

          (add-after 'build 'neutralize-store-references
            (lambda _
              ;; Mangle the store references to compilers & other build tools in
              ;; about:buildconfig, reducing Tor Browser's closure significant.
              ;; The resulting files are saved in lib/firefox/omni.ja
              (substitute*
               "objdir/dist/bin/chrome/toolkit/content/global/buildconfig.html"
               (((format #f "(~a/)([0-9a-df-np-sv-z]{32})"
                         (regexp-quote (%store-directory))) _ store hash)
                (string-append store
                               (string-take hash 8)
                               "<!-- Guix: not a runtime dependency -->"
                               (string-drop hash 8))))
              #t))

          (replace 'configure
            (lambda* (#:key inputs outputs configure-flags #:allow-other-keys)
              (let* ((out (assoc-ref outputs "out"))
                     (bash (which "bash"))
                     (flags `(,(string-append "--prefix=" out)
                                              ,@configure-flags)))
                (setenv "SHELL" bash)
                (setenv "AUTOCONF" (string-append
                                    (assoc-ref %build-inputs "autoconf")
                                               "/bin/autoconf"))
                (setenv "CONFIG_SHELL" bash)
                (setenv "PYTHON" (string-append
                                  (assoc-ref inputs "python2")
                                  "/bin/python"))
                (setenv "MOZ_BUILD_DATE"
                        ,%torbrowser-build-id) ; avoid timestamp.
                (setenv "LDFLAGS" (string-append
                                   "-Wl,-rpath="
                                   (assoc-ref outputs "out")
                                   "/lib/firefox"))
                ;; This needs reworking to use the mozconfig available on
                ;; tor-browser-builder repo which is the one Tor Project
                ;; actually uses and which warranted some of the changes
                ;; below.
                (substitute* ".mozconfig"
                  ;; Arch independent builddir.
                  (("(mk_add_options MOZ_OBJDIR=@TOPSRCDIR@/obj).*" _ m)
                   (string-append m "dir\n"))
                  (("ac_add_options --disable-tor-launcher") "")
                  ;; We won't be building incrementals.
                  (("ac_add_options --enable-signmar") "")
                  (("ac_add_options --enable-verify-mar") "")
                  (("ac_add_options --with-tor-browser-version=dev-build")
                   (string-append
                    "ac_add_options --with-tor-browser-version=org.gnu\n"
                    "ac_add_options --with-unsigned-addon-scopes=app\n"
                    "ac_add_options --enable-pulseaudio\n"
                    "ac_add_options --disable-debug-symbols\n"
                    "ac_add_options --disable-updater\n"
                    "ac_add_options --disable-gconf\n"
                    ;; Other syslibs that can be unbundled? (nss, nspr)
                    "ac_add_options --enable-system-pixman\n"
                    "ac_add_options --enable-system-ffi\n"
                    "ac_add_options --with-system-bz2\n"
                    "ac_add_options --with-system-icu\n"
                    "ac_add_options --with-system-jpeg\n"
                    "ac_add_options --with-system-libevent\n"
                    "ac_add_options --with-system-zlib\n"
                    ;; Without these clang is not found.
                    "ac_add_options --with-clang-path="
                    (assoc-ref %build-inputs "clang") "/bin/clang\n"
                    "ac_add_options --with-libclang-path="
                    (assoc-ref %build-inputs "clang") "/lib\n")))

                (substitute* "browser/app/profile/000-tor-browser.js"
                  ;; Tor Browser updates are disabled on mozconfig, but let's be sure.
                  (("(pref\\(\"extensions.torbutton.versioncheck_enabled\").*" _ m)
                   (string-append m ",false);\n")))

                (substitute*
                 "browser/extensions/tor-launcher/src/defaults/preferences/torlauncher-prefs.js"
                  ;; Not multilingual. See tor-browser/build:141. Currently disabled on
                  ;; tor-launcher, but let's make sure while missing langpacks.
                 (("(pref\\(\"extensions.torlauncher.prompt_for_locale\").*" _ m)
                  (string-append m ", false);\n")))

                ;; For user data outside the guix store.
                (substitute* "xpcom/io/TorFileUtils.cpp"
                  (("ANDROID") "GNUGUIX"))
                   (substitute* "old-configure.in"
                  (("(AC_SUBST\\(TOR_BROWSER_DISABLE_TOR_LAUNCHER\\))" _ m)
                   (string-append m "\n AC_DEFINE(GNUGUIX)\n")))

                (format #t "Invoking mach configure ...~%")
                (invoke "./mach" "configure"))
              #t))

          (replace 'build
            (lambda _ (invoke "./mach" "build")
              #t))

          ;; Tor Browser just do a stage-package here and copy files to its places.
          (replace 'install
            (lambda* (#:key inputs native-inputs outputs
                      configure-flags #:allow-other-keys)
              (let* ((out (assoc-ref outputs "out"))
                     (applications (string-append out "/share/applications"))
                     (build "objdir/dist/firefox")
                     (bin (string-append out "/bin"))
                     (lib (string-append out "/lib/firefox"))
                     (start-script
                      "tbb-scripts/RelativeLink/start-tor-browser")
                     (desktop-file
                      "tbb-scripts/RelativeLink/start-tor-browser.desktop"))
                (invoke "./mach" "build" "stage-package")
                ;; Tor Browser doesn't use those.
                ;; See: tor-browser-build.git/projects/firefox/build:167
                (format #t "Deleting spurious files ...~%")
                (with-directory-excursion build
                  (for-each (lambda (file)
                              (if (file-exists? file)
                                  (delete-file file)
                                  (display (string-append
                                            "Warning: file " file
                                            " not found! Skipping...\n"))))
                            '("firefox-bin" "libfreeblpriv3.chk" "libnssdbm3.chk"
                              "libsoftokn3.chk" "fonts/TwemojiMozilla.ttf")))
                (rmdir (string-append build "/fonts"))
                (format #t "Creating install dirs ...~%")
                (mkdir-p applications)
                (mkdir-p lib)
                (mkdir bin)
                (format #t "Copying files to install dirs ...~%")
                (copy-recursively build (string-append lib "/")
                                  #:log (%make-void-port "w"))
                (copy-file start-script
                           (string-append lib "/start-tor-browser"))
                (copy-file desktop-file
                           (string-append lib "/start-tor-browser.desktop"))
                (chmod (string-append lib "/start-tor-browser") #o555)
                (chmod (string-append lib "/start-tor-browser.desktop") #o555)
                (format #t "Linking start-tor-browser script ...~%")
                (symlink (string-append lib "/start-tor-browser")
                         (string-append bin "/start-tor-browser"))
                (format #t "Installing desktop file ...~%")
                (install-file desktop-file applications))
              #t))

          (add-after 'install 'install-icons
            (lambda* (#:key outputs #:allow-other-keys)
              (let* ((out (assoc-ref outputs "out"))
                     (icons-src (string-append
                                 out "/lib/firefox/browser/chrome/icons/default")))
                (with-directory-excursion
                 icons-src
                 (for-each
                   (lambda (file)
                     (let* ((size (string-filter char-numeric? file))
                            (icons (string-append out "/share/icons/hicolor/"
                                                  size "x" size "/apps")))
                       (mkdir-p icons)
                       (copy-file file (string-append icons "/torbrowser.png"))))
                   '("default16.png" "default32.png" "default48.png" "default64.png"
                     "default128.png"))))
              #t))

          (add-after 'install-icons 'install-fonts
            (lambda* (#:key inputs native-inputs outputs #:allow-other-keys)
              (let* ((out (assoc-ref outputs "out"))
                     (lib (string-append out "/lib/firefox/"))
                     (fonts  (string-append (or (assoc-ref native-inputs
                                                           "torbrowser-fonts")
                                                (assoc-ref inputs
                                                           "torbrowser-fonts"))
                                            "/share")))
                (copy-recursively fonts lib
                                  #:log (%make-void-port "w"))
                (symlink (string-append lib "/fonts")
                         (string-append out "/share/fonts")))
              #t))

          (add-after 'install-fonts 'install-extensions
            (lambda* (#:key inputs native-inputs outputs #:allow-other-keys)
              (let* ((out (assoc-ref outputs "out"))
                     (ext (string-append out "/lib/firefox/browser/extensions"))
                     (noscript-id "{73a6fe31-595d-460b-a920-fcc0f8843232}")
                     (httpse-id "https-everywhere-eff@eff.org")
                     (noscript (assoc-ref inputs "noscript"))
                     (httpse (assoc-ref inputs "https-everywhere")))
                (mkdir-p ext)
                (copy-file noscript (string-append
                                     ext "/" noscript-id ".xpi"))
                (copy-recursively httpse
                                  (string-append ext "/" httpse-id)
                                  #:log (%make-void-port "w"))
                (chmod (string-append ext "/" noscript-id ".xpi") #o555))
              #t))

          (add-after 'install-extensions 'link-binaries
            (lambda* (#:key inputs native-inputs outputs #:allow-other-keys)
              (let* ((out (assoc-ref outputs "out"))
                     (tordir (string-append out "/lib/firefox/TorBrowser/Tor"))
                     (ptdir (string-append tordir "/PluggableTransports"))
                     (obfs4 (string-append (assoc-ref inputs "obfs4")
                                           "/bin/obfs4proxy"))
                     (tor (string-append (assoc-ref inputs "tor")
                                         "/bin/tor")))
                (mkdir-p ptdir)
                (symlink tor (string-append tordir "/tor"))
                (symlink obfs4 (string-append ptdir "/obfs4proxy")))
              #t))

          (add-after 'link-binaries 'copy-bundle-data
            (lambda* (#:key inputs native-inputs outputs #:allow-other-keys)
              (let* ((out (assoc-ref outputs "out"))
                     (lib (string-append out "/lib/firefox"))
                     (tbb "tbb-scripts")
                     (ptconf (string-append tbb "/Bundle-Data/PTConfigs"))
                     (docs (string-append lib "/TorBrowser/Docs"))
                     (data (string-append lib "/TorBrowser/Data")))
                (mkdir-p data)
                (mkdir docs)
                (with-directory-excursion
                 (string-append tbb "/Bundle-Data/linux/Data")
                 (for-each (lambda (file)
                             (copy-recursively file
                                               (string-append data "/" file)
                                               #:log (%make-void-port "w")))
                           '("Browser" "fontconfig" "Tor")))
                (copy-file (string-append ptconf "/linux/torrc-defaults-appendix")
                           (string-append data "/Tor/torrc-defaults-appendix"))
                (copy-file (string-append ptconf "/bridge_prefs.js")
                           (string-append
                            data "/Browser/bridge-prefs-js-appendix"))
                (copy-recursively (string-append tbb "/Bundle-Data/Docs")
                                  (string-append docs "/")
                                  #:log (%make-void-port "w")))
              #t))

          ;; This fixes the file chooser crash that happens with GTK 3
          (add-after 'copy-bundle-data 'wrap-program
            (lambda* (#:key inputs outputs #:allow-other-keys)
              (let* ((out (assoc-ref outputs "out"))
                     (lib (string-append out "/lib/firefox"))
                     (gtk (assoc-ref inputs "gtk+"))
                     (gtk-share (string-append gtk "/share"))
                     (mesa (assoc-ref inputs "mesa"))
                     (mesa-lib (string-append mesa "/lib"))
                     (pulseaudio (assoc-ref inputs "pulseaudio"))
                     (pulseaudio-lib (string-append pulseaudio "/lib"))
                     (libxscrnsaver (assoc-ref inputs "libxscrnsaver"))
                     (libxscrnsaver-lib (string-append libxscrnsaver "/lib")))
                (wrap-program (car (find-files lib "^firefox$"))
                  `("XDG_DATA_DIRS" prefix (,gtk-share))
                  `("LD_LIBRARY_PATH" prefix (,pulseaudio-lib ,mesa-lib
                                              ,libxscrnsaver-lib))))
              #t)))))
     (home-page "https://www.torproject.org")
     (synopsis "Anonymous browser derived from Mozilla Firefox")
     (description
      "Tor Browser is the Tor Project version of Firefox browser.  It is
the only recommended way to anonymously browse the web that is supported by
the project.  It modifies Firefox in order to avoid many know application
level attacks on the privacy of Tor users.

WARNING: This is not the official Tor Browser and is currently on testing.
Https-everywhere browser extension is currently not working so use it at
your own risk and please report back on guix channels if you find any
issues.")
     (license license:mpl2.0)))) ;and others, see toolkit/content/license.html