[bug#39641] [PATCH 0/2] Add opensurge.

[bug#39641] [PATCH 0/2] Add opensurge.

[Timotej Lazar]

Hi,

these patches add opensurge[0] and its game engine, surgescript. The
bundled copies of Roboto fonts are replaced with the store versions.

I kept the Gothic A1 font because it isn’t packaged for Guix. While the
font is distributed under OFL[1], I could only find it on font repos
such as https://fontlibrary.org and not on the official site[2]. If
downloading from repos is OK, I can add the package for the Gothic A1
font and update this submission.

Thanks!

[0] https://opensurge2d.org/
[1] https://fontlibrary.org/en/font/gothic-a1
[2] https://www.hanyang.co.kr/hygothic/

Timotej Lazar (2):
  gnu: Add surgescript.
  gnu: Add opensurge.

 gnu/packages/game-development.scm | 28 +++++++++++++
 gnu/packages/games.scm            | 67 +++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

-- 
2.25.0

[bug#39641] [PATCH 1/2] gnu: Add surgescript.

[Timotej Lazar]

* gnu/packages/game-development.scm (surgescript): New variable.
---
 gnu/packages/game-development.scm | 28 ++++++++++++++++++++++++++++
 1 file changed, 28 insertions(+)

diff --git a/gnu/packages/game-development.scm b/gnu/packages/game-development.scm
index 6fa4fed74f..24527abae1 100644
--- a/gnu/packages/game-development.scm
+++ b/gnu/packages/game-development.scm
@@ -585,6 +585,34 @@ sounds from presets such as \"explosion\" or \"powerup\".")
     (home-page "http://www.drpetter.se/project_sfxr.html")
     (license license:expat)))
 
