[bug#41752] [PATCH] gnu: Add bash-hosts.

[bug#41752] [PATCH] gnu: Add bash-hosts.

[Oleg Pykhalov]

* gnu/packages/admin.scm (bash-hosts): New variable.
---
 gnu/packages/admin.scm | 43 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/gnu/packages/admin.scm b/gnu/packages/admin.scm
index bb93f7efb1..dd0ada0422 100644
--- a/gnu/packages/admin.scm
+++ b/gnu/packages/admin.scm
@@ -3841,3 +3841,46 @@ It supports mounting local filesystems of any kind the normal mount utility
 supports.  It can also mount encrypted LUKS volumes using the password
 supplied by the user when logging in.")
     (license (list license:gpl2+ license:lgpl2.1+))))
+
+(define-public bash-hosts
+  (package
+    (name "bash-hosts")
+    (version "3.5.1")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://github.com/xwmx/hosts.git")
+                    (commit version)))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "0q02n28sng0757cgkkc7r45krs07j993k6sgyyp27n8v0l8q6fv4"))))
+    (build-system trivial-build-system)
+    (inputs
+     `(("bash" ,bash)))
+    (arguments
+     `(#:modules ((guix build utils))
+       #:builder
+       (begin
+         (use-modules (guix build utils))
+         (copy-recursively (assoc-ref %build-inputs "source") ".")
+         (substitute* "hosts"
+           (("/usr/bin/env bash")
+            (string-append (assoc-ref %build-inputs "bash")
+                           "/bin/bash")))
+         (install-file "hosts" (string-append %output "/bin"))
+         (let ((bash-completion (string-append %output
+                                               "/etc/bash_completion.d")))
+           (mkdir-p bash-completion)
+           (copy-file "etc/hosts-completion.bash"
+                      (string-append bash-completion "/hosts")))
+         #t)))
+    (home-page "https://github.com/xwmx/hosts/")
+    (synopsis "Command line hosts file editor in a single portable script")
+    (description "@code{hosts} is a command line program for managing hosts
+file entries.  @code{hosts} works with existing hosts files and entries,
+making it easier to add, remove, comment, and search hosts file entries using
+simple, memorable commands.  @code{hosts} is designed to be lightweight, easy
+to use, and contained in a single, portable script that can be curled into any
+environment.")
+    (license license:expat)))
-- 
2.26.2

[bug#41752] [PATCH] gnu: Add bash-hosts.

[Tobias Geerinckx-Rice via Guix-patches via]

[-- Attachment #1: Type: text/plain, Size: 3982 bytes --]

Oleg,

Oleg Pykhalov 写道：
> * gnu/packages/admin.scm (bash-hosts): New variable.

Thanks!  The package should be called just ‘hosts’.

> +(define-public bash-hosts
> +  (package
> +    (name "bash-hosts")
> +    (version "3.5.1")
> +    (source (origin
> +              (method git-fetch)
> +              (uri (git-reference
> +                    (url "https://github.com/xwmx/hosts.git")
> +                    (commit version)))
> +              (file-name (git-file-name name version))
> +              (sha256
> +               (base32
> + 
> "0q02n28sng0757cgkkc7r45krs07j993k6sgyyp27n8v0l8q6fv4"))))
> +    (build-system trivial-build-system)
> +    (inputs
> +     `(("bash" ,bash)))

Like all non-trivial shell scripts it assumes coreutils are 
present.  It also hard-depends on ncurses (for tput), gawk, sed, & 
grep.  You can substitute* these as well, or use wrap-script 
(which requires adding guile-3.0) since ‘performance’ probably 
doesn't matter here.  But read on.

Keeping optional dependencies (like sudo) up to the user is good.

> +    (arguments
> +     `(#:modules ((guix build utils))
> +       #:builder
> +       (begin
> +         (use-modules (guix build utils))
> +         (copy-recursively (assoc-ref %build-inputs "source") 
> ".")
> +         (substitute* "hosts"
> +           (("/usr/bin/env bash")
> +            (string-append (assoc-ref %build-inputs "bash")
> +                           "/bin/bash")))
> +         (install-file "hosts" (string-append %output "/bin"))

We should copy LICENSE and README to /share/doc/,name-,version 
too.

> +         (let ((bash-completion (string-append %output
> + 
> "/etc/bash_completion.d")))
> +           (mkdir-p bash-completion)
> +           (copy-file "etc/hosts-completion.bash"
> +                      (string-append bash-completion 
> "/hosts")))
> +         #t)))
> +    (home-page "https://github.com/xwmx/hosts/")
> +    (synopsis "Command line hosts file editor in a single 
> portable script")

I don't think ‘in a single portable script’ (like ‘Free’ or 
‘cross-platform’ or ‘now contains Rust!’) adds value here.  Write 
@file{hosts} for clarity.

> +    (description "@code{hosts} is a command line program

@code{hosts} should be either @command{hosts} or simply ‘Hosts’. 
I favour the latter, at least for this occurrence.

> for managing hosts file entries.

You can use @file{/etc/hosts} mark-up here too to make up for it.

> @code{hosts} works with existing hosts files and entries,

Nitpick: every sentence starting with ‘Hosts’ sounds odd to me. 
This could start with ‘It’.

> +making it easier to add, remove, comment, and search hosts file 
> entries using
> +simple, memorable commands.  @code{hosts} is designed to be 
> lightweight, easy
> +to use, and contained in a single, portable script that can be 
> curled into any
> +environment.")

Users will have to invoke it as ‘sh ./hosts’ to skip the patched 
shebang, but it would work.  If we patch or wrap it to include 
store patch for all dependencies it won't be true at all.

If this feature matters to you, I think you could do something 
like

    (substitute* "hosts"
      (("#!/usr/bin/env bash")
       (string-append "#! "(assoc-ref %build-inputs "bash")
                      "/bin/bash\n"
                      ;; Just a rough example.
                      "PATH=\"" (getenv "PATH") ":$PATH\"")))

To avoid a separate .hosts-real file and keep the script working 
both in pure environments and when scp'd to random hosts.

But Guix packages in general don't care about being self-contained 
like this.  Maybe it's not worth supporting; one can always curl 
the unguixed original instead?

> +    (license license:expat)))

I've opened a bug report about the unclear licencing: 
<https://github.com/xwmx/hosts/issues/10>.

Kind regards,

T G-R

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 227 bytes --]

[bug#41752] [PATCH] gnu: Add bash-hosts.

[Tobias Geerinckx-Rice via Guix-patches via]

[-- Attachment #1: Type: text/plain, Size: 184 bytes --]

Oleg Pykhalov 写道：
> +    (name "bash-hosts")
> +    (version "3.5.1")

There's now a 3.6.1 release that includes a licence header in the 
script.

Kind regards,

T G-R

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 227 bytes --]

bug#41752: [PATCH] gnu: Add bash-hosts.

[Oleg Pykhalov]

[-- Attachment #1: Type: text/plain, Size: 155 bytes --]

Hello,

Thank you for review!

I applied all your suggestions, added ZSH completion and tests.

Pushed as ceb233bb7642b2a7efec57073bf205b62ebd8f97.

Oleg.

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 832 bytes --]