;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 David Thompson <davet@gnu.org>
;;; Copyright © 2015 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services web)
  #:use-module (gnu services)
  #:use-module (gnu services dmd)
  #:use-module (gnu system shadow)
  #:use-module (gnu packages admin)
  #:use-module (gnu packages web)
  #:use-module (guix records)
  #:use-module (guix gexp)
  #:use-module (ice-9 match)
  #:use-module (srfi srfi-1)
  #:export (nginx-configuration
            nginx-configuration?
            nginx-configuration-log-directory
            nginx-configuration-run-directory
            nginx-configuration-file
            nginx-configuration-servers

            nginx-service-type
            nginx-service))

;;; Commentary:
;;;
;;; Web services.
;;;
;;; Code:

(define-record-type* <nginx-configuration>
  nginx-configuration make-nginx-configuration
  nginx-configuration?
  (nginx         nginx-configuration-nginx)         ; <package>
  (log-directory nginx-configuration-log-directory) ; string
  (run-directory nginx-configuration-run-directory) ; string
  (file          nginx-configuration-file)          ; file-like
  (servers       nginx-configuration-servers))      ; list of file-like

(define (nginx-configuration-file* config)
  (match config
    (($ <nginx-configuration> _ log run file servers)
     (apply mixed-text-file "nginx.conf"
            `("user nginx nginx;\n"
              "pid " ,run "/pid;\n"
              "error_log " ,log "/error.log info;\n"
              "include " ,file ";\n"
              "http {\n"
              "  access_log " ,log "/access.log;\n"
              ,@(append-map (lambda (server-config)
                              (list "include " server-config ";\n"))
                            servers)
              "}\n")))))

(define %nginx-accounts
  (list (user-group (name "nginx") (system? #t))
        (user-account
         (name "nginx")
         (group "nginx")
         (system? #t)
         (comment "nginx server user")
         (home-directory "/var/empty")
         (shell #~(string-append #$shadow "/sbin/nologin")))))

(define nginx-activation
  (lambda (config)
    (match config
      (($ <nginx-configuration> nginx log-directory run-directory _)
       #~(begin
           (use-modules (guix build utils))

           (format #t "creating nginx log directory '~a'~%" #$log-directory)
           (mkdir-p #$log-directory)
           (format #t "creating nginx run directory '~a'~%" #$run-directory)
           (mkdir-p #$run-directory)
           ;; Check configuration file syntax.
           (system* (string-append #$nginx "/sbin/nginx")
                    "-c" #$(nginx-configuration-file* config) "-t"))))))

(define (nginx-dmd-service config)
  (match config
    (($ <nginx-configuration> nginx log run file servers)
     (let* ((nginx-binary #~(string-append #$nginx "/sbin/nginx"))
            (config-file (nginx-configuration-file* config))
            (nginx-action
             (lambda args
               #~(lambda _
                   (zero?
                    (system* #$nginx-binary "-c" #$config-file #$@args))))))

       (list (dmd-service
              (provision '(nginx))
              (documentation "Run the nginx daemon.")
              (requirement '(user-processes loopback))
              (start (nginx-action "-p" run))
              (stop (nginx-action "-s" "stop"))))))))

(define (extend-nginx config servers)
  (nginx-configuration
   (inherit config)
   (servers (append (nginx-configuration-servers config) servers))))

(define nginx-service-type
  (service-type (name 'nginx)
                (extensions
                 (list (service-extension dmd-root-service-type
                                          nginx-dmd-service)
                       (service-extension activation-service-type
                                          nginx-activation)
                       (service-extension account-service-type
                                          (const %nginx-accounts))))
                (compose concatenate)
                (extend extend-nginx)))

(define* (nginx-service #:key (nginx nginx)
                        (log-directory "/var/log/nginx")
                        (run-directory "/var/run/nginx")
                        ;; Nginx requires an 'events' block.
                        (config-file (plain-file "nginx-main.conf"
                                                 "events {}"))
                        (servers '()))
  "Return a service that runs NGINX, the nginx web server.

The nginx daemon loads its runtime configuration from CONFIG-FIGLE, stores log
files in LOG-DIRECTORY, and stores temporary runtime files in RUN-DIRECTORY."
  (service nginx-service-type
           (nginx-configuration
            (nginx nginx)
            (log-directory log-directory)
            (run-directory run-directory)
            (file config-file)
            (servers servers))))