1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
| | ;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2013, 2014, 2015, 2018 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2013 Cyril Roelandt <tipecaml@gmail.com>
;;; Copyright © 2014, 2015 Andreas Enge <andreas@enge.fr>
;;; Copyright © 2017 Efraim Flashner <efraim@flashner.co.il>
;;; Copyright © 2024 Greg Hogan <code@greghogan.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build cmake-build-system)
#:use-module ((guix build gnu-build-system) #:prefix gnu:)
#:use-module (guix build utils)
#:use-module (ice-9 match)
#:use-module (srfi srfi-34)
#:export (%standard-phases
cmake-build))
;; Commentary:
;;
;; Builder-side code of the standard cmake build procedure.
;;
;; Code:
(define* (configure #:key outputs (configure-flags '()) (out-of-source? #t)
build-type target generator
#:allow-other-keys)
"Configure the given package."
(let* ((out (assoc-ref outputs "out"))
(abs-srcdir (getcwd))
(srcdir (if out-of-source?
(string-append "../" (basename abs-srcdir))
".")))
(format #t "source directory: ~s (relative from build: ~s)~%"
abs-srcdir srcdir)
(when out-of-source?
(mkdir "../build")
(chdir "../build"))
(format #t "build directory: ~s~%" (getcwd))
(let ((args `(,srcdir
,@(if generator
(list (string-append "-G" generator))
'())
,@(if build-type
(list (string-append "-DCMAKE_BUILD_TYPE="
build-type))
'())
,(string-append "-DCMAKE_INSTALL_PREFIX=" out)
;; ensure that the libraries are installed into /lib
"-DCMAKE_INSTALL_LIBDIR=lib"
;; add input libraries to rpath
"-DCMAKE_INSTALL_RPATH_USE_LINK_PATH=TRUE"
;; add (other) libraries of the project itself to rpath
,(string-append "-DCMAKE_INSTALL_RPATH=" out "/lib")
;; enable verbose output from builds
"-DCMAKE_VERBOSE_MAKEFILE=ON"
;; Cross-build
,@(if target
(list (string-append "-DCMAKE_C_COMPILER="
target "-gcc")
(string-append "-DCMAKE_CXX_COMPILER="
target "-g++")
(if (string-contains target "mingw")
"-DCMAKE_SYSTEM_NAME=Windows"
"-DCMAKE_SYSTEM_NAME=Linux"))
'())
,@configure-flags)))
(format #t "running 'cmake' with arguments ~s~%" args)
(apply invoke "cmake" args))))
(define* (build #:key (parallel-build? #t) #:allow-other-keys)
(apply invoke "cmake"
`("--build"
"."
,@(if parallel-build?
`("-j" ,(number->string (parallel-job-count)))
;; When unset CMake defers to the build system.
'("-j" "1")))))
(define %test-suite-log-regexp
;; Name of test suite log files as commonly found in CMake.
"^LastTest\\.log$")
(define* (check #:key (tests? #t) (test-exclude "")
(parallel-tests? #t)
(test-suite-log-regexp %test-suite-log-regexp)
#:allow-other-keys)
(if tests?
(guard (c ((invoke-error? c)
;; Dump the test suite log to facilitate debugging.
(display "\nTest suite failed, dumping logs.\n"
(current-error-port))
(gnu:dump-file-contents "." test-suite-log-regexp)
(raise c)))
(apply invoke "ctest" "--output-on-failure"
`(,@(if (string-null? test-exclude)
'()
`("--exclude-regex" ,test-exclude))
,@(if parallel-tests?
`("-j" ,(number->string (parallel-job-count)))
;; When unset CMake defers to the build system.
'("-j" "1")))))
(format #t "test suite not run~%")))
(define* (install #:rest args)
(invoke "cmake" "--install" "."))
(define %standard-phases
(modify-phases gnu:%standard-phases
(delete 'bootstrap)
(replace 'build build)
(replace 'check check)
(replace 'configure configure)
(replace 'install install)))
(define* (cmake-build #:key inputs (phases %standard-phases)
#:allow-other-keys #:rest args)
"Build the given package, applying all of PHASES in order."
(apply gnu:gnu-build #:inputs inputs #:phases phases args))
;;; cmake-build-system.scm ends here
|