unofficial mirror of guix-patches@gnu.org 
 help / color / mirror / code / Atom feed
* [bug#59739] [PATCH] tests: Add gdm test.
@ 2022-12-01 13:20 mirai
  2022-12-04 22:07 ` bug#59739: " Ludovic Courtès
  0 siblings, 1 reply; 2+ messages in thread
From: mirai @ 2022-12-01 13:20 UTC (permalink / raw)
  To: 59739; +Cc: Bruno Victal

From: Bruno Victal <mirai@makinata.eu>

* gnu/tests/gdm.scm: New file.
* gnu/local.mk: Register it.
---

Small test suite for investigating the issue 57589 (https://issues.guix.gnu.org/57589)
basing on the hint at reply #6.


 gnu/local.mk      |   1 +
 gnu/tests/gdm.scm | 126 ++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 127 insertions(+)
 create mode 100644 gnu/tests/gdm.scm

diff --git a/gnu/local.mk b/gnu/local.mk
index 379e600b06..be6870b469 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -759,6 +759,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/tests/docker.scm				\
   %D%/tests/file-sharing.scm			\
   %D%/tests/ganeti.scm				\
+  %D%/tests/gdm.scm				\
   %D%/tests/guix.scm				\
   %D%/tests/monitoring.scm                      \
   %D%/tests/nfs.scm				\
diff --git a/gnu/tests/gdm.scm b/gnu/tests/gdm.scm
new file mode 100644
index 0000000000..137e70544e
--- /dev/null
+++ b/gnu/tests/gdm.scm
@@ -0,0 +1,126 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2022 Bruno Victal <mirai@makinata.eu>.
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu tests gdm)
+  #:use-module (gnu tests)
+  #:use-module (gnu packages freedesktop)
+  #:use-module (gnu services)
+  #:use-module (gnu services desktop)
+  #:use-module (gnu services xorg)
+  #:use-module (gnu system)
+  #:use-module (gnu system file-systems)
+  #:use-module (gnu system vm)
+  #:use-module (guix gexp)
+  #:use-module (ice-9 format)
+  #:export (%test-gdm-x11
+            %test-gdm-wayland
+            %test-gdm-wayland-tmpfs))
+
+(define* (make-os #:key wayland? tmp-tmpfs?)
+  (operating-system
+    (inherit %simple-os)
+    (services
+     (modify-services %desktop-services
+       (gdm-service-type config => (gdm-configuration
+                                    (inherit config)
+                                    (wayland? wayland?)))))
+    (file-systems (if tmp-tmpfs? (cons (file-system
+                                         (mount-point "/tmp")
+                                         (device "none")
+                                         (type "tmpfs")
+                                         (flags '(no-dev no-suid))
+                                         (check? #f))
+                                       %base-file-systems)
+                      %base-file-systems))))
+
+(define* (run-gdm-test #:key wayland? tmp-tmpfs?)
+  "Run tests in a vm which has gdm running."
+  (define os
+    (marionette-operating-system
+     (make-os #:wayland? wayland? #:tmp-tmpfs? tmp-tmpfs?)
+     #:imported-modules '((gnu services herd))))
+
+  (define vm
+    (virtual-machine
+     (operating-system os)
+     (memory-size 1024)))
+
+  (define name (format #f "gdm-~:[x11~;wayland~]~:[~;-tmpfs~]" wayland? tmp-tmpfs?))
+
+  (define test
+    (with-imported-modules '((gnu build marionette))
+      #~(begin
+          (use-modules (gnu build marionette)
+                       (ice-9 format)
+                       (srfi srfi-64))
+
+          (let* ((marionette (make-marionette (list #$vm)))
+                 (expected-session-type #$(if wayland? "wayland" "x11")))
+
+            (test-runner-current (system-test-runner #$output))
+            (test-begin #$name)
+
+            ;; service for gdm is called xorg-server
+            (test-assert "service is running"
+              (marionette-eval
+               '(begin
+                  (use-modules (gnu services herd))
+                  (start-service 'xorg-server))
+               marionette))
+
+            (test-assert "gdm ready"
+              (wait-for-file "/var/run/gdm/gdm.pid" marionette))
+
+            (test-equal (string-append "session-type is " expected-session-type)
+              expected-session-type
+              (marionette-eval
+               '(begin
+                  (use-modules (ice-9 popen)
+                               (ice-9 rdelim))
+
+                  (let* ((loginctl #$(file-append elogind "/bin/loginctl"))
+                         (get-session-cmd (string-join `(,loginctl "show-user" "gdm"
+                                                                   "--property Display" "--value")))
+                         (session (call-with-port (open-input-pipe get-session-cmd) read-line))
+                         (get-type-cmd (string-join `(,loginctl "show-session" ,session
+                                                                "--property Type" "--value")))
+                         (type (call-with-port (open-input-pipe get-type-cmd) read-line)))
+                    type))
+               marionette))
+
+            (test-end)))))
+
+  (gexp->derivation (string-append name "-test") test))
+
+(define %test-gdm-x11
+  (system-test
+   (name "gdm")
+   (description "Basic tests for the GDM service. (X11)")
+   (value (run-gdm-test))))
+
+(define %test-gdm-wayland
+  (system-test
+   (name "gdm")
+   (description "Basic tests for the GDM service. (Wayland)")
+   (value (run-gdm-test #:wayland? #t))))
+
+(define %test-gdm-wayland-tmpfs
+  (system-test
+   (name "gdm")
+   (description "Basic tests for the GDM service. (Wayland, /tmp as tmpfs)")
+   (value (run-gdm-test #:wayland? #t #:tmp-tmpfs? #t))))

base-commit: a712c07d6ada1160855c583556e854ccb48c47e1
-- 
2.38.1





^ permalink raw reply related	[flat|nested] 2+ messages in thread

* bug#59739: [PATCH] tests: Add gdm test.
  2022-12-01 13:20 [bug#59739] [PATCH] tests: Add gdm test mirai
@ 2022-12-04 22:07 ` Ludovic Courtès
  0 siblings, 0 replies; 2+ messages in thread
From: Ludovic Courtès @ 2022-12-04 22:07 UTC (permalink / raw)
  To: mirai; +Cc: 59739-done

[-- Attachment #1: Type: text/plain, Size: 428 bytes --]

Hello,

mirai@makinata.eu skribis:

> From: Bruno Victal <mirai@makinata.eu>
>
> * gnu/tests/gdm.scm: New file.
> * gnu/local.mk: Register it.
> ---
>
> Small test suite for investigating the issue 57589 (https://issues.guix.gnu.org/57589)
> basing on the hint at reply #6.

Excellent!  The tests all had the same name; I fixed that so I could
actually run them all (see below).

Applied, thanks!

Ludo’.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: Type: text/x-patch, Size: 766 bytes --]

diff --git a/gnu/tests/gdm.scm b/gnu/tests/gdm.scm
index 137e70544e..4f67551e63 100644
--- a/gnu/tests/gdm.scm
+++ b/gnu/tests/gdm.scm
@@ -109,18 +109,18 @@ (define test
 
 (define %test-gdm-x11
   (system-test
-   (name "gdm")
+   (name "gdm-x11")
    (description "Basic tests for the GDM service. (X11)")
    (value (run-gdm-test))))
 
 (define %test-gdm-wayland
   (system-test
-   (name "gdm")
+   (name "gdm-wayland")
    (description "Basic tests for the GDM service. (Wayland)")
    (value (run-gdm-test #:wayland? #t))))
 
 (define %test-gdm-wayland-tmpfs
   (system-test
-   (name "gdm")
+   (name "gdm-wayland-tmpfs")
    (description "Basic tests for the GDM service. (Wayland, /tmp as tmpfs)")
    (value (run-gdm-test #:wayland? #t #:tmp-tmpfs? #t))))

^ permalink raw reply related	[flat|nested] 2+ messages in thread

end of thread, other threads:[~2022-12-04 22:09 UTC | newest]

Thread overview: 2+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2022-12-01 13:20 [bug#59739] [PATCH] tests: Add gdm test mirai
2022-12-04 22:07 ` bug#59739: " Ludovic Courtès

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/guix.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).