Self-contained Guix tarball

[ludo@gnu.org (Ludovic Courtès)]

[-- Attachment #1.1: Type: text/plain, Size: 1325 bytes --]

Pjotr Prins <pjotr.public12@thebird.nl> skribis:

> Well yes, you need to install all prerequisites and that is not always
> trivial. Try bootstrapping on an old Centos install, for example.
> Can't even get Docker going there.
>
> It would be nice to have an installable binary tar ball for Guix. Just
> unpack in root and go...

I’ve given that a try since it’s actually quite simple to do.  The
procedure in the attached file produces a self-contained tarball.  It
contains the closure of Guix, as well as /var/guix and an initial
/root/.guix-profile from which one can use the ‘guix’ commands.

I’ve uploaded the result (for x86_64) at:

  http://www.fdn.fr/~lcourtes/software/guix/guix-tarball-0.8.1.1140.tar.lz
  http://www.fdn.fr/~lcourtes/software/guix/guix-tarball-0.8.1.1140.tar.lz.sig
  SHA1: afde62b3e9f97f9ae0c57eaccfaca842b157cd2f

To install Guix on a foreign distro, follow these steps:

  1. Download the tarball (38 MiB.)

  2. As root, run:
       cd /
       tar xf /path/to/guix-tarball-0.8.1.1140.tar.lz
     You need lzip and GNU tar.

  3. Setup the daemon as explained in the manual, and run it from
     /root/.guix-profile/bin/guix-daemon.

And hopefully, that’s it.

I haven’t actually tried it, so feedback is welcome!  :-)

Thanks,
Ludo’.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.2: tarball creation --]
[-- Type: text/x-scheme, Size: 3477 bytes --]

(use-modules (guix)
             (guix profiles)
             (gnu packages base)
             (gnu packages compression)
             (gnu packages package-management))

(define* (self-contained-tarball #:key (guix guix))
  (mlet %store-monad ((profile (profile-derivation
                                (manifest
                                 (list (package->manifest-entry guix))))))
    (gexp->derivation "guix-tarball.tar.lz"
                      #~(begin
                          (use-modules (guix build store-copy)
                                       (guix build utils)
                                       (gnu build install)
                                       (srfi srfi-26))

                          (define %root
                            (string-append (getcwd) "/root"))
                          (define %root-profile
                            "/var/guix/profiles/per-user/root")

                          (define (mkdir-p* dir)
                            (mkdir-p (string-append %root "/" dir)))

                          (define (symlink* old new)
                            (symlink old (string-append %root "/" new)))

                          (setenv "PATH"
                                  (string-append #$guix "/sbin:"
                                                 #$tar "/bin:" #$lzip "/bin"))

                          ;; Populate the store.
                          (populate-store '("profile") %root)
                          (for-each (cut register-closure %root <>)
                                    '("profile"))

                          ;; 'guix-register' registers profiles as GC roots
                          ;; but the symlink target uses $TMPDIR.  Fix that.
                          (delete-file
                           (string-append %root
                                          "/var/guix/gcroots/profiles"))
                          (symlink* "/var/guix/profiles"
                                    "/var/guix/gcroots/profiles")

                          ;; Make root's profile, which makes it a GC root.
                          (mkdir-p* %root-profile)
                          (symlink* #$profile
                                    (string-append %root-profile
                                                   "/guix-profile-1-link"))
                          (symlink* (string-append %root-profile
                                                   "/guix-profile-1-link")
                                    (string-append %root-profile
                                                   "/guix-profile"))

                          (mkdir-p* "/root")
                          (symlink* (string-append %root-profile
                                                   "/guix-profile")
                                    "/root/.guix-profile")

                          ;; Create the tarball.  Use GNU format so there's no
                          ;; file name length limitation.
                          (chdir %root)
                          (zero? (system* "tar" "--lzip" "--format=gnu"
                                          "-cvf" #$output ".")))
                      #:references-graphs `(("profile" ,profile))
                      #:modules '((guix build utils)
                                  (guix build store-copy)
                                  (gnu build install)))))

;; (pk (with-store store
;;       (run-with-store store (self-contained-tarball))))

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 818 bytes --]