unofficial mirror of guix-patches@gnu.org 
 help / color / mirror / code / Atom feed
* [bug#43976] [PATCH] Chicken build system + some example eggs
@ 2020-10-13  8:52 raingloom
  2020-10-18 16:10 ` Ludovic Courtès
  0 siblings, 1 reply; 12+ messages in thread
From: raingloom @ 2020-10-13  8:52 UTC (permalink / raw)
  To: 43976

[-- Attachment #1: Type: text/plain, Size: 1022 bytes --]

Here it is, chicken-build-system.

# What works
Building eggs, dependencies, importing them from search path.

# What's broken
Cross-compilation has not been attempted beacuse the Go build system I
based this on does not support it either.

# Necessary improvements
The Go build system removes some references. I was not sure if this is
needed for Chicken, so for now I left it out.

# Eggs
Some were selected because I'll need for the 9p egg, the rest because
the agrep egg was the first one I found that had dependencies, so it
was selected as a perfect test case.
I don't know if all eggs will work. Eggs that bind to native libraries
(like SDL) still need to be tested.

## SRFI-14 licensing
SRFI-14 has a weird license. The metadata says it's "BSD" but it's
clearly not BSD. I'm not sure what it is or if it's compatible with
Guix. If not, we could probably contact the authors and ask them to
relicense it.

# Chicken 4
Not attempted. Nix supports it but it's old and looks mostly abandoned.
I think we can skip it.

[-- Attachment #2: 0001-gnu-Added-search-paths-for-Chicken-Scheme.patch --]
[-- Type: text/x-patch, Size: 1267 bytes --]

From 502235505c75446758cc1932bd1ba333644423ca Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Mon, 12 Oct 2020 04:11:59 +0200
Subject: [PATCH 01/11] gnu: Added search paths for Chicken Scheme.

* gnu/packages/chicken.scm (chicken): Added search paths
  [native-search-paths]: added CHICKEN_REPOSITORY_PATH and CHICKEN_INCLUDE_PATH
---
 gnu/packages/chicken.scm | 8 ++++++++
 1 file changed, 8 insertions(+)

diff --git a/gnu/packages/chicken.scm b/gnu/packages/chicken.scm
index 7b86a58012..0dd5571eec 100644
--- a/gnu/packages/chicken.scm
+++ b/gnu/packages/chicken.scm
@@ -59,6 +59,14 @@
 
        ;; Parallel builds are not supported, as noted in README.
        #:parallel-build? #f))
+    (native-search-paths
+     (list (search-path-specification
+            (variable "CHICKEN_REPOSITORY_PATH")
+            ;; TODO extract binary version into a module level definition.
+            (files (list "var/lib/chicken/11")))
+           (search-path-specification
+            (variable "CHICKEN_INCLUDE_PATH")
+            (files '("share")))))
     (propagated-inputs `(("gcc-toolchain", gcc-toolchain)))
     (home-page "https://www.call-cc.org/")
     (synopsis "R5RS Scheme implementation that compiles native code via C")
-- 
2.28.0


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #3: 0002-guix-Added-chicken-build-system.patch --]
[-- Type: text/x-patch, Size: 11985 bytes --]

From a734e591ad066c20a53f9d0f955716ba8422bac5 Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Tue, 13 Oct 2020 09:26:52 +0200
Subject: [PATCH 02/11] guix: Added chicken-build-system.

* guix/build-system/chicken.scm: New file.
* guix/build/chicken-build-system.scm: New file.
* Makefile.am: Add them.
---
 Makefile.am                         |   2 +
 guix/build-system/chicken.scm       | 137 ++++++++++++++++++++++++++++
 guix/build/chicken-build-system.scm | 103 +++++++++++++++++++++
 3 files changed, 242 insertions(+)
 create mode 100644 guix/build-system/chicken.scm
 create mode 100644 guix/build/chicken-build-system.scm

diff --git a/Makefile.am b/Makefile.am
index 8e91e1e558..a2b2ca1093 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -113,6 +113,7 @@ MODULES =					\
   guix/build-system/android-ndk.scm		\
   guix/build-system/ant.scm			\
   guix/build-system/cargo.scm			\
+  guix/build-system/chicken.scm			\
   guix/build-system/clojure.scm			\
   guix/build-system/cmake.scm			\
   guix/build-system/dub.scm			\
