[PATCH 1/3] gnu: hurd: Add kernel-headers package.

[PATCH 1/3] gnu: hurd: Add kernel-headers package.

[Manolis Ragkousis]

[-- Attachment #1: Type: text/plain, Size: 175 bytes --]

This package is a union of the Mach and Hurd headers and the Hurd-minimal
package which are needed for both glibc and gcc. It will make our lifes easier
when handling inputs.

[-- Attachment #2: 0001-gnu-hurd-Add-kernel-headers-package.patch --]
[-- Type: text/x-patch, Size: 2433 bytes --]

From 39bd88957a4f16426458dcb1215d89b39b0ac474 Mon Sep 17 00:00:00 2001
From: Manolis Ragkousis <manolis837@gmail.com>
Date: Fri, 31 Jul 2015 15:26:17 +0300
Subject: [PATCH 1/3] gnu: hurd: Add kernel-headers package.

* gnu/packages/hurd.scm (kernel-headers): Add kernel-headers package.
---
 gnu/packages/hurd.scm | 42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/gnu/packages/hurd.scm b/gnu/packages/hurd.scm
index ae84362..c99f81a 100644
--- a/gnu/packages/hurd.scm
+++ b/gnu/packages/hurd.scm
@@ -183,3 +183,45 @@ Library and other user programs.")
      "This package provides libihash, needed to build the GNU C 
 Library for GNU/Hurd.")
     (license gpl2+)))
