From: Oleg Pykhalov <go.wigust@gmail.com>
To: Christopher Baines <mail@cbaines.net>
Cc: 27855@debbugs.gnu.org
Subject: [bug#27855] [PATCH] gnu: Add rsync service.
Date: Sat, 23 Sep 2017 04:47:10 +0300 [thread overview]
Message-ID: <87r2uyb2zl.fsf@gmail.com> (raw)
In-Reply-To: <20170918072004.10337804@cbaines.net> (Christopher Baines's message of "Mon, 18 Sep 2017 07:20:04 +0100")
[-- Attachment #1: Type: text/plain, Size: 3917 bytes --]
Christopher Baines <mail@cbaines.net> writes:
> Ideally this wouldn't be in Miscellaneous Services as I don't think
> that is very helpful for users discovering what services Guix offers.
> I think Networking Services might be better, what do you think? It
> includes things like Tor, which are about using networks, and not
> about core networking.
Done.
>> +@deffn {Scheme Variable} rsync-service-type
>> +This is the type for the @uref{https://rsync.samba.org} rsync daemon,
>> +@command{rsync-configuration} record as in this example:
>
> @uref{https://rsync.samba.org, rsync} looks nicer to me here.
Done.
>> +@example
>> +(service rsync-service-type
>> + (rsync-configuration))
>> +@end example
>
> You may as well give the simpler (service rsync-service-type) version
> here now that the service-type has a default value.
Done.
>> +@item @code{port-number} (default: @code{873})
>> +TCP port on which @command{rsync} listens for incoming connections.
>> If +port is less than @code{1024} @command{rsync} will be started as
>> the +@code{root} user and group.
>
> I think this needs to read "needs to be" rather than "will be".
Done.
>> +@item @code{uid} (default: @var{"rsyncd"})
>> +User name or user ID that file transfers to and from that module
>> should take +place as when the daemon was run as @code{root}.
>> +
>> +@item @code{gid} (default: @var{"rsyncd"})
>> +Group name or group ID that will be used when accessing the
>> module.
>
> I'm not sure what "module" is here.
I took this description from *Man 5 rsyncd.conf* MODULE PARAMETERS.
After the global parameters you should define a number of modules,
each module exports a directory tree as a symbolic name. Modules are
exported by specifying a module name in square brackets [module]
followed by the param‐ eters for that module. The module name cannot
contain a slash or a closing square bracket. If the name contains
whitespace, each internal sequence of whitespace will be changed into
a single space, while leading or trailing whitespace will be
discarded. Also, the name cannot be "global" as that exact name
indicates that global parameters follow (see above).
>> +(define (rsync-activation config)
>> + "Return the activation GEXP for CONFIG."
>> + #~(begin
>> + (use-modules (guix build utils))
>
> Using with-imported-modules with this gexp here would be good, to
> ensure it has the (guix build utils) module.
Done.
>> +(define (rsync-config-file config)
>> + "Return the rsync configuration file corresponding to CONFIG."
>> + (let ((port-number (rsync-configuration-port-number config))
>> + (pid-file (rsync-configuration-pid-file config))
>> + (lock-file (rsync-configuration-lock-file config))
>> + (log-file (rsync-configuration-log-file config))
>> + (use-chroot? (rsync-configuration-use-chroot? config))
>> + (share-path (rsync-configuration-share-path config))
>> + (share-comment (rsync-configuration-share-comment config))
>> + (read-only? (rsync-configuration-read-only? config))
>> + (timeout (rsync-configuration-timeout config))
>> + (user (rsync-configuration-user config))
>> + (group (rsync-configuration-group config))
>> + (uid (rsync-configuration-uid config))
>> + (gid (rsync-configuration-gid config)))
>
> Using match, or match-lambda might neaten this up a bit. There are a
> few examples of using this in Guix.
Done.
> I'm pretty happy with this now. I think updating the documentation to
> match the recent changes in the service would be good to do before
> merging this but that is all. Good job :)
Thank you for support! I learned much new things.
Attached a patch. Tested successfully.
[-- Attachment #2: 0001-gnu-Add-rsync-service.patch --]
[-- Type: text/x-patch, Size: 17064 bytes --]
From a68a97bdd6132de59d44ec0da7de3e3dadb1132e Mon Sep 17 00:00:00 2001
From: Oleg Pykhalov <go.wigust@gmail.com>
Date: Thu, 27 Jul 2017 04:01:01 +0300
Subject: [PATCH] gnu: Add rsync service.
* doc/guix.texi (Incremental file transfer): Add documentation.
* gnu/services/rsync.scm (<rsync-configuration>): New record type.
(rsync-accounts, rsync-shepherd-service): New service extensions.
(rsync-service-type): New service type.
* gnu/tests/rsync.scm: New file.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
---
doc/guix.texi | 69 ++++++++++++++++++++
gnu/local.mk | 2 +
gnu/services/rsync.scm | 172 +++++++++++++++++++++++++++++++++++++++++++++++++
gnu/tests/rsync.scm | 128 ++++++++++++++++++++++++++++++++++++
4 files changed, 371 insertions(+)
create mode 100644 gnu/services/rsync.scm
create mode 100644 gnu/tests/rsync.scm
diff --git a/doc/guix.texi b/doc/guix.texi
index 0369a150f..0462a6419 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -10335,6 +10335,75 @@ In addition, @var{extra-settings} specifies a string to append to the
configuration file.
@end deffn
+The @code{(gnu services rsync)} module provides the following services:
+
+You might want an rsync daemon if you have files that you want available
+so anyone (or just yourself) can download existing files or upload new
+files.
+
+@deffn {Scheme Variable} rsync-service-type
+This is the type for the @uref{https://rsync.samba.org, rsync} rsync daemon,
+@command{rsync-configuration} record as in this example:
+
+@example
+(service rsync-service-type)
+@end example
+
+See below for details about @code{rsync-configuration}.
+@end deffn
+
+@deftp {Data Type} rsync-configuration
+Data type representing the configuration for @code{rsync-service}.
+
+@table @asis
+@item @code{package} (default: @var{rsync})
+@code{rsync} package to use.
+
+@item @code{port-number} (default: @code{873})
+TCP port on which @command{rsync} listens for incoming connections. If port
+is less than @code{1024} @command{rsync} needs to be started as the
+@code{root} user and group.
+
+@item @code{pid-file} (default: @code{"/var/run/rsyncd/rsyncd.pid"})
+Name of the file where @command{rsync} writes its PID.
+
+@item @code{lock-file} (default: @code{"/var/run/rsyncd/rsyncd.lock"})
+Name of the file where @command{rsync} writes its lock file.
+
+@item @code{log-file} (default: @code{"/var/log/rsyncd.log"})
+Name of the file where @command{rsync} writes its log file.
+
+@item @code{use-chroot?} (default: @var{#t})
+Whether to use chroot for @command{rsync} shared directory.
+
+@item @code{share-path} (default: @file{/srv/rsync})
+Location of the @command{rsync} shared directory.
+
+@item @code{share-comment} (default: @code{"Rsync share"})
+Comment of the @command{rsync} shared directory.
+
+@item @code{read-only?} (default: @var{#f})
+Read-write permissions to shared directory.
+
+@item @code{timeout} (default: @code{300})
+I/O timeout in seconds.
+
+@item @code{user} (default: @var{"root"})
+Owner of the @code{rsync} process.
+
+@item @code{group} (default: @var{"root"})
+Group of the @code{rsync} process.
+
+@item @code{uid} (default: @var{"rsyncd"})
+User name or user ID that file transfers to and from that module should take
+place as when the daemon was run as @code{root}.
+
+@item @code{gid} (default: @var{"rsyncd"})
+Group name or group ID that will be used when accessing the module.
+
+@end table
+@end deftp
+
Furthermore, @code{(gnu services ssh)} provides the following services.
@cindex SSH
@cindex SSH server
diff --git a/gnu/local.mk b/gnu/local.mk
index 68c4852d9..2406fae55 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -451,6 +451,7 @@ GNU_SYSTEM_MODULES = \
%D%/services/shepherd.scm \
%D%/services/herd.scm \
%D%/services/pm.scm \
+ %D%/services/rsync.scm \
%D%/services/sddm.scm \
%D%/services/spice.scm \
%D%/services/ssh.scm \
@@ -497,6 +498,7 @@ GNU_SYSTEM_MODULES = \
%D%/tests/mail.scm \
%D%/tests/messaging.scm \
%D%/tests/networking.scm \
+ %D%/tests/rsync.scm \
%D%/tests/ssh.scm \
%D%/tests/virtualization.scm \
%D%/tests/web.scm
diff --git a/gnu/services/rsync.scm b/gnu/services/rsync.scm
new file mode 100644
index 000000000..621e6c46d
--- /dev/null
+++ b/gnu/services/rsync.scm
@@ -0,0 +1,172 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2017 Oleg Pykhalov <go.wigust@gmail.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu services rsync)
+ #:use-module (gnu services)
+ #:use-module (gnu services base)
+ #:use-module (gnu services shepherd)
+ #:use-module (gnu system shadow)
+ #:use-module (gnu packages rsync)
+ #:use-module (gnu packages admin)
+ #:use-module (guix records)
+ #:use-module (guix gexp)
+ #:use-module (srfi srfi-1)
+ #:use-module (srfi srfi-26)
+ #:use-module (ice-9 match)
+ #:export (rsync-configuration
+ rsync-configuration?
+ rsync-service-type))
+
+;;;; Commentary:
+;;;
+;;; This module implements a service that to run instance of Rsync,
+;;; files synchronization tool.
+;;;
+;;;; Code:
+
+(define-record-type* <rsync-configuration>
+ rsync-configuration
+ make-rsync-configuration
+ rsync-configuration?
+ (package rsync-configuration-package ; package
+ (default rsync))
+ (port-number rsync-configuration-port-number ; integer
+ (default 873))
+ (pid-file rsync-configuration-pid-file ; string
+ (default "/var/run/rsyncd/rsyncd.pid"))
+ (lock-file rsync-configuration-lock-file ; string
+ (default "/var/run/rsyncd/rsyncd.lock"))
+ (log-file rsync-configuration-log-file ; string
+ (default "/var/log/rsyncd.log"))
+ (use-chroot? rsync-configuration-use-chroot? ; boolean
+ (default #t))
+ (share-path rsync-configuration-share-path ; string
+ (default "/srv/rsyncd"))
+ (share-comment rsync-configuration-share-comment ; string
+ (default "Rsync share"))
+ (read-only? rsync-configuration-read-only? ; boolean
+ (default #f))
+ (timeout rsync-configuration-timeout ; integer
+ (default 300))
+ (user rsync-configuration-user ; string
+ (default "root"))
+ (group rsync-configuration-group ; string
+ (default "root"))
+ (uid rsync-configuration-uid ; string
+ (default "rsyncd"))
+ (gid rsync-configuration-gid ; string
+ (default "rsyncd")))
+
+(define (rsync-account config)
+ "Return the user accounts and user groups for CONFIG."
+ (let ((rsync-user (if (rsync-configuration-uid config)
+ (rsync-configuration-uid config)
+ (rsync-configuration-user config)))
+ (rsync-group (if (rsync-configuration-gid config)
+ (rsync-configuration-gid config)
+ (rsync-configuration-group config))))
+ (list (user-group (name rsync-group) (system? #t))
+ (user-account
+ (name rsync-user)
+ (system? #t)
+ (group rsync-group)
+ (comment "rsyncd privilege separation user")
+ (home-directory (string-append "/var/run/"
+ rsync-user))
+ (shell #~(string-append #$shadow "/sbin/nologin"))))))
+
+(define (rsync-activation config)
+ "Return the activation GEXP for CONFIG."
+ (with-imported-modules '((guix build utils))
+ #~(begin
+ (let ((share-directory #$(rsync-configuration-share-path config))
+ (user (getpw (if #$(rsync-configuration-uid config)
+ #$(rsync-configuration-uid config)
+ #$(rsync-configuration-user config))))
+ (group (getpw (if #$(rsync-configuration-gid config)
+ #$(rsync-configuration-gid config)
+ #$(rsync-configuration-group config)))))
+ (mkdir-p (dirname #$(rsync-configuration-pid-file config)))
+ (and=> share-directory mkdir-p)
+ (chown share-directory
+ (passwd:uid user)
+ (group:gid group))))))
+
+(define rsync-config-file
+ ;; Return the rsync configuration file corresponding to CONFIG.
+ (match-lambda
+ (($ <rsync-configuration> package port-number pid-file lock-file log-file
+ use-chroot? share-path share-comment read-only?
+ timeout user group uid gid)
+ (if (not (string=? user "root"))
+ (cond
+ ((<= port-number 1024)
+ (error (string-append "rsync-service: to run on port "
+ (number->string port-number)
+ ", user must be root.")))
+ (use-chroot?
+ (error (string-append "rsync-service: to run in a chroot"
+ ", user must be root.")))
+ (uid
+ (error "rsync-service: to use uid, user must be root."))
+ (gid
+ (error "rsync-service: to use gid, user must be root."))))
+ (mixed-text-file
+ "rsync.conf"
+ "# Generated by 'rsync-service'.\n\n"
+ "pid file = " pid-file "\n"
+ "lock file = " lock-file "\n"
+ "log file = " log-file "\n"
+ "port = " (number->string port-number) "\n"
+ "use chroot = " (if use-chroot? "true" "false") "\n"
+ (if uid (string-append "uid = " uid "\n") "")
+ "gid = " (if gid gid "nogroup") "\n" ; no group nobody
+ "\n"
+ "[files]\n"
+ "path = " share-path "\n"
+ "comment = " share-comment "\n"
+ "read only = " (if read-only? "true" "false") "\n"
+ "timeout = " (number->string timeout) "\n"))))
+
+(define (rsync-shepherd-service config)
+ "Return a <shepherd-service> for rsync with CONFIG."
+ (let* ((rsync (rsync-configuration-package config))
+ (pid-file (rsync-configuration-pid-file config))
+ (port-number (rsync-configuration-port-number config))
+ (user (rsync-configuration-user config))
+ (group (rsync-configuration-group config)))
+ (list (shepherd-service
+ (provision '(rsync))
+ (documentation "Run rsync daemon.")
+ (start #~(make-forkexec-constructor
+ (list (string-append #$rsync "/bin/rsync")
+ "--config" #$(rsync-config-file config)
+ "--daemon")
+ #:pid-file #$pid-file
+ #:user #$user
+ #:group #$group))
+ (stop #~(make-kill-destructor))))))
+
+(define rsync-service-type
+ (service-type
+ (name 'rsync)
+ (extensions
+ (list (service-extension shepherd-root-service-type rsync-shepherd-service)
+ (service-extension account-service-type rsync-account)
+ (service-extension activation-service-type rsync-activation)))
+ (default-value (rsync-configuration))))
diff --git a/gnu/tests/rsync.scm b/gnu/tests/rsync.scm
new file mode 100644
index 000000000..691b88e0d
--- /dev/null
+++ b/gnu/tests/rsync.scm
@@ -0,0 +1,128 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2017 Christopher Baines <mail@cbaines.net>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu tests rsync)
+ #:use-module (gnu packages rsync)
+ #:use-module (gnu tests)
+ #:use-module (gnu system)
+ #:use-module (gnu system file-systems)
+ #:use-module (gnu system shadow)
+ #:use-module (gnu system vm)
+ #:use-module (gnu services)
+ #:use-module (gnu services rsync)
+ #:use-module (gnu services networking)
+ #:use-module (guix gexp)
+ #:use-module (guix store)
+ #:export (%test-rsync))
+
+(define* (run-rsync-test rsync-os #:optional (rsync-port 581))
+ "Run tests in %RSYNC-OS, which has rsync running and listening on
+PORT."
+ (define os
+ (marionette-operating-system
+ rsync-os
+ #:imported-modules '((gnu services herd)
+ (guix combinators))))
+
+ (define vm
+ (virtual-machine
+ (operating-system os)
+ (port-forwardings '())))
+
+ (define test
+ (with-imported-modules '((gnu build marionette))
+ #~(begin
+ (use-modules (srfi srfi-11) (srfi srfi-64)
+ (gnu build marionette))
+
+ (define marionette
+ (make-marionette (list #$vm)))
+
+ (mkdir #$output)
+ (chdir #$output)
+
+ (test-begin "rsync")
+
+ ;; Wait for rsync to be up and running.
+ (test-eq "service running"
+ 'running!
+ (marionette-eval
+ '(begin
+ (use-modules (gnu services herd))
+ (start-service 'rsync)
+ 'running!)
+ marionette))
+
+ ;; Make sure the PID file is created.
+ (test-assert "PID file"
+ (marionette-eval
+ '(file-exists? "/var/run/rsyncd/rsyncd.pid")
+ marionette))
+
+ (test-assert "Test file copied to share"
+ (marionette-eval
+ '(begin
+ (call-with-output-file "/tmp/input"
+ (lambda (port)
+ (display "test-file-contents\n" port)))
+ (zero?
+ (system* "rsync" "/tmp/input"
+ (string-append "rsync://localhost:"
+ (number->string #$rsync-port)
+ "/files/input"))))
+ marionette))
+
+ (test-equal "Test file correctly received from share"
+ "test-file-contents"
+ (marionette-eval
+ '(begin
+ (use-modules (ice-9 rdelim))
+ (zero?
+ (system* "rsync"
+ (string-append "rsync://localhost:"
+ (number->string #$rsync-port)
+ "/files/input")
+ "/tmp/output"))
+ (call-with-input-file "/tmp/output"
+ (lambda (port)
+ (read-line port))))
+ marionette))
+
+ (test-end)
+ (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
+
+ (gexp->derivation "rsync-test" test))
+
+(define* (%rsync-os #:optional (rsync-port 581))
+ "Return operating system under test."
+ (let ((base-os
+ (simple-operating-system
+ (dhcp-client-service)
+ (service rsync-service-type
+ (rsync-configuration
+ (port-number rsync-port))))))
+ (operating-system
+ (inherit base-os)
+ (packages (cons* rsync
+ (operating-system-packages base-os))))))
+
+(define %test-rsync
+ (system-test
+ (name "rsync")
+ (description "Connect to a running RSYNC server.")
+ (value (run-rsync-test (%rsync-os)))))
--
2.14.1
next prev parent reply other threads:[~2017-09-23 1:48 UTC|newest]
Thread overview: 32+ messages / expand[flat|nested] mbox.gz Atom feed top
2017-07-27 22:01 [bug#27855] [PATCH] gnu: Add rsync service Oleg Pykhalov
2017-07-27 22:22 ` [bug#27855] ERROR: rsync rsync://localhost/files Oleg Pykhalov
2017-07-28 6:45 ` [bug#27855] [PATCH] services: rsync: Fix invalid gid nobody Oleg Pykhalov
2017-07-28 22:17 ` [bug#27855] [PATCH] gnu: Add rsync service Christopher Baines
2017-07-29 11:03 ` Oleg Pykhalov
2017-07-29 11:55 ` Christopher Baines
2017-08-03 15:20 ` Oleg Pykhalov
2017-08-03 15:29 ` Oleg Pykhalov
2017-08-03 15:33 ` Christopher Baines
2017-08-03 16:20 ` Oleg Pykhalov
2017-08-03 16:34 ` Oleg Pykhalov
2017-08-10 7:18 ` Christopher Baines
2017-08-10 18:21 ` Christopher Baines
2017-08-10 18:56 ` Oleg Pykhalov
2017-08-11 19:28 ` Oleg Pykhalov
2017-08-12 6:59 ` Christopher Baines
2017-08-12 13:13 ` Oleg Pykhalov
2017-08-12 17:46 ` Christopher Baines
2017-08-12 20:19 ` Oleg Pykhalov
2017-08-12 21:19 ` Christopher Baines
2017-08-19 20:34 ` Oleg Pykhalov
2017-08-19 22:19 ` Christopher Baines
2017-08-24 22:40 ` Oleg Pykhalov
2017-08-30 23:59 ` Christopher Baines
2017-08-31 13:04 ` Ludovic Courtès
2017-09-16 22:44 ` Oleg Pykhalov
2017-09-16 22:49 ` Oleg Pykhalov
2017-09-17 8:40 ` [bug#27855] Status: " Oleg Pykhalov
2017-09-18 6:20 ` [bug#27855] " Christopher Baines
2017-09-23 1:47 ` Oleg Pykhalov [this message]
2017-09-23 2:38 ` Oleg Pykhalov
2017-09-23 20:12 ` bug#27855: " Christopher Baines
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://guix.gnu.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=87r2uyb2zl.fsf@gmail.com \
--to=go.wigust@gmail.com \
--cc=27855@debbugs.gnu.org \
--cc=mail@cbaines.net \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/guix.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).