[PATCH 00/13] KDE Frameworks Tier 2 packages and phonon/gpgmepp.

[PATCH 00/13] KDE Frameworks Tier 2 packages and phonon/gpgmepp.

[David Craven]

kactivities-stats is also listed as a tier 2 package on the KDE Frameworks
website, but since kactivities (a tier 3 package) is a dependency, I'm putting
it with the tier 3 packages.

David Craven (13):
  gnu: kde-frameworks: Add phonon.
  gnu: kde-frameworks: Add kauth.
  gnu: kde-frameworks: Add kcompletion.
  gnu: kde-frameworks: Add kcrash.
  gnu: kde-frameworks: Add kdoctools.
  gnu: kde-frameworks: Add kfilemetadata.
  gnu: kde-frameworks: Add kimageformats.
  gnu: kde-frameworks: Add kjobwidgets.
  gnu: kde-frameworks: Add knotifications.
  gnu: kde-frameworks: Add kpackage.
  gnu: kde-frameworks: Add kpty.
  gnu: kde-frameworks: Add kunitconversion.
  gnu: kde-frameworks: Add gpgmepp.

 gnu/packages/kde-frameworks.scm | 471 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 471 insertions(+)

--
2.9.0

[PATCH 01/13] gnu: kde-frameworks: Add phonon.

[David Craven]

---
 gnu/packages/kde-frameworks.scm | 28 ++++++++++++++++++++++++++++
 1 file changed, 28 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index a679c64..875d94a 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -77,6 +77,34 @@ modules provided by CMake to find common software.  In addition, it provides
 common build settings used in software produced by the KDE community.")
     (license license:bsd-3)))
 
+(define-public phonon
+  (package
+    (name "phonon")
+    (version "4.9.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/phonon"
+                            "/" version "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "1q5hvsk4sfcb91625wcmldy7kgjmfpmpmkgzi6mxkqdd307v8x5v"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)))
+    (inputs
+     `(("qtbase" ,qtbase)))
+    (arguments
+     `(#:configure-flags
+       '("-DCMAKE_CXX_FLAGS=-fPIC"
+         "-DPHONON_BUILD_PHONON4QT5=ON")))
+    (home-page "https://phonon.kde.org")
+    (synopsis "KDE's multimedia library")
+    (description "KDE's multimedia library.")
+    (license license:lgpl2.1+)))
+
+
 ;; Tier 1
 ;;
 ;; Tier 1 frameworks depend only on Qt (and possibly a small number of other
-- 
2.9.0

[PATCH 02/13] gnu: kde-frameworks: Add kauth.

[David Craven]

* gnu/packages/kde-frameworks.scm (kauth): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 43 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index 875d94a..ca57e58 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -34,6 +34,7 @@
   #:use-module (gnu packages gnome)
   #:use-module (gnu packages linux)
   #:use-module (gnu packages pkg-config)
+  #:use-module (gnu packages polkit)
   #:use-module (gnu packages python)
   #:use-module (gnu packages qt)
   #:use-module (gnu packages xorg))
@@ -1020,3 +1021,45 @@ ASpell and HUNSPELL.")
     (description "ThreadWeaver is a helper for multithreaded programming.  It
 uses a job-based interface to queue tasks and execute them in an efficient way.")
     (license license:lgpl2.1+)))
+
+
+;; Tier 2
+;;
+;; Tier 2 frameworks additionally depend on tier 1 frameworks, but still have
+;; easily manageable dependencies.
+
+(define-public kauth
+  (package
+    (name "kauth")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "14sjjfgl3arqyqcr77w9qhpnd8mrnh53r5rfss6bvlk26bmihs49"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("dbus" ,dbus)
+       ("extra-cmake-modules" ,extra-cmake-modules)
+       ("qttools" ,qttools)))
+    (inputs
+     `(("kcoreaddons" ,kcoreaddons)
+       ("polkit-qt" ,polkit-qt)
+       ("qtbase" ,qtbase)))
+    (arguments
+     `(#:phases
+        (modify-phases %standard-phases
+          (replace 'check
+            (lambda* _
+              (setenv "DBUS_FATAL_WARNINGS" "0")
+              (zero? (system* "dbus-launch" "ctest" ".")))))))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Execute actions as privileged user")
+    (description "KAuth provides a convenient, system-integrated way to offload
+actions that need to be performed as a privileged user to small set of helper
+utilities.")
+    (license license:lgpl2.1+)))
-- 
2.9.0

