[PATCH] gnu: Add nfs-utils

[PATCH] gnu: Add nfs-utils

[John Darrington]

* gnu/packages/linux.scm (nfs-utils): New variable.
---
 gnu/packages/linux.scm | 87 +++++++++++++++++++++++++++++++++++++++++++++++++-
 1 file changed, 86 insertions(+), 1 deletion(-)

diff --git a/gnu/packages/linux.scm b/gnu/packages/linux.scm
index 030e35e..eb9cb03 100644
--- a/gnu/packages/linux.scm
+++ b/gnu/packages/linux.scm
@@ -55,9 +55,14 @@
   #:use-module (gnu packages gnuzilla)
   #:use-module (gnu packages gperf)
   #:use-module (gnu packages gtk)
+  #:use-module (gnu packages gsasl)
+  #:use-module (gnu packages libevent)
   #:use-module (gnu packages libusb)
   #:use-module (gnu packages maths)
+  #:use-module (gnu packages mit-krb5)
   #:use-module (gnu packages ncurses)
+  #:use-module (gnu packages networking)
+  #:use-module (gnu packages onc-rpc)
   #:use-module (gnu packages perl)
   #:use-module (gnu packages pciutils)
   #:use-module (gnu packages pkg-config)
@@ -228,6 +233,86 @@ the default @code{nsswitch} and the experimental @code{umich_ldap}.")
     (license (license:non-copyleft "file://COPYING"
                                    "See COPYING in the distribution."))))
 
