;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2016 Kei Kebreau <kkebreau@posteo.net>
;;; Copyright © 2017 Gábor Boskovits <boskovits@gmail.com>
;;; Copyright © 2018, 2020, 2022 Tobias Geerinckx-Rice <me@tobias.gr>
;;; Copyright © 2020 Jakub Kądziołka <kuba@kadziolka.net>
;;; Copyright © 2024 Artyom V. Poptsov <poptsov.artyom@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu packages hexedit)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix gexp)
  #:use-module (guix packages)
  #:use-module (gnu packages)
  #:use-module (gnu packages autotools)
  #:use-module (gnu packages compression)
  #:use-module (gnu packages gl)
  #:use-module (gnu packages man)
  #:use-module (gnu packages cpp)
  #:use-module (gnu packages gcc)
  #:use-module (gnu packages tls)
  #:use-module (gnu packages curl)
  #:use-module (gnu packages llvm)
  #:use-module (gnu packages ruby)
  #:use-module (gnu packages glib)
  #:use-module (gnu packages boost)
  #:use-module (gnu packages backup)
  #:use-module (gnu packages python)
  #:use-module (gnu packages libffi)
  #:use-module (gnu packages ncurses)
  #:use-module (gnu packages fontutils)
  #:use-module (gnu packages pkg-config)
  #:use-module (gnu packages engineering)
  #:use-module (gnu packages pretty-print)
  #:use-module (guix download)
  #:use-module (guix git-download)
  #:use-module (guix build-system gnu)
  #:use-module (guix build-system cmake))

