From: Maxime Devos <maximedevos@telenet.be>
To: "Ludovic Courtès" <ludo@gnu.org>
Cc: 50384@debbugs.gnu.org
Subject: [bug#50384] [PATCH v2] Optimise search-patch (reducing I/O)
Date: Sun, 05 Sep 2021 21:48:22 +0200 [thread overview]
Message-ID: <0ec7f0270fcccec730808f9210f074cd5339961f.camel@telenet.be> (raw)
In-Reply-To: <87tuj0xaja.fsf@gnu.org>
[-- Attachment #1.1: Type: text/plain, Size: 9561 bytes --]
Ludovic Courtès schreef op zo 05-09-2021 om 00:04 [+0200]:
> Maxime Devos <maximedevos@telenet.be> skribis:
>
> > +(define-syntax search-patch
> > + (lambda (s)
> > + "Search the patch FILE-NAME and compute its hash at expansion time
> > +if possible. Return #f if not found."
> > + (syntax-case s ()
> > + ((_ file-name)
> > + (string? (syntax->datum #'file-name))
> > + ;; FILE-NAME is a constant string, so the hash can be computed
> > + ;; in advance.
> > + (let ((patch (try-search-patch (syntax->datum #'file-name))))
> > + (if patch
> > + #`(%local-patch-file file-name #,(file-hash* patch #:select? true))
> > + (begin
> > + (warning (source-properties->location
> > + (syntax-source #'file-name))
> > + (G_ "~a: patch not found at expansion time")
> > + (syntax->datum #'ile-name))
> > + #'(%search-patch file-name)))))
> > + ;; FILE-NAME is variable, so the hash cannot be pre-computed.
> > + ((_ file-name) #'(%search-patch file-name))
> > + ;; search-patch is being used used in a construct like
> > + ;; (map search-patch ...).
> > + (id (identifier? #'id) #'%search-patch))))
>
> It’s clever… but also a bit evil, in that it changes the semantics of
> package files in a surprising way. Modifying foo.patch without
> recompiling foo.scm would lead you to still use the old foo.patch, which
> can be rather off-putting and error-prone IMO.
I added two patches adding (limited) dependency tracking to compile-all.scm.
If a patch file is now modified or deleted, the corresponding package modules
will be recompiled. This should remove the ‘evilness’ I think.
> To address this, ‘local-file’ could store the inode/mtime + computed
> store file name (rather than the SHA256). ‘local-file-compiler’ would
> check whether the actual file has matching inode/mtime before returning
> the computed store file name. Problem is that inode/mtime are
> guaranteed to differ once you’ve run “make install”. :-/
An additional problem is that 'local-file-compiler' would have to 'stat'
the file even if it is already in the store, undoing the (fairly limited?)
performance gains of this patch series.
The dependency tracking avoids this.
> Intuitively, I’d have imagined a cache populated at run time; it would
> map, say, file name/inode/mtime to a store file name. ‘add-to-store’
> (or some wrapper above it) would check the cache and return the store
> file name directly, unless ‘valid-path?’ says it no longer exists.
> Downside is that this would be a per-user cache and you’d still pay the
> cost until it’s warm. Advantage is that you could easily tell whether
> it’s stale.
>
> Thoughts?
Intuitively, I'd have imagined doing as much as possible at compilation time.
The cost at compilation is only paid once (or, more correctly, at every
"guix pull"), while if you delay things until runtime, you need to check the
caches.
With this patch series (+ the two patches mentioned previously), the ‘cache’
is always fresh (though possibly not warm: the patch might not yet be in the
store).
Ludovic Courtès schreef op za 04-09-2021 om 23:47 [+0200]:
> Hi!
>
> Some initial comments…
>
> Maxime Devos <maximedevos@telenet.be> skribis:
>
> > +++ b/guix/gexp.scm
> > @@ -531,13 +531,37 @@ appears."
> > (define-gexp-compiler (local-file-compiler (file <local-file>) system target)
> > [...]
> > + (if sha256
> > + (let ((path (fixed-output-path name sha256 #:recursive? recursive?)))
> > + ;; If the hash is known in advance and the store already has the
> > + ;; item, there is no need to intern the file.
> > + (if (file-exists? path)
> > + (mbegin %store-monad
> > + ;; Tell the GC that PATH will be used, such that it won't
> > + ;; be deleted.
> > + ((store-lift add-temp-root) path)
> > + ;; The GC could have deleted the item before add-temp-root
> > + ;; completed, so check again if PATH exists.
> > + (if (file-exists? path)
> > + (return path)
> > + ;; If it has been removed, fall-back interning.
> > + (intern)))
> > + ;; If PATH does not yet exist, fall back to interning.
> > + (intern)))
> > + (intern))))))
>
> ‘file-exists?’ won’t work when talking to a remote store (e.g.,
> GUIX_DAEMON_SOCKET=ssh://…).
>
> ‘add-temp-root’ doesn’t throw if the given store item does not exist.
> So it could be written like this:
>
> (if sha256
> (mbegin %store-monad
> (add-temp-root* item)
> (if (valid-path?* item)
> (return item)
> (intern)))
> (intern))
Done in the v2.
> But then, we’d add one RPC for every ‘add-to-store’ RPC corresponding to
> a patch (you can set “GUIX_PROFILING=rpc” to see the numbers), which is
> not great.
>
> Ludo’.
Note that 'intern' is only called if the patch isn't yet in the store.
In practice, the patch is almost always already in the store. For example,
suppose I have a few packages in my profile. As the packages are in my
profile, they had to have their derivation computed at some point, so the
corresponding patches had to be interned.
If I now run "guix pull && guix package -u", when computing the derivation
of the updated profile, most required patches are already in the store,
because patches don't change often.
Likewise, if I run "guix environment guix" in one terminal, then in another,
then in yet another ... possibly for the first invocation, some patches need
to be interned, but for the other invocations, it's already in the store.
Because fixed-output-path is now called more often, I've added a patch
optimising (guix base32).
Let's compare the numbers again! This time, I've run
echo powersave |sudo tee /sys/devices/system/cpu/cpufreq/policy{0,1,2,3}/scaling_governor
to make sure the CPU frequency doesn't change. On a hot (disk) cache:
# After the patch series
time GUIX_PROFILING="rpc gc" ./the-optimised-guix/bin/guix build -d --no-grafts pigx
Remote procedure call summary: 5949 RPCs
built-in-builders ... 1
add-to-store ... 3
add-to-store/tree ... 26
add-temp-root ... 195
valid-path? ... 195
add-text-to-store ... 5529
Garbage collection statistics:
heap size: 93.85 MiB
allocated: 312.04 MiB
GC times: 17
time spent in GC: 3.34 seconds (25% of user time)
# averaged over three runs
real 0m14,035s
user 0m14,138s
sys 0m0,650s
# Before the patch series
time GUIX_PROFILING="rpc gc" ./the-unoptimised-guix/bin/guix build -d --no-grafts pigx
/gnu/store/fq6x8d2vcm6sbjkimg7g8kcgb4c5xv1b-pigx-0.0.3.drv
Remote procedure call summary: 5749 RPCs
built-in-builders ... 1
add-to-store/tree ... 26
add-to-store ... 193
add-text-to-store ... 5529
Garbage collection statistics:
heap size: 93.85 MiB
allocated: 325.24 MiB
GC times: 18
time spent in GC: 3.66 seconds (26% of user time)
real 0m13,700s
user 0m14,051s
sys 0m0,658s
So on a hot disk cache, there doesn't appear to be any improvement
(except for ‘time spent in GC’ -- presumably that's due to the optimisations
to guix/base32.scm).
What about a cold cache?
# After the patch series
sync && echo 3 | sudo tee /proc/sys/vm/drop_caches
./the-optimised-guix/bin/guix --help
time GUIX_PROFILING="rpc gc" ./the-optimised-guix/bin/guix build -d --no-grafts pigx
/gnu/store/fq6x8d2vcm6sbjkimg7g8kcgb4c5xv1b-pigx-0.0.3.drv
Remote procedure call summary: 5949 RPCs
built-in-builders ... 1
add-to-store ... 3
add-to-store/tree ... 26
add-temp-root ... 195
valid-path? ... 195
add-text-to-store ... 5529
Garbage collection statistics:
heap size: 93.85 MiB
allocated: 312.03 MiB
GC times: 17
time spent in GC: 3.37 seconds (23% of user time)
real 1m39,178s
user 0m14,557s
sys 0m0,990s
# Before the patch series
sync && echo 3 | sudo tee /proc/sys/vm/drop_caches
./the-unoptimised-guix/bin/guix --help
time GUIX_PROFILING="rpc gc" ./the-unoptimised-guix/bin/guix build -d --no-grafts pigx
Remote procedure call summary: 5749 RPCs
built-in-builders ... 1
add-to-store/tree ... 26
add-to-store ... 193
add-text-to-store ... 5529
Garbage collection statistics:
heap size: 93.85 MiB
allocated: 325.25 MiB
GC times: 18
time spent in GC: 3.63 seconds (25% of user time)
real 1m42,100s
user 0m14,690s
sys 0m1,127s
It seems that if the disk cache is cold, the time-to-derivation decreases
a little by this patch series. Much less than I had hoped for though; I'll
have to look into other areas for interesting performance gains ...
Greetings,
Maxime.
[-- Attachment #1.2: v2-0001-build-self-Implement-basic-hash-algorithm.patch --]
[-- Type: text/x-patch, Size: 1863 bytes --]
From a8e24a5258aa05689bcafa70af071da5296f63a4 Mon Sep 17 00:00:00 2001
From: Maxime Devos <maximedevos@telenet.be>
Date: Sat, 4 Sep 2021 20:09:03 +0200
Subject: [PATCH v2 1/9] build-self: Implement basic 'hash-algorithm'.
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit
The module (guix hash) used from 'search-patch' in a future
patch needs it to be properly defined when (guix hash) is being
compiled. 'search-patch' is used when the derivation of Guix is
being computed, so it is important to avoid the ‘wrong type to
apply: #<syntax-transformer hash-algorithm>’ error.
* build-aux/build-self.scm
(build-program)[fake-gcrypt-hash]: Define hash-algorithm for sha1
and sha256.
---
build-aux/build-self.scm | 13 +++++++++++--
1 file changed, 11 insertions(+), 2 deletions(-)
diff --git a/build-aux/build-self.scm b/build-aux/build-self.scm
index 3a2d13cc09..2c13d9d530 100644
--- a/build-aux/build-self.scm
+++ b/build-aux/build-self.scm
@@ -259,8 +259,17 @@ interface (FFI) of Guile.")
(define fake-gcrypt-hash
;; Fake (gcrypt hash) module; see below.
(scheme-file "hash.scm"
- #~(define-module (gcrypt hash)
- #:export (sha1 sha256))))
+ #~(begin
+ (define-module (gcrypt hash)
+ #:export (sha1 sha256 hash-algorithm))
+ ;; Avoid ‘Wrong type to apply:
+ ;; #<syntax-transformer hash-algorithm>’ errors.
+ (define sha1)
+ (define sha256)
+ (define-syntax hash-algorithm
+ (syntax-rules (sha1 sha256)
+ ((_ sha1) 2)
+ ((_ sha256) 8))))))
(define fake-git
(scheme-file "git.scm" #~(define-module (git))))
--
2.33.0
[-- Attachment #1.3: v2-0002-guix-hash-Extract-file-hashing-procedures.patch --]
[-- Type: text/x-patch, Size: 5554 bytes --]
From c38cae11df08a57b5a3f483601b6482c379a0749 Mon Sep 17 00:00:00 2001
From: Sarah Morgensen <iskarian@mgsn.dev>
Date: Sun, 15 Aug 2021 16:25:24 -0700
Subject: [PATCH v2 2/9] guix hash: Extract file hashing procedures.
* guix/scripts/hash.scm (guix-hash)[vcs-file?, file-hash]: Extract logic
to...
* guix/hash.scm: ...here. New file.
* Makefile.am (MODULES): Add new file.
---
Makefile.am | 1 +
guix/hash.scm | 51 +++++++++++++++++++++++++++++++++++++++++++
guix/scripts/hash.scm | 29 ++++++------------------
3 files changed, 59 insertions(+), 22 deletions(-)
create mode 100644 guix/hash.scm
diff --git a/Makefile.am b/Makefile.am
index 327d3f9961..8f8089c05c 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -107,6 +107,7 @@ MODULES = \
guix/narinfo.scm \
guix/derivations.scm \
guix/grafts.scm \
+ guix/hash.scm \
guix/repl.scm \
guix/transformations.scm \
guix/inferior.scm \
diff --git a/guix/hash.scm b/guix/hash.scm
new file mode 100644
index 0000000000..8c2ab8187f
--- /dev/null
+++ b/guix/hash.scm
@@ -0,0 +1,51 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2021 Sarah Morgensen <iskarian@mgsn.dev>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix hash)
+ #:use-module (gcrypt hash)
+ #:use-module (guix serialization)
+ #:use-module (srfi srfi-1)
+ #:use-module (srfi srfi-11)
+ #:export (vcs-file?
+ file-hash*))
+
+(define (vcs-file? file stat)
+ "Returns true if FILE is a version control system file."
+ (case (stat:type stat)
+ ((directory)
+ (member (basename file) '(".bzr" ".git" ".hg" ".svn" "CVS")))
+ ((regular)
+ ;; Git sub-modules have a '.git' file that is a regular text file.
+ (string=? (basename file) ".git"))
+ (else
+ #f)))
+
+(define* (file-hash* file #:key
+ (algorithm (hash-algorithm sha256))
+ (recursive? #t)
+ (select? (negate vcs-file?)))
+ "Compute the hash of FILE with ALGORITHM. If RECURSIVE? is true, recurse
+into subdirectories of FILE, computing the combined hash of all files for
+which (SELECT? FILE STAT) returns true."
+ (if recursive?
+ (let-values (((port get-hash)
+ (open-hash-port algorithm)))
+ (write-file file port #:select? select?)
+ (force-output port)
+ (get-hash))
+ (file-hash algorithm file)))
diff --git a/guix/scripts/hash.scm b/guix/scripts/hash.scm
index b8622373cc..353ca30c2c 100644
--- a/guix/scripts/hash.scm
+++ b/guix/scripts/hash.scm
@@ -3,6 +3,7 @@
;;; Copyright © 2013 Nikita Karetnikov <nikita@karetnikov.org>
;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
;;; Copyright © 2018 Tim Gesthuizen <tim.gesthuizen@yahoo.de>
+;;; Copyright © 2021 Sarah Morgensen <iskarian@mgsn.dev>
;;;
;;; This file is part of GNU Guix.
;;;
@@ -23,6 +24,7 @@
#:use-module (gcrypt hash)
#:use-module (guix serialization)
#:use-module (guix ui)
+ #:use-module (guix hash)
#:use-module (guix scripts)
#:use-module (guix base16)
#:use-module (guix base32)
@@ -125,16 +127,6 @@ and 'base16' ('hex' and 'hexadecimal' can be used as well).\n"))
(parse-command-line args %options (list %default-options)
#:build-options? #f))
- (define (vcs-file? file stat)
- (case (stat:type stat)
- ((directory)
- (member (basename file) '(".bzr" ".git" ".hg" ".svn" "CVS")))
- ((regular)
- ;; Git sub-modules have a '.git' file that is a regular text file.
- (string=? (basename file) ".git"))
- (else
- #f)))
-
(let* ((opts (parse-options))
(args (filter-map (match-lambda
(('argument . value)
@@ -150,18 +142,11 @@ and 'base16' ('hex' and 'hexadecimal' can be used as well).\n"))
;; Compute the hash of FILE.
;; Catch and gracefully report possible '&nar-error' conditions.
(with-error-handling
- (if (assoc-ref opts 'recursive?)
- (let-values (((port get-hash)
- (open-hash-port (assoc-ref opts 'hash-algorithm))))
- (write-file file port #:select? select?)
- (force-output port)
- (get-hash))
- (match file
- ("-" (port-hash (assoc-ref opts 'hash-algorithm)
- (current-input-port)))
- (_ (call-with-input-file file
- (cute port-hash (assoc-ref opts 'hash-algorithm)
- <>)))))))
+ (match file
+ ("-" (port-hash (assoc-ref opts 'hash-algorithm)
+ (current-input-port)))
+ (_ (file-hash* #:algorithm (assoc-ref opts 'hash-algorithm)
+ #:recursive? (assoc-ref opts 'recursive?))))))
(match args
((file)
--
2.33.0
[-- Attachment #1.4: v2-0003-gexp-Allow-computing-the-hash-of-the-local-file-i.patch --]
[-- Type: text/x-patch, Size: 3317 bytes --]
From e5dc46800597023dfc1c9d53cc6e0db2f3999022 Mon Sep 17 00:00:00 2001
From: Maxime Devos <maximedevos@telenet.be>
Date: Sat, 4 Sep 2021 15:35:51 +0200
Subject: [PATCH v2 3/9] gexp: Allow computing the hash of the local file in
advance.
The new field is currently unused. The following patches will
populate and use the field to reduce the time-to-derivation
when the file is already interned in the store.
* guix/gexp.scm
(<local-file>): Add sha256 field.
(%local-file): Add sha256 argument for populating the field.
(local-file-compiler): Adjust 'match' expression.
---
guix/gexp.scm | 12 ++++++++----
1 file changed, 8 insertions(+), 4 deletions(-)
diff --git a/guix/gexp.scm b/guix/gexp.scm
index f3d278b3e6..a633984688 100644
--- a/guix/gexp.scm
+++ b/guix/gexp.scm
@@ -419,13 +419,16 @@ Here TARGET is bound to the cross-compilation triplet or #f."
;; A local file name. FILE is the file name the user entered, which can be a
;; relative file name, and ABSOLUTE is a promise that computes its canonical
;; absolute file name. We keep it in a promise to compute it lazily and avoid
-;; repeated 'stat' calls.
+;; repeated 'stat' calls. Allow computing the hash of the file in advance,
+;; to avoid having to send the file to the daemon when it is already interned
+;; in the store.
(define-record-type <local-file>
- (%%local-file file absolute name recursive? select?)
+ (%%local-file file absolute name sha256 recursive? select?)
local-file?
(file local-file-file) ;string
(absolute %local-file-absolute-file-name) ;promise string
(name local-file-name) ;string
+ (sha256 local-file-sha256) ;sha256 bytevector | #f
(recursive? local-file-recursive?) ;Boolean
(select? local-file-select?)) ;string stat -> Boolean
@@ -434,6 +437,7 @@ Here TARGET is bound to the cross-compilation triplet or #f."
(define* (%local-file file promise #:optional (name (basename file))
#:key
(literal? #t) location
+ sha256
recursive? (select? true))
;; This intermediate procedure is part of our ABI, but the underlying
;; %%LOCAL-FILE is not.
@@ -441,7 +445,7 @@ Here TARGET is bound to the cross-compilation triplet or #f."
(warning (and=> location source-properties->location)
(G_ "resolving '~a' relative to current directory~%")
file))
- (%%local-file file promise name recursive? select?))
+ (%%local-file file promise name sha256 recursive? select?))
(define (absolute-file-name file directory)
"Return the canonical absolute file name for FILE, which lives in the
@@ -517,7 +521,7 @@ appears."
(define-gexp-compiler (local-file-compiler (file <local-file>) system target)
;; "Compile" FILE by adding it to the store.
(match file
- (($ <local-file> file (= force absolute) name recursive? select?)
+ (($ <local-file> file (= force absolute) name sha256 recursive? select?)
;; Canonicalize FILE so that if it's a symlink, it is resolved. Failing
;; to do that, when RECURSIVE? is #t, we could end up creating a dangling
;; symlink in the store, and when RECURSIVE? is #f 'add-to-store' would
--
2.33.0
[-- Attachment #1.5: v2-0004-gexp-Allow-overriding-the-absolute-file-name.patch --]
[-- Type: text/x-patch, Size: 2453 bytes --]
From 8a64ac78767013e82f26cfddae951a8ef2e2caf8 Mon Sep 17 00:00:00 2001
From: Maxime Devos <maximedevos@telenet.be>
Date: Sat, 4 Sep 2021 16:25:22 +0200
Subject: [PATCH v2 4/9] gexp: Allow overriding the absolute file name.
This will be used by the next patch to implement search-patch in
terms of local-file.
* guix/gexp.scm
(precanonicalized-file-name): New macro.
(local-file): Use the absolute file name from precanonicalized-file-name
when available.
---
guix/gexp.scm | 12 +++++++++++-
1 file changed, 11 insertions(+), 1 deletion(-)
diff --git a/guix/gexp.scm b/guix/gexp.scm
index a633984688..c69e4aa299 100644
--- a/guix/gexp.scm
+++ b/guix/gexp.scm
@@ -51,6 +51,7 @@
gexp-input-output
gexp-input-native?
+ precanonicalized-file-name
assume-valid-file-name
local-file
local-file?
@@ -463,6 +464,12 @@ the given file name is valid, even if it's not a string literal, and thus not
warn about it."
file)
+(define-syntax-rule (precanonicalized-file-name file absolute)
+ "This is a syntactic keyword to tell 'local-file' that it can assume that
+the given file name FILE has ABSOLUTE as absolute file name and 'local-file'
+does not need to compute the absolute file name by itself."
+ absolute)
+
(define-syntax local-file
(lambda (s)
"Return an object representing local file FILE to add to the store; this
@@ -481,7 +488,7 @@ where FILE is the entry's absolute file name and STAT is the result of
This is the declarative counterpart of the 'interned-file' monadic procedure.
It is implemented as a macro to capture the current source directory where it
appears."
- (syntax-case s (assume-valid-file-name)
+ (syntax-case s (assume-valid-file-name precanonicalized-file-name)
((_ file rest ...)
(string? (syntax->datum #'file))
;; FILE is a literal, so resolve it relative to the source directory.
@@ -495,6 +502,9 @@ appears."
#'(%local-file file
(delay (absolute-file-name file (getcwd)))
rest ...))
+ ((_ (precanonicalized-file-name file absolute) rest ...)
+ ;; Use the given file name ABSOLUTE as absolute file name.
+ #'(%local-file file (delay absolute) rest ...))
((_ file rest ...)
;; Resolve FILE relative to the current directory.
(with-syntax ((location (datum->syntax s (syntax-source s))))
--
2.33.0
[-- Attachment #1.6: v2-0005-packages-Compute-the-hash-of-patches-in-advance-w.patch --]
[-- Type: text/x-patch, Size: 9376 bytes --]
From 737d7fb8e18c4e6e4db1d82455211ee5bdfae14d Mon Sep 17 00:00:00 2001
From: Maxime Devos <maximedevos@telenet.be>
Date: Sat, 4 Sep 2021 17:25:58 +0200
Subject: [PATCH v2 5/9] packages: Compute the hash of patches in advance when
possible.
* gnu/packages.scm
(search-patch): Rename to ...
(%search-patch): ... this.
(try-search-patch): New procedure, extracted from ...
(%search-patch): ... this procedure.
(%local-patch-file): New procedure.
(true): New procedure.
(search-patch): New macro, behaving like %search-patch, but computing the
hash at expansion time when possible.
* gnu/packages/chromium.scm
(%guix-patches): Use search-patches instead of local-file +
assume-valid-file-name + search-patch.
* gnu/packages/gnuzilla.scm
(icecat-source)[gnuzilla-fixes-patch]: Use search-patch instead of
local-file + assule-valid-file-name + search-patch.
(icecat-source)[makeicecat-patch]: Likewise.
* gnu/packages/embedded.scm
(gcc-arm-none-eabi-4.9)[source]{patches}: Expect patches to be
local-file objects instead of strings.
of strings.
* guix/lint.scm (check-patch-file-names): Allow local-file objects.
---
gnu/packages.scm | 42 +++++++++++++++++++++++++++++++++++++--
gnu/packages/chromium.scm | 4 +---
gnu/packages/embedded.scm | 3 ++-
gnu/packages/gnuzilla.scm | 8 ++------
guix/lint.scm | 28 ++++++++++++++++----------
5 files changed, 62 insertions(+), 23 deletions(-)
diff --git a/gnu/packages.scm b/gnu/packages.scm
index ccfc83dd11..f5552e5a9b 100644
--- a/gnu/packages.scm
+++ b/gnu/packages.scm
@@ -4,6 +4,7 @@
;;; Copyright © 2014 Eric Bavier <bavier@member.fsf.org>
;;; Copyright © 2016, 2017 Alex Kost <alezost@gmail.com>
;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
+;;; Copyright © 2021 Maxime Devos <maximedevos@telenet.be>
;;;
;;; This file is part of GNU Guix.
;;;
@@ -21,11 +22,13 @@
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu packages)
+ #:use-module (guix gexp)
#:use-module (guix packages)
#:use-module (guix ui)
#:use-module (guix utils)
#:use-module (guix diagnostics)
#:use-module (guix discovery)
+ #:use-module (guix hash)
#:use-module (guix memoization)
#:use-module ((guix build utils)
#:select ((package-name->name+version
@@ -90,12 +93,47 @@
"Search the auxiliary FILE-NAME. Return #f if not found."
(search-path (%auxiliary-files-path) file-name))
-(define (search-patch file-name)
+(define (try-search-patch file-name)
+ "Search the patch FILE-NAME. Return #f if not found."
+ (search-path (%patch-path) file-name))
+
+(define (%search-patch file-name)
"Search the patch FILE-NAME. Raise an error if not found."
- (or (search-path (%patch-path) file-name)
+ (or (try-search-patch file-name)
(raise (formatted-message (G_ "~a: patch not found")
file-name))))
+(define (%local-patch-file file-name hash)
+ "Search the patch FILE-NAME, which is known to have HASH."
+ (local-file (precanonicalized-file-name file-name (%search-patch file-name))
+ #:sha256 hash #:recursive? #t))
+
+(define true (const #t))
+
+(define-syntax search-patch
+ (lambda (s)
+ "Search the patch FILE-NAME and compute its hash at expansion time
+if possible. Return #f if not found."
+ (syntax-case s ()
+ ((_ file-name)
+ (string? (syntax->datum #'file-name))
+ ;; FILE-NAME is a constant string, so the hash can be computed
+ ;; in advance.
+ (let ((patch (try-search-patch (syntax->datum #'file-name))))
+ (if patch
+ #`(%local-patch-file file-name #,(file-hash* patch #:select? true))
+ (begin
+ (warning (source-properties->location
+ (syntax-source #'file-name))
+ (G_ "~a: patch not found at expansion time")
+ (syntax->datum #'ile-name))
+ #'(%search-patch file-name)))))
+ ;; FILE-NAME is variable, so the hash cannot be pre-computed.
+ ((_ file-name) #'(%search-patch file-name))
+ ;; search-patch is being used used in a construct like
+ ;; (map search-patch ...).
+ (id (identifier? #'id) #'%search-patch))))
+
(define-syntax-rule (search-patches file-name ...)
"Return the list of absolute file names corresponding to each
FILE-NAME found in %PATCH-PATH."
diff --git a/gnu/packages/chromium.scm b/gnu/packages/chromium.scm
index 26ae1e2550..cf419cf41b 100644
--- a/gnu/packages/chromium.scm
+++ b/gnu/packages/chromium.scm
@@ -351,9 +351,7 @@
"0wbcbjzh5ak4nciahqw4yvxc4x8ik4x0iz9h4kfy0m011sxzy174"))))
(define %guix-patches
- (list (local-file
- (assume-valid-file-name
- (search-patch "ungoogled-chromium-extension-search-path.patch")))))
+ (search-patches "ungoogled-chromium-extension-search-path.patch"))
;; This is a source 'snippet' that does the following:
;; *) Applies various patches for unbundling purposes and libstdc++ compatibility.
diff --git a/gnu/packages/embedded.scm b/gnu/packages/embedded.scm
index f388c11c3d..826f5655c3 100644
--- a/gnu/packages/embedded.scm
+++ b/gnu/packages/embedded.scm
@@ -30,6 +30,7 @@
#:use-module (guix packages)
#:use-module (guix download)
#:use-module (guix svn-download)
+ #:use-module (guix gexp)
#:use-module (guix git-download)
#:use-module ((guix licenses) #:prefix license:)
#:use-module (guix build-system cmake)
@@ -91,7 +92,7 @@
;; Remove the one patch that doesn't apply to this 4.9 snapshot (the
;; patch is for 4.9.4 and later but this svn snapshot is older).
(patches (remove (lambda (patch)
- (string=? (basename patch)
+ (string=? (local-file-name patch)
"gcc-arm-bug-71399.patch"))
(origin-patches (package-source xgcc))))))
(native-inputs
diff --git a/gnu/packages/gnuzilla.scm b/gnu/packages/gnuzilla.scm
index 576bc2586f..be674dce8f 100644
--- a/gnu/packages/gnuzilla.scm
+++ b/gnu/packages/gnuzilla.scm
@@ -736,14 +736,10 @@ from forcing GEXP-PROMISE."
(base32
"00ws3540x5whpicc5fx4k949ff73cqvajz6jp13ahn49wqdads47"))))
- ;; 'search-patch' returns either a valid file name or #f, so wrap it
- ;; in 'assume-valid-file-name' to avoid 'local-file' warnings.
(gnuzilla-fixes-patch
- (local-file (assume-valid-file-name
- (search-patch "icecat-use-older-reveal-hidden-html.patch"))))
+ (search-patch "icecat-use-older-reveal-hidden-html.patch"))
(makeicecat-patch
- (local-file (assume-valid-file-name
- (search-patch "icecat-makeicecat.patch")))))
+ (search-patch "icecat-makeicecat.patch")))
(origin
(method computed-origin-method)
diff --git a/guix/lint.scm b/guix/lint.scm
index 3a7f3be327..b0a2fbc327 100644
--- a/guix/lint.scm
+++ b/guix/lint.scm
@@ -46,6 +46,7 @@
gexp->approximate-sexp))
#:use-module (guix licenses)
#:use-module (guix records)
+ #:use-module (guix gexp)
#:use-module (guix grafts)
#:use-module (guix upstream)
#:use-module (guix utils)
@@ -928,6 +929,8 @@ patch could not be found."
(starts-with-package-name? (basename patch)))
((? origin? patch)
(starts-with-package-name? (origin-actual-file-name patch)))
+ ((? local-file? patch)
+ (starts-with-package-name? (local-file-name patch)))
(_ #f)) ;must be some other file-like object
patches)
'()
@@ -941,19 +944,22 @@ patch could not be found."
(let ((prefix (string-length (%distro-directory)))
(margin (string-length "guix-2.0.0rc3-10000-1234567890/"))
(max 99))
+ (define (test-patch-name file-name)
+ (if (> (+ margin (if (string-prefix? (%distro-directory) file-name)
+ (- (string-length file-name) prefix)
+ (string-length file-name)))
+ max)
+ (make-warning
+ package
+ (G_ "~a: file name is too long")
+ (list (basename file-name))
+ #:field 'patch-file-names)
+ #f))
(filter-map (match-lambda
((? string? patch)
- (if (> (+ margin (if (string-prefix? (%distro-directory)
- patch)
- (- (string-length patch) prefix)
- (string-length patch)))
- max)
- (make-warning
- package
- (G_ "~a: file name is too long")
- (list (basename patch))
- #:field 'patch-file-names)
- #f))
+ (test-patch-name patch))
+ ((? local-file? patch)
+ (test-patch-name (local-file-absolute-file-name patch)))
(_ #f))
patches)))))
--
2.33.0
[-- Attachment #1.7: v2-0006-compile-all-compile-Keep-track-of-dependencies-of.patch --]
[-- Type: text/x-patch, Size: 8457 bytes --]
From 40debc8910799df60bca343caca05f8c79f46421 Mon Sep 17 00:00:00 2001
From: Maxime Devos <maximedevos@telenet.be>
Date: Sun, 5 Sep 2021 14:02:30 +0200
Subject: [PATCH v2 6/9] compile-all,compile: Keep track of dependencies of
compiled modules.
This patch defines a 'notice-dependency' procedure.
Macros can use this procedure to inform build-aux/compile-all.scm
that a module needs to be recompiled when some file is updated.
* guix/build/compile.scm
(current-dependency-info, current-output-file): New parameters.
(notice-dependency): New procedure.
(compile-files)[build]: Set 'output-file'. Delete the old compiled file
if necessary. Remove old dependency information.
* build-aux/compile-all.scm: Populate current-dependency-info from a file.
Populate the file dependency-info.scm from the hash table.
(builddir): New variable.
(file-needs-compilation?): Check if the .go file is older than the
dependencies.
* .gitignore: Ignore dependency-info.scm.
---
.gitignore | 1 +
build-aux/compile-all.scm | 37 ++++++++++++++++++++++++++++----
guix/build/compile.scm | 45 ++++++++++++++++++++++++++++++++-------
3 files changed, 71 insertions(+), 12 deletions(-)
diff --git a/.gitignore b/.gitignore
index 88fe24586d..f24ea5fc3b 100644
--- a/.gitignore
+++ b/.gitignore
@@ -154,3 +154,4 @@ tmp
/gnu/packages/bootstrap
/gnu/packages/aux-files/guile-guile-launcher.o
/guile
+/dependency-info.scm
diff --git a/build-aux/compile-all.scm b/build-aux/compile-all.scm
index 9ffbce43ad..02294073ed 100644
--- a/build-aux/compile-all.scm
+++ b/build-aux/compile-all.scm
@@ -1,6 +1,7 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2016 Taylan Ulrich Bayırlı/Kammer <taylanbayirli@gmail.com>
;;; Copyright © 2016, 2017, 2019, 2020, 2021 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2021 Maxime Devos <maximedevos@telenet.be>
;;;
;;; This file is part of GNU Guix.
;;;
@@ -20,12 +21,15 @@
(use-modules (ice-9 format)
(ice-9 match)
(ice-9 threads)
+ (ice-9 hash-table)
(srfi srfi-1)
+ (srfi srfi-26)
(guix build compile)
(guix build utils))
(define host (getenv "host"))
(define srcdir (getenv "srcdir"))
+(define builddir (getcwd))
(define (relative-file file)
(if (string-prefix? (string-append srcdir "/") file)
@@ -41,10 +45,33 @@
(without-extension (string-drop-right relative 4)))
(string-append without-extension ".go")))
+;; Read dependency information from previous "make" runs.
+(current-dependency-info (make-hash-table))
+(if (file-exists? "dependency-info.scm")
+ (current-dependency-info
+ (alist->hash-table
+ (call-with-input-file "dependency-info.scm" read #:encoding "UTF-8")))
+ (current-dependency-info (make-hash-table)))
+
+(define (dump-dependency-info)
+ "Dump the current dependency information for the next \"make\" run."
+ (call-with-output-file "dependency-info.scm.new"
+ (lambda (port)
+ (display ";; This is auto-generated by build-aux/compile-all.scm,
+;; do not modify manually!
+" port)
+ (write (hash-map->list cons (current-dependency-info)) port))
+ #:encoding "UTF-8")
+ (rename-file "dependency-info.scm.new" "dependency-info.scm"))
+
(define (file-needs-compilation? file)
- (let ((go (scm->go file)))
+ (let* ((go (scm->go file))
+ (extra-dependencies
+ (hash-ref (current-dependency-info) (in-vicinity builddir go)
+ '())))
(or (not (file-exists? go))
- (file-mtime<? go file))))
+ (file-mtime<? go file)
+ (any (cut file-mtime<? go <>) extra-dependencies))))
(define* (parallel-job-count #:optional (flags (getenv "MAKEFLAGS")))
"Return the number of parallel jobs as determined by FLAGS, the flags passed
@@ -109,7 +136,7 @@ to 'make'."
(let* ((to-build (filter file-needs-compilation? files))
(processed (+ processed
(- (length files) (length to-build)))))
- (compile-files srcdir (getcwd) to-build
+ (compile-files srcdir builddir to-build
#:workers (parallel-job-count*)
#:host host
#:report-load (lambda (file total completed)
@@ -127,8 +154,10 @@ to 'make'."
(* 2 processed))
(* 2 grand-total))
(scm->go file))
- (force-output))))))
+ (force-output)))))
+ (dump-dependency-info))
(lambda _
+ (dump-dependency-info)
(primitive-exit 1))
(lambda args
;; Try to report the error in an intelligible way.
diff --git a/guix/build/compile.scm b/guix/build/compile.scm
index b86ec3b743..c259b27abf 100644
--- a/guix/build/compile.scm
+++ b/guix/build/compile.scm
@@ -1,6 +1,7 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2013, 2014, 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2015 Taylan Ulrich Bayırlı/Kammer <taylanbayirli@gmail.com>
+;;; Copyright © 2021 Maxime Devos <maximedevos@telenet.be>
;;;
;;; This file is part of GNU Guix.
;;;
@@ -29,14 +30,27 @@
#:use-module (guix build utils)
#:use-module (language tree-il optimize)
#:use-module (language cps optimize)
- #:export (compile-files))
+ #:export (compile-files notice-dependency current-dependency-info))
;;; Commentary:
;;;
-;;; Support code to compile Guile code as efficiently as possible (with 2.2).
+;;; Support code to compile Guile code as efficiently as possible (with 2.2)
+;;; and keep track of the dependencies of compiled files.
;;;
;;; Code:
+(define current-dependency-info (make-parameter #f))
+(define current-output-file (make-parameter #f))
+
+(define (notice-dependency dependency)
+ "Add the file DEPENDENCY to the list of dependencies of the compiled file
+that is being computed, if any."
+ (define dependency-table (current-dependency-info))
+ (define output (current-output-file))
+ (when (and dependency-table output)
+ (hash-set! dependency-table output
+ (cons dependency (hash-ref dependency-table output '())))))
+
(define optimizations-for-level
(or (and=> (false-if-exception
(resolve-interface '(system base optimize)))
@@ -207,12 +221,27 @@ files are for HOST, a GNU triplet such as \"x86_64-linux-gnu\"."
;; Exit as soon as something goes wrong.
(exit-on-exception
file
- (let ((relative (relative-file source-directory file)))
- (compile-file file
- #:output-file (string-append build-directory "/"
- (scm->go relative))
- #:opts (append warning-options
- (optimization-options relative))))))
+ (let* ((relative (relative-file source-directory file))
+ (output-file (string-append build-directory "/"
+ (scm->go relative))))
+ (parameterize ((current-output-file output-file))
+ (when (current-dependency-info)
+ ;; If dependency information is being tracked, remove
+ ;; the old compiled file first. Otherwise, if recompiling
+ ;; the file due to an updated dependency causes an exception,
+ ;; the new dependency information won't include the compiled
+ ;; file and therefore the old compiled file would be considered
+ ;; up-to-date on the following "make" run.
+ (when (file-exists? output-file)
+ (delete-file output-file))
+ ;; Remove the old dependency information, otherwise
+ ;; the dependency information table will keep growing
+ ;; after each "make" run.
+ (hash-remove! (current-dependency-info) output-file))
+ (compile-file file
+ #:output-file output-file
+ #:opts (append warning-options
+ (optimization-options relative)))))))
(with-augmented-search-path %load-path source-directory
(with-augmented-search-path %load-compiled-path build-directory
--
2.33.0
[-- Attachment #1.8: v2-0007-packages-Add-patches-to-the-dependency-list-of-pa.patch --]
[-- Type: text/x-patch, Size: 1491 bytes --]
From 2bc29d443dc5d6096962da3d5a1028473462c431 Mon Sep 17 00:00:00 2001
From: Maxime Devos <maximedevos@telenet.be>
Date: Sun, 5 Sep 2021 17:15:08 +0200
Subject: [PATCH v2 7/9] packages: Add patches to the dependency list of
package modules.
* gnu/packages.scm (search-patch): Call 'notice-dependency' on
the patch file.
---
gnu/packages.scm | 7 ++++++-
1 file changed, 6 insertions(+), 1 deletion(-)
diff --git a/gnu/packages.scm b/gnu/packages.scm
index f5552e5a9b..39929ae022 100644
--- a/gnu/packages.scm
+++ b/gnu/packages.scm
@@ -34,6 +34,8 @@
#:select ((package-name->name+version
. hyphen-separated-name->name+version)
mkdir-p))
+ ;; only required at expansion time
+ #:autoload (guix build compile) (notice-dependency)
#:use-module (guix profiles)
#:use-module (guix describe)
#:use-module (guix deprecation)
@@ -121,7 +123,10 @@ if possible. Return #f if not found."
;; in advance.
(let ((patch (try-search-patch (syntax->datum #'file-name))))
(if patch
- #`(%local-patch-file file-name #,(file-hash* patch #:select? true))
+ (begin
+ (notice-dependency patch)
+ #`(%local-patch-file file-name
+ #,(file-hash* patch #:select? true)))
(begin
(warning (source-properties->location
(syntax-source #'file-name))
--
2.33.0
[-- Attachment #1.9: v2-0008-gexp-Do-not-intern-if-the-file-is-already-in-the-.patch --]
[-- Type: text/x-patch, Size: 3313 bytes --]
From b6907f76040fa524110a503848ed9b9d9b19dfaf Mon Sep 17 00:00:00 2001
From: Maxime Devos <maximedevos@telenet.be>
Date: Sat, 4 Sep 2021 18:10:32 +0200
Subject: [PATCH v2 8/9] gexp: Do not intern if the file is already in the
store.
* guix/gexp.scm (local-file-compiler): When the file is already in the
store, re-use the fixed output path instead of interning the file
again.
* guix/gexp.scm (add-temp-root*, valid-path?*): New procedures.
---
guix/gexp.scm | 41 ++++++++++++++++++++++++++++++++++-------
1 file changed, 34 insertions(+), 7 deletions(-)
diff --git a/guix/gexp.scm b/guix/gexp.scm
index c69e4aa299..6a6d130110 100644
--- a/guix/gexp.scm
+++ b/guix/gexp.scm
@@ -528,16 +528,43 @@ appears."
'system-error' exception is raised if FILE could not be found."
(force (%local-file-absolute-file-name file)))
+(define add-temp-root* (store-lift add-temp-root))
+(define valid-path?* (store-lift valid-path?))
+
(define-gexp-compiler (local-file-compiler (file <local-file>) system target)
;; "Compile" FILE by adding it to the store.
(match file
- (($ <local-file> file (= force absolute) name sha256 recursive? select?)
- ;; Canonicalize FILE so that if it's a symlink, it is resolved. Failing
- ;; to do that, when RECURSIVE? is #t, we could end up creating a dangling
- ;; symlink in the store, and when RECURSIVE? is #f 'add-to-store' would
- ;; just throw an error, both of which are inconvenient.
- (interned-file absolute name
- #:recursive? recursive? #:select? select?))))
+ ;; Delay computing the absolute file name until 'intern', as this
+ ;; might be a relatively expensive computation (e.g. if search-patch
+ ;; is used), especially on a spinning disk.
+ (($ <local-file> file absolute-promise name sha256 recursive? select?)
+ (let ()
+ (define (intern)
+ ;; Canonicalize FILE so that if it's a symlink, it is resolved.
+ ;; Failing to do that, when RECURSIVE? is #t, we could end up creating
+ ;; a dangling symlink in the store, and when RECURSIVE? is #f
+ ;; 'add-to-store' would just throw an error, both of which are
+ ;; inconvenient.
+ (interned-file (force absolute-promise) name
+ #:recursive? recursive? #:select? select?))
+ ;; If the hash is known in advance and the store already has the
+ ;; item, there is no need to intern the file.
+ (if sha256
+ (let ((path (fixed-output-path name sha256 #:recursive? recursive?)))
+ (mbegin %store-monad
+ ;; Tell the GC that PATH will be used, such that it won't
+ ;; be deleted.
+ (add-temp-root* path)
+ ;; 'add-temp-root*' doesn't thow an error if the store item
+ ;; does not exist, so we need to check if PATH actually exists.
+ (mlet %store-monad
+ ((valid? (valid-path?* path)))
+ (if valid?
+ (return path)
+ ;; If it has been removed, fall-back interning.
+ (intern)))))
+ ;; If PATH does not yet exist, fall back to interning.
+ (intern))))))
(define-record-type <plain-file>
(%plain-file name content references)
--
2.33.0
[-- Attachment #1.10: v2-0009-base32-Reduce-GC-pressure-in-make-bytevector-base.patch --]
[-- Type: text/x-patch, Size: 2264 bytes --]
From ccbaa1a4b447c67f997a63494a82c8e2b905dccd Mon Sep 17 00:00:00 2001
From: Maxime Devos <maximedevos@telenet.be>
Date: Sun, 5 Sep 2021 16:28:33 +0200
Subject: [PATCH v2 9/9] base32: Reduce GC pressure in
make-bytevector->base32-string.
The following code has been used to compare performance:
;; first 20 bytes of sha256 of #vu8(#xde #xad #xbe #xef)
(define bv #vu8(95 120 195 50 116 228 63 169 222 86 89 38 92 29 145 126 37 192 55 34))
,profile
(let loop ((n 0))
(when (< n #e1e6)
((@ (guix base32) bytevector->nix-base32-string) bv)
(loop (+ n 1))))
Before this change, the output was:
[...]
Sample count: 1140
Total time: 27.465560018 seconds (10.659331433 seconds in GC)
After this change, the output was:
[...]
Sample count: 957
Total time: 20.478847143 seconds (6.139721189 seconds in GC)
* guix/base32.scm
(make-bytevector->base32-string): Eliminate 'reverse', use mutation instead.
---
guix/base32.scm | 18 ++++++++++++------
1 file changed, 12 insertions(+), 6 deletions(-)
diff --git a/guix/base32.scm b/guix/base32.scm
index 49f191ba26..e76bf35ecc 100644
--- a/guix/base32.scm
+++ b/guix/base32.scm
@@ -141,12 +141,18 @@ the previous application or INIT."
(define (make-bytevector->base32-string quintet-fold base32-chars)
(lambda (bv)
"Return a base32 encoding of BV using BASE32-CHARS as the alphabet."
- (let ((chars (quintet-fold (lambda (q r)
- (cons (vector-ref base32-chars q)
- r))
- '()
- bv)))
- (list->string (reverse chars)))))
+ ;; Mutation can be avoided with 'reverse'. However, that would
+ ;; make this procedure about 30% slower due to the extra GC pressure.
+ (let* ((start (cons #f #f))
+ (end (quintet-fold (lambda (q r)
+ (define pair
+ (cons (vector-ref base32-chars q) #f))
+ (set-cdr! r pair)
+ pair)
+ start
+ bv)))
+ (set-cdr! end '())
+ (list->string (cdr start)))))
(define %nix-base32-chars
;; See `libutil/hash.cc'.
--
2.33.0
[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 260 bytes --]
next prev parent reply other threads:[~2021-09-05 19:49 UTC|newest]
Thread overview: 16+ messages / expand[flat|nested] mbox.gz Atom feed top
2021-09-04 21:17 [bug#50384] [PATCH] Optimise search-patch (reducing I/O) Maxime Devos
2021-09-04 21:47 ` Ludovic Courtès
2021-09-04 22:04 ` Ludovic Courtès
2021-09-05 19:48 ` Maxime Devos [this message]
2021-09-05 22:40 ` [bug#50384] [PATCH v2] " Maxime Devos
2021-09-06 8:39 ` zimoun
2021-09-06 10:06 ` Maxime Devos
2021-09-09 14:51 ` [bug#50384] [PATCH] " Ludovic Courtès
2021-09-21 16:55 ` [bug#50384] [PATCH v4] " Ludovic Courtès
2021-09-23 17:26 ` Maxime Devos
2021-09-27 16:17 ` Ludovic Courtès
2021-10-04 16:46 ` [bug#50384] [PATCH] " zimoun
2021-10-08 7:41 ` Ludovic Courtès
2021-10-11 8:09 ` [bug#39258] bug#50384: " zimoun
2021-09-09 20:25 ` [bug#50384] [PATCH v3] " Maxime Devos
2021-09-10 9:54 ` bug#50384: " Maxime Devos
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://guix.gnu.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=0ec7f0270fcccec730808f9210f074cd5339961f.camel@telenet.be \
--to=maximedevos@telenet.be \
--cc=50384@debbugs.gnu.org \
--cc=ludo@gnu.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/guix.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).