Re: [PATCH] gnu: Add qscintilla.

[Kei Kebreau <kei@openmailbox.org>]

[-- Attachment #1: Type: text/plain, Size: 4379 bytes --]

Leo Famulari <leo@famulari.name> writes:

> On Tue, Sep 13, 2016 at 10:37:56AM -0400, Kei Kebreau wrote:
>> Kei Kebreau <kei@openmailbox.org> writes:
>> > A component necessary for GNU Octave's GUI.
>> > How does it look?
>> Not sure how packaging Qt packages goes, but I've discovered that
>> GNU Octave's GUI only builds with Qt4 support. I've changed the patch to
>> adjust this. Should I leave the old patch as is and add a qt4 package
>> that inherits from it?
>
> Since Qt 4 is no longer supported upstream, we are trying to remove
> users of the qt-4 package so that we can eventually remove the qt-4
> package itself.
>
> With that in mind, how about a qscintilla-for-octave package? This
> package can inherit from a qscintilla that uses qtbase, and I think it
> should be declared privately [using (define) instead of (define-public].
>
>> +         (replace 'configure
>> +           (lambda _
>> +             (chdir "Qt4Qt5")
>> +             (zero? (system* "qmake" "qscintilla.pro"))))
>
> I would change directory in a separate 'chdir' phase.
>
>> +               (substitute* (find-files "." "Makefile")
>> +                 (((string-append "INSTALL_ROOT)" qt))
>> +                  (string-append "INSTALL_ROOT)" out)))))))))
>                      ^
> Inconsistent indentation. Also, this phase should return #t, since the
> return value of substitute* is unspecified.
>
>> +    (synopsis "Qt5 port of the Scintilla editing component")
>
> Make sure to adjust the Qt name as appropriate :)

Like below? And how could I then access qscintilla-for-octave from
maths.scm if it isn't defined publicly?

(define-public qscintilla
  (package
    (name "qscintilla")
    (version "2.9.3")
    (source (origin
              (method url-fetch)
              (uri (string-append "mirror://sourceforge/QScintilla2/QScintilla-"
                                  version "/QScintilla_gpl-" version ".tar.gz"))
              (sha256
               (base32
                "0znvdncpj64zcpbkyvj11dm8bdc3nfn5girggj33ammhfcyvkalq"))))
    (build-system gnu-build-system)
    (arguments
     `(#:phases
       (modify-phases %standard-phases
         (add-before 'configure 'change-directory
           (lambda _ (chdir "Qt4Qt5") #t))
         (replace 'configure
           (lambda _ (zero? (system* "qmake" "qscintilla.pro"))))
         (add-before 'install 'fix-Makefiles
           (lambda* (#:key inputs outputs #:allow-other-keys)
             (let ((out    (assoc-ref outputs "out"))
                   (qtbase (assoc-ref inputs "qtbase")))
               (substitute* (find-files "." "Makefile")
                 (((string-append "INSTALL_ROOT)" qtbase))
                   (string-append "INSTALL_ROOT)" out))))
             #t)))))
    (native-inputs
     `(("python-pyqt" ,python-pyqt)
       ("qtbase" ,qtbase))) ; for qmake
    (home-page "https://www.riverbankcomputing.com/software/qscintilla/intro")
    (synopsis "Qt5 port of the Scintilla editing component")
    (description
     "QScintilla is a port to Qt of Neil Hodgson's Scintilla C++ editor control.
As well as features found in standard text editing components, QScintilla
includes features especially useful when editing and debugging source code.
These include support for syntax styling, error indicators, code completion and
call tips.")
    (license (list license:bsd-2 ; Python/configure.py
                   license:expat ; src/ and include/
                   license:gpl3))))

(define qtscintilla-for-octave
  (package
    (inherit qtscintilla)
    (name "qtscintilla-for-octave")
    (arguments
     `(#:phases
       (modify-phases %standard-phases
         (add-before 'configure 'change-directory
           (lambda _ (chdir "Qt4Qt5") #t))
         (replace 'configure
           (lambda _ (zero? (system* "qmake" "qscintilla.pro"))))
         (add-before 'install 'fix-Makefiles
           (lambda* (#:key inputs outputs #:allow-other-keys)
             (let ((out    (assoc-ref outputs "out"))
                   (qt (assoc-ref inputs "qt")))
               (substitute* (find-files "." "Makefile")
                 (((string-append "INSTALL_ROOT)" qt))
                   (string-append "INSTALL_ROOT)" out))))
             #t)))))
    (native-inputs
     `(("python-pyqt" ,python-pyqt)
       ("qt" ,qt-4))) ; for qmake
    (synopsis "Qt4 port of the Scintilla editing component")))

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 818 bytes --]