From: David Craven <david@craven.ch>
To: guix-devel@gnu.org
Subject: [PATCH 1/7] build-system: Add cargo build system.
Date: Wed, 28 Sep 2016 17:15:32 +0200 [thread overview]
Message-ID: <20160928151538.11679-1-david@craven.ch> (raw)
* guix/build-system/cargo.scm (default-cargo, default-rustc,
%cargo-build-system-modules, cargo-build, lower, cargo-build-system):
New variables.
* guix/build/cargo-build-system.scm (configure, build, check, install,
%standard-phases, cargo-build): New variables.
---
guix/build-system/cargo.scm | 149 ++++++++++++++++++++++++++++++++++++++
guix/build/cargo-build-system.scm | 81 +++++++++++++++++++++
2 files changed, 230 insertions(+)
create mode 100644 guix/build-system/cargo.scm
create mode 100644 guix/build/cargo-build-system.scm
diff --git a/guix/build-system/cargo.scm b/guix/build-system/cargo.scm
new file mode 100644
index 0000000..84cb644
--- /dev/null
+++ b/guix/build-system/cargo.scm
@@ -0,0 +1,149 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2013, 2014, 2015, 2016 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
+;;; Copyright © 2013 Nikita Karetnikov <nikita@karetnikov.org>
+;;; Copyright © 2016 David Craven <david@craven.ch>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build-system cargo)
+ #:use-module (guix search-paths)
+ #:use-module (guix store)
+ #:use-module (guix utils)
+ #:use-module (guix derivations)
+ #:use-module (guix packages)
+ #:use-module (guix build-system)
+ #:use-module (guix build-system gnu)
+ #:use-module (ice-9 match)
+ #:export (cargo-build-system
+ crate-uri
+ system->rust-platform))
+
+(define (crate-uri name version)
+ "Return a URI string for the crate package hosted at crates.io corresponding
+to NAME and VERSION."
+ (string-append "https://crates.io/api/v1/crates/" name "/" version "/download"))
+
+(define (system->rust-platform system)
+ (cond
+ ((string-prefix? "x86_64" system) "x86_64-unknown-linux-gnu")
+ ((string-prefix? "i686" system) "i686-unknown-linux-gnu")))
+
+(define (default-cargo)
+ "Return the default Cargo package."
+ ;; Lazily resolve the binding to avoid a circular dependency.
+ (let ((rust (resolve-interface '(gnu packages rust))))
+ (module-ref rust 'cargo-bootstrap)))
+
+(define (default-rustc)
+ "Return the default Rustc package."
+ ;; Lazily resolve the binding to avoid a circular dependency.
+ (let ((rust (resolve-interface '(gnu packages rust))))
+ (module-ref rust 'rustc-bootstrap)))
+
+(define %cargo-build-system-modules
+ ;; Build-side modules imported by default.
+ `((guix build cargo-build-system)
+ ,@%gnu-build-system-modules))
+
+(define* (cargo-build store name inputs
+ #:key
+ (tests? #t)
+ (test-target #f)
+ (configure-flags #f)
+ (phases '(@ (guix build cargo-build-system)
+ %standard-phases))
+ (outputs '("out"))
+ (search-paths '())
+ (system (%current-system))
+ (guile #f)
+ (imported-modules %cargo-build-system-modules)
+ (modules '((guix build cargo-build-system)
+ (guix build utils))))
+ "Build SOURCE using CARGO, and with INPUTS."
+
+ (define builder
+ `(begin
+ (use-modules ,@modules)
+ (cargo-build #:name ,name
+ #:source ,(match (assoc-ref inputs "source")
+ (((? derivation? source))
+ (derivation->output-path source))
+ ((source)
+ source)
+ (source
+ source))
+ #:system ,system
+ #:test-target ,test-target
+ #:tests? ,tests?
+ #:phases ,phases
+ #:outputs %outputs
+ #:search-paths ',(map search-path-specification->sexp
+ search-paths)
+ #:inputs %build-inputs)))
+
+ (define guile-for-build
+ (match guile
+ ((? package?)
+ (package-derivation store guile system #:graft? #f))
+ (#f ; the default
+ (let* ((distro (resolve-interface '(gnu packages commencement)))
+ (guile (module-ref distro 'guile-final)))
+ (package-derivation store guile system #:graft? #f)))))
+
+ (build-expression->derivation store name builder
+ #:inputs inputs
+ #:system system
+ #:modules imported-modules
+ #:outputs outputs
+ #:guile-for-build guile-for-build))
+
+(define* (lower name
+ #:key source inputs native-inputs outputs system target
+ (cargo (default-cargo))
+ (rustc (default-rustc))
+ #:allow-other-keys
+ #:rest arguments)
+ "Return a bag for NAME."
+
+ (define private-keywords
+ '(#:source #:target #:cargo #:rustc #:inputs #:native-inputs))
+
+ (and (not target) ;; TODO: support cross-compilation
+ (bag
+ (name name)
+ (system system)
+ (target target)
+ (host-inputs `(,@(if source
+ `(("source" ,source))
+ '())
+ ,@inputs
+
+ ;; Keep the standard inputs of 'gnu-build-system'
+ ,@(standard-packages)))
+ (build-inputs `(("cargo" ,cargo)
+ ("rustc" ,rustc)
+ ,@native-inputs))
+ (outputs outputs)
+ (build (if target cargo-cross-build cargo-build))
+ (arguments (strip-keyword-arguments private-keywords arguments)))))
+
+(define cargo-build-system
+ (build-system
+ (name 'cargo)
+ (description
+ "Cargo build system, to build Rust crates")
+ (lower lower)))
diff --git a/guix/build/cargo-build-system.scm b/guix/build/cargo-build-system.scm
new file mode 100644
index 0000000..abe7e05
--- /dev/null
+++ b/guix/build/cargo-build-system.scm
@@ -0,0 +1,81 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2016 David Craven <david@craven.ch>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build cargo-build-system)
+ #:use-module ((guix build gnu-build-system) #:prefix gnu:)
+ #:use-module (guix build utils)
+ #:use-module (ice-9 match)
+ #:use-module (ice-9 ftw)
+ #:use-module (srfi srfi-1)
+ #:use-module (srfi srfi-26)
+ #:export (%standard-phases
+ cargo-build))
+
+;; Commentary:
+;;
+;; Builder-side code of the standard Rust package build procedure.
+;;
+;; Code:
+
+(define* (configure #:rest _)
+ "Replace Cargo.toml [dependencies] section with guix inputs."
+ ;; TODO
+ #t)
+
+(define* (build #:key (cargo-build-flags '("--release")) #:allow-other-keys)
+ "Build a given Cargo package."
+ (zero? (apply system* `("cargo" "build" ,@cargo-build-flags))))
+
+(define* (check #:rest _)
+ "Run tests for a given Cargo package."
+ (zero? (system* "cargo" "test")))
+
+(define* (install #:key inputs outputs #:allow-other-keys)
+ "Install a given Cargo package."
+ (let* ((out (assoc-ref outputs "out"))
+ (src (assoc-ref inputs "source"))
+ (bin (string-append out "/bin"))
+ (rsrc (string-append out "/rustsrc")))
+ (mkdir-p rsrc)
+ ;; Rust doesn't have a stable ABI yet. Because of this
+ ;; Cargo doesn't have a search path for binaries yet.
+ ;; Until this changes we are working around this by
+ ;; distributing crates as source and replacing
+ ;; references in Cargo.toml with store paths.
+ (copy-recursively "src" (string-append rsrc "/src"))
+ (install-file "Cargo.toml" rsrc)
+ ;; When the package includes executables we install
+ ;; it using cargo install. This fails when the crate
+ ;; doesn't contain an executable.
+ (system* "cargo" "install" "--root" bin)
+ #t))
+
+(define %standard-phases
+ ;; 'configure' phase is not needed.
+ (modify-phases gnu:%standard-phases
+ (replace 'configure configure)
+ (replace 'build build)
+ (replace 'check check)
+ (replace 'install install)))
+
+(define* (cargo-build #:key inputs (phases %standard-phases)
+ #:allow-other-keys #:rest args)
+ "Build the given Cargo package, applying all of PHASES in order."
+ (apply gnu:gnu-build #:inputs inputs #:phases phases args))
+
+;;; cargo-build-system.scm ends here
--
2.9.0
next reply other threads:[~2016-09-28 15:16 UTC|newest]
Thread overview: 32+ messages / expand[flat|nested] mbox.gz Atom feed top
2016-09-28 15:15 David Craven [this message]
2016-09-28 15:15 ` [PATCH 2/7] import: Add importer for rust crates David Craven
2016-10-04 9:14 ` Ludovic Courtès
2016-09-28 15:15 ` [PATCH 3/7] import: crate: Add crate updater David Craven
2016-10-04 9:05 ` Ludovic Courtès
2016-09-28 15:15 ` [PATCH 4/7] upstream: Use a the first url from urls when find2 returns #f David Craven
2016-09-28 15:19 ` David Craven
2016-10-04 9:07 ` Ludovic Courtès
2016-09-28 15:15 ` [PATCH 5/7] gnu: Add rustc-bootstrap David Craven
2016-09-28 15:20 ` David Craven
2016-09-29 12:35 ` David Craven
2016-10-04 8:57 ` Ludovic Courtès
2016-10-04 9:11 ` ng0
2016-10-04 13:09 ` Ludovic Courtès
2016-10-04 13:55 ` ng0
2016-10-04 13:59 ` David Craven
2016-10-04 14:11 ` ng0
2016-10-04 8:59 ` Ludovic Courtès
2016-09-28 15:15 ` [PATCH 6/7] gnu: Add cargo-bootstrap David Craven
2016-10-04 9:11 ` Ludovic Courtès
2016-09-28 15:15 ` [PATCH 7/7] gnu: Add rust-libc David Craven
2016-09-30 7:21 ` [PATCH 1/7] build-system: Add cargo build system Ricardo Wurmus
2016-09-30 10:49 ` David Craven
2016-10-04 9:03 ` Ludovic Courtès
2016-12-09 12:17 ` ng0
2016-12-09 14:17 ` Ludovic Courtès
2016-12-11 19:47 ` David Craven
2016-12-13 17:15 ` Ludovic Courtès
2016-12-13 18:07 ` David Craven
2016-12-13 22:11 ` Ludovic Courtès
2016-12-14 11:48 ` David Craven
2016-12-15 15:45 ` Ludovic Courtès
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://guix.gnu.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20160928151538.11679-1-david@craven.ch \
--to=david@craven.ch \
--cc=guix-devel@gnu.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/guix.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).