+(define-public surgescript
+  (package
+    (name "surgescript")
+    (version "0.5.4.3")
+    (source
+     (origin
+       (method git-fetch)
+       (uri (git-reference
+             (url "https://github.com/alemart/surgescript.git")
+             (commit (string-append "v" version))))
+       (file-name (git-file-name name version))
+       (sha256
+        (base32 "13q81439zg1bn7gskligskjgcfq0rdapp6f3llmrlk48vnyq49s0"))))
+     (build-system cmake-build-system)
+     (arguments
+      '(#:configure-flags
+        (let ((share (string-append (assoc-ref %outputs "out") "/share")))
+          (list (string-append "-DICON_PATH=" share "/pixmaps")
+                (string-append "-DMETAINFO_PATH=" share "/metainfo")))
+        #:tests? #f))
+     (home-page "https://docs.opensurge2d.org")
+     (synopsis "Scripting language for games")
+     (description "@code{SurgeScript} is a dynamically typed object-oriented
+scripting language designed for games.  Each object is a state machine that
+can be customized by attaching other objects.  The language supports automatic
+garbage collection and can be extended with plugins.")
+    (license license:asl2.0)))
+
 (define-public physfs
   (package
     (name "physfs")
-- 
2.25.0

[bug#39641] [PATCH 2/2] gnu: Add opensurge.

[Timotej Lazar]

* gnu/packages/games.scm (opensurge): New variable.
---
 gnu/packages/games.scm | 67 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
index cb21a66133..f565b3a1ca 100644
--- a/gnu/packages/games.scm
+++ b/gnu/packages/games.scm
@@ -856,6 +856,73 @@ and much more stand between you and the exit.  Record your moves and let your
 shadow mimic them to reach blocks you couldn't reach alone.")
     (license license:gpl3+)))
 
+(define-public opensurge
+  (package
+    (name "opensurge")
+    (version "0.5.1.2")
+    (source
+     (origin
+       (method git-fetch)
+       (uri (git-reference
+             (url "https://github.com/alemart/opensurge.git")
+             (commit (string-append "v" version))))
+       (file-name (git-file-name name version))
+       (sha256
+        (base32 "0ih7hlqjnp9rv0m4lqf7c0s1ai532way5i4pk45jq1gqm8325dbv"))))
+    (build-system cmake-build-system)
+    (arguments
+     `(#:configure-flags
+       (let* ((out (assoc-ref %outputs "out"))
+              (share (string-append out "/share")))
+         (list (string-append "-DCMAKE_INSTALL_PREFIX=" out "/bin")
+               (string-append "-DGAME_DATADIR=" share "/" ,name)
+               (string-append "-DDESKTOP_ENTRY_PATH=" share "/applications")
+               (string-append "-DDESKTOP_ICON_PATH=" share "/pixmaps")
+               (string-append "-DDESKTOP_METAINFO_PATH=" share "/metainfo")))
+       #:phases
+       (modify-phases %standard-phases
+         (add-after 'unpack 'fix-xdg-open-path
+           (lambda _
+             ;; Look for xdg-open in the store.
+             (substitute* "src/core/web.c"
+               (("/usr(/bin/xdg-open)" _ bin)
+                (string-append (assoc-ref %build-inputs "xdg-utils") bin)))
+             #t))
+         (add-after 'unpack 'unbundle-fonts
+           (lambda _
+             ;; Replace bundled Roboto fonts with links to the store.
+             (with-directory-excursion "fonts"
+               (let ((roboto-dir (string-append
+                                  (assoc-ref %build-inputs "font-google-roboto")
+                                  "/share/fonts/truetype/")))
+                 (for-each (lambda (font)
+                             (delete-file font)
+                             (symlink (string-append roboto-dir font) font))
+                           '("Roboto-Black.ttf" "Roboto-Bold.ttf" "Roboto-Medium.ttf")))
+               #t))))
+       #:tests? #f)) ; There are no tests.
+    (inputs
+     `(("allegro" ,allegro)
+       ("font-google-roboto" ,font-google-roboto)
+       ("surgescript" ,surgescript)
+       ("xdg-utils" ,xdg-utils)))
+    (home-page "https://opensurge2d.org")
+    (synopsis "2D retro side-scrolling game")
+    (description "@code{Open Surge} is a 2D retro side-scrolling platformer
+inspired by the Sonic games.  The player runs at high speeds through each
+level while collecting items and avoiding obstacles.  The game includes a
+built-in level editor.")
+    (license
+     ;; Code is under GPL 3+, assets are under various licenses.
+     ;; See src/misc/credits.c for details.
+     (list license:gpl3+
+           license:cc0
+           license:cc-by3.0
+           license:cc-by-sa3.0
+           license:expat
+           license:public-domain
+           license:silofl1.1))))
+
 (define-public knights
   (package
     (name "knights")
-- 
2.25.0

[bug#39641] [PATCH 0/2] Add opensurge.

[Nicolas Goaziou]

Hello,

Timotej Lazar <timotej.lazar@araneo.si> writes:

> these patches add opensurge[0] and its game engine, surgescript. The
> bundled copies of Roboto fonts are replaced with the store versions.

Thank you for this! I applied your patches.

> I kept the Gothic A1 font because it isn’t packaged for Guix. While the
> font is distributed under OFL[1], I could only find it on font repos
> such as https://fontlibrary.org and not on the official site[2]. If
> downloading from repos is OK, I can add the package for the Gothic A1
> font and update this submission.

I am not a reference on that matter, but I think that downloading from
font repos should be avoided, if possible. So I suggest to add this as
a TODO note for later, if we find font in an official place.

WDYT?

Regards,

-- 
Nicolas Goaziou

[bug#39641] [PATCH 0/2] Add opensurge.

[Timotej Lazar]

Nicolas Goaziou <mail@nicolasgoaziou.fr> [2020-02-18 02:35:33+0100]:
> Timotej Lazar <timotej.lazar@araneo.si> writes:
>> I kept the Gothic A1 font because it isn’t packaged for Guix. While the
>> font is distributed under OFL[1], I could only find it on font repos
>
> I am not a reference on that matter, but I think that downloading from
> font repos should be avoided, if possible. So I suggest to add this as
> a TODO note for later, if we find font in an official place.

I agree. I’ll add the TODO locally and submit it with the next package
upgrade, if that’s OK.

Thanks for the review!
Timotej

bug#39641: [PATCH 0/2] Add opensurge.

[Nicolas Goaziou]

Hello,

Timotej Lazar <timotej.lazar@araneo.si> writes:

> Nicolas Goaziou <mail@nicolasgoaziou.fr> [2020-02-18 02:35:33+0100]:

>> I am not a reference on that matter, but I think that downloading from
>> font repos should be avoided, if possible. So I suggest to add this as
>> a TODO note for later, if we find font in an official place.
>
> I agree. I’ll add the TODO locally and submit it with the next package
> upgrade, if that’s OK.

Fine by me. Meanwhile, I'm closing this bug report.

Regards,

-- 
Nicolas Goaziou