[PATCH 03/13] gnu: kde-frameworks: Add kcompletion.

[David Craven]

* gnu/packages/kde-frameworks.scm (kcompletion): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 42 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index ca57e58..572edb8 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -1063,3 +1063,45 @@ uses a job-based interface to queue tasks and execute them in an efficient way."
 actions that need to be performed as a privileged user to small set of helper
 utilities.")
     (license license:lgpl2.1+)))
+
+(define-public kcompletion
+  (package
+    (name "kcompletion")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "1qln0v31gn86kzwhnkijr1ydf129n32jmiybbckrp4w6hyx6xfxv"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)
+       ("qttools" ,qttools)
+       ("xorg-server" ,xorg-server)))
+    (inputs
+     `(("kconfig" ,kconfig)
+       ("kwidgetsaddons" ,kwidgetsaddons)
+       ("qtbase" ,qtbase)))
+    (arguments
+     `(#:phases
+        (modify-phases %standard-phases
+          (add-before 'check 'check-setup
+            (lambda* _
+              (setenv "DBUS_FATAL_WARNINGS" "0")))
+          (add-before 'check 'start-xorg-server
+            (lambda* (#:key inputs #:allow-other-keys)
+              ;; The test suite requires a running X server.
+              (system (string-append (assoc-ref inputs "xorg-server")
+                                     "/bin/Xvfb :1 &"))
+              (setenv "DISPLAY" ":1")
+             #t)))))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Powerful autocompletion framework and widgets")
+    (description "This framework helps implement autocompletion in Qt-based
+applications.  It provides a set of completion-ready widgets, or can be
+integrated it into your application's other widgets.")
+    (license license:lgpl2.1+)))
-- 
2.9.0

Re: [PATCH 03/13] gnu: kde-frameworks: Add kcompletion.

[Mark H Weaver]

David Craven <david@craven.ch> writes:

> * gnu/packages/kde-frameworks.scm (kcompletion): New variable.
>
> Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>

This fails to build on hydra:

  https://hydra.gnu.org/eval/109095?filter=kcompletion

      Mark

Re: [PATCH 03/13] gnu: kde-frameworks: Add kcompletion.

[David Craven]

Fixed in 548f99b3e0d3647f29ddc3c3864ca36b655f14ec.

[PATCH 04/13] gnu: kde-frameworks: Add kcrash.

[David Craven]

* gnu/packages/kde-frameworks.scm (kcrash): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index 572edb8..6fc0c85 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -1105,3 +1105,41 @@ utilities.")
 applications.  It provides a set of completion-ready widgets, or can be
 integrated it into your application's other widgets.")
     (license license:lgpl2.1+)))
+
+(define-public kcrash
+  (package
+    (name "kcrash")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "1lahgfwlp9b5rsl244kzp7rsl4ybv1q4qlvpv0xxz5ygssk48l0w"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)
+       ("xorg-server" ,xorg-server)))
+    (inputs
+     `(("kcoreaddons" ,kcoreaddons)
+       ("kwindowsystem" ,kwindowsystem)
+       ("qtbase" ,qtbase)
+       ("qtx11extras" ,qtx11extras)))
+    (arguments
+     `(#:phases
+        (modify-phases %standard-phases
+          (add-before 'check 'start-xorg-server
+            (lambda* (#:key inputs #:allow-other-keys)
+              ;; The test suite requires a running X server.
+              (system (string-append (assoc-ref inputs "xorg-server")
+                                     "/bin/Xvfb :1 &"))
+              (setenv "DISPLAY" ":1")
+             #t)))))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Graceful handling of application crashes")
+    (description "KCrash provides support for intercepting and handling
+application crashes.")
+    (license license:lgpl2.1+)))
-- 
2.9.0

[PATCH 05/13] gnu: kde-frameworks: Add kdoctools.

[David Craven]

* gnu/packages/kde-frameworks.scm (kdoctools): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 51 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index 6fc0c85..85aad67 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -28,15 +28,19 @@
   #:use-module (gnu packages admin)
   #:use-module (gnu packages bison)
   #:use-module (gnu packages compression)
+  #:use-module (gnu packages docbook)
   #:use-module (gnu packages freedesktop)
   #:use-module (gnu packages gettext)
   #:use-module (gnu packages glib)
   #:use-module (gnu packages gnome)
   #:use-module (gnu packages linux)
+  #:use-module (gnu packages perl)
   #:use-module (gnu packages pkg-config)
   #:use-module (gnu packages polkit)
   #:use-module (gnu packages python)
   #:use-module (gnu packages qt)
+  #:use-module (gnu packages web)
+  #:use-module (gnu packages xml)
   #:use-module (gnu packages xorg))
 
 (define-public extra-cmake-modules
@@ -1143,3 +1147,50 @@ integrated it into your application's other widgets.")
     (description "KCrash provides support for intercepting and handling
 application crashes.")
     (license license:lgpl2.1+)))
+
+(define-public kdoctools
+  (package
+    (name "kdoctools")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "1r129kpq0d11b9l87cqbal6fm5ycwhsps1g3r1a7jsxz70scz4ri"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)))
+    (inputs
+     `(("docbook-xml" ,docbook-xml)
+       ("docbook-xsl" ,docbook-xsl)
+       ("karchive" ,karchive)
+       ("ki18n" ,ki18n)
+       ("libxml2" ,libxml2)
+       ("libxslt" ,libxslt)
+       ("perl" ,perl)
+       ("perl-uri" ,perl-uri)
+       ("qtbase" ,qtbase)))
+    (arguments
+     `(#:phases
+        (modify-phases %standard-phases
+          (add-after 'unpack 'cmake-find-docbook
+            (lambda* (#:key inputs #:allow-other-keys)
+              (substitute* (find-files "cmake" "\\.cmake$")
+                (("CMAKE_SYSTEM_PREFIX_PATH")
+                  "CMAKE_PREFIX_PATH"))
+               (substitute* "cmake/FindDocBookXML4.cmake"
+                 (("^.*xml/docbook/schema/dtd.*$")
+                   "xml/dtd/docbook\n"))
+               (substitute* "cmake/FindDocBookXSL.cmake"
+                 (("^.*xml/docbook/stylesheet.*$")
+                  (string-append "xml/xsl/docbook-xsl-"
+                                 ,(package-version docbook-xsl) "\n"))))))))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Create documentation from DocBook")
+    (description "Provides tools to generate documentation in various format
+from DocBook files.")
+    (license license:lgpl2.1+)))
-- 
2.9.0

[PATCH 06/13] gnu: kde-frameworks: Add kfilemetadata.

[David Craven]

* gnu/packages/kde-frameworks.scm (kfilemetadata): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index 85aad67..0c3e809 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -26,6 +26,7 @@
   #:use-module (guix packages)
   #:use-module (guix utils)
   #:use-module (gnu packages admin)
+  #:use-module (gnu packages attr)
   #:use-module (gnu packages bison)
   #:use-module (gnu packages compression)
   #:use-module (gnu packages docbook)
@@ -1194,3 +1195,33 @@ application crashes.")
     (description "Provides tools to generate documentation in various format
 from DocBook files.")
     (license license:lgpl2.1+)))
+
+(define-public kfilemetadata
+  (package
+    (name "kfilemetadata")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "02n9qhpr0jlwdgdbid0k34abhs3bzhlsa56ybl5dq1aib6izk1sy"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)
+       ("python-2" ,python-2)))
+    (inputs
+     `(("attr" ,attr)
+       ("karchive" ,karchive)
+       ("ki18n" ,ki18n)
+       ("qtbase" ,qtbase)))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Extract metadata from different fileformats")
+    (description "KFileMetaData provides a simple library for extracting the
+text and metadata from a number of different files.  This library is typically
+used by file indexers to retreive the metadata.  This library can also be used
+by applications to write metadata.")
+    (license (list license:lgpl2.0 license:lgpl2.1 license:lgpl3))))
-- 
2.9.0

[PATCH 07/13] gnu: kde-frameworks: Add kimageformats.

[David Craven]

* gnu/packages/kde-frameworks.scm (kimageformats): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index 0c3e809..eeedbdd 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -1225,3 +1225,40 @@ text and metadata from a number of different files.  This library is typically
 used by file indexers to retreive the metadata.  This library can also be used
 by applications to write metadata.")
     (license (list license:lgpl2.0 license:lgpl2.1 license:lgpl3))))
+
+(define-public kimageformats
+  (package
+    (name "kimageformats")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "12mhgckmhnvcnm8k7mk15mipxrnm7i9ip7ykbjh8nxjiwyk1pmwc"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)
+       ("xorg-server" ,xorg-server)))
+    (inputs
+     `(("qtbase" ,qtbase)))
+    (arguments
+     `(#:phases
+       (modify-phases %standard-phases
+         (add-before 'check 'start-xorg-server
+           (lambda* (#:key inputs #:allow-other-keys)
+             ;; The test suite requires a running X server.
+             (system (string-append (assoc-ref inputs "xorg-server")
+                                    "/bin/Xvfb :1 &"))
+             (setenv "DISPLAY" ":1")
+            #t)))))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Plugins to allow QImage to support extra file formats")
+    (description "This framework provides additional image format plugins for
+QtGui.  As such it is not required for the compilation of any other software,
+but may be a runtime requirement for Qt-based software to support certain image
+formats.")
+    (license license:lgpl2.1+)))
-- 
2.9.0

[PATCH 08/13] gnu: kde-frameworks: Add kjobwidgets.

[David Craven]

* gnu/packages/kde-frameworks.scm (kjobwidgets): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 28 ++++++++++++++++++++++++++++
 1 file changed, 28 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index eeedbdd..428a525 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -1262,3 +1262,31 @@ QtGui.  As such it is not required for the compilation of any other software,
 but may be a runtime requirement for Qt-based software to support certain image
 formats.")
     (license license:lgpl2.1+)))
+
+(define-public kjobwidgets
+  (package
+    (name "kjobwidgets")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "1mcvrz66xcqjgbp08zpqsf943cm462wbqm5gh719p9s25hx8hwrc"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)
+       ("qttools" ,qttools)))
+    (inputs
+     `(("kcoreaddons" ,kcoreaddons)
+       ("kwidgetsaddons" ,kwidgetsaddons)
+       ("qtbase" ,qtbase)
+       ("qtx11extras" ,qtx11extras)))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Widgets for showing progress of asynchronous jobs")
+    (description "KJobWIdgets provides widgets for showing progress of
+asynchronous jobs.")
+    (license license:lgpl2.1+)))
-- 
2.9.0

[PATCH 09/13] gnu: kde-frameworks: Add knotifications.

[David Craven]

* gnu/packages/kde-frameworks.scm (knotifications): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 42 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index 428a525..0e39a4a 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -1290,3 +1290,45 @@ formats.")
     (description "KJobWIdgets provides widgets for showing progress of
 asynchronous jobs.")
     (license license:lgpl2.1+)))
+
+(define-public knotifications
+  (package
+    (name "knotifications")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "0qryp41phnpx4r9wa6rfhmnzy7nxl0ijnyrafadf2n2xb53ipkpa"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)
+       ("dbus" ,dbus)
+       ("qttools" ,qttools)))
+    (inputs
+     `(("kcodecs" ,kcodecs)
+       ("kconfig" ,kconfig)
+       ("kcoreaddons" ,kcoreaddons)
+       ("kwindowsystem" ,kwindowsystem)
+       ("phonon" ,phonon)
+       ("qtbase" ,qtbase)
+       ("qtx11extras" ,qtx11extras)))
+    (arguments
+     `(#:phases
+       (modify-phases %standard-phases
+         (add-before 'check 'check-setup
+           (lambda* _
+             (setenv "HOME" (getcwd))))
+         (replace 'check
+           (lambda* _
+             (setenv "DBUS_FATAL_WARNINGS" "0")
+             (zero? (system* "dbus-launch" "ctest" ".")))))))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Desktop notifications")
+    (description "KNotification is used to notify the user of an event.  It
+covers feedback and persistent events.")
+    (license license:lgpl2.1+)))
-- 
2.9.0