@@ -162,6 +163,7 @@ MODULES =					\
   guix/build/download-nar.scm			\
   guix/build/cargo-build-system.scm		\
   guix/build/cargo-utils.scm			\
+  guix/build/chicken-build-system.scm		\
   guix/build/cmake-build-system.scm		\
   guix/build/dub-build-system.scm		\
   guix/build/dune-build-system.scm		\
diff --git a/guix/build-system/chicken.scm b/guix/build-system/chicken.scm
new file mode 100644
index 0000000000..b1629b9929
--- /dev/null
+++ b/guix/build-system/chicken.scm
@@ -0,0 +1,137 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2020 raingloom <raingloom@riseup.net>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build-system chicken)
+  #:use-module (guix utils)
+  #:use-module (guix derivations)
+  #:use-module (guix search-paths)
+  #:use-module (guix build-system)
+  #:use-module (guix build-system gnu)
+  #:use-module (guix packages)
+  #:use-module (ice-9 match)
+  #:export (%chicken-build-system-modules
+            chicken-build
+            chicken-build-system))
+
+(define %chicken-build-system-modules
+  ;; Build-side modules imported and used by default.
+  `((guix build chicken-build-system)
+    (guix build union)
+    ,@%gnu-build-system-modules))
+
+(define (default-chicken)
+  ;; Lazily resolve the binding to avoid a circular dependency.
+  ;; TODO is this actually needed in every build system?
+  (let ((chicken (resolve-interface '(gnu packages chicken))))
+      (module-ref chicken 'chicken)))
+
+(define* (lower name
+                #:key source inputs native-inputs outputs system target
+                (chicken (default-chicken))
+                #:allow-other-keys
+                #:rest arguments)
+  "Return a bag for NAME."
+  (define private-keywords
+    '(#:source #:target #:chicken #:inputs #:native-inputs))
+
+  ;; TODO: cross-compilation support
+  (and (not target)
+       (bag
+         (name name)
+         (system system)
+         (host-inputs `(,@(if source
+                              `(("source" ,source))
+                              '())
+                        ,@inputs
+
+                        ;; Keep the standard inputs of 'gnu-build-system'.
+                        ;; Chicken compiles Scheme by using C as an intermediate language.
+                        ,@(standard-packages)))
+         (build-inputs `(("chicken" ,chicken)
+                         ,@native-inputs))
+         (outputs outputs)
+         (build chicken-build)
+         (arguments (strip-keyword-arguments private-keywords arguments)))))
+
+(define* (chicken-build store name inputs
+                   #:key
+                   (phases '(@ (guix build chicken-build-system)
+                               %standard-phases))
+                   (outputs '("out"))
+                   (search-paths '())
+                   (install-source? #t)
+                   (egg-name "")
+                   (unpack-path "")
+                   (build-flags ''())
+                   (tests? #t)
+                   ;; TODO holdover from go.scm
+                   ;; not yet sure if it should be removed.
+                   (allow-chicken-reference? #f)
+                   (system (%current-system))
+                   (guile #f)
+                   (imported-modules %chicken-build-system-modules)
+                   (modules '((guix build chicken-build-system)
+                              (guix build union)
+                              (guix build utils))))
+  (define builder
+    `(begin
+       (use-modules ,@modules)
+       (chicken-build #:name ,name
+                 #:source ,(match (assoc-ref inputs "source")
+                             (((? derivation? source))
+                              (derivation->output-path source))
+                             ((source)
+                              source)
+                             (source
+                              source))
+                 #:system ,system
+                 #:phases ,phases
+                 #:outputs %outputs
+                 #:search-paths ',(map search-path-specification->sexp
+                                       search-paths)
+                 #:install-source? ,install-source?
+                 #:egg-name ,egg-name
+                 #:unpack-path ,unpack-path
+                 #:build-flags ,build-flags
+                 #:tests? ,tests?
+                 #:allow-chicken-reference? ,allow-chicken-reference?
+                 #:inputs %build-inputs)))
+
+  (define guile-for-build
+    (match guile
+      ((? package?)
+       (package-derivation store guile system #:graft? #f))
+      (#f                                         ; the default
+       (let* ((distro (resolve-interface '(gnu packages commencement)))
+              (guile  (module-ref distro 'guile-final)))
+         (package-derivation store guile system
+                             #:graft? #f)))))
+
+  (build-expression->derivation store name builder
+                                #:inputs inputs
+                                #:system system
+                                #:modules imported-modules
+                                #:outputs outputs
+                                #:guile-for-build guile-for-build))
+
+(define chicken-build-system
+  (build-system
+    (name 'chicken)
+    (description
+     "Build system for Chicken Scheme programs")
+    (lower lower)))
diff --git a/guix/build/chicken-build-system.scm b/guix/build/chicken-build-system.scm
new file mode 100644
index 0000000000..ee2b15d6c1
--- /dev/null
+++ b/guix/build/chicken-build-system.scm
@@ -0,0 +1,103 @@
+(define-module (guix build chicken-build-system)
+  #:use-module ((guix build gnu-build-system) #:prefix gnu:)
+  #:use-module (guix build union)
+  #:use-module (guix build utils)
+  #:use-module (ice-9 match)
+  #:use-module (ice-9 ftw)
+  #:use-module (srfi srfi-1)
+  #:use-module (srfi srfi-26)
+  #:use-module (rnrs io ports)
+  #:use-module (rnrs bytevectors)
+  #:export (%standard-phases
+            chicken-build))
+
+;; CHICKEN_EGG_CACHE is where sources are fetched and binaries are built
+;; CHICKEN_INSTALL_REPOSITORY is where dependencies are looked up
+;; its first component is also where new eggs are installed.
+
+;; TODO: deduplicate with go-build-system.scm ?
+;; TODO: the binary version should be defined in one of the relevant modules
+;; instead of being hardcoded everywhere. Tried to do that but got undefined
+;; variable errors.
+
+(define (chicken-package? name)
+  (string-prefix? "chicken-" name))
+
+(define* (setup-chicken-environment #:key inputs outputs #:allow-other-keys)
+  (setenv "CHICKEN_INSTALL_REPOSITORY"
+          (string-concatenate
+           ;; see TODO item about binary version above
+           (append (list (assoc-ref outputs "out") "/var/lib/chicken/11/")
+                   (let ((oldenv (getenv "CHICKEN_INSTALL_REPOSITORY")))
+                     (if oldenv
+                         (list  ":" oldenv)
+                         '())))))
+  (setenv "CHICKEN_EGG_CACHE" (getcwd))
+  #t)
+
+;; This is copied from go-build-system.scm so it could probably be simplified.
+;; I used it because the source of the egg needs to be unpacked into a directory
+;; that is named after the egg and I knew that the go build system does that.
+(define* (unpack #:key source egg-name unpack-path #:allow-other-keys)
+  "Relative to $CHICKEN_EGG_CACHE, unpack SOURCE in UNPACK-PATH, or EGG-NAME
+when UNPACK-PATH is unset.  If the SOURCE archive has a single top level
+directory, it is stripped so that the sources appear directly under UNPACK-PATH.
+When SOURCE is a directory, copy its content into UNPACK-PATH instead of
+unpacking."
+  (define (unpack-maybe-strip source dest)
+    (let* ((scratch-dir (string-append (or (getenv "TMPDIR") "/tmp")
+                                       "/scratch-dir"))
+           (out (mkdir-p scratch-dir)))
+      (with-directory-excursion scratch-dir
+        (if (string-suffix? ".zip" source)
+            (invoke "unzip" source)
+            (invoke "tar" "-xvf" source))
+        (let ((top-level-files (remove (lambda (x)
+                                         (member x '("." "..")))
+                                       (scandir "."))))
+          (match top-level-files
+            ((top-level-file)
+             (when (file-is-directory? top-level-file)
+               (copy-recursively top-level-file dest #:keep-mtime? #t)))
+            (_
+             (copy-recursively "." dest #:keep-mtime? #t)))))
+      (delete-file-recursively scratch-dir)))
+
+  (when (string-null? egg-name)
+    (display "WARNING: The egg name is unset.\n"))
+  (when (string-null? unpack-path)
+    (set! unpack-path egg-name))
+  (let ((dest (string-append (getenv "CHICKEN_EGG_CACHE") "/" unpack-path)))
+    (mkdir-p dest)
+    (if (file-is-directory? source)
+        (copy-recursively source dest #:keep-mtime? #t)
+        (unpack-maybe-strip source dest)))
+  #t)
+
+(define* (build #:key egg-name #:allow-other-keys)
+  "Build the Chicken egg named by EGG-NAME"
+  (invoke "chicken-install" "-cached" "-no-install" egg-name))
+
+(define* (install #:key egg-name outputs #:allow-other-keys)
+  "Install the already built egg named by EGG-NAME"
+  (invoke "chicken-install" "-cached" egg-name))
+
+;; TODO how do we run tests???
+
+;; TODO remove references
+
+(define %standard-phases
+  (modify-phases gnu:%standard-phases
+    (replace 'unpack unpack)
+    (delete 'bootstrap)
+    (delete 'configure)
+    (delete 'patch-generated-file-shebangs)
+    (add-before 'unpack 'setup-chicken-environment setup-chicken-environment)
+    (replace 'build build)
+    (delete 'check)
+    (replace 'install install)))
+
+(define* (chicken-build #:key inputs (phases %standard-phases)
+                       #:allow-other-keys #:rest args)
+  "Build the given Chicken package, applying all of PHASES in order."
+  (apply gnu:gnu-build #:inputs inputs #:phases phases args))
-- 
2.28.0


[-- Attachment #4: 0003-gnu-Use-qualified-license-names-in-chicken.scm-inste.patch --]
[-- Type: text/x-patch, Size: 1110 bytes --]

From 8a03cdcda02988384fd3a2e6e36adf0713264311 Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Tue, 13 Oct 2020 09:49:35 +0200
Subject: [PATCH 03/11] gnu: Use qualified license names in chicken.scm instead
 of selective import.

* gnu/packages/chicken.scm (chicken)[license]: Use qualified name.
---
 gnu/packages/chicken.scm | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/gnu/packages/chicken.scm b/gnu/packages/chicken.scm
index 0dd5571eec..567e043741 100644
--- a/gnu/packages/chicken.scm
+++ b/gnu/packages/chicken.scm
@@ -24,7 +24,7 @@
   #:use-module (guix download)
   #:use-module (gnu packages commencement)
   #:use-module ((guix licenses)
-                #:select (bsd-3)))
+                #:prefix license:))
 
 (define-public chicken
   (package
@@ -74,4 +74,4 @@
      "CHICKEN is a compiler for the Scheme programming language.  CHICKEN
 produces portable and efficient C, supports almost all of the R5RS Scheme
 language standard, and includes many enhancements and extensions.")
-    (license bsd-3)))
+    (license license:bsd-3)))
-- 
2.28.0


[-- Attachment #5: 0004-gnu-Added-imports-for-chicken-eggs.patch --]
[-- Type: text/x-patch, Size: 927 bytes --]

From a7e3b91b76625e01eed749c2c83a94862e3ef738 Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Tue, 13 Oct 2020 09:55:42 +0200
Subject: [PATCH 04/11] gnu: Added imports for chicken eggs.

* gnu/packages/chicken.scm: New module imports.
---
 gnu/packages/chicken.scm | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/gnu/packages/chicken.scm b/gnu/packages/chicken.scm
index 567e043741..b9738c4737 100644
--- a/gnu/packages/chicken.scm
+++ b/gnu/packages/chicken.scm
@@ -20,8 +20,11 @@
 (define-module (gnu packages chicken)
   #:use-module (gnu packages)
   #:use-module (guix packages)
+  #:use-module (guix build-system chicken)
   #:use-module (guix build-system gnu)
   #:use-module (guix download)
+  #:use-module (guix git-download)
+  #:use-module (guix svn-download)
   #:use-module (gnu packages commencement)
   #:use-module ((guix licenses)
                 #:prefix license:))
-- 
2.28.0


[-- Attachment #6: 0005-gnu-Added-chicken-srfi-1.patch --]
[-- Type: text/x-patch, Size: 1712 bytes --]

From 3cbb676b118c2db197b0d2b621cbcb5133e09fd9 Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Tue, 13 Oct 2020 09:51:02 +0200
Subject: [PATCH 05/11] gnu: Added chicken-srfi-1.

* gnu/packages/chicken.scm (chicken-srfi-1): New variable.
---
 gnu/packages/chicken.scm | 29 +++++++++++++++++++++++++++++
 1 file changed, 29 insertions(+)

diff --git a/gnu/packages/chicken.scm b/gnu/packages/chicken.scm
index b9738c4737..d937ec7044 100644
--- a/gnu/packages/chicken.scm
+++ b/gnu/packages/chicken.scm
@@ -78,3 +78,32 @@
 produces portable and efficient C, supports almost all of the R5RS Scheme
 language standard, and includes many enhancements and extensions.")
     (license license:bsd-3)))
+
+(define-public chicken-srfi-1
+  (package
+    (name "chicken-srfi-1")
+    (version "0.5.1")
+    (source
+     (origin
+       (method svn-fetch)
+       (uri (svn-reference
+             (url (string-append
+                   "https://code.call-cc.org/svn/chicken-eggs/"
+                   "release/5/srfi-1/tags/"
+                   version))
+             (revision 39055)
+             (user-name "anonymous")
+             (password "")))
+       (file-name "srfi-1")
+       (sha256
+        (base32
+         "02940zsjrmn7c34rnp1rllm2nahh9jvszlzrw8ak4pf31q09cmq1"))))
+    (build-system chicken-build-system)
+    (arguments '(#:egg-name "srfi-1"))
+    (home-page "http://wiki.call-cc.org/eggref/5/srfi-1")
+    (synopsis "SRFI-1 list library")
+    (description
+     "The list library defined in SRFI-1 contains a lot of useful list
+processing procedures for construction, examining, destructuring and
+manipulating lists and pairs.")
+    (license license:bsd-3)))
-- 
2.28.0


[-- Attachment #7: 0006-gnu-Added-chicken-srfi-69.patch --]
[-- Type: text/x-patch, Size: 1633 bytes --]

From f564a2ac0e3c716347245b90fe8c7d4332b91889 Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Tue, 13 Oct 2020 09:52:08 +0200
Subject: [PATCH 06/11] gnu: Added chicken-srfi-69

* gnu/packages/chicken.scm (chicken-srfi-69): New variable.
---
 gnu/packages/chicken.scm | 25 +++++++++++++++++++++++++
 1 file changed, 25 insertions(+)

diff --git a/gnu/packages/chicken.scm b/gnu/packages/chicken.scm
index d937ec7044..b8878685fa 100644
--- a/gnu/packages/chicken.scm
+++ b/gnu/packages/chicken.scm
@@ -107,3 +107,28 @@ language standard, and includes many enhancements and extensions.")
 processing procedures for construction, examining, destructuring and
 manipulating lists and pairs.")
     (license license:bsd-3)))
+
+(define-public chicken-srfi-69
+  (package
+    (name "chicken-srfi-69")
+    (version "0.4.1")
+    (source
+     (origin
+       (method svn-fetch)
+       (uri (svn-reference
+             (url (string-append "https://code.call-cc.org/svn/chicken-eggs/"
+                                 "release/5/srfi-69/tags/"
+                                 version))
+             (revision 39057)
+             (user-name "anonymous")
+             (password "")))
+       (sha256
+        (base32
+         "1z0m9vmg9bj9z0a941pls6igvg8nmhq4mj5psjjidbp0fac572mp"))))
+    (arguments '(#:egg-name "srfi-69"))
+    (build-system chicken-build-system)
+    (home-page "http://wiki.call-cc.org/eggref/5/srfi-69")
+    (synopsis "An implementation of SRFI 69 with SRFI 90 extensions")
+    (description
+     "Hash table implementation and binary search")
+    (license license:bsd-3)))
-- 
2.28.0


[-- Attachment #8: 0007-gnu-Added-chicken-iset.patch --]
[-- Type: text/x-patch, Size: 1527 bytes --]

From 062e1ba3e468df07115bd022130d577132d13a41 Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Tue, 13 Oct 2020 09:52:54 +0200
Subject: [PATCH 07/11] gnu: Added chicken-iset.

* gnu/packages/chicken.scm (chicken-iset): New variable.
---
 gnu/packages/chicken.scm | 25 +++++++++++++++++++++++++
 1 file changed, 25 insertions(+)

diff --git a/gnu/packages/chicken.scm b/gnu/packages/chicken.scm
index b8878685fa..7462431ba4 100644
--- a/gnu/packages/chicken.scm
+++ b/gnu/packages/chicken.scm
@@ -132,3 +132,28 @@ manipulating lists and pairs.")
     (description
      "Hash table implementation and binary search")
     (license license:bsd-3)))
+
+(define-public chicken-iset
+  (package
+    (name "chicken-iset")
+    (version "2.2")
+    (source
+     (origin
+       (method svn-fetch)
+       (uri (svn-reference
+             (url (string-append "https://code.call-cc.org/svn/chicken-eggs/"
+                                 "release/5/iset/tags/" version))
+             (revision 39057)
+             (user-name "anonymous")
+             (password "")))
+       (sha256
+        (base32
+         "0gz50n5i561n5sk9prry0lrxz6bfrq9if5bclaq6a0f7lzinhnzb"))))
+    (build-system chicken-build-system)
+    (arguments '(#:egg-name "iset"))
+    (synopsis "Integer set library")
+    (home-page "http://wiki.call-cc.org/eggref/5/iset")
+    (description
+     " Bit-vectors provide an abstract interface to bitwise operations
+typically done with integers")
+    (license license:bsd-3)))
-- 
2.28.0


[-- Attachment #9: 0008-gnu-Added-chicken-datatype.patch --]
[-- Type: text/x-patch, Size: 1665 bytes --]

From bb4c402ff458239a9270680d1b7032182fcab5df Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Tue, 13 Oct 2020 09:53:40 +0200
Subject: [PATCH 08/11] gnu: Added chicken-datatype.

* gnu/packages/chicken.scm (chicken-datatype): New variable.
---
 gnu/packages/chicken.scm | 25 +++++++++++++++++++++++++
 1 file changed, 25 insertions(+)

diff --git a/gnu/packages/chicken.scm b/gnu/packages/chicken.scm
index 7462431ba4..fcd5f242f4 100644
--- a/gnu/packages/chicken.scm
+++ b/gnu/packages/chicken.scm
@@ -157,3 +157,28 @@ manipulating lists and pairs.")
      " Bit-vectors provide an abstract interface to bitwise operations
 typically done with integers")
     (license license:bsd-3)))
+
+(define-public chicken-datatype
+  (package
+    (name "chicken-datatype")
+    (version "1.6")
+    (source
+     (origin
+       (method svn-fetch)
+       (uri (svn-reference
+             (url (string-append "https://code.call-cc.org/svn/chicken-eggs/"
+                                 "release/5/datatype/tags/" version))
+             (revision 39057)
+             (user-name "anonymous")
+             (password "")))
+       (sha256
+        (base32
+         "1a58q8ypjkjz6wdv25247wixds4179239d36nnvsfn6gp70s9jfq"))))
+    (build-system chicken-build-system)
+    (arguments '(#:egg-name "datatype"))
+    (home-page "http://wiki.call-cc.org/eggref/5/datatype")
+    (synopsis "A facility for creating and using variant records")
+    (description
+     "A facility for creating and using variant records, as described
+in the book Essentials of Programming Languages by Friedman, Wand and Haynes")
+    (license license:bsd-3)))
-- 
2.28.0


[-- Attachment #10: 0009-gnu-Added-chicken-srfi-14.patch --]
[-- Type: text/x-patch, Size: 1764 bytes --]

From f20607f28be8bd050407e0ae582db7c03285dbb2 Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Tue, 13 Oct 2020 09:24:12 +0200
Subject: [PATCH 09/11] gnu: Added chicken-srfi-14.

* gnu/packages/chicken.scm (chicken-srfi-14): New variable.
---
 gnu/packages/chicken.scm | 27 +++++++++++++++++++++++++++
 1 file changed, 27 insertions(+)

diff --git a/gnu/packages/chicken.scm b/gnu/packages/chicken.scm
index fcd5f242f4..4229d0b21f 100644
--- a/gnu/packages/chicken.scm
+++ b/gnu/packages/chicken.scm
@@ -108,6 +108,33 @@ processing procedures for construction, examining, destructuring and
 manipulating lists and pairs.")
     (license license:bsd-3)))
 
+(define-public chicken-srfi-14
+  (package
+    (name "chicken-srfi-14")
+    (version "0.2.1")
+    (source
+     (origin
+       (method svn-fetch)
+       (uri (svn-reference
+             (url (string-append "https://code.call-cc.org/svn/chicken-eggs/"
+                                 "release/5/srfi-14/tags/" version))
+             (revision 39057)
+             (user-name "anonymous")
+             (password "")))
+       (sha256
+        (base32
+         "0wjsqfwawh9bx6vvii1gwag166bxkflc0ib374fbws14914g2ac1"))))
+    (build-system chicken-build-system)
+    (arguments '(#:egg-name "srfi-14"))
+    (home-page "http://wiki.call-cc.org/eggref/5/srfi-14")
+    (synopsis "Character set library")
+    (description
+     "Character sets can be created, extended, tested for the membership of
+a characters and be compared to other character sets")
+    (license (license:non-copyleft
+              "file://srfi-14.scm"
+              "See end of srfi-14.scm in the distribution."))))
+
 (define-public chicken-srfi-69
   (package
     (name "chicken-srfi-69")
-- 
2.28.0


[-- Attachment #11: 0010-gnu-Added-chicken-agrep.patch --]
[-- Type: text/x-patch, Size: 1829 bytes --]

From aaef438dd04f85305c50f50003d0f17082bfb83c Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Tue, 13 Oct 2020 09:54:39 +0200
Subject: [PATCH 10/11] gnu: Added chicken-agrep.

* gnu/packages/chicken.scm (chicken-agrep): New variable.
---
 gnu/packages/chicken.scm | 29 +++++++++++++++++++++++++++++
 1 file changed, 29 insertions(+)

diff --git a/gnu/packages/chicken.scm b/gnu/packages/chicken.scm
index 4229d0b21f..09f51a10af 100644
--- a/gnu/packages/chicken.scm
+++ b/gnu/packages/chicken.scm
@@ -209,3 +209,32 @@ typically done with integers")
      "A facility for creating and using variant records, as described
 in the book Essentials of Programming Languages by Friedman, Wand and Haynes")
     (license license:bsd-3)))
+
+(define-public chicken-agrep
+  (package
+    (name "chicken-agrep")
+    (version "1.7")
+    (source
+     (origin
+       (method git-fetch)
+       (uri (git-reference
+             (url "https://github.com/iraikov/chicken-agrep")
+             (commit version)))
+       (sha256
+        (base32
+         "0z05x7f154n9bgmainrsmncf5i6dil43r9ymr3rdgwbg4wnxmz4s"))))
+    ;; TODO do we really have to make these propagated?
+    ;; I don't know Chicken's module system well enough to tell
+    (propagated-inputs
+     `(("chicken-datatype" ,chicken-datatype)
+       ("chicken-srfi-1" ,chicken-srfi-1)
+       ("chicken-srfi-14" ,chicken-srfi-14)))
+    (build-system chicken-build-system)
+    (arguments '(#:egg-name "agrep"))
+    (synopsis "Approximate string matching library")
+    (home-page "http://wiki.call-cc.org/eggref/5/agrep")
+    (description
+     "This library implements the Wu-Manber algorithm for string searching
+with errors, popularized by the agrep Unix command and the glimpse file
+indexing tool.")
+    (license license:gpl3+)))
-- 
2.28.0


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #12: 0011-gnu-Added-myself-to-chicken.scm-copyright.patch --]
[-- Type: text/x-patch, Size: 772 bytes --]

From 52a27d11eb3d4d0ced3deda01fe901bf2f1937fd Mon Sep 17 00:00:00 2001
From: raingloom <raingloom@riseup.net>
Date: Mon, 12 Oct 2020 04:19:46 +0200
Subject: [PATCH 11/11] gnu: Added myself to chicken.scm copyright.

---
 gnu/packages/chicken.scm | 1 +
 1 file changed, 1 insertion(+)

diff --git a/gnu/packages/chicken.scm b/gnu/packages/chicken.scm
index 09f51a10af..378449582c 100644
--- a/gnu/packages/chicken.scm
+++ b/gnu/packages/chicken.scm
@@ -1,6 +1,7 @@
 ;;; GNU Guix --- Functional package management for GNU
 ;;; Copyright © 2020 Ekaitz Zarraga <ekaitz@elenq.tech>
 ;;; Copyright © 2020 Evan Hanson <evhan@foldling.org>
+;;; Copyright © 2020 raingloom <raingloom@riseup.net>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
-- 
2.28.0


^ permalink raw reply related	[flat|nested] 12+ messages in thread

end of thread, other threads:[~2020-12-03 16:06 UTC | newest]

Thread overview: 12+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2020-10-13  8:52 [bug#43976] [PATCH] Chicken build system + some example eggs raingloom
2020-10-18 16:10 ` Ludovic Courtès
2020-11-20  4:51   ` raingloom
2020-11-21 11:23     ` Ludovic Courtès
2020-11-21 20:45     ` raingloom
2020-11-21 20:58       ` Efraim Flashner
2020-11-21 22:13         ` raingloom
2020-11-22 23:12       ` raingloom
2020-11-24 20:22         ` raingloom
2020-11-27  9:09           ` Ludovic Courtès
2020-12-01  4:14             ` raingloom
2020-12-03 16:04               ` bug#43976: " Ludovic Courtès

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/guix.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).