[PATCH 1/3] gnu: Add openal.

[PATCH 1/3] gnu: Add openal.

[David Thompson]

* gnu/packages/games.scm (openal): New variable.
---
 gnu/packages/games.scm | 34 +++++++++++++++++++++++++++++++++-
 1 file changed, 33 insertions(+), 1 deletion(-)

diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
index 84e09aa..e6ef402 100644
--- a/gnu/packages/games.scm
+++ b/gnu/packages/games.scm
@@ -41,7 +41,10 @@
   #:use-module (gnu packages sqlite)
   #:use-module (gnu packages sdl)
   #:use-module (gnu packages texinfo)
-  #:use-module (guix build-system gnu))
+  #:use-module (gnu packages pulseaudio)
+  #:use-module (gnu packages linux)
+  #:use-module (guix build-system gnu)
+  #:use-module (guix build-system cmake))
 
 (define-public gnubg
   (package
@@ -321,3 +324,32 @@ and Makruk.  Several lesser-known variants are also supported.  It presents a
 fully interactive graphical interface and it can load and save games in the
 Portable Game Notation.")
     (license gpl3+)))
+
+(define-public openal
+  (package
+    (name "openal")
+    (version "1.15.1")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append
+                    "http://kcat.strangesoft.net/openal-releases/openal-soft-"
+                    version ".tar.bz2"))
+              (sha256
+               (base32
+                "0mmhdqiyb3c9dzvxspm8h2v8jibhi8pfjxnf6m0wn744y1ia2a8f"))))
+    (build-system cmake-build-system)
+    (arguments
+     `(#:tests? #f)) ; no check target
+    (inputs
+     `(("alsa-lib" ,alsa-lib)
+       ("pulseaudio" ,pulseaudio)))
+    (synopsis "3D audio API")
+    (description
+     "OpenAL provides capabilities for playing audio in a virtual 3D
+environment.  Distance attenuation, doppler shift, and directional sound
+emitters are among the features handled by the API.  More advanced effects,
+including air absorption, occlusion, and environmental reverb, are available
+through the EFX extension.  It also facilitates streaming audio, multi-channel
+buffers, and audio capture.")
+    (home-page "http://kcat.strangesoft.net/openal.html")
+    (license lgpl2.0+)))
-- 
2.1.0

[PATCH 2/3] gnu: Add irrlicht.

[David Thompson]

* gnu/packages/games.scm (irrlicht): New variable.
---
 gnu/packages/games.scm | 47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
index e6ef402..86ad436 100644
--- a/gnu/packages/games.scm
+++ b/gnu/packages/games.scm
@@ -20,6 +20,7 @@
 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
 
 (define-module (gnu packages games)
+  #:use-module (srfi srfi-1)
   #:use-module (guix licenses)
   #:use-module (guix packages)
   #:use-module (guix download)
@@ -43,6 +44,7 @@
   #:use-module (gnu packages texinfo)
   #:use-module (gnu packages pulseaudio)
   #:use-module (gnu packages linux)
+  #:use-module (gnu packages zip)
   #:use-module (guix build-system gnu)
   #:use-module (guix build-system cmake))
 
@@ -353,3 +355,48 @@ through the EFX extension.  It also facilitates streaming audio, multi-channel
 buffers, and audio capture.")
     (home-page "http://kcat.strangesoft.net/openal.html")
     (license lgpl2.0+)))
