;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2019 Andreas Enge <andreas@enge.fr>
;;; Copyright © 2019 Nicolas Goaziou <mail@nicolasgoaziou.fr>
;;; Copyright © 2019, 2020 Tobias Geerinckx-Rice <me@tobias.gr>
;;; Copyright © 2020 Jakub Kądziołka <kuba@kadziolka.net>
;;; Copyright © 2021 Efraim Flashner <efraim@flashner.co.il>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu packages sagemath)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix build-system copy)
  #:use-module (guix build-system cmake)
  #:use-module (guix build-system gnu)
  #:use-module (guix build-system python)
  #:use-module (guix build-system trivial)
  #:use-module (guix download)
  #:use-module (guix gexp)
  #:use-module (guix git-download)
  #:use-module (guix packages)
  #:use-module (guix utils)
  #:use-module (gnu packages)
  #:use-module (gnu packages algebra)
  #:use-module (gnu packages autotools)
  #:use-module (gnu packages base)
  #:use-module (gnu packages bdw-gc)
  #:use-module (gnu packages boost)
  #:use-module (gnu packages commencement)
  #:use-module (gnu packages compression)
  #:use-module (gnu packages freedesktop)
  #:use-module (gnu packages gd)
  #:use-module (gnu packages graph)
  #:use-module (gnu packages image)
  #:use-module (gnu packages lisp)
  #:use-module (gnu packages maths)
  #:use-module (gnu packages multiprecision)
  #:use-module (gnu packages pkg-config)
  #:use-module (gnu packages popt)
  #:use-module (gnu packages python)
  #:use-module (gnu packages python-build)
  #:use-module (gnu packages python-science)
  #:use-module (gnu packages python-xyz))


(define-public python-cypari2
  (package
    (name "python-cypari2")
    (version "2.1.2")
    (source
     (origin
       (method url-fetch)
       (uri (pypi-uri "cypari2" version))
       (sha256
        (base32
         "0ymc4i9y60aazscc1blivirkr1rflzz6akkmvfzyn5l7mgnlbk83"))))
    (build-system python-build-system)
    (native-inputs
     (list python-cython))
    (propagated-inputs
     (list python-cysignals))
    (inputs
     (list gmp pari-gp))
    (home-page "https://cypari2.readthedocs.io/")
    (synopsis
     "Python interface to the number theory library libpari")
    (description
     "Cypari2 provides a Python interface to the number theory library
PARI/GP.  It has been spun off from the SageMath mathematics software system,
but it can be used independently.")
    (license license:gpl2+)))

;; The stable version of the following package is not young enough to be
;; used with Sage, since it does not support cython; so we use a beta
;; release.
(define-public python-gmpy2
  (package
    (name "python-gmpy2")
    (version "2.1.0b1")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://github.com/aleaxit/gmpy")
                    (commit (string-append "gmpy2-" version))))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "0ljvnmhxqdfsp0yy4c2hynhk5sggm63kkqsq4iwq4k9vsnx2xm97"))))
    (build-system python-build-system)
    (native-inputs
     (list unzip))
    (inputs
     (list gmp mpfr mpc))
    (home-page "https://github.com/aleaxit/gmpy")
    (synopsis
     "GMP/MPIR, MPFR, and MPC interface to Python 2.6+ and 3.x")
    (description
     "This package provides a Python interface to the GNU multiprecision
libraries GMO, MPFR and MPC.")
    (license license:lgpl3+)))

(define-public cliquer
  (package
    (name "cliquer")
    (version "1.22")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://github.com/dimpase/autocliquer")
                    (commit (string-append "v" version))))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "00gcmrhi2fjn8b246w5a3b0pl7p6haxy5wjvd9kcqib1xanz59z4"))))
    (build-system gnu-build-system)
    (native-inputs (list autoconf automake libtool))
    (synopsis "C routines for finding cliques in weighted graphs")
    (description "Cliquer is a set of reentrant C routines for finding
cliques in a weighted or unweighted graph.  It uses an exact
branch-and-bound algorithm.  It can search for maximum or maximum-weight
cliques or cliques with size or weight within a given range, restrict the
search to maximal cliques, store cliques in memory and call a user-defined
function for every found clique.")
    (license license:gpl2+)
    (home-page "https://github.com/dimpase/autocliquer")))