+(define-public nfs-utils
+  (package
+    (name "nfs-utils")
+    (version "1.3.4")
+    (source (origin
+             (method url-fetch)
+             (uri (string-append
+                   "mirror://kernel.org/linux/utils/nfs-utils/" version
+                   "/nfs-utils-" version ".tar.xz"))
+             (sha256
+              (base32
+               "0xarqhwy757vazv9gqhyrgxsrx083yhvkkih01jh83fqm305naml"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:configure-flags
+       `("--without-tcp-wrappers"
+         ,(string-append "--with-start-statd="
+                         (assoc-ref %outputs "out") "/sbin/start-statd")
+         ,(string-append "--with-krb5=" (assoc-ref %build-inputs "mit-krb5")))
+       #:phases (modify-phases %standard-phases
+                  (add-before
+                      'configure 'mutate-source
+                    (lambda _
+                      ;; Eventually, we should provide our own start-statd
+                      ;; script instead ... one which starts the rpc.statd
+                      ;; service (which we don't yet have)
+                      (substitute* `("utils/statd/start-statd")
+                        (("^PATH=.*") "")
+                        (("^flock")
+                         (string-append
+                          (assoc-ref %build-inputs "util-linux")
+                          "/bin/flock"))
+                        (("^exec rpc.statd")
+                         (string-append "exec "
+                          (assoc-ref %outputs "out") "/sbin/rpc.statd")))
+
+                      ;; This hook tries to write to /var
+                      ;; That needs to be done by a service too.
+                      (substitute* `("Makefile.in")
+                        (("^install-data-hook:")
+                         "install-data-hook-disabled-for-guix:"))
+
+                      ;; Replace some hard coded paths
+                      (substitute* `("utils/nfsd/nfssvc.c")
+                        (("/bin/mount")
+                         (string-append
+                          (assoc-ref %build-inputs "util-linux")
+                          "/bin/mount")))
+                      (substitute* `("utils/statd/statd.c")
+                        (("/usr/sbin/")
+                         (string-append (assoc-ref %outputs "out") "/sbin/")))
+                      (substitute* `("utils/osd_login/Makefile.in"
+                                     "utils/mount/Makefile.in"
+                                     "utils/nfsdcltrack/Makefile.in")
+                        (("^sbindir = /sbin")
+                         (string-append "sbindir = "
+                                        (assoc-ref %outputs "out") "/sbin"))))))))
+    (inputs `(("libevent" ,libevent)
+              ("libnfsidmap" ,libnfsidmap)
+              ("sqlite" ,sqlite)
+              ("lvm2" ,lvm2)
+              ("gss" ,gss)
+              ("util-linux" ,util-linux)
+              ("mit-krb5" ,mit-krb5)
+              ("libtirpc" ,libtirpc)))
+    (native-inputs
+     `(("pkg-config" ,pkg-config)))
+    (home-page "http://www.kernel.org/pub/linux/utils/nfs-utils/")
+    (synopsis "Tools for loading and managing Linux NFS mounts")
+    (description "The Network File System (NFS) was developed to allow
+machines to mount a disk partition on a remote machine as if it were a local
+disk.  It allows for fast, seamless sharing of files across a network.")
+    ;; It is hard to be sure what the licence is.  Most of the source files
+    ;; contain no licence notice at all.  A few have a licence notice for a 3
+    ;; clause non-copyleft licence.  However the tarball has a COPYING file
+    ;; with the text of GPLv2 -- It seems then that GLPv2 is the most
+    ;; restrictive licence, and until advice to the contrary we must assume
+    ;; that is what is intended.
+    (license license:gpl2)))
+
 (define %boot-logo-patch
   ;; Linux-Libre boot logo featuring Freedo and a gnu.
   (origin
@@ -2183,7 +2268,7 @@ WLAN, Bluetooth and mobile broadband.")
     (version "1.7")
     (source (origin
               (method url-fetch)
-              (uri (string-append "mirror://sourceforge/acpiclient/acpiclient/" 
+              (uri (string-append "mirror://sourceforge/acpiclient/acpiclient/"
                                   version "/" name "-" version ".tar.gz"))
               (sha256
                (base32
-- 
2.1.4

Re: [PATCH] gnu: Add nfs-utils

[Danny Milosavljevic]

> +       `("--without-tcp-wrappers"
            ^^^
Since you also provided tcp-wrappers in a seperate patch, was this on purpose?

Re: [PATCH] gnu: Add nfs-utils

[John Darrington]

[-- Attachment #1: Type: text/plain, Size: 535 bytes --]

On Wed, Sep 07, 2016 at 10:29:37PM +0200, Danny Milosavljevic wrote:
     > +       `("--without-tcp-wrappers"
                 ^^^
     Since you also provided tcp-wrappers in a seperate patch, was this on purpose?

Yes. It was.   There are some unresolved issues with tcp-wrappers vs. NFS.

J'

-- 
Avoid eavesdropping.  Send strong encrypted email.
PGP Public key ID: 1024D/2DE827B3 
fingerprint = 8797 A26D 0854 2EAB 0285  A290 8A67 719C 2DE8 27B3
See http://sks-keyservers.net or any PGP keyserver for public key.


[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 181 bytes --]

Re: [PATCH] gnu: Add nfs-utils

[Ludovic Courtès]

John Darrington <jmd@gnu.org> skribis:

> * gnu/packages/linux.scm (nfs-utils): New variable.

(gnu packages linux) was meant for things that use non-portable
interfaces of the kernel Linux.  I don’t think that is the case here?

So maybe this should go to (gnu packages onc-rpc) or (gnu packages nfs).

> +       #:phases (modify-phases %standard-phases
> +                  (add-before
> +                      'configure 'mutate-source

Move to line above.

Maybe ‘adjust-command-file-names’ would be more descriptive a phase
name?

> +                    (lambda _
> +                      ;; Eventually, we should provide our own start-statd
> +                      ;; script instead ... one which starts the rpc.statd
> +                      ;; service (which we don't yet have)
> +                      (substitute* `("utils/statd/start-statd")
> +                        (("^PATH=.*") "")
> +                        (("^flock")
> +                         (string-append
> +                          (assoc-ref %build-inputs "util-linux")
> +                          "/bin/flock"))
> +                        (("^exec rpc.statd")
> +                         (string-append "exec "
> +                          (assoc-ref %outputs "out") "/sbin/rpc.statd")))

I think the comment should probably mention something like “Remove FHS
assumptions from the 'start-statd' script.”  The bit about the need for
a service is not really relevant here, IMO.

Please punctuate sentences too.  :-)

> +    ;; It is hard to be sure what the licence is.  Most of the source files
> +    ;; contain no licence notice at all.  A few have a licence notice for a 3
> +    ;; clause non-copyleft licence.  However the tarball has a COPYING file
> +    ;; with the text of GPLv2 -- It seems then that GLPv2 is the most
> +    ;; restrictive licence, and until advice to the contrary we must assume
> +    ;; that is what is intended.
> +    (license license:gpl2)))

I think this should be gpl2+ unless the “or later version” wording has
been explicitly removed.

OK with these changes, thanks!

Ludo’.