[bug#32947] Add java-xalan.

[Maxime Devos <maximedevos@telenet.be>]

[-- Attachment #1.1: Type: text/plain, Size: 1209 bytes --]

Frank Pursel schreef op vr 18-03-2022 om 10:29 [-0700]:
> No, I don't think generate-jar-indices is broken.  The problem is that
> the xalan build is dependent on xml-apis.jar which guix has broken out
> into pieces that are split between the guix builds of xerces and jaxp.
> The index fails because it looks for all the requirements specified in
> the manifest which now must identify xerces and jaxp.  So, those jars
> (jaxp and xerces) now need to be brought over into the outputs(out)
> directory to allow the indexing to succeed.  I don't know if the
> symlinks are required after completion of the indexing but saw no harm
> in it since we need to propagate those inputs anyway or else xalan will
> not be able to find all it's dependencies when called.  I was pleased to
> be able to find all the xml-apis requirements already provided by the
> guix builds of xerces and jaxp.

Ok, seems like due to the changes Guix made to the packaging, the
manifest became incorrect, so that needs to be worked around.  As an
alternative work-around, I've removed the jars from the Class-Path, see
attached package definition.  This seems a little simpler to me, YMMV.

Greetings,
Maxime.

[-- Attachment #1.2: r.scm --]
[-- Type: text/x-scheme, Size: 2879 bytes --]

(use-modules (guix packages) (guix build-system ant) (gnu packages java)(guix download)(gnu packages xml)
  (guix utils)
  ((guix licenses) #:prefix license:))
(define-public java-xalan-interp
  (package
    (name "java-xalan-interp")
    (version "2.7.2")
    (source
     (origin
       (method url-fetch)
       (uri (string-append "mirror://apache/xalan/xalan-j/source/xalan-"
                           (string-replace-substring version "." "_") "-src.tar.gz"))
       (sha256
        (base32 "166vg9i11qzi0vbv09abfb50q8caq8wr6zrwg0cwqws9k394l62w"))
       (modules '((guix build utils)))
       (snippet '(begin
                   ;; Removing bundled jars
                   (format #t "~%~a~%" "Removing Bundled Jars")
                   (for-each
                    (lambda (f)
                      (format #t "~/Deleting: ~a~%" f)
                      (delete-file f))
                    (find-files "." "\\.jar$"))))))
    (build-system ant-build-system)
    (arguments
     `(#:phases (modify-phases
                %standard-phases
                (add-after 'unpack 'prepare-for-build
                  (lambda* (#:key inputs outputs #:allow-other-keys)
                    (setenv "ANT_OPTS" "-Dxsltc.java_cup.not_needed=true")
                    (substitute* "build.xml"
                      ;; Only the interpretive compiler.  xsltc contains a
                      ;; circular reference java_cup.
                      (("(<target name=\"jar\" depends=\"xalan-interpretive.compile),.*"
                        all pre)
                       (string-append pre "\""))
                      (("xml-apis") "jaxp"))
                    (substitute* (list "src/MANIFEST.MF"
                                       "src/manifest.xalan-interpretive"
                                       "src/MANIFEST.SERIALIZER"
                                       "src/manifest.xsltc")
                      ;; This stops the indexing phase from searching for
                      ;; xml-apis in the wrong location -- java-xerces and
                      ;; java-jaxp are propagated, so the eventual Java
                      ;; application package will still have access to it.
                      (("^Class-Path:(.*)$") ""))))
                ;; By default, no jars would be installed.
                (replace 'install
                  (install-jars "build")))))
    (native-inputs (list java-junit java-hamcrest-core))
    (propagated-inputs (list java-jaxp java-xerces))
    (home-page "https://xalan.apache.org/xalan-j/index.html")
    (synopsis "Java XSLT processor")
    (description "XSLT processor in java implementing XSLT Version 1.0, XPath
Version 1.0, and JAXP 1.3.  It builds on SAX2 and DOM level 3.  This version
is the fully functional interpreter, xslt, not the xsltc version which may be
faster.")
    (license license:asl2.0)))
java-xalan-interp

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]