+
+(define-public irrlicht
+  (package
+    (name "irrlicht")
+    (version "1.8.1")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append
+                    "mirror://sourceforge/irrlicht/Irrlicht%20SDK/"
+                    (string-join (take (string-split version #\.) 2) ".")
+                    "/" version "/irrlicht-" version ".zip"))
+              (sha256
+               (base32
+                "0yz9lvsc8aqk8wj4rnpanxrw90gqpwn9w5hxp94r8hnm2q0vjjw1"))))
+    (build-system gnu-build-system)
+    (arguments
+     '(#:phases (alist-cons-after
+                 'unpack 'fix-build-env
+                 (lambda* (#:key outputs #:allow-other-keys)
+                   (let ((prefix (assoc-ref outputs "out")))
+                     (substitute* "Makefile"
+                       (("INSTALL_DIR = /usr/local/lib")
+                        (string-append "INSTALL_DIR = " prefix "/lib")))
+                     ;; The Makefile assumes these directories exist.
+                     (mkdir-p (string-append prefix "/lib"))
+                     (mkdir-p (string-append prefix "/include"))))
+                 (alist-replace
+                  'unpack
+                  (lambda* (#:key source #:allow-other-keys)
+                    (and (zero? (system* "unzip" source))
+                         ;; The actual source is buried a few directories deep.
+                         (chdir "irrlicht-1.8.1/source/Irrlicht/")))
+                  ;; No configure script
+                  (alist-delete 'configure %standard-phases)))
+       #:tests? #f ; no check target
+       #:make-flags '("CC=gcc" "sharedlib")))
+    (native-inputs
+     `(("unzip" ,unzip)))
+    (inputs
+     `(("mesa" ,mesa)))
+    (synopsis "3D game engine")
+    (description
+     "3D game engine.")
+    (home-page "http://irrlicht.sourceforge.net/")
+    (license bsd-3)))
-- 
2.1.0

Re: [PATCH 2/3] gnu: Add irrlicht.

[Eric Bavier]

David Thompson writes:

> +                 (lambda* (#:key outputs #:allow-other-keys)
> +                   (let ((prefix (assoc-ref outputs "out")))

This should probably be named "out" rather than "prefix" for consistency
with the rest of guix's packages.

> +    (description
> +     "3D game engine.")

Perhaps something more descriptive.  Like:

"The Irrlicht Engine is a high performance realtime 3D engine written in
C++.  It is completely cross-platform, using D3D, OpenGL and its own
software renderers, and has all of the state-of-the-art features."

> +    (license bsd-3)))

It's actually the zlib license.

-- 
Eric Bavier

Please avoid sending me Word or PowerPoint attachments.
See http://www.gnu.org/philosophy/no-word-attachments.html

Re: [PATCH 2/3] gnu: Add irrlicht.

[David Thompson]

[-- Attachment #1: Type: text/plain, Size: 906 bytes --]

Eric Bavier <ericbavier@gmail.com> writes:

> David Thompson writes:
>
>> +                 (lambda* (#:key outputs #:allow-other-keys)
>> +                   (let ((prefix (assoc-ref outputs "out")))
>
> This should probably be named "out" rather than "prefix" for consistency
> with the rest of guix's packages.
>

Done.

>> +    (description
>> +     "3D game engine.")
>
> Perhaps something more descriptive.  Like:
>
> "The Irrlicht Engine is a high performance realtime 3D engine written in
> C++.  It is completely cross-platform, using D3D, OpenGL and its own
> software renderers, and has all of the state-of-the-art features."
>

I used just the first sentence.  The second sentence mentioned
proprietary software (D3D) and sounded too much like marketing.

>> +    (license bsd-3)))
>
> It's actually the zlib license.
>

Damn, you're right.  Fixed.

Thanks for the feedback.  New patch below.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0002-gnu-Add-irrlicht.patch --]
[-- Type: text/x-diff, Size: 3196 bytes --]

From db3bc54eb6aa5c42888125ce8bb69447284d03d3 Mon Sep 17 00:00:00 2001
From: David Thompson <dthompson2@worcester.edu>
Date: Fri, 5 Sep 2014 13:16:50 -0400
Subject: [PATCH 2/3] gnu: Add irrlicht.

* gnu/packages/games.scm (irrlicht): New variable.
---
 gnu/packages/games.scm | 48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
index e6ef402..3faf892 100644
--- a/gnu/packages/games.scm
+++ b/gnu/packages/games.scm
@@ -20,6 +20,7 @@
 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
 
 (define-module (gnu packages games)
+  #:use-module (srfi srfi-1)
   #:use-module (guix licenses)
   #:use-module (guix packages)
   #:use-module (guix download)
@@ -43,6 +44,7 @@
   #:use-module (gnu packages texinfo)
   #:use-module (gnu packages pulseaudio)
   #:use-module (gnu packages linux)
+  #:use-module (gnu packages zip)
   #:use-module (guix build-system gnu)
   #:use-module (guix build-system cmake))
 
@@ -353,3 +355,49 @@ through the EFX extension.  It also facilitates streaming audio, multi-channel
 buffers, and audio capture.")
     (home-page "http://kcat.strangesoft.net/openal.html")
     (license lgpl2.0+)))
+
+(define-public irrlicht
+  (package
+    (name "irrlicht")
+    (version "1.8.1")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append
+                    "mirror://sourceforge/irrlicht/Irrlicht%20SDK/"
+                    (string-join (take (string-split version #\.) 2) ".")
+                    "/" version "/irrlicht-" version ".zip"))
+              (sha256
+               (base32
+                "0yz9lvsc8aqk8wj4rnpanxrw90gqpwn9w5hxp94r8hnm2q0vjjw1"))))
+    (build-system gnu-build-system)
+    (arguments
+     '(#:phases (alist-cons-after
+                 'unpack 'fix-build-env
+                 (lambda* (#:key outputs #:allow-other-keys)
+                   (let ((out (assoc-ref outputs "out")))
+                     (substitute* "Makefile"
+                       (("INSTALL_DIR = /usr/local/lib")
+                        (string-append "INSTALL_DIR = " out "/lib")))
+                     ;; The Makefile assumes these directories exist.
+                     (mkdir-p (string-append out "/lib"))
+                     (mkdir-p (string-append out "/include"))))
+                 (alist-replace
+                  'unpack
+                  (lambda* (#:key source #:allow-other-keys)
+                    (and (zero? (system* "unzip" source))
+                         ;; The actual source is buried a few directories deep.
+                         (chdir "irrlicht-1.8.1/source/Irrlicht/")))
+                  ;; No configure script
+                  (alist-delete 'configure %standard-phases)))
+       #:tests? #f ; no check target
+       #:make-flags '("CC=gcc" "sharedlib")))
+    (native-inputs
+     `(("unzip" ,unzip)))
+    (inputs
+     `(("mesa" ,mesa)))
+    (synopsis "3D game engine")
+    (description
+     "The Irrlicht Engine is a high performance realtime 3D engine written in
+C++.")
+    (home-page "http://irrlicht.sourceforge.net/")
+    (license zlib)))
-- 
2.1.0


[-- Attachment #3: Type: text/plain, Size: 136 bytes --]


-- 
David Thompson
Web Developer - Free Software Foundation - http://fsf.org
GPG Key: 0FF1D807
Support the FSF: https://fsf.org/donate

[PATCH 3/3] gnu: Add minetest.

[David Thompson]

* gnu/packages/games.scm (minetest): New variable.
---
 gnu/packages/games.scm | 58 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
index 86ad436..e79e8a7 100644
--- a/gnu/packages/games.scm
+++ b/gnu/packages/games.scm
@@ -45,6 +45,9 @@
   #:use-module (gnu packages pulseaudio)
   #:use-module (gnu packages linux)
   #:use-module (gnu packages zip)
+  #:use-module (gnu packages xiph)
+  #:use-module (gnu packages curl)
+  #:use-module (gnu packages lua)
   #:use-module (guix build-system gnu)
   #:use-module (guix build-system cmake))
 
@@ -400,3 +403,58 @@ buffers, and audio capture.")
      "3D game engine.")
     (home-page "http://irrlicht.sourceforge.net/")
     (license bsd-3)))
+
+(define-public minetest
+  (package
+    (name "minetest")
+    (version "0.4.10")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append
+                    "https://github.com/minetest/minetest/archive/"
+                    version ".tar.gz"))
+              (sha256
+               (base32
+                "1xxv0g83iqszjgwnbdcbsprqg76cb6jnbsh5qhm7lcwx4wy2y2k2"))))
+    (build-system cmake-build-system)
+    (arguments
+     '(#:phases (alist-cons-before
+                 'configure 'set-cpath
+                 (lambda* (#:key inputs #:allow-other-keys)
+                   ;; Adjust the CPATH so that cmake can find irrlicht,
+                   ;; openal, and curl headers.
+                   (setenv "CPATH"
+                           (string-append
+                            (getenv "CPATH") ":"
+                            (assoc-ref inputs "irrlicht")
+                            "/include/irrlicht:"
+                            (assoc-ref inputs "openal")
+                            "/include/AL:"
+                            (assoc-ref inputs "curl")
+                            "/include/curl")))
+                 %standard-phases)
+       #:configure-flags '("-DRUN_IN_PLACE=0"
+                           "-DENABLE_FREETYPE=1"
+                           "-DENABLE_GETTEXT=1")
+       #:tests? #f)) ; no check target
+    (native-inputs
+     `(("pkg-config" ,pkg-config)))
+    (inputs
+     `(("irrlicht" ,irrlicht)
+       ("libpng" ,libpng)
+       ("libjpeg-8" ,libjpeg-8)
+       ("libxxf86vm" ,libxxf86vm)
+       ("mesa" ,mesa)
+       ("libogg" ,libogg)
+       ("libvorbis" ,libvorbis)
+       ("openal" ,openal)
+       ("freetype" ,(@ (gnu packages fontutils) freetype))
+       ("curl" ,curl)
+       ("luajit" ,luajit)
+       ("gettext" ,gnu-gettext)
+       ("sqlite" ,sqlite)))
+    (synopsis "Infinite-world block sandbox game")
+    (description
+     "Minetest is an infinite-world block sandbox game and a game engine.")
+    (home-page "http://minetest.net")
+    (license lgpl2.1+)))
-- 
2.1.0

Re: [PATCH 3/3] gnu: Add minetest.

[Ludovic Courtès]

David Thompson <dthompson2@worcester.edu> skribis:

> * gnu/packages/games.scm (minetest): New variable.

[...]

> +    (arguments
> +     '(#:phases (alist-cons-before
> +                 'configure 'set-cpath
> +                 (lambda* (#:key inputs #:allow-other-keys)
> +                   ;; Adjust the CPATH so that cmake can find irrlicht,
> +                   ;; openal, and curl headers.

Why is this needed?  Doesn’t CMake use `pkg-config openal --cflags` and
similar?

Perhaps ‘set-path-environment-variable’ could be used, as done for
Abbaye?

> +    (description
> +     "Minetest is an infinite-world block sandbox game and a game engine.")

Please expound a bit.

Thanks,
Ludo’.

Re: [PATCH 3/3] gnu: Add minetest.

[David Thompson]

[-- Attachment #1: Type: text/plain, Size: 1009 bytes --]

Ludovic Courtès <ludo@gnu.org> writes:

> David Thompson <dthompson2@worcester.edu> skribis:
>
>> * gnu/packages/games.scm (minetest): New variable.
>
> [...]
>
>> +    (arguments
>> +     '(#:phases (alist-cons-before
>> +                 'configure 'set-cpath
>> +                 (lambda* (#:key inputs #:allow-other-keys)
>> +                   ;; Adjust the CPATH so that cmake can find irrlicht,
>> +                   ;; openal, and curl headers.
>
> Why is this needed?  Doesn’t CMake use `pkg-config openal --cflags` and
> similar?
>

Not from what I can tell.  At least not the way this cmake file is written.

> Perhaps ‘set-path-environment-variable’ could be used, as done for
> Abbaye?
>

'set-path-environment-variable' is much cleaner.  Forgot about that
handy procedure.

>> +    (description
>> +     "Minetest is an infinite-world block sandbox game and a game engine.")
>
> Please expound a bit.
>

Added a longer description.  New patch below.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0003-gnu-Add-minetest.patch --]
[-- Type: text/x-diff, Size: 3274 bytes --]

From 55e5624ec2a18c18d5d135170cd8693dbf2c8bda Mon Sep 17 00:00:00 2001
From: David Thompson <dthompson2@worcester.edu>
Date: Fri, 5 Sep 2014 14:46:44 -0400
Subject: [PATCH 3/3] gnu: Add minetest.

* gnu/packages/games.scm (minetest): New variable.
---
 gnu/packages/games.scm | 59 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
index 3faf892..79521da 100644
--- a/gnu/packages/games.scm
+++ b/gnu/packages/games.scm
@@ -45,6 +45,9 @@
   #:use-module (gnu packages pulseaudio)
   #:use-module (gnu packages linux)
   #:use-module (gnu packages zip)
+  #:use-module (gnu packages xiph)
+  #:use-module (gnu packages curl)
+  #:use-module (gnu packages lua)
   #:use-module (guix build-system gnu)
   #:use-module (guix build-system cmake))
 
@@ -401,3 +404,59 @@ buffers, and audio capture.")
 C++.")
     (home-page "http://irrlicht.sourceforge.net/")
     (license zlib)))
+
+(define-public minetest
+  (package
+    (name "minetest")
+    (version "0.4.10")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append
+                    "https://github.com/minetest/minetest/archive/"
+                    version ".tar.gz"))
+              (sha256
+               (base32
+                "1xxv0g83iqszjgwnbdcbsprqg76cb6jnbsh5qhm7lcwx4wy2y2k2"))))
+    (build-system cmake-build-system)
+    (arguments
+     '(#:phases (alist-cons-before
+                 'configure 'set-cpath
+                 (lambda* (#:key inputs #:allow-other-keys)
+                   ;; Adjust the CPATH so that cmake can find irrlicht,
+                   ;; openal, and curl headers.
+                   (set-path-environment-variable "CPATH"
+                                                  '("include/AL"
+                                                    "include/irrlicht"
+                                                    "include/curl"
+                                                    "include")
+                                                  (map cdr inputs)))
+                 %standard-phases)
+       #:configure-flags '("-DRUN_IN_PLACE=0"
+                           "-DENABLE_FREETYPE=1"
+                           "-DENABLE_GETTEXT=1")
+       #:tests? #f)) ; no check target
+    (native-inputs
+     `(("pkg-config" ,pkg-config)))
+    (inputs
+     `(("irrlicht" ,irrlicht)
+       ("libpng" ,libpng)
+       ("libjpeg-8" ,libjpeg-8)
+       ("libxxf86vm" ,libxxf86vm)
+       ("mesa" ,mesa)
+       ("libogg" ,libogg)
+       ("libvorbis" ,libvorbis)
+       ("openal" ,openal)
+       ("freetype" ,(@ (gnu packages fontutils) freetype))
+       ("curl" ,curl)
+       ("luajit" ,luajit)
+       ("gettext" ,gnu-gettext)
+       ("sqlite" ,sqlite)))
+    (synopsis "Infinite-world block sandbox game")
+    (description
+     "Minetest is a sandbox construction game.  Players can create and destroy
+various types of blocks in a three-dimensional open world.  This allows
+forming structures in every possible creation, on multiplayer servers or as a
+single player.  Mods and texture packs allow players to personalize the game
+in different ways.")
+    (home-page "http://minetest.net")
+    (license lgpl2.1+)))
-- 
2.1.0


[-- Attachment #3: Type: text/plain, Size: 136 bytes --]


-- 
David Thompson
Web Developer - Free Software Foundation - http://fsf.org
GPG Key: 0FF1D807
Support the FSF: https://fsf.org/donate

Re: [PATCH 3/3] gnu: Add minetest.

[Ludovic Courtès]

David Thompson <dthompson2@worcester.edu> skribis:

> From 55e5624ec2a18c18d5d135170cd8693dbf2c8bda Mon Sep 17 00:00:00 2001
> From: David Thompson <dthompson2@worcester.edu>
> Date: Fri, 5 Sep 2014 14:46:44 -0400
> Subject: [PATCH 3/3] gnu: Add minetest.
>
> * gnu/packages/games.scm (minetest): New variable.

LGTM, please push.

Ludo’.

Re: [PATCH 3/3] gnu: Add minetest.

[David Thompson]

Ludovic Courtès <ludo@gnu.org> writes:

> David Thompson <dthompson2@worcester.edu> skribis:
>
>> From 55e5624ec2a18c18d5d135170cd8693dbf2c8bda Mon Sep 17 00:00:00 2001
>> From: David Thompson <dthompson2@worcester.edu>
>> Date: Fri, 5 Sep 2014 14:46:44 -0400
>> Subject: [PATCH 3/3] gnu: Add minetest.
>>
>> * gnu/packages/games.scm (minetest): New variable.
>
> LGTM, please push.

I won't be pushing this one.  I'm going to send 2 new patches that
improve on this. :)

-- 
David Thompson
Web Developer - Free Software Foundation - http://fsf.org
GPG Key: 0FF1D807
Support the FSF: https://fsf.org/donate

Re: [PATCH 1/3] gnu: Add openal.

[Ludovic Courtès]

OK