;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2022 (unmatched parenthesis <paren@disroot.org>
;;; Copyright © 2022 Antero Mejr <antero@mailbox.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu packages hare)
  #:use-module (gnu packages base)
  #:use-module (gnu packages c)
  #:use-module (gnu packages man)
  #:use-module (guix build-system gnu)
  #:use-module (guix download)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix gexp)
  #:use-module (guix git-download)
  #:use-module (guix packages)
  #:use-module (guix platform)
  #:use-module (guix utils))

(define-public harec
  (let ((commit "bbabe09bddf74bd699f8ad2224fdd6e2eefbd35e") (revision "0"))
    (package
      (name "harec")
      (version (git-version "0.0.0" revision commit))
      (source (origin
                (method git-fetch)
                (uri (git-reference
                      (url "https://git.sr.ht/~sircmpwn/harec")
                      (commit commit)))
                (file-name (git-file-name name version))
                (sha256
                 (base32
                  "0sa8rjj5w01n55svql8drv761ks6i1bl9q4gj1yzr31dixaf6xvr"))))
      (build-system gnu-build-system)
      (arguments
       (list #:configure-flags #~(list (string-append "--prefix=" #$output))
             #:phases #~(modify-phases %standard-phases
                          (replace 'configure
                            (lambda* (#:key outputs
                                      (configure-flags '()) #:allow-other-keys)
                              (setenv "AR" #$(ar-for-target))
                              (setenv "AS" #$(as-for-target))
                              (setenv "CC" #$(cc-for-target))
                              (setenv "LD" #$(ld-for-target))
                              (setenv "QBE" (string-append #$qbe "/bin/qbe"))
                              (apply invoke "./configure" configure-flags))))))
      (inputs (list qbe))
      (home-page "https://harelang.org")
      (synopsis "Hare bootstrap compiler in C")
      (description "This package provides @code{harec}, the Hare language's
bootstrap written in C.  Currently, the self-hosting @code{harec} rewrite is
incomplete, so this is used as the default compiler in the build driver.")
      (license license:gpl3))))

(define-public hare
  (let ((commit "19e380ccb7dfe2bcab5f94e6bd03004e3e2c6005") (revision "0"))
    (package
      (name "hare")
      (version (git-version "0.0.0" revision commit))
      (source (origin
                (method git-fetch)
                (uri (git-reference
                      (url "https://git.sr.ht/~sircmpwn/hare")
                      (commit commit)))
                (file-name (git-file-name name version))
                (sha256
                 (base32
                  "04fk3akj3410f8fxw2ixp6l6f9x54pnnk00c0hx0297p7hdzzzq4"))))
      (build-system gnu-build-system)
      (arguments
       (list #:make-flags
             #~(list (string-append "BINDIR=" #$output "/bin")
                     (string-append "MANDIR=" #$output "/share/man")
                     (string-append "SRCDIR=" #$output "/src")
                     (string-append "LOCALSRCDIR=" #$output "/src/hare")
                     (string-append "HAREC=" #$harec "/bin/harec")
                     (string-append "PLATFORM=" "linux")
                     (string-append "HAREPATH="
                                    #$output "/src/hare/stdlib:"
                                    #$output "/src/hare/third-party")
                     (string-append "ARCH="
                                    #$(platform-linux-architecture
                                       (lookup-platform-by-target-or-system
                                        (or (%current-target-system)
                                            (%current-system)))))
                     (string-append "AR=" #$(ar-for-target))
                     (string-append "AS=" #$(as-for-target))
                     (string-append "LD=" #$(ld-for-target))
                     (string-append "QBE=" #$qbe "/bin/qbe")
                     (string-append "SCDOC=" #$scdoc "/bin/scdoc")
                     "HARECACHE=.cache"
                     "BINOUT=.bin")
             #:phases
             #~(modify-phases %standard-phases
                 (add-after 'unpack 'patch-failing-tests
                   (lambda _
                     ;; These tests fail due to a NaN-related bug in QBE when
                     ;; used on glibc.
                     (substitute* "math/complex/+test.ha"
                       (("@test (fn (cos|cosh|exp)\\(\\) void =)" _ func)
                        func))))
                 (add-after 'unpack 'patch-makefile
                   (lambda _
                     (substitute* "Makefile"
                       (("include config.mk") ""))))
                 (delete 'configure))))
      (native-inputs (list scdoc))
      (inputs (list tzdata))
      (propagated-inputs (list binutils harec qbe))
      (supported-systems (list "x86_64-linux" "aarch64-linux" "riscv64-linux"))
      (native-search-paths
       (list (search-path-specification
              (variable "HAREPATH")
              (files '("src/hare/stdlib" "src/hare/third-party")))))
      (home-page "https://harelang.org")
      (synopsis "Systems programming language")
      (description "Hare is a systems programming language that aims to improve
on C while retaining its core philosophy. Its principles are:
@itemize
@item Trust the programmer.
@item Provide tools the programmer may use when they don't trust themselves.
@item Prefer explicit behavior over implicit behavior.
@item A good program must be both correct and simple.
@end itemize")
      (license (list license:gpl3 ;compiler and build driver
                     license:mpl2.0))))) ;standard library