;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2021 Andrew Tropin <andrew@trop.in>
;;; Copyright © 2021 Xinglu Chen <public@yoctocell.xyz>
;;; Copyright © 2022 Taiju HIGASHI <higashi@taiju.info>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu home services fontutils)
  #:use-module (gnu home services)
  #:use-module (gnu packages fontutils)
  #:use-module (gnu services configuration)
  #:use-module (guix diagnostics)
  #:use-module (guix gexp)
  #:use-module (guix i18n)
  #:use-module (guix records)
  #:use-module (srfi srfi-1)
  #:use-module (sxml simple)
  #:use-module (ice-9 match)

  #:export (home-fontconfig-service-type
            home-fontconfig-configuration))

;;; Commentary:
;;;
;;; Services related to fonts.  home-fontconfig service provides
;;; fontconfig configuration, which allows fc-* utilities to find
;;; fonts in Guix Home's profile and regenerates font cache on
;;; activation.
;;;
;;; Code:

(define (sxml->xml-string sxml)
  "Serialize the sxml tree @var{tree} as XML. The output will be string."
  (call-with-output-string
    (lambda (port)
      (sxml->xml sxml port))))

(define guix-home-font-dir "~/.guix-home/profile/share/fonts")

(define (string-list? value)
  (and (pair? value) (every string? value)))

(define (serialize-string-list field-name value)
  (sxml->xml-string
   (map
    (lambda (path) `(dir ,path))
    (if (member guix-home-font-dir value)
        value
        (append (list guix-home-font-dir) value)))))

(define (serialize-string field-name value)
  (define (serialize type value)
    (sxml->xml-string
     `(alias
       (family ,type)
       (prefer
        (family ,value)))))
  (match (list field-name value)
    (('default-font-serif-family family)
     (serialize 'serif family))
    (('default-font-sans-serif-family family)
     (serialize 'sans-serif family))
    (('default-font-monospace-family family)
     (serialize 'monospace family))))

(define-maybe string)

(define extra-config-list? list?)

(define-maybe extra-config-list)

(define (serialize-extra-config-list field-name value)
  (sxml->xml-string
   (map (match-lambda
          ((? pair? sxml) sxml)
          ((? string? xml) (xml->sxml xml))
          (else
           (raise (formatted-message
                   (G_ "'extra-config' type must be xml string or sxml list, was given: ~a")
                   value))))
        value)))

(define-configuration home-fontconfig-configuration
  (font-directories
   (string-list (list guix-home-font-dir))
   "The directory list that provides fonts.")
  (default-font-serif-family
    maybe-string
    "The preffered default fonts of serif.")
  (default-font-sans-serif-family
    maybe-string
    "The preffered default fonts of sans-serif.")
  (default-font-monospace-family
    maybe-string
    "The preffered default fonts of monospace.")
  (extra-config
   maybe-extra-config-list
   "Extra configuration values to append to the fonts.conf."))

(define (add-fontconfig-config-file user-config)
  `(("fontconfig/fonts.conf"
     ,(mixed-text-file
       "fonts.conf"
       "<?xml version='1.0'?>
<!DOCTYPE fontconfig SYSTEM 'fonts.dtd'>
<fontconfig>"
       (serialize-configuration user-config home-fontconfig-configuration-fields)
       "</fontconfig>\n"))))

(define (regenerate-font-cache-gexp _)
  `(("profile/share/fonts"
     ,#~(system* #$(file-append fontconfig "/bin/fc-cache") "-fv"))))

(define home-fontconfig-service-type
  (service-type (name 'home-fontconfig)
                (extensions
                 (list (service-extension
                        home-xdg-configuration-files-service-type
                        add-fontconfig-config-file)
                       (service-extension
                        home-run-on-change-service-type
                        regenerate-font-cache-gexp)
                       (service-extension
                        home-profile-service-type
                        (const (list fontconfig)))))
                (default-value (home-fontconfig-configuration))
                (description
                 "Provides configuration file for fontconfig and make
fc-* utilities aware of font packages installed in Guix Home's profile.")))