;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2014, 2015, 2016, 2017, 2019 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2021, 2022 Maxime Devos <maximedevos@telenet.be>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (guix tests http)
  #:use-module (ice-9 threads)
  #:use-module (web server)
  #:use-module (web server http)
  #:use-module (web response)
  #:use-module (srfi srfi-11)
  #:use-module (srfi srfi-39)
  #:use-module (ice-9 match)
  #:export (with-http-server
            with-http-server/keep-lingering
            with-http-server*
            call-with-http-server
            call-with-http-server*
            %http-server-port
            %local-url*
            %local-url))

;;; Commentary:
;;;
;;; Code to spawn a Web server for testing purposes.
;;;
;;; Code:

(define %http-server-port
  ;; TCP port to use for the stub HTTP server.
  ;; If 0, the OS will automatically choose
  ;; a port.
  (make-parameter 0))

(define (open-http-server-socket)
  "Return a listening socket for the web server and the port
actually listened at (in case %http-server-port was 0)."
  (catch 'system-error
    (lambda ()
      (let ((sock (socket PF_INET SOCK_STREAM 0)))
        (setsockopt sock SOL_SOCKET SO_REUSEADDR 1)
        (bind sock
              (make-socket-address AF_INET INADDR_LOOPBACK
                                   (%http-server-port)))
        (values sock
                (sockaddr:port (getsockname sock)))))
    (lambda args
      (let ((err (system-error-errno args)))
        (format (current-error-port)
                "warning: cannot run Web server for tests: ~a~%"
                (strerror err))
        (values #f #f)))))

(define* (%local-url* resource #:optional (port (%http-server-port)))
  ;; The URL to the resource named RESOURCE on the current HTTP server.
  (when (= port 0)
    (error "no web server is running!"))
  (string-append "http://localhost:" (number->string port) resource))
(define* (%local-url #:optional (port (%http-server-port)))
  ;; URL to use for 'home-page' tests.
  (%local-url* "/foo/bar" port))

(define* (call-with-http-server* handle thunk #:key (keep-lingering? #false)
                                 (last-response? (const #false)))
  "Call THUNK with an HTTP server running and responding to HTTP requests
with HANDLE (see (guile)Web Server).

%http-server-port will be set to the port listened at
The port listened at will be set for the dynamic extent of THUNK.
The server will quit after THUNK returns, unless KEEP-LINGERING? is true.
It will also quit if LAST-RESPONSE? returns true."
  (define (http-write server client response body)
    "Write RESPONSE."
    (let* ((response (write-response response client))
           (port     (response-port response)))
      (cond
       ((not body))                               ;pass
       (else
        (write-response-body response body)))
      (close-port port)
      (when (last-response?)
        (throw 'quit))
      (values)))

  ;; Mutex and condition variable to synchronize with the HTTP server.
  (define %http-server-lock (make-mutex))
  (define %http-server-ready (make-condition-variable))
  (define %http-real-server-port #f)

  (define (http-open . args)
    "Start listening for HTTP requests and signal %HTTP-SERVER-READY."
    (with-mutex %http-server-lock
      (let ((result (apply (@@ (web server http) http-open) args)))
        (signal-condition-variable %http-server-ready)
        result)))

  (define-server-impl stub-http-server
    ;; Stripped-down version of Guile's built-in HTTP server.
    http-open
    (@@ (web server http) http-read)
    http-write
    (@@ (web server http) http-close))

  (define (server-body)
    (let-values (((socket port) (open-http-server-socket)))
      (set! %http-real-server-port port)
      (catch 'quit
        (lambda ()
          ;; HANDLE might want to include the port in its responses,
          ;; so set %http-server-port here as well.
          (parameterize ((%http-server-port port))
            (run-server handle stub-http-server
                        `(#:socket ,socket))))
        (lambda _
          (close-port socket)))))

  (with-mutex %http-server-lock
    (let ((server (make-thread server-body)))
      (wait-condition-variable %http-server-ready %http-server-lock)
      ;; Normally SERVER exits automatically once it has received a request.
      (let-values ((results
                    (parameterize ((%http-server-port %http-real-server-port))
                      (thunk))))
        (unless keep-lingering?
          ;; exit the server thread
          (system-async-mark (lambda () (throw 'quit)) server))
        (apply values results)))))


(define* (call-with-http-server responses+data thunk #:key (keep-lingering? #false))
  "Call THUNK with an HTTP server running and returning RESPONSES+DATA
on HTTP requests.  Each element of RESPONSES+DATA must be a tuple containing a
response and a string, or an HTTP response code and a string.

The argument RESPONSES+DATA is thunked.  As such, RESPONSES+DATA can use
%http-server-port.  %http-server-port will be set to the port listened at.
It will be set for the dynamic extent of THUNK and RESPONSES+DATA.

The server will exit after the last response.  When KEEP-LINGERING? is false,
the server will also exit after THUNK returns."
  (define (responses)
    (map (match-lambda
           (((? response? response) data)
            (list response data))
           (((? integer? code) data)
            (list (build-response #:code code
                                  #:reason-phrase "Such is life")
                  data)))
         (responses+data)))
  (define (handle request body)
    (match (responses)
      (((response data) rest ...)
       (set! responses (const rest))
       (values response data))))
  (call-with-http-server* handle thunk #:keep-lingering? keep-lingering?
                          #:last-response?
                          (lambda () (null? (responses)))))

(define-syntax with-http-server
  (syntax-rules ()
    ((_ responses+data body ...)
     (call-with-http-server (lambda () responses+data) (lambda () body ...)))))

(define-syntax with-http-server/keep-lingering
  (syntax-rules ()
    ((_ responses+data body ...)
     (call-with-http-server (lambda () responses+data) (lambda () body ...)
                            #:keep-lingering? #true))))

(define-syntax with-http-server*
  (syntax-rules ()
    ((_ handle body ...)
     (call-with-http-server* handle (lambda () body ...)))))

;;; http.scm ends here