;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 David Thompson <davet@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services web)
  #:use-module (gnu services)
  #:use-module (gnu system shadow)
  #:use-module (gnu packages admin)
  #:use-module (gnu packages web)
  #:use-module (guix records)
  #:use-module (guix monads)
  #:use-module (guix store)
  #:use-module (guix gexp)
  #:export (nginx-service))

;;; Commentary:
;;;
;;; Web services.
;;;
;;; Code:

(define %default-nginx-config
  (text-file* "nginx.conf"
              "user nginx nginx;\n"
              "pid /var/run/nginx/pid;\n"
              "error_log /var/log/nginx/error.log info;\n"
              "http {\n"
              "    access_log /var/log/nginx/access.log;\n"
              "    root /var/www;\n"
              "    server {}\n"
              "}\n"
              "events {}\n"))

(define* (nginx-service #:key (nginx nginx)
                        (config-file %default-nginx-config)
                        (log-directory "/var/log/nginx")
                        (run-directory "/var/run/nginx"))
  "Return a service that runs NGINX, the nginx web server.

The nginx daemon loads its runtime configuration from CONFIG-FIGLE, stores log
files in LOG-DIRECTORY, and stores temporary runtime files in RUN-DIRECTORY."
  (define nginx* #~(string-append #$nginx "/sbin/nginx"))

  (define start-script
    (mlet %store-monad ((config-file config-file))
      (gexp->script "start-nginx"
                    #~(system* #$nginx* "-c" #$config-file
                               "-p" #$run-directory))))

  (define stop-script
    (mlet %store-monad ((config-file config-file))
      (gexp->script "stop-nginx"
                    #~(system* #$nginx* "-c" #$config-file
                               "-p" #$run-directory "-s" "stop"))))

  (define activate
    (mlet %store-monad ((config-file config-file))
      (return
       #~(begin
           (use-modules (guix build utils))
           (format #t "creating nginx log directory '~a'~%" #$log-directory)
           (mkdir-p #$log-directory)
           (format #t "creating nginx run directory '~a'~%" #$run-directory)
           (mkdir-p #$run-directory)
           ;; Check configuration file syntax.
           (system* #$nginx* "-c" #$config-file "-t")))))

  (mlet %store-monad ((start-script start-script)
                      (stop-script  stop-script)
                      (activate     activate))
    (return
     (service
      (provision '(nginx))
      (documentation "Run the nginx daemon.")
      (requirement '(user-processes loopback))
      (start #~(lambda _
                 (zero? (status:exit-val (system* #$start-script)))))
      (stop #~(lambda _
                (zero? (status:exit-val (system* #$stop-script)))))
      (activate activate)
      (user-groups (list (user-group
                          (name "nginx")
                          (system? #t))))
      (user-accounts (list (user-account
                            (name "nginx")
                            (group "nginx")
                            (system? #t)
                            (comment "nginx server user")
                            (home-directory "/var/empty")
                            (shell
                             #~(string-append #$shadow "/sbin/nologin")))))))))