[PATCH 10/13] gnu: kde-frameworks: Add kpackage.

[David Craven]

* gnu/packages/kde-frameworks.scm (kpackage): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index 0e39a4a..082942c 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -1332,3 +1332,44 @@ asynchronous jobs.")
     (description "KNotification is used to notify the user of an event.  It
 covers feedback and persistent events.")
     (license license:lgpl2.1+)))
+
+(define-public kpackage
+  (package
+    (name "kpackage")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "03aqzkpqz3c1v4qgwfbs3ncdbapiyg7psrkhxqv3z48rklavk1ri"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)))
+    (inputs
+     `(("karchive" ,karchive)
+       ("kconfig" ,kconfig)
+       ("kcoreaddons" ,kcoreaddons)
+       ("ki18n" ,ki18n)
+       ("qtbase" ,qtbase)))
+    (arguments
+     `(#:tests? #f ; FIXME: 1/4 tests fail.
+       #:phases
+       (modify-phases %standard-phases
+         (add-after 'unpack 'patch-test
+           (lambda* _
+             (substitute* "autotests/packagestructuretest.cpp"
+                (("//qDebug\\(\\) << path;") "qDebug() << path;"))))
+         (add-before 'check 'check-setup
+           (lambda* _
+             (setenv "HOME" (getcwd))
+             (setenv "CTEST_OUTPUT_ON_FAILURE" "1"))))))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Installation and loading of additional content as packages")
+    (description "The Package framework lets the user install and load packages
+of non binary content such as scripted extensions or graphic assets, as if they
+were traditional plugins.")
+    (license (list license:gpl2+ license:lgpl2.1+))))
-- 
2.9.0