(define-public libbraiding
  (package
    (name "libbraiding")
    (version "1.0")
    (source
     (origin
       (method git-fetch)
       (uri (git-reference
              (url (string-append "https://github.com/miguelmarco/"
                                  name))
              (commit version)))
       (file-name (git-file-name name version))
       (sha256
        (base32
         "0l68rikfr7k2l547gb3pp3g8cj5zzxwipm79xrb5r8ffj466ydxg"))))
    (build-system gnu-build-system)
    (native-inputs
     (list autoconf automake libtool))
    (synopsis "Computations with braid groups")
    (description "libbraiding performs computations with braid groups,
in particular it computes normal forms of group elements.")
    (license license:gpl2+)
    (home-page "https://github.com/miguelmarco/libbraiding")))

(define-public libhomfly
  (package
    (name "libhomfly")
    (version "1.02r6")
    (source
     (origin
       (method git-fetch)
       (uri (git-reference
              (url (string-append "https://github.com/miguelmarco/"
                                  name))
              (commit version)))
       (file-name (git-file-name name version))
       (sha256
        (base32
         "0sv3cwrf9v9sb5a8wbhjmarxvya13ma3j8y8592f9ymxlk5y0ldk"))))
    (build-system gnu-build-system)
    (native-inputs
     (list autoconf automake libtool))
    (inputs
     (list libgc))
    (synopsis "Computation of homfly polynomials of links")
    (description "libhomfly computes homfly polynomials of links,
represented as strings.")
    (license license:public-domain)
    (home-page "https://github.com/miguelmarco/libhomfly")))

(define-public pynac
  (package
    (name "pynac")
    (version "0.7.26")
    (source
     (origin
       (method git-fetch)
       (uri (git-reference
              (url "https://github.com/pynac/pynac/")
              (commit (string-append "pynac-" version))))
       (file-name (git-file-name name version))
       (sha256
        (base32 "09d2p74x1arkydlxy6pw4p4byi7r8q7f29w373h4d8a215kadc6d"))))
    (build-system gnu-build-system)
    (native-inputs
     (list autoconf automake libtool pkg-config))
    (inputs
     (list flint gmp python singular))
    (synopsis "Sage fork of GiNaC")
    (description "Pynac is a derivative of the C++ library GiNaC, which
allows manipulation of symbolic expressions.  It currently provides the
backend for symbolic expressions in Sage.  The main difference between
Pynac and GiNaC is that Pynac relies on Sage to provide the operations
on numerical types, while GiNaC depends on CLN for this purpose.")
    (license license:gpl2+)
    (home-page "http://pynac.org/")))

;; Sage has become upstream of the following package.
(define-public zn-poly
  (package
    (name "zn-poly")
    (version "0.9.2")
    (source
     (origin
       (method git-fetch)
       (uri (git-reference
              (url (string-append "https://gitlab.com/sagemath/"
                                  "zn_poly.git/"))
              (commit version)))
       (file-name (git-file-name "zn_poly" version))
       (sha256
        (base32 "1wbc3apxcldxfcw1dnwnn7fvlfb6bwvlr8glvgv6hf79p9r2s4j0"))))
    (build-system gnu-build-system)
    (native-inputs
     `(("python" ,python-2)))
    (inputs
     (list gmp))
    (arguments
     `(#:phases
       (modify-phases %standard-phases
         (replace 'configure
           ;; The configure script chokes on --enable-fast-install.
           (lambda* (#:key inputs outputs #:allow-other-keys)
             (invoke "./configure"
                     (string-append "--prefix=" (assoc-ref outputs "out"))
                     "--cflags=-O3 -fPIC")))
         (add-before 'build 'prepare-build
           (lambda _
             (setenv "CC" "gcc")
             #t))
         (add-after 'build 'build-so
           (lambda _
             (invoke "make" "libzn_poly.so")))
         (add-after 'install 'install-so
           (lambda* (#:key outputs #:allow-other-keys)
             (let* ((out (assoc-ref outputs "out"))
                    (lib (string-append out "/lib"))
                    (soname (string-append "libzn_poly-" ,version ".so"))
                    (target (string-append lib "/" soname)))
               (install-file "libzn_poly.a" lib)
               (install-file soname lib)
               (symlink target
                        (string-append lib "/libzn_poly.so"))
               (symlink target
                        (string-append lib "/libzn_poly-"
                                       ,(version-major+minor version)
                                       ".so")))
             #t)))))
    (synopsis "Arithmetic for polynomials over Z/NZ")
    (description "zn_poly implements the arithmetic of polynomials the
coefficients of which are modular integers.")
    (license (list license:gpl2 license:gpl3)) ; dual licensed
    (home-page "https://gitlab.com/sagemath/zn_poly")))

(define-public brial
  (package
    (name "brial")
    (version "1.2.8")
    (source
    (origin
      (method git-fetch)
      (uri (git-reference
             (url "https://github.com/BRiAl/BRiAl/")
             (commit version)))
      (file-name (git-file-name name version))
      (sha256
       (base32 "0qhgckd4fvbs40jw14mvw89rccv94d3df27kipd27hxd4cx7y80y"))))
    (build-system gnu-build-system)
    (native-inputs
     (list autoconf automake libtool pkg-config))
    (inputs
     (list boost libpng m4ri))
    (arguments
    ;; We are missing the boost unit test framework.
     `(#:tests? #f
       #:configure-flags (list "--without-boost-unit-test-framework")))
    (synopsis "Arithmetic of polynomials over boolean rings")
    (description "BRiAl is the successor to  PolyBoRi maintained by the
Sage community.  Its core is a C++ library, which provides high-level data
types for Boolean polynomials and monomials, exponent vectors, as well as
for the underlying polynomial rings and subsets of the powerset of the
Boolean variables.  As a unique approach, binary decision diagrams are
used as internal storage type for polynomial structures.")
    (license license:gpl2+)
    (home-page "https://github.com/BRiAl/BRiAl/")))

(define-public lcalc
  (package
    (name "lcalc")
    (version "2.0.5")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://gitlab.com/sagemath/lcalc")
                    (commit version)))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "1rwyx292y3jbsp88wagn9nhl9z7wsnl2yrs5imxkbxq87pnrj5a7"))))
    (build-system gnu-build-system)
    (arguments
     (list #:configure-flags '(list "--with-pari")))
    (inputs (list pari-gp))
    (native-inputs (list autoconf automake libtool pkg-config gengetopt))
    (home-page "https://gitlab.com/sagemath/lcalc")
    (synopsis "C++ library for with L-functions")
    (description
     "Lcalc computes L-functions, in particular the Riemann zeta function and its
twists by quadratic characters.")
    (license license:gpl2+)))

(define-public ratpoints
  (package
    (name "ratpoints")
    (version "2.1.3")
    (source (origin
              (method url-fetch)
              (uri (string-append
                    "http://www.mathe2.uni-bayreuth.de/stoll/programs/"
                    "ratpoints-" version ".tar.gz"))
              (sha256
               (base32
                "0zhad84sfds7izyksbqjmwpfw4rvyqk63yzdjd3ysd32zss5bgf4"))
              (patches
               ;; Taken from
               ;; <https://git.sagemath.org/sage.git/plain/build/pkgs/ratpoints/patches/>
               (search-patches "ratpoints-sturm_and_rp_private.patch"))))
    (build-system gnu-build-system)
    (arguments
     `(#:test-target "test"
       #:make-flags
       (list (string-append "INSTALL_DIR=" (assoc-ref %outputs "out"))
             "CCFLAGS=-fPIC")
       #:phases
       (modify-phases %standard-phases
         (delete 'configure)            ;no configure script
         (add-before 'install 'create-install-directories
           (lambda* (#:key outputs #:allow-other-keys)
             (let ((out (assoc-ref outputs "out")))
               (mkdir-p out)
               (with-directory-excursion out
                 (for-each (lambda (d) (mkdir-p d))
                           '("bin" "include" "lib"))))
             #t)))))
    (inputs
     (list gmp))
    (home-page "http://www.mathe2.uni-bayreuth.de/stoll/programs/")
    (synopsis "Find rational points on hyperelliptic curves")
    (description "Ratpoints tries to find all rational points within
a given height bound on a hyperelliptic curve in a very efficient way,
by using an optimized quadratic sieve algorithm.")
    (license license:gpl2+)))

(define-public python-memory-allocator
  (package
    (name "python-memory-allocator")
    (version "0.1.3")
    (source (origin
              (method url-fetch)
              (uri (pypi-uri "memory_allocator" version))
              (sha256
               (base32
                "0qiijpv8zr7c5rjy64i4q3rb8qhn6v4yms5mza4p86y0w4m5r00k"))))
    (build-system python-build-system)
    (propagated-inputs (list python-cython))
    (home-page "https://github.com/sagemath/memory_allocator")
    (synopsis "An extension class to allocate memory easily with cython")
    (description "An extension class to allocate memory easily with cython")
    (license license:gpl3)))

(define-public python-pplpy
  (package
    (name "python-pplpy")
    (version "0.8.7")
    (source (origin
              (method url-fetch)
              (uri (pypi-uri "pplpy" version))
              (sha256
               (base32
                "1gfq5czkqxl395k06s77zij3xv7maiwagjvzmrpraxhsmvsd02sh"))))
    (build-system python-build-system)
    (inputs (list gmp
                  mpc
                  mpfr
                  pari-gp
                  ppl
                  python-cysignals
                  python-gmpy2))
    (native-inputs (list python-cython))
    (home-page "https://gitlab.com/videlec/pplpy")
    (synopsis "Python PPL wrapper")
    (description
     "This Python module pplpy provides a wrapper to the C++ Parma Polyhedra
Library (PPL).")
    (license license:gpl3)))

(define-public primecount
  (package
    (name "primecount")
    (version "7.4")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://github.com/kimwalisch/primecount/")
                    (commit (string-append "v" version))))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "1dnkkmszc2knrrqmfbwf96ajxd7rpmaw0b8dx6z5r0f9w1wx7ak4"))))
    (build-system cmake-build-system)
    (arguments '(#:configure-flags (list "-DBUILD_SHARED_LIBS=ON" "-DBUILD_TESTS=ON")))
    (home-page "https://github.com/kimwalisch/primecount/")
    (synopsis "Fast prime counting function implementations")
    (description "primecount is a command-line program and C/C++ library that counts the number
of primes ≤ x (maximum 10^31) using highly optimized implementations of the
combinatorial prime counting algorithms.")
    (license license:bsd-2)))

(define-public python-primecountpy
  (package
    (name "python-primecountpy")
    (version "0.1.0")
    (source (origin
              (method url-fetch)
              (uri (pypi-uri "primecountpy" version))
              (sha256
               (base32
                "0xh6zx5zw5scy7jygqirks9y6z4zyfm0zjfp8nd6dw0m471przkq"))))
    (build-system python-build-system)
    (arguments (list #:phases #~(modify-phases %standard-phases
                                  (add-before 'build 'set-cflags
                                    (lambda _
                                      (setenv "CFLAGS" "-fopenmp")
                                      (setenv "CXXFLAGS" "-fopenmp"))))))
    (inputs (list pari-gp primecount))
    (propagated-inputs (list python-cysignals python-cython))
    (home-page "https://github.com/dimpase/primecountpy")
    (synopsis "Cython interface for C++ primecount library")
    (description "Cython interface for C++ primecount library")
    (license license:gpl3)))

(define-public python-lrcalc
  (package
    (name "python-lrcalc")
    (version "2.1")
    (source (origin
              (method url-fetch)
              (uri (pypi-uri "lrcalc" version))
              (sha256
               (base32
                "1adassfjalsdsngy01c37835qsx3gj0jx9cinc9b91x4xnd51873"))))
    (build-system python-build-system)
    (inputs (list lrcalc))
    (native-inputs (list python-cython))
    (home-page "https://math.rutgers.edu/~asbuch/lrcalc")
    (synopsis "Littlewood-Richardson Calculator bindings")
    (description "Littlewood-Richardson Calculator bindings")
    (license license:gpl3+)))

(define-public palp
  (package
    (name "palp")
    (version "2.20")
    (source (origin
              (method url-fetch)
              (uri (string-append "http://hep.itp.tuwien.ac.at/~kreuzer/CY/palp/palp-" version ".tar.gz"))
              (sha256
               (base32
                "1q1cl3vpdir16szy0jcadysydcrjp48hqxyx42kr8g9digkqjgkj"))))
    (build-system gnu-build-system)
    (arguments
     (list #:make-flags #~(list (string-append "CC=" #$(cc-for-target)))
           #:tests? #f                  ; no tests
           #:phases #~(modify-phases %standard-phases
                        (delete 'configure)
                        (replace 'install
                          (lambda _
                            (for-each
                             (lambda (name)
                               (install-file name (string-append #$output "/bin")))
                             '("class.x" "cws.x" "mori.x" "nef.x" "poly.x")))))))
    (home-page "http://hep.itp.tuwien.ac.at/~kreuzer/CY/CYpalp.html")
    (synopsis "Package for Analyzing Lattice Polytopes")
    (description synopsis)
    (license license:gpl3)))

(define-public gfan
  (package
    (name "gfan")
    (version "0.6.2")
    (source (origin
              (method url-fetch)
              (uri (string-append "https://users-math.au.dk/jensen/software/gfan/gfan" version ".tar.gz"))
              (sha256
               (base32
                "02pihqb1lb76a0xbfwjzs1cd6ay3ldfxsm8dvsbl6qs3vkjxax56"))))
    (build-system gnu-build-system)
    (arguments
     (list #:make-flags #~(list (string-append "PREFIX=" #$output)
                                (string-append "CC=" #$(cc-for-target))
                                (string-append "CXX=" #$(cxx-for-target)))
           #:phases #~(modify-phases %standard-phases
                        (delete 'configure)
                        (add-before 'build 'fix-cddlib-include
                          (lambda _
                            (substitute* '("src/lp_cdd.cpp" "src/gfanlib_zcone.cpp" "src/app_librarytest.cpp")
                              (("^#include \"cdd/") "#include \"cddlib/")))))))
    (inputs (list cddlib gmp))
    (home-page "https://users-math.au.dk/jensen/software/gfan/gfan.html")
    (synopsis "Software package for computing Gröbner fans and tropical varieties")
    (description synopsis)
    (license license:gpl2+)))

(define-public flintqs
  (package
    (name "flintqs")
    (version "1.0")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://github.com/sagemath/FlintQS")
                    (commit (string-append "v" version))))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "1f0lnayz6j6qgasx8pbq61d2fqam0wwhsmh6h15l4vq58l1vvbwj"))))
    (build-system gnu-build-system)
    (arguments
     (list #:phases #~(modify-phases %standard-phases
                        (add-after 'unpack 'create-changelog
                          (lambda _
                            (with-output-to-file "ChangeLog"
                              (lambda () (display ""))))))))
    (inputs (list gmp))
    (native-inputs (list autoconf automake))
    (home-page "https://github.com/sagemath/FlintQS")
    (synopsis "Highly optimized multi-polynomial quadratic sieve for integer
factorization")
    (description synopsis)
    (license license:gpl2)))

(define-public tachyon
  (package
    (name "tachyon")
    (version "0.99.5")
    (source (origin
              (method url-fetch)
              (uri (string-append
                    "http://jedi.ks.uiuc.edu/~johns/raytracer/files/" version
                    "/tachyon-" version ".tar.gz"))
              (sha256
               (base32
                "1xd6h5d4v6dsnm6w46bdcr15fwkcz44p8dncymfry50i4c83q809"))
              (patches (search-patches "tachyon-make-arch.patch"))))
    (build-system gnu-build-system)
    (arguments
     (list #:tests? #f ; no tests
           #:make-flags #~(list "linux-thr"
                                (string-append "CC=" #$(cc-for-target))
                                (string-append "AR=" #$(ar-for-target)))
           #:phases #~(modify-phases %standard-phases
                        (delete 'configure)
                        (add-after 'unpack 'cd-to-src
                          (lambda _
                            (chdir "unix")))
                        (add-before 'build 'enable-png-jpeg-support
                          (lambda* (#:key inputs #:allow-other-keys)
                            (substitute* "Make-config"
                              (("USEJPEG=") "USEJPEG = -DUSEJPEG")
                              (("JPEGLIB=") "JPEGLIB = -ljpeg")
                              (("USEPNG=") "USEPNG = -DUSEPNG")
                              (("PNGLIB=") "PNGLIB = -lpng -lz"))))
                        (add-before 'build 'fix-paths
                          (lambda* (#:key inputs #:allow-other-keys)
                            (substitute* "Make-config"
                              (("SHELL=/bin/sh")
                               (string-append "SHELL=" (search-input-file inputs "/bin/sh"))))))
                        (replace 'install
                          (lambda _
                            (install-file "../compile/tachyon"
                                          (string-append #$output "/bin"))
                            (install-file "../compile/libtachyon.a"
                                          (string-append #$output "/lib")))))))
    (inputs (list libjpeg-turbo libpng))
    (home-page "http://jedi.ks.uiuc.edu/~johns/raytracer/")
    (synopsis "Multithreaded ray tracing software")
    (description synopsis)
    (license license:bsd-3)))

(define-public sagemath-data-conway-polynomials
  (let
      ((install-py-origin
        (origin
          (method url-fetch)
          (uri
           "https://raw.githubusercontent.com/sagemath/sage/9.6/build/pkgs/conway_polynomials/spkg-install.py")
          (sha256 (base32
                   "1bwnqasnyv793hxg29viing4dnliz29grkhldsirq19d509yk1fs")))))
    (package
      (name "sagemath-data-conway-polynomials")
      (version "0.5")
      (source (origin
                (method url-fetch)
                (uri (string-append
                      "https://mirrors.mit.edu/sage/spkg/upstream/conway_polynomials/conway_polynomials-"
                      version ".tar.bz2"))
                (sha256
                 (base32
                  "05zb1ly9x2bbscqv0jgc45g48xx77mfs7qdbqhn4ihmihn57iwnq"))))
      (build-system trivial-build-system)
      (arguments
       (list #:modules '((guix build utils))
             #:builder #~(begin
                           (use-modules (guix build utils))

                           (setenv "PATH"
                                   (string-append #+(file-append bzip2 "/bin")
                                                  ":"
                                                  #+(file-append tar "/bin")
                                                  ":"
                                                  #+(file-append python "/bin")))
                           (setenv "SAGE_SHARE" (string-append #$output "/share"))
                           (setenv "PYTHONPATH" (getcwd))

                           (invoke "tar" "-xvf" #$source)
                           (symlink (string-append "conway_polynomials-" #$version) "src")
                           (invoke "python3" (assoc-ref %build-inputs "install-py")))))
      (inputs `(("install-py" ,install-py-origin)))
      (home-page
       "https://www.math.rwth-aachen.de/~Frank.Luebeck/data/ConwayPol/index.html")
      (synopsis "Tables of Conway polynomials over finite fields")
      (description synopsis)
      ;; no idea, Arch claims gpl, debian gpl2+??
      (license #f))))

(define-public sagemath-data-elliptic-curves
  (let
      ((install-py-origin
        (origin
          (method url-fetch)
          (uri
           "https://raw.githubusercontent.com/sagemath/sage/9.6/build/pkgs/elliptic_curves/spkg-install.py")
          (sha256 (base32
                   "116g684i6mvs11fvb6fzfsr4fn903axn31vigdyb8bgpf8l4hvc5")))))
    (package
      (name "sagemath-data-elliptic-curves")
      (version "0.8.1")
      (source (origin
                (method url-fetch)
                (uri (string-append
                      "https://mirrors.mit.edu/sage/spkg/upstream/elliptic_curves/elliptic_curves-"
                      version ".tar.bz2"))
                (sha256
                 (base32
                  "0l7xh4abw5sb4d37r0ylr3vwb88fpx2zrvfm5ql0c7yrv5q59fjz"))))
      (build-system trivial-build-system)
      (arguments
       (list #:modules '((guix build utils))
             #:builder #~(begin
                           (use-modules (guix build utils))

                           (setenv "PATH"
                                   (string-append #+(file-append bzip2 "/bin")
                                                  ":"
                                                  #+(file-append tar "/bin") ":"
                                                  #+(file-append python "/bin")))
                           (setenv "SAGE_SHARE" (string-append #$output "/share"))
                           (setenv "PYTHONPATH" (getcwd))

                           (invoke "tar" "-xvf" #$source)
                           (symlink (string-append "elliptic_curves-" #$version) "src")
                           (invoke "python3" (assoc-ref %build-inputs "install-py")))))
      (inputs `(("install-py" ,install-py-origin)))
      (home-page "https://johncremona.github.io/ecdata/")
      (synopsis "Databases of elliptic curves")
      (description synopsis)
      ;; no idea, Arch claims gpl, alledgedly is part of
      ;; https://github.com/JohnCremona/ecdata Artistic 2.0
      (license #f))))

(define-public sagemath-data-combinatorial-designs
  (package
    (name "sagemath-data-combinatorial-designs")
    (version "20140630")
    (source (origin
              (method url-fetch)
              (uri (string-append
                    "https://mirrors.mit.edu/sage/spkg/upstream/combinatorial_designs/combinatorial_designs-"
                    version
                    ".tar.bz2"))
              (sha256
               (base32
                "0bj8ngiq59hipa6izi6g5ph5akmy4cbk0vlsb0wa67f7grnnqj69"))))
    (build-system copy-build-system)
    (arguments '(#:install-plan '(("." "share/combinatorial_designs/"))))
    (home-page "https://www.sagemath.org")
    (synopsis "Data for Combinatorial Designs")
    (description synopsis)
    ;; Sage claims public domain
    (license #f)))

(define-public sagemath-data-graphs
  (package
    (name "sagemath-data-graphs")
    (version "202110214")
    (source (origin
              (method url-fetch)
              (uri (string-append
                    "https://mirrors.mit.edu/sage/spkg/upstream/graphs/graphs-"
                    version
                    ".tar.bz2"))
              (sha256
               (base32
                "0h9p5wrxips51x6vpfiiaqzp9j004nwppzc9qc2iaqakk06pq8q7"))))
    (build-system copy-build-system)
    (arguments '(#:install-plan '(("." "share/graphs"))))
    (home-page "https://github.com/jasongrout/graph_database") ;; correct?
    (synopsis "A database of graphs")
    (description synopsis)
    ;; Arch says gpl
    (license #f)))

(define-public sagemath-data-polytopes-db
  (package
    (name "sagemath-data-polytopes-db")
    (version "20170220")
    (source (origin
              (method url-fetch)
              (uri (string-append
                    "https://mirrors.mit.edu/sage/spkg/upstream/polytopes/polytopes-"
                    version
                    ".tar.bz2"))
              (sha256
               (base32
                "1q0cd811ilhax4dsj9y5p7z8prlalqr7k9mzq178c03frbgqny6b"))))
    (build-system copy-build-system)
    (arguments '(#:install-plan '(("." "share/reflexive_polytopes"))))
    (home-page "https://www.sagemath.org")
    (synopsis "Lists of 2- and 3-dimensional reflexive polytopes")
    (description synopsis)
    ;; Sage says gpl
    (license #f)))

(define-public pari-galdata
  (package
    (name "pari-galdata")
    (version "20080412")
    (source (origin
              (method url-fetch)
              ;; no versioning, seem to moved moved to old/... on update
              (uri "https://pari.math.u-bordeaux.fr/pub/pari/packages/galdata.tgz")
              (sha256
               (base32
                "1pch6bk76f1i6cwwgm7hhxi5h71m52lqayp4mnyj0jmjk406bhdp"))))
    (build-system copy-build-system)
    (arguments '(#:install-plan '(("." "share/pari"))))
    (home-page "https://pari.math.u-bordeaux.fr/packages.html")
    (synopsis "PARI database needed to compute Galois group in degrees 8
through 11")
    (description synopsis)
    ;; see home-page
    (license license:gpl2+)))

;;; This only builds sagemath, using the minimum set of dependencies
(define-public sagemath-just-build
  (package
    (name "sagemath-just-build")
    (version "9.6")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://github.com/sagemath/sage")
                    (commit version)))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "0k91l3aid09hy94ps2r6acg22bxgsprxnh1b92hma3z1mn0ii3s1"))))
    (build-system python-build-system)
    (arguments
     (list #:tests? #f ; see sagemath-tests
           #:use-setuptools? #f
           #:modules '((guix build python-build-system)
                       (guix build utils)
                       (ice-9 ftw))
           #:phases #~(modify-phases %standard-phases
                        (add-after 'unpack 'prepare-build
                          (lambda _
                            (setenv "SAGE_NUM_THREADS"
                                    (number->string (parallel-job-count)))
                            (setenv "SAGE_VENV" #$output)
                            (chdir "src")))
                        (add-after 'install 'fix-logo-symlinks
                          ;; these symlinks point to /tmp/guix-build-... so we
                          ;; need to recreate them
                          (lambda _
                            (for-each
                             (lambda (file)
                               (let
                                   ((source (string-append "sage/ext_data/notebook-ipython/" file))
                                    (target (string-append #$output "/share/jupyter/kernels/sagemath/" file)))
                                 (delete-file target)
                                 (copy-file source target)))
                             '("logo.svg" "logo-64x64.png"))))
                        (add-after 'install 'delete-nbextensions
                          ;; broken symlink to threejs-sage which we don't
                          ;; even package
                          (lambda _
                            (delete-file-recursively (string-append #$output "/share/jupyter/nbextensions"))))
                        (add-after 'install 'install-missing-files
                          ;; not installed yet for some reason
                          (lambda _
                            (copy-recursively "sage/ext_data"
                                              (string-append #$output "/lib/python3.9/site-packages/sage/ext_data"))
                            (install-file "sage/libs/gap/sage.gaprc"
                                          (string-append #$output "/lib/python3.9/site-packages/sage/libs/gap"))
                            (install-file "sage/interfaces/sage-maxima.lisp"
                                          (string-append #$output "/lib/python3.9/site-packages/sage/interfaces"))))
                        (add-after 'install 'install-bin
                          ;; so far, we have only installed the
                          ;; library part of sage
                          (lambda _
                            (copy-recursively "bin" (string-append #$output "/bin"))
                            ;; we don't need these
                            (delete-file (string-append #$output "/bin/sage-env-config.in"))
                            (delete-file (string-append #$output "/bin/sage-src-env-config.in"))))
                        (add-after 'install-bin 'wrap-bin
                          (lambda _
                            (with-directory-excursion (string-append #$output "/bin")
                              (for-each
                               (lambda (file)
                                 (wrap-program file
                                   `("PATH" ":" suffix (,(string-append #$output "/bin")
                                                        #$(file-append sed "/bin")
                                                        #$(file-append coreutils "/bin")
                                                        #$(file-append python "/bin")))))
                               (scandir "."
                                        ;; select only executables
                                        (lambda (file)
                                          (and (eq? 'regular (stat:type (stat file)))
                                               (access? file X_OK)))))))))))
    (inputs (list arb
                  boost
                  brial
                  cliquer
                  ecl
                  eclib
                  edge-addition-planarity-suite
                  flint
                  gap
                  gd
                  giac
                  givaro
                  glpk
                  gmp
                  gmp-ecm
                  gsl
                  iml
                  lcalc
                  libbraiding
                  libhomfly
                  linbox
                  m4ri
                  m4rie
                  mpc
                  mpfi
                  ntl
                  openblas
                  pari-gp
                  python-cypari2
                  python-gmpy2
                  python-jinja2
                  python-jupyter-core
                  python-memory-allocator
                  python-numpy
                  python-pkgconfig
                  python-pplpy
                  python-setuptools
                  python-wheel
                  rw
                  singular
                  symmetrica
                  zlib
                  zn-poly))
    (native-inputs (list pkg-config python-cython))
    (home-page "https://www.sagemath.org")
    (synopsis "Python-based computer algebra system")
    (description
     "SageMath is a free open-source mathematics software system licensed under the
GPL. It builds on top of many existing open-source packages: NumPy, SciPy,
matplotlib, Sympy, Maxima, GAP, FLINT, R and many more. Access their combined
power through a common, Python-based language or directly via interfaces or
wrappers.")
    (license license:gpl3)))

;;; this propagates all dependencies not needed to build sagemath
(define-public sagemath-with-dependencies
  (package
    (name "sagemath-with-dependencies")
    (version "9.6")
    (source #f)
    (build-system trivial-build-system)
    (arguments
     (list #:modules '((guix build utils))
           #:builder #~(begin
                         (use-modules (guix build utils))

                         (mkdir-p #$output))))
    (propagated-inputs (list cddlib
                             ecl
                             eclib
                             flint
                             flintqs
                             gap
                             gap
                             gcc-toolchain
                             gfan
                             gfortran-toolchain
                             giac
                             gmp-ecm
                             gsl
                             lcalc
                             maxima
                             mpfr
                             nauty
                             ntl
                             openblas
                             palp
                             pari-galdata
                             pari-gp
                             pkg-config
                             python-fpylll
                             python-ipython
                             python-ipywidgets
                             python-lrcalc
                             python-networkx
                             python-pkgconfig
                             python-primecountpy
                             python-scipy
                             python-sympy
                             sagemath-data-combinatorial-designs
                             sagemath-data-conway-polynomials
                             sagemath-data-elliptic-curves
                             sagemath-data-graphs
                             sagemath-data-polytopes-db
                             sagemath-just-build
                             singular
                             tachyon
                             xdg-utils))
    (home-page "")
    (synopsis "")
    (description "")
    (license #f)))

(define-public sagemath-tests
  (package
    (name "sagemath-tests")
    (version "9.6")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://github.com/sagemath/sage")
                    (commit version)))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "0k91l3aid09hy94ps2r6acg22bxgsprxnh1b92hma3z1mn0ii3s1"))))
    (build-system python-build-system)
    (arguments
     (list #:tests? #f
           #:modules '((guix build python-build-system)
                       (guix build utils)
                       (ice-9 ftw))
           #:phases #~(modify-phases %standard-phases
                        (add-after 'unpack 'prepare
                          (lambda _
                            (setenv "MAXIMA_FAS" #$(file-append maxima "/lib/maxima/" (package-version maxima) "/binary-ecl/maxima.fas"))
                            (setenv "COMBINATORIAL_DESIGN_DATA_DIR" #$(file-append sagemath-data-combinatorial-designs "/share/combinatorial_designs"))
                            (setenv "CONWAY_POLYNOMIALS_DATA_DIR" #$(file-append sagemath-data-conway-polynomials "/share/conway_polynomials"))
                            (setenv "ELLCURVE_DATA_DIR" #$(file-append sagemath-data-elliptic-curves "/share/ellcurves"))
                            (setenv "GRAPHS_DATA_DIR" #$(file-append sagemath-data-graphs "/share/graphs"))
                            (setenv "CREMONA_MINI_DATA_DIR" #$(file-append sagemath-data-elliptic-curves "/share/cremona"))
                            (setenv "GAP_SO" #$(file-append gap "/lib/libgap.so"))
                            (setenv "GAP_ROOT_DIR" #$(file-append gap "/share/gap"))
                            (setenv "GP_DATA_DIR" #$(file-append pari-galdata "/share/pari"))
                            (setenv "POLYTOPE_DATA_DIR" #$(file-append sagemath-data-polytopes-db "/share/reflexive_polytopes"))
                            (setenv "HOME" (string-append (getenv "TMPDIR") "/home"))
                            (chdir "src")))
                        (replace 'build
                          (lambda _
                            (invoke #$(file-append sagemath-just-build "/bin/sage")
                                    "-t"
                                    "--nthreads" (number->string (parallel-job-count))
                                    "--all")))
                        (replace 'install
                          (lambda _
                            (with-output-to-file #$output
                              (lambda () (display "")))))
                        (delete 'install-license-files))))
    (native-inputs (list sagemath-with-dependencies))
    (home-page "")
    (synopsis "")
    (description "")
    (license #f)))