+
+(define-public kernel-headers
+  (package
+    ;; This package is a union of the Mach and Hurd headers and the
+    ;; Hurd-minimal package which are needed for both glibc and gcc.
+    (name "kernel-headers")
+    (version "0")
+    (source #f)
+    (build-system gnu-build-system)
+    (propagated-inputs
+     `(("gnumach-headers" ,gnumach-headers)
+       ("hurd-headers" ,hurd-headers)
+       ("hurd-minimal" ,hurd-minimal)))
+    (arguments
+     `(#:phases (alist-delete
+                 'unpack
+                 (alist-delete
+                  'configure
+                  (alist-delete
+                   'build
+                   (alist-replace
+                    'install
+                    (lambda* (#:key inputs outputs #:allow-other-keys)
+                      (let* ((out  (assoc-ref outputs "out"))
+                             (incdir (string-append out "/include"))
+                             (libdir (string-append out "/lib"))
+                             (mach (assoc-ref inputs "gnumach-headers"))
+                             (hurd (assoc-ref inputs "hurd-headers"))
+                             (hurd-minimal (assoc-ref inputs "hurd-minimal")))
+                        (mkdir-p incdir)
+                        (mkdir-p libdir)
+                        (copy-recursively (string-append mach "/include") incdir)
+                        (copy-recursively (string-append hurd "/include") incdir)
+                        (copy-recursively (string-append hurd-minimal "/lib") libdir)
+                        #t))
+                    %standard-phases))))
+
+         #:tests? #f))
+    (home-page #f)
+    (synopsis #f)
+    (description #f)
+    (license gpl2+)))
-- 
2.4.6

Re: [PATCH 1/3] gnu: hurd: Add kernel-headers package.

[Andreas Enge]

Hello,

this package is strange - it propagates its inputs, and then it copies
their content into its own output? So if I understand things correctly,
upon installation, each of its files will be in conflict with the same
file from a propagated input.

How about using normal inputs and "union-build"? See sdl-union for an
example.

Andreas

Re: [PATCH 1/3] gnu: hurd: Add kernel-headers package.

[Manolis Ragkousis]

[-- Attachment #1: Type: text/plain, Size: 85 bytes --]

Hello Andreas :-D

You were right, now it's much prettier!!

Updated patch.

Manolis

[-- Attachment #2: 0001-gnu-hurd-Add-kernel-headers-package.patch --]
[-- Type: text/x-patch, Size: 1976 bytes --]

From 7ad4b64b93ac558a2683609fd77d1156c98474ee Mon Sep 17 00:00:00 2001
From: Manolis Ragkousis <manolis837@gmail.com>
Date: Fri, 31 Jul 2015 15:26:17 +0300
Subject: [PATCH 1/3] gnu: hurd: Add kernel-headers package.

* gnu/packages/hurd.scm (kernel-headers): Add kernel-headers package.
---
 gnu/packages/hurd.scm | 26 ++++++++++++++++++++++++++
 1 file changed, 26 insertions(+)

diff --git a/gnu/packages/hurd.scm b/gnu/packages/hurd.scm
index ae84362..d77e1ca 100644
--- a/gnu/packages/hurd.scm
+++ b/gnu/packages/hurd.scm
@@ -23,6 +23,7 @@
   #:use-module (gnu packages)
   #:use-module (guix utils)
   #:use-module (guix build-system gnu)
+  #:use-module (guix build-system trivial)
   #:use-module (gnu packages flex)
   #:use-module (gnu packages bison)
   #:use-module (gnu packages perl)
@@ -183,3 +184,28 @@ Library and other user programs.")
      "This package provides libihash, needed to build the GNU C 
 Library for GNU/Hurd.")
     (license gpl2+)))
+
+(define-public kernel-headers
+  (package
+    (name "kernel-headers")
+    (version (package-version hurd-headers))
+    (source #f)
+    (build-system trivial-build-system)
+    (arguments
+     '(#:modules ((guix build union))
+       #:builder (begin
+                   (use-modules (ice-9 match)
+                                (guix build union))
+                   (match %build-inputs
+                     (((names . directories) ...)
+                      (union-build (assoc-ref %outputs "out")
+                                   directories))))))
+    (inputs `(("gnumach-headers" ,gnumach-headers)
+              ("hurd-headers" ,hurd-headers)
+              ("hurd-minimal" ,hurd-minimal)))
+    (synopsis "Union of the Hurd headers and libs")
+    (description
+     "A union of the Mach and Hurd headers and the Hurd-minimal package
+which are needed for both glibc and gcc")
+    (home-page (package-home-page hurd-headers))
+    (license (package-license hurd-headers))))
-- 
2.5.0

Re: [PATCH 1/3] gnu: hurd: Add kernel-headers package.

[Mark H Weaver]

Manolis Ragkousis <manolis837@gmail.com> writes:
> This package is a union of the Mach and Hurd headers and the Hurd-minimal
> package which are needed for both glibc and gcc. It will make our lifes easier
> when handling inputs.

Can you help me understand the rationale for this?  There are a couple
of packages that need both hurd headers and gnumach headers.  I'm not
sure this justifies making a union package just for this purpose.

If we do add this package, I think its name should have 'hurd' somewhere
in it.

     Mark

Re: [PATCH 1/3] gnu: hurd: Add kernel-headers package.

[Manolis Ragkousis]

[-- Attachment #1: Type: text/plain, Size: 360 bytes --]

I forgot to send the updated patch so here it is. As I told Mark in the irc
this union package is a way to make the job of choosing which
headers to use each time, easier.
With this patch, we can have a procedure, as in
https://lists.gnu.org/archive/html/guix-devel/2015-08/msg00001.html to choose
what to use each time, as Ludo suggested in the irc.

Manolis

[-- Attachment #2: 0001-gnu-hurd-Add-kernel-headers-package.patch --]
[-- Type: text/x-patch, Size: 1992 bytes --]

From d60bac39582ff7be0217b2336e6d547829d0114b Mon Sep 17 00:00:00 2001
From: Manolis Ragkousis <manolis837@gmail.com>
Date: Fri, 31 Jul 2015 15:26:17 +0300
Subject: [PATCH] gnu: hurd: Add hurd-kernel-headers package.

* gnu/packages/hurd.scm (kernel-headers): Add hurd-kernel-headers package.
---
 gnu/packages/hurd.scm | 26 ++++++++++++++++++++++++++
 1 file changed, 26 insertions(+)

diff --git a/gnu/packages/hurd.scm b/gnu/packages/hurd.scm
index ae84362..8f32c9b 100644
--- a/gnu/packages/hurd.scm
+++ b/gnu/packages/hurd.scm
@@ -23,6 +23,7 @@
   #:use-module (gnu packages)
   #:use-module (guix utils)
   #:use-module (guix build-system gnu)
+  #:use-module (guix build-system trivial)
   #:use-module (gnu packages flex)
   #:use-module (gnu packages bison)
   #:use-module (gnu packages perl)
@@ -183,3 +184,28 @@ Library and other user programs.")
      "This package provides libihash, needed to build the GNU C 
 Library for GNU/Hurd.")
     (license gpl2+)))
+
+(define-public hurd-kernel-headers
+  (package
+    (name "hurd-kernel-headers")
+    (version (package-version hurd-headers))
+    (source #f)
+    (build-system trivial-build-system)
+    (arguments
+     '(#:modules ((guix build union))
+       #:builder (begin
+                   (use-modules (ice-9 match)
+                                (guix build union))
+                   (match %build-inputs
+                     (((names . directories) ...)
+                      (union-build (assoc-ref %outputs "out")
+                                   directories))))))
+    (inputs `(("gnumach-headers" ,gnumach-headers)
+              ("hurd-headers" ,hurd-headers)
+              ("hurd-minimal" ,hurd-minimal)))
+    (synopsis "Union of the Hurd headers and libs")
+    (description
+     "A union of the Mach and Hurd headers and the Hurd-minimal package
+which are needed for both glibc and gcc")
+    (home-page (package-home-page hurd-headers))
+    (license (package-license hurd-headers))))
-- 
2.5.0

Re: [PATCH 1/3] gnu: hurd: Add kernel-headers package.

[Mark H Weaver]

Manolis Ragkousis <manolis837@gmail.com> writes:

> From d60bac39582ff7be0217b2336e6d547829d0114b Mon Sep 17 00:00:00 2001
> From: Manolis Ragkousis <manolis837@gmail.com>
> Date: Fri, 31 Jul 2015 15:26:17 +0300
> Subject: [PATCH] gnu: hurd: Add hurd-kernel-headers package.

Okay to push to wip-hurd.

    Thanks!
      Mark

Re: [PATCH 1/3] gnu: hurd: Add kernel-headers package.

[Mark H Weaver]

Manolis Ragkousis <manolis837@gmail.com> writes:

> From d60bac39582ff7be0217b2336e6d547829d0114b Mon Sep 17 00:00:00 2001
> From: Manolis Ragkousis <manolis837@gmail.com>
> Date: Fri, 31 Jul 2015 15:26:17 +0300
> Subject: [PATCH] gnu: hurd: Add hurd-kernel-headers package.
>
> * gnu/packages/hurd.scm (kernel-headers): Add hurd-kernel-headers package.

Sorry, I just noticed that this commit log is improper, it should
instead say:

* gnu/packages/hurd.scm (hurd-kernel-headers): New variable.

     Mark