(define-public hexedit
  (package
    (name "hexedit")
    (version "1.6")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://github.com/pixel/hexedit")
                    (commit version)))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "00l8vazbjzdg09azp6w3nzq4rl7qyh06i65dh621r6zaprp0z23w"))))
    (build-system gnu-build-system)
    (arguments
     `(#:tests? #f                      ; no check target
       #:phases
       (modify-phases %standard-phases
         ;; Make F1 open the man page even if man-db is not in the profile.
         (add-after 'unpack 'patch-man-path
           (lambda* (#:key inputs outputs #:allow-other-keys)
             (substitute* "interact.c"
               (("\"man\"")
                (string-append "\"" (assoc-ref inputs "man-db") "/bin/man\""))
               (("\"hexedit\"")
                (string-append "\"" (assoc-ref outputs "out")
                               "/share/man/man1/hexedit.1.gz\""))))))))
    (native-inputs
     (list autoconf automake))
    (inputs
     (list man-db ncurses))
    (synopsis "View and edit files or devices in hexadecimal or ASCII")
    (description "hexedit shows a file both in ASCII and in hexadecimal.  The
file can be a device as the file is read a piece at a time.  You can modify
the file and search through it.")
    (home-page "http://rigaux.org/hexedit.html")
    (license license:gpl2+)))

(define-public ht
  (package
    (name "ht")
    (version "2.1.0")
    (source (origin
              (method url-fetch)
              (uri (string-append
                    "https://sourceforge.net/projects/hte/files/ht-source/"
                    name "-" version ".tar.bz2"))
              (sha256
               (base32
                "0w2xnw3z9ws9qrdpb80q55h6ynhh3aziixcfn45x91bzrbifix9i"))))
    (build-system gnu-build-system)
    (inputs
     (list lzo ncurses))
    (synopsis "Viewer, editor, and analyzer for executable binaries")
    (description
     "ht is a terminal-based program to view, edit, and analyze any file, but
with a special focus on executable binaries.  Its goal is to combine the
low-level functionality of a debugger with the usability of an @dfn{Integrated
Development Environment} (IDE).")
    (home-page "https://hte.sourceforge.net/")
    (license license:gpl2)))

;; NOTE: `imhex-pattern-language' should improve it's build system to be used
;; easily outside of ImHex. It should update it's shared library install target
;; to deploy the header files and it should create the pertinent
;; 'libpl-config.cmake' and 'libpl-config-version.cmake' files.
(define-public imhex-pattern-language
  (package
    (name "imhex-pattern-language")
    (version "1.35.4")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://github.com/WerWolv/PatternLanguage")
                    (commit (string-append "ImHex-v" version))
                    (recursive? #t)))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "0riphslp3rca6z6f5zfvsisdh94apijfi03s7yap1vjnf6i93pks"))
              (snippet
               #~(begin
                   (use-modules (guix build utils))
                   ;; NOTE: the `throwing-ptr' hasn't been updated in 6 years and
                   ;; the testsuite expects to use an outdated version of Conan,
                   ;; since this library if not interesting to have it in Guix
                   ;; it will remain bundled.
                   ;; NOTE: `libwolf' does not have an install target. Until the
                   ;; maintainers create one, it will be bundled.
                   (with-directory-excursion "external"
                     (for-each (lambda (path)
                                 (delete-file-recursively path))
                               '("nlohmann_json" "cli11")))))))
    (build-system cmake-build-system)
    (arguments
     (list
      #:configure-flags
      ''("-DLIBPL_SHARED_LIBRARY=ON"
         "-DLIBPL_ENABLE_TESTS=ON"

         "-DUSE_SYSTEM_NLOHMANN_JSON=ON"
         "-DUSE_SYSTEM_CLI11=ON"
         ;; NOTE: the `fmt' package is vendored since it needs
         ;; a specific commit. Until there is a compatible
         ;; release, there is no interest in creating a Guix
         ;; package for it.
         "-DUSE_SYSTEM_FMT=OFF")
      #:phases
      #~(modify-phases %standard-phases
          (add-after 'unpack 'fix-rel-paths
            (lambda _
              (substitute* "tests/include/test_patterns/test_pattern_format.hpp"
                (("../tests/files/export/")
                 "../source/tests/files/export/"))))
          (add-after 'build 'build-tests
            (lambda _
              (invoke "make" "pattern_language_tests" "plcli")))
          (add-before 'check 'plcli-integration-tests
            (lambda _
              (with-directory-excursion "../source"
                (invoke "python3"
                        "tests/integration/integration.py"
                        "../build/cli/plcli")))))))
    (native-inputs (list cli11 gcc-14 nlohmann-json python))
    (home-page "https://imhex.werwolv.net")
    (synopsis "The Pattern Language used by the ImHex Hex Editor")
    (description "The Pattern Language used by the ImHex Hex Editor.")
    (license license:lgpl2.1)))

(define-public imhex
  (package
    (name "imhex")
    (version "1.35.4")
    (source
     (origin
       (method git-fetch)
       (uri (git-reference
             (url "https://github.com/WerWolv/ImHex")
             (commit (string-append "v" version))
             (recursive? #t)))
       (file-name (git-file-name name version))
       (sha256
        (base32 "0gi5772w0fzgr1w403ckq2mkwiyvcxv08frs2fjr2hlc8hb6c2p9"))
       (snippet
        #~(begin
            (use-modules (guix build utils))
            (define (delete-files-from-list-recursively . args)
              (for-each (lambda (path)
                          (delete-file-recursively path))
                        args))

            (define (replace-files-from-list-recursively lst)
              (for-each
               (lambda (elt)
                 (delete-file-recursively (cdr elt))
                 (copy-recursively (car elt) (cdr elt)))
               lst))

            ;; NOTE: `libwolf' does not have an install target. Until the
            ;; maintainers create one, it will remain bundled.
            ;; NOTE: `libromfs' it's meant to be bundled and cannot be compiled
            ;; independently. Until the maintainers support building it
            ;; independently, it will remain bundled.
            ;; NOTE: `imhex-pattern-language' it's meant to be bundled and
            ;; cannot be linked independently. Until the maintainers support
            ;; linking it independently, it's source will be replaced in-tree.
            (replace-files-from-list-recursively
             `((#$(package-source imhex-pattern-language)
                . "lib/external/pattern_language")))
            ;; NOTE: `hashlibplus' has been left as a submodule since it's a fork
            ;; which only makes sense within ImHex.
            (with-directory-excursion "lib/third_party"
              (delete-files-from-list-recursively
               "nlohmann_json" "capstone" "llvm-demangle" "fmt" "nativefiledialog"
               ;; NOTE: for versions above c++20 it is not required.
               "jthread/jthread")
              (replace-files-from-list-recursively
               `((#$(package-source lunasvg) . "lunasvg")
                 (#$(package-source xdgpp) . "xdgpp")
                 (#$(file-append miniaudio "/include/miniaudio.h")
                    . "miniaudio/include/miniaudio.h"))))))))
    (build-system cmake-build-system)
    (arguments
     (list
      ;; NOTE: there is an issue with the way the test library is linked with
      ;; the output binaries. Tests are intrusive and should not be shipped
      ;; with the release, when the issue is fixed we could add a phase which
      ;; builds the package with the tests and runs the testsuite and a second
      ;; build phase which prepares the output binary.
      #:configure-flags
      ''("-DIMHEX_OFFLINE_BUILD=ON"
         "-DIMHEX_ENABLE_UNIT_TESTS=ON"
         ;; NOTE: required for the `validate-runpath' phase.
         ;; If OFF, the pluggings won't be able to find `libimhex.so'.
         "-DIMHEX_PLUGIN_ADD_INSTALL_PREFIX_TO_RPATH=ON"

         "-DUSE_SYSTEM_NLOHMANN_JSON=ON"
         "-DUSE_SYSTEM_CAPSTONE=ON"
         "-DUSE_SYSTEM_CLI11=ON"
         "-DUSE_SYSTEM_LLVM=ON"
         "-DUSE_SYSTEM_FMT=ON"

         "-DUSE_SYSTEM_BOOST=ON"
         "-DUSE_SYSTEM_EDLIB=ON"
         "-DUSE_SYSTEM_NFD=ON"

         ;; NOTE: the build system doesn't correctly support
         ;; locating these system libraries. Until fixed
         ;; upstream, drop the sources where they are
         ;; expected, this is done in the `<origin>' snippet.
         "-DUSE_SYSTEM_MINIAUDIO=OFF"
         "-DUSE_SYSTEM_LUNASVG=OFF"

         ;; TODO: package them.
         "-DUSE_SYSTEM_YARA=OFF")
      #:phases
      #~(modify-phases %standard-phases
          (add-after 'unpack 'fix-paths
            (lambda _
              (substitute* "main/gui/source/window/linux_window.cpp"
                (("dbus-send")
                 #$(file-append dbus "/bin/dbus-send")))
              (substitute* "cmake/build_helpers.cmake"
                (("boost REQUIRED")
                 "Boost COMPONENTS regex REQUIRED")
                (("boost::regex")
                 "Boost::regex"))
              (substitute* "lib/libimhex/CMakeLists.txt"
                (("boost")
                 "Boost"))))
          (add-before 'check 'build-tests
            (lambda _
              (invoke "make" "unit_tests"))))))
    (native-inputs
     (list cli11
           nlohmann-json
           pkg-config
           python
           python-wrapper
           ruby
           gcc-14))
    (inputs
     (list boost
           capstone
           curl
           edlib
           fmt
           glfw
           libarchive
           libffi
           llvm-17
           mbedtls
           mesa
           nativefiledialog-extended
           xz
           zlib
           freetype))
    (home-page "https://imhex.werwolv.net")
    (synopsis "Hex Editor to display, decode and analyze binary data")
    (description "@command{imhex} is a hex editor with many advanced features
that can often only be found in paid applications.  Such features are a
completely custom binary template and pattern language to decode and highlight
structures in the data, a graphical node-based data processor to pre-process
values before they're displayed, a disassembler, diffing support, bookmarks
and much much more.")
    (license license:gpl2)))

(define-public bvi
  (package
    (name "bvi")
    (version "1.4.2")
    (source (origin
              (method url-fetch)
              (uri (string-append
                    "mirror://sourceforge/bvi/bvi/" version
                    "/bvi-" version ".src.tar.gz"))
              (sha256
               (base32
                "1wllrvs8r8bdm11sx01095j8cj4drjmw0dlkjfdkm5lnnk11dfjb"))))
    (build-system gnu-build-system)
    (arguments '(#:tests? #f))          ; no check target
    (inputs
     (list ncurses))
    (synopsis "Binary file editor")
    (description "@command{bvi} is a display-oriented editor for binary files,
based on the @command{vi} text editor.")
    (home-page "https://bvi.sourceforge.net/")
    (license license:gpl3+)))