[bug#53953] [PATCH] gnu: Add acpilight.

[bug#53953] [PATCH] gnu: Add acpilight.

[Brice Waegeneire]

* gnu/packages/linux.scm (acpilight): New variable.
---
 gnu/packages/linux.scm | 42 +++++++++++++++++++++++++++++++++++++++++-
 1 file changed, 41 insertions(+), 1 deletion(-)

diff --git a/gnu/packages/linux.scm b/gnu/packages/linux.scm
index bcbaa2166d..2d6c024906 100644
--- a/gnu/packages/linux.scm
+++ b/gnu/packages/linux.scm
@@ -35,7 +35,7 @@
 ;;; Copyright © 2019 Tim Gesthuizen <tim.gesthuizen@yahoo.de>
 ;;; Copyright © 2019, 2020, 2021 Maxim Cournoyer <maxim.cournoyer@gmail.com>
 ;;; Copyright © 2019 Stefan Stefanović <stefanx2ovic@gmail.com>
-;;; Copyright © 2019, 2020, 2021 Brice Waegeneire <brice@waegenei.re>
+;;; Copyright © 2019-2022 Brice Waegeneire <brice@waegenei.re>
 ;;; Copyright © 2019 Kei Kebreau <kkebreau@posteo.net>
 ;;; Copyright © 2020, 2021 Oleg Pykhalov <go.wigust@gmail.com>
 ;;; Copyright © 2020 Pierre Neidhardt <mail@ambrevar.xyz>
@@ -8806,3 +8806,43 @@ (define-public libgpiod
     (license (list license:lgpl2.1+   ;; libgpiod
                    license:gpl2+      ;; gpio-tools
                    license:lgpl3+)))) ;; C++ bindings
+
+(define-public acpilight
+  (package
+    (name "acpilight")
+    (version "1.2")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://gitlab.com/wavexx/acpilight.git")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1r0r3nx6x6vkpal6vci0zaa1n9dfacypldf6k8fxg7919vzxdn1w"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:tests? #f  ;no tests
+       #:make-flags (list "prefix="
+                          (string-append "DESTDIR="
+                                         (assoc-ref %outputs "out")))
+       #:phases
+       (modify-phases %standard-phases
+         (delete 'configure)
+         (add-after 'unpack 'patch
+           (lambda* (#:key inputs #:allow-other-keys)
+             (substitute* "Makefile"
+               (("udevadm") "true"))
+             (substitute* "90-backlight.rules"
+               (("/bin")
+                (string-append (assoc-ref inputs "coreutils") "/bin")))
+             #t)))))
+    (inputs
+     (list python))
+    (home-page "https://gitlab.com/wavexx/acpilight")
+    (synopsis "Backward-compatibile xbacklight replacement")
+    (description "acpilight is a backward-compatibile replacement for
+xbacklight that uses the ACPI interface to set the display
+brightness.  On modern laptops acpilight can control both display and
+keyboard backlight uniformly on either X11, the console or Wayland.")
+    (license license:gpl3+)))

base-commit: 068d99978a0c9c6fb66f95455060c8d08ba55ac5
-- 
2.34.0

[bug#53953] [PATCH] gnu: Add acpilight.

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 515 bytes --]

Brice Waegeneire schreef op za 12-02-2022 om 11:44 [+0100]:
> +             (substitute* "90-backlight.rules"
> +               (("/bin")
> +                (string-append (assoc-ref inputs "coreutils") "/bin")))
> +             #t)))))
> +    (inputs
> +     (list python))

coreutils-minimal needs to be added to inputs, otherwise the
substitute* above won't work when cross-compiling.  Also, phases do not
have to return #t anymore.

Greetings,
Maxime

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#53953] [PATCH] gnu: Add acpilight.

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 961 bytes --]

Brice Waegeneire schreef op za 12-02-2022 om 11:44 [+0100]:
> +       #:make-flags (list "prefix="
> +                          (string-append "DESTDIR="
> +                                         (assoc-ref %outputs "out")))

%outputs, %build-inputs and friends are being deprecated (not 100%
sure, you might want to confirm with ludo) in favour of G-exps. More
concretely: (list #:make-flags #~(list "prefix=" (string-append
"DESTDIR=" #$output))).

Also, about prefix= and DESTDIR=, it's normally the other way around.

#~(list ; (probably) no need to set DESTDIR=, it's normally "" by default:
        (string-append "prefix=" #$output)).

(Search for "Staged installation" for details)

Also, are you sure about the case of 'prefix'?  Usually, Makefiles use
uppercase 'PREFIX' and not 'prefix' (for ./configure, it's other way
around).

Greetings,
Maxime.



[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#53953] [PATCH v2] gnu: Add acpilight.

[Brice Waegeneire]

* gnu/packages/linux.scm (acpilight): New variable.
---
Maxime,

Thanks for the review.  I should have re-read this old package more throughly,
I have fixed what you pointed out:
- using gexp in arguments field
- don't returning #t in phases
- adding coreutils-minimal to inputs

As for the odd make-flags, this is because of the uncanonical Makefile¹ of
acpilight, It don't build with an empty DESTDIR.

¹ https://gitlab.com/wavexx/acpilight/-/blob/master/Makefile

Cheers,
- Brice

 gnu/packages/linux.scm | 40 +++++++++++++++++++++++++++++++++++++++-
 1 file changed, 39 insertions(+), 1 deletion(-)

diff --git a/gnu/packages/linux.scm b/gnu/packages/linux.scm
index bcbaa2166d..fe88d9ad26 100644
--- a/gnu/packages/linux.scm
+++ b/gnu/packages/linux.scm
@@ -35,7 +35,7 @@
 ;;; Copyright © 2019 Tim Gesthuizen <tim.gesthuizen@yahoo.de>
 ;;; Copyright © 2019, 2020, 2021 Maxim Cournoyer <maxim.cournoyer@gmail.com>
 ;;; Copyright © 2019 Stefan Stefanović <stefanx2ovic@gmail.com>
-;;; Copyright © 2019, 2020, 2021 Brice Waegeneire <brice@waegenei.re>
+;;; Copyright © 2019-2022 Brice Waegeneire <brice@waegenei.re>
 ;;; Copyright © 2019 Kei Kebreau <kkebreau@posteo.net>
 ;;; Copyright © 2020, 2021 Oleg Pykhalov <go.wigust@gmail.com>
 ;;; Copyright © 2020 Pierre Neidhardt <mail@ambrevar.xyz>
@@ -8806,3 +8806,41 @@ (define-public libgpiod
     (license (list license:lgpl2.1+   ;; libgpiod
                    license:gpl2+      ;; gpio-tools
                    license:lgpl3+)))) ;; C++ bindings
+
+(define-public acpilight
+  (package
+    (name "acpilight")
+    (version "1.2")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://gitlab.com/wavexx/acpilight.git")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1r0r3nx6x6vkpal6vci0zaa1n9dfacypldf6k8fxg7919vzxdn1w"))))
+    (build-system gnu-build-system)
+    (arguments
+     (list #:tests? #f  ;no tests
+           #:make-flags #~(list "prefix="
+                                (string-append "DESTDIR=" #$output))
+           #:phases
+           #~(modify-phases %standard-phases
+               (delete 'configure)
+               (add-after 'unpack 'patch
+                 (lambda* (#:key inputs #:allow-other-keys)
+                   (substitute* "Makefile"
+                     (("udevadm") "true"))
+                   (substitute* "90-backlight.rules"
+                     (("/bin")
+                      (string-append (assoc-ref inputs "coreutils-minimal") "/bin"))))))))
+    (inputs
+     (list python coreutils-minimal))
+    (home-page "https://gitlab.com/wavexx/acpilight")
+    (synopsis "Backward-compatibile xbacklight replacement")
+    (description "acpilight is a backward-compatibile replacement for
+xbacklight that uses the ACPI interface to set the display
+brightness.  On modern laptops acpilight can control both display and
+keyboard backlight uniformly on either X11, the console or Wayland.")
+    (license license:gpl3+)))

base-commit: e641d707e1ec8de2bfc658dcd1757360300aa509
-- 
2.34.0

[bug#53953] [PATCH v2] gnu: Add acpilight.

[Maxime Devos]

[-- Attachment #1: Type: text/plain, Size: 807 bytes --]

Brice Waegeneire schreef op za 12-02-2022 om 18:21 [+0100]:
> As for the odd make-flags, this is because of the uncanonical Makefile¹ of
> acpilight, It don't build with an empty DESTDIR.
> 
> ¹ https://gitlab.com/wavexx/acpilight/-/blob/master/Makefile

Looks like the problem is caused by 'sysconfdir' not being based
on 'prefix', but that can be resolved by

#~(list (string-append "prefix=" #$output)
	(string-append "sysconfdir=" (string-append #$output "/etc")))

which is not 100% canonical, but it does seems closer to me?

Also, apparently there's a 'python-minimal' package, so you could use
that instead of 'python' to reduce the closure?  Might be counter-
productive though, since most packages seem to use plain 'python'
instead ...

whose closure
would be smaller than

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]

[bug#53953] [PATCH v3] gnu: Add acpilight.

[Brice Waegeneire]

* gnu/packages/linux.scm (acpilight): New variable.
---
Hello Maxime,

Maxime Devos <maximedevos@telenet.be> writes:

> Brice Waegeneire schreef op za 12-02-2022 om 18:21 [+0100]:
>> As for the odd make-flags, this is because of the uncanonical Makefile¹ of
>> acpilight, It don't build with an empty DESTDIR.
>> 
>> ¹ https://gitlab.com/wavexx/acpilight/-/blob/master/Makefile
>
> Looks like the problem is caused by 'sysconfdir' not being based
> on 'prefix', but that can be resolved by
>
> #~(list (string-append "prefix=" #$output)
> 	(string-append "sysconfdir=" (string-append #$output "/etc")))
>
> which is not 100% canonical, but it does seems closer to me?

I remember trying someting like that unsuccesfully before sending the previous
patch version but I probablly missend something because it actually work!

> Also, apparently there's a 'python-minimal' package, so you could use
> that instead of 'python' to reduce the closure?  Might be counter-
> productive though, since most packages seem to use plain 'python'
> instead ...

Done.

Cheers,
- Brice

 gnu/packages/linux.scm | 44 +++++++++++++++++++++++++++++++++++++++++-
 1 file changed, 43 insertions(+), 1 deletion(-)

diff --git a/gnu/packages/linux.scm b/gnu/packages/linux.scm
index 4edb5bf858..fd68901391 100644
--- a/gnu/packages/linux.scm
+++ b/gnu/packages/linux.scm
@@ -35,7 +35,7 @@
 ;;; Copyright © 2019 Tim Gesthuizen <tim.gesthuizen@yahoo.de>
 ;;; Copyright © 2019, 2020, 2021 Maxim Cournoyer <maxim.cournoyer@gmail.com>
 ;;; Copyright © 2019 Stefan Stefanović <stefanx2ovic@gmail.com>
-;;; Copyright © 2019, 2020, 2021 Brice Waegeneire <brice@waegenei.re>
+;;; Copyright © 2019-2022 Brice Waegeneire <brice@waegenei.re>
 ;;; Copyright © 2019 Kei Kebreau <kkebreau@posteo.net>
 ;;; Copyright © 2020, 2021 Oleg Pykhalov <go.wigust@gmail.com>
 ;;; Copyright © 2020 Pierre Neidhardt <mail@ambrevar.xyz>
@@ -8806,3 +8806,45 @@ (define-public libgpiod
     (license (list license:lgpl2.1+   ;; libgpiod
                    license:gpl2+      ;; gpio-tools
                    license:lgpl3+)))) ;; C++ bindings
+
+(define-public acpilight
+  (package
+    (name "acpilight")
+    (version "1.2")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://gitlab.com/wavexx/acpilight.git")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1r0r3nx6x6vkpal6vci0zaa1n9dfacypldf6k8fxg7919vzxdn1w"))))
+    (build-system gnu-build-system)
+    (arguments
+     (list #:tests? #f                  ; no tests
+           #:make-flags
+           #~(list (string-append "prefix=" #$output)
+                   (string-append "sysconfdir=" #$output "/etc"))
+           #:phases
+           #~(modify-phases %standard-phases
+               (delete 'configure)
+               (add-after 'unpack 'patch
+                 (lambda* (#:key inputs #:allow-other-keys)
+                   ;; Prevent reloading udev at build time
+                   (substitute* "Makefile"
+                     (("udevadm") "true"))
+                   (substitute* "90-backlight.rules"
+                     (("/bin")
+                      (string-append (assoc-ref inputs "coreutils-minimal")
+                                     "/bin"))))))))
+    (inputs
+     (list coreutils-minimal
+           python-minimal))
+    (home-page "https://gitlab.com/wavexx/acpilight")
+    (synopsis "Backward-compatibile xbacklight replacement")
+    (description "acpilight is a backward-compatibile replacement for
+xbacklight that uses the ACPI interface to set the display
+brightness.  On modern laptops acpilight can control both display and
+keyboard backlight uniformly on either X11, the console or Wayland.")
+    (license license:gpl3+)))

base-commit: 52269e27c628d34af896e95347870b1755cb3e5f
-- 
2.34.0

[bug#53953] [PATCH] gnu: Add acpilight.

[Ludovic Courtès]

Hi Brice,

Brice Waegeneire <brice@waegenei.re> skribis:

> * gnu/packages/linux.scm (acpilight): New variable.

LGTM, please push!

Thanks,
Ludo’.

[bug#53953] [PATCH] gnu: Add acpilight.

[Ludovic Courtès]

Ping! :-)

Ludovic Courtès <ludo@gnu.org> skribis:

> Hi Brice,
>
> Brice Waegeneire <brice@waegenei.re> skribis:
>
>> * gnu/packages/linux.scm (acpilight): New variable.
>
> LGTM, please push!
>
> Thanks,
> Ludo’.

bug#53953: [PATCH] gnu: Add acpilight.

[Maxim Cournoyer]

Hello,

Ludovic Courtès <ludo@gnu.org> writes:

> Ping! :-)
>
> Ludovic Courtès <ludo@gnu.org> skribis:
>
>> Hi Brice,
>>
>> Brice Waegeneire <brice@waegenei.re> skribis:
>>
>>> * gnu/packages/linux.scm (acpilight): New variable.
>>
>> LGTM, please push!

Pushed myself, closing!

Maxim

[bug#53953] [PATCH] gnu: Add acpilight.

[Antero Mejr via Guix-patches via]

Any update on this merge? I was hoping to install acpilight but it doesn't appear to be in the latest master (commit 16a0aea02d). Thanks.