Re: [PATCH 10/13] gnu: kde-frameworks: Add kpackage.

[Leo Famulari]

On Sat, Aug 13, 2016 at 02:19:28PM +0200, David Craven wrote:
> * gnu/packages/kde-frameworks.scm (kpackage): New variable.

> +    (arguments
> +     `(#:tests? #f ; FIXME: 1/4 tests fail.
> +       #:phases
> +       (modify-phases %standard-phases
> +         (add-after 'unpack 'patch-test
> +           (lambda* _
> +             (substitute* "autotests/packagestructuretest.cpp"
> +                (("//qDebug\\(\\) << path;") "qDebug() << path;"))))

So, this is "un-commenting" the line, right? Will you add a comment in
the package definition explaining why we do it?

Re: [PATCH 10/13] gnu: kde-frameworks: Add kpackage.

[David Craven]

Right. I can just as well remove it, since I don't think it's actually
doing anything... Good to go otherwise?

[PATCH 11/13] gnu: kde-frameworks: Add kpty.

[David Craven]

* gnu/packages/kde-frameworks.scm (kpty): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index 082942c..1cc132f 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -1373,3 +1373,40 @@ covers feedback and persistent events.")
 of non binary content such as scripted extensions or graphic assets, as if they
 were traditional plugins.")
     (license (list license:gpl2+ license:lgpl2.1+))))
+
+(define-public kpty
+  (package
+    (name "kpty")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "1ybvdzqpa53kkki9p5da0ff9x3c63rmksk7865wqwlgy8apzi2fs"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)))
+    (inputs
+     `(("kcoreaddons" ,kcoreaddons)
+       ("ki18n" ,ki18n)
+       ("qtbase" ,qtbase)))
+    (arguments
+     `(#:tests? #f ; FIXME: 1/1 tests fail.
+       #:phases
+       (modify-phases %standard-phases
+         (add-after 'unpack 'patch-tests
+         (lambda _
+           (setenv "CTEST_OUTPUT_ON_FAILURE" "1")
+           (substitute* "autotests/kptyprocesstest.cpp"
+             (("/bin/bash") (which "bash")))
+           #t)))))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Interfacing with pseudo terminal devices")
+    (description "This library provides primitives to interface with pseudo
+terminal devices as well as a KProcess derived class for running child processes
+and communicating with them using a pty.")
+    (license (list license:gpl2+ license:lgpl2.1+))))
-- 
2.9.0

Re: [PATCH 11/13] gnu: kde-frameworks: Add kpty.

[Leo Famulari]

On Sat, Aug 13, 2016 at 02:19:29PM +0200, David Craven wrote:
> * gnu/packages/kde-frameworks.scm (kpty): New variable.

> +    (arguments
> +     `(#:tests? #f ; FIXME: 1/1 tests fail.
> +       #:phases
> +       (modify-phases %standard-phases
> +         (add-after 'unpack 'patch-tests
> +         (lambda _
> +           (setenv "CTEST_OUTPUT_ON_FAILURE" "1")

Can you add a comment explaining why we set this variable? I'm guessing
it enables verbose output of failed tests?

[PATCH 12/13] gnu: kde-frameworks: Add kunitconversion.

[David Craven]

* gnu/packages/kde-frameworks.scm (kunitconversion): New variable.

Co-authored-by: Hartmut Goebel <h.goebel@crazy-compilers.com>
---
 gnu/packages/kde-frameworks.scm | 27 +++++++++++++++++++++++++++
 1 file changed, 27 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index 1cc132f..cb942bf 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -1410,3 +1410,30 @@ were traditional plugins.")
 terminal devices as well as a KProcess derived class for running child processes
 and communicating with them using a pty.")
     (license (list license:gpl2+ license:lgpl2.1+))))
+
+(define-public kunitconversion
+  (package
+    (name "kunitconversion")
+    (version "5.24.0")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/frameworks/"
+                            (version-major+minor version) "/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "03dfjn4lm6sl2zcdrvw0b9irzvkyc2w2j5xixag5j8nw373742h8"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)))
+    (inputs
+     `(("ki18n" ,ki18n)
+       ("qtbase" ,qtbase)))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "Converting physical units")
+    (description "KUnitConversion provides functions to convert values in
+different physical units.  It supports converting different prefixes (e.g. kilo,
+mega, giga) as well as converting between different unit systems (e.g. liters,
+gallons).")
+    (license license:lgpl2.1+)))
-- 
2.9.0

[PATCH 13/13] gnu: kde-frameworks: Add gpgmepp.

[David Craven]

* gnu/packages/kde-frameworks.scm (gpgmepp): New variable.
---
 gnu/packages/kde-frameworks.scm | 26 ++++++++++++++++++++++++++
 1 file changed, 26 insertions(+)

diff --git a/gnu/packages/kde-frameworks.scm b/gnu/packages/kde-frameworks.scm
index cb942bf..f248343 100644
--- a/gnu/packages/kde-frameworks.scm
+++ b/gnu/packages/kde-frameworks.scm
@@ -110,6 +110,32 @@ common build settings used in software produced by the KDE community.")
     (description "KDE's multimedia library.")
     (license license:lgpl2.1+)))
 
+(define-public gpgmepp
+  (package
+    (name "gpgmepp")
+    (version "16.04.3")
+    (source
+      (origin
+        (method url-fetch)
+        (uri (string-append "mirror://kde/stable/applications"
+                            "/" version "/src/"
+                            name "-" version ".tar.xz"))
+        (sha256
+         (base32
+          "1850pdysi7c1w0nxnhcbrhnkrfqyrcl0laxyjcw1g1ln764pwcmj"))))
+    (build-system cmake-build-system)
+    (native-inputs
+     `(("extra-cmake-modules" ,extra-cmake-modules)))
+    (propagated-inputs
+     `(("boost" ,boost)
+       ("gpgme" ,gpgme)))
+    (inputs
+     `(("qtbase" ,qtbase)))
+    (home-page "https://community.kde.org/Frameworks")
+    (synopsis "C++ bindings/wrapper for gpgme")
+    (description "C++ bindings/wrapper for gpgme.")
+    (license license:lgpl2.1+)))
+
 
 ;; Tier 1
 ;;
-- 
2.9.0

Re: [PATCH 00/13] KDE Frameworks Tier 2 packages and phonon/gpgmepp.

[Andreas Enge]

On Sat, Aug 13, 2016 at 02:19:18PM +0200, David Craven wrote:
> kactivities-stats is also listed as a tier 2 package on the KDE Frameworks
> website, but since kactivities (a tier 3 package) is a dependency, I'm putting
> it with the tier 3 packages.

Well, it would be a tier 4 package then, no?

Andreas

Re: [PATCH 00/13] KDE Frameworks Tier 2 packages and phonon/gpgmepp.

[David Craven]

Nope, tier 3 packages have quite a few inter-dependencies. There is
currently only one tier 4 package. Quoting the website:

"Tier 4 frameworks can be mostly ignored by application programmers;
this tier consists of plugins acting behind the scenes to provide
additional functionality or platform integration to existing
frameworks (including Qt)."

Currently I can build all tier 3 packages except kdewebkit, which I
think requires qtwebengine and qtwebview. Qtwebengine is going to take
some effort, I've already made some progress, since I also need it to
build calamares. Other than that I need to debug test failures, fixing
all the easy ones will probably take me an afternoon.

I've also made progress on sddm and hawaii-desktop. It would be nice
if we could get the mesa update in sometime, and I've got a patch to
xorg-server to enable Xephyr, which is required by sddm.

[0] https://api.kde.org/frameworks/index.html