;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2021 Jack Hill <jackhill@jackhill.us>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (guix build-system janet)
  #:use-module (guix build-system)
  #:use-module (guix build-system gnu)
  #:use-module (guix derivations)
  #:use-module (guix packages)
  #:use-module (guix utils)
  #:use-module (ice-9 match)
  #:export (janet-build
            janet-build-system))

(define %janet-build-system-modules
  ;; Build-side modules imported by default.
  `((guix build janet-build-system)
    ,@%gnu-build-system-modules))

(define (default-janet)
  "Return the default Janet package."
  ;; Lazily resolve the binding to avoid a circular dependency.
  (let ((lisp (resolve-interface '(gnu packages lisp))))
    (module-ref lisp 'janet)))

(define* (lower name
                #:key source inputs native-inputs outputs
                system target
                (janet (default-janet))
                #:allow-other-keys
                #:rest arguments)
  "Return a bag for NAME."
  (define private-keywords
    '(#:source #:target #:janet #:inputs #:native-inputs))

  (bag
    (name name)
    (system system)
    (host-inputs `(,@(if source
                         `(("source" ,source))
                         '())
                   ,@inputs
                   ;; Keep the standard inputs of 'gnu-build-system'.
                   ,@(standard-packages)))
    (build-inputs `(("janet" ,janet)
                    ,@native-inputs))
    (outputs outputs)
    (build janet-build)
    (arguments (strip-keyword-arguments private-keywords arguments))))

(define* (janet-build store name inputs
                      #:key
                      (search-paths '())
                     (tests? #t)
                     (phases '(@ (guix build janet-build-system)
                                 %standard-phases))
                     (outputs '("out"))
                     (system (%current-system))
                     (locale "en_US.utf8")
                     (guile #f)
                     (imported-modules %janet-build-system-modules)
                     (modules '((guix build janet-build-system)
                                (guix build utils)
                                (guix utils))))
  "Build SOURCE using RUBY and INPUTS."
  (define builder
    `(begin
       (use-modules ,@modules)
       (janet-build #:name ,name
                    #:source ,(match (assoc-ref inputs "source")
                                (((? derivation? source))
                                 (derivation->output-path source))
                                ((source)
                                 source)
                                (source
                                 source))
                    #:tests? ,tests?
                    #:phases ,phases
                    #:outputs %outputs
                    #:inputs %build-inputs)))

  (define guile-for-build
    (match guile
      ((? package?)
       (package-derivation store guile system #:graft? #f))
      (#f
       (let* ((distro (resolve-interface '(gnu packages commencement)))
              (guile  (module-ref distro 'guile-final)))
         (package-derivation store guile system #:graft? #f)))))

  (build-expression->derivation store name builder
                                #:inputs inputs
                                #:system system
                                #:modules imported-modules
                                #:outputs outputs
                                #:guile-for-build guile-for-build))

(define janet-build-system
  (build-system
    (name 'janet)
    (description "The standard Janet build system")
    (lower lower)))