[PATCH 1/5] gnu: Add gnome-online-accounts.

[PATCH 1/5] gnu: Add gnome-online-accounts.

[宋文武]

* gnu/packages/gnome.scm (gnome-online-accounts): New variable.
---
 gnu/packages/gnome.scm | 38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

diff --git a/gnu/packages/gnome.scm b/gnu/packages/gnome.scm
index 6779cfb..70b9285 100644
--- a/gnu/packages/gnome.scm
+++ b/gnu/packages/gnome.scm
@@ -3901,3 +3901,41 @@ desktop via OpenGL.  Mutter combines a sophisticated display engine using the
 Clutter toolkit with solid window-management logic inherited from the Metacity
 window manager.")
     (license license:gpl2+)))
+
+(define-public gnome-online-accounts
+  (package
+    (name "gnome-online-accounts")
+    (version "3.18.1")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "mirror://gnome/sources/" name "/"
+                                  (version-major+minor version) "/"
+                                  name "-" version ".tar.xz"))
+              (sha256
+               (base32
+                "1hn2fvkr1f4qh4gix03avnvk7pklvv5272ns8ws56v4kcq4nppkc"))))
+    (build-system glib-or-gtk-build-system)
+    (native-inputs
+     `(("glib:bin" ,glib "bin") ; for glib-compile-schemas, etc.
+       ("gobject-introspection" ,gobject-introspection)
+       ("intltool" ,intltool)
+       ("pkg-config" ,pkg-config)
+       ("xsltproc" ,libxslt)))
+    (propagated-inputs
+     `(("glib" ,glib)           ; required by goa-1.0.pc
+       ("gtk+" ,gtk+)))         ; required by goa-backend-1.0.pc
+    (inputs
+     `(("docbook-xsl" ,docbook-xsl)
+       ("json-glib" ,json-glib)
+       ("libsecret" ,libsecret)
+       ("rest" ,rest)
+       ("telepathy-glib" ,telepathy-glib)
+       ("webkitgtk" ,webkitgtk)))
+    (synopsis "Single sign-on framework for GNOME")
+    (home-page "https://wiki.gnome.org/Projects/GnomeOnlineAccounts")
+    (description
+     "GNOME Online Accounts provides interfaces so that applications and
+libraries in GNOME can access the user's online accounts.  It has providers for
+Google, ownCloud, Facebook, Flickr, Windows Live, Pocket, Foursquare, Microsoft
+Exchange, Last.fm, IMAP/SMTP, Jabber, SIP and Kerberos.")
+    (license license:lgpl2.0+)))
-- 
2.5.0

[PATCH 2/5] gnu: Add evolution-data-server.

[宋文武]

* gnu/packages/gnome.scm (evolution-data-server): New variable.
---
 gnu/packages/gnome.scm | 64 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/gnu/packages/gnome.scm b/gnu/packages/gnome.scm
index 70b9285..9e018d6 100644
--- a/gnu/packages/gnome.scm
+++ b/gnu/packages/gnome.scm
@@ -39,6 +39,7 @@
   #:use-module (gnu packages avahi)
   #:use-module (gnu packages base)
   #:use-module (gnu packages bison)
+  #:use-module (gnu packages calendar)
   #:use-module (gnu packages cups)
   #:use-module (gnu packages curl)
   #:use-module (gnu packages databases)
@@ -52,6 +53,7 @@
   #:use-module (gnu packages gnuzilla)
   #:use-module (gnu packages gstreamer)
   #:use-module (gnu packages gtk)
+  #:use-module (gnu packages gperf)
   #:use-module (gnu packages guile)
   #:use-module (gnu packages pdf)
   #:use-module (gnu packages polkit)
@@ -3939,3 +3941,65 @@ libraries in GNOME can access the user's online accounts.  It has providers for
 Google, ownCloud, Facebook, Flickr, Windows Live, Pocket, Foursquare, Microsoft
 Exchange, Last.fm, IMAP/SMTP, Jabber, SIP and Kerberos.")
     (license license:lgpl2.0+)))
+
+(define-public evolution-data-server
+  (package
+    (name "evolution-data-server")
+    (version "3.18.2")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "mirror://gnome/sources/" name "/"
+                                  (version-major+minor version) "/"
+                                  name "-" version ".tar.xz"))
+              (sha256
+               (base32
+                "16yfd2a00xqxikyf6pi2awfd0qfq4hwdhfar88axrb4mycfgqhjr"))))
+    (build-system gnu-build-system)
+    (arguments
+     '(;; XXX: fails with:
+       ;;   /Fixture/Calendar0: cleaning up pid xxxx
+       ;;   t status: 139)
+       #:tests? #f
+       #:configure-flags
+       (let ((nss  (assoc-ref %build-inputs "nss"))
+             (nspr (assoc-ref %build-inputs "nspr")))
+         (list "--disable-uoa"    ; disable Ubuntu Online Accounts support
+               "--disable-google" ; disable Google Contacts support
+             (string-append "--with-nspr-includes=" nspr "/include/nspr")
+             (string-append "--with-nss-includes=" nss "/include/nss")
+             (string-append "--with-nss-libs=" nss "/lib/nss")))
+       #:phases
+       (modify-phases %standard-phases
+         (add-before
+          'check 'pre-check
+          (lambda _
+            (substitute* "tests/test-server-utils/e-test-server-utils.c"
+              (("/bin/rm") (which "rm")))
+            #t)))))
+    (native-inputs
+     `(("glib:bin" ,glib "bin") ; for glib-mkenums, etc.
+       ("gobject-introspection" ,gobject-introspection)
+       ("gperf" ,gperf)
+       ("intltool" ,intltool)
+       ("pkg-config" ,pkg-config)
+       ("python" ,python)))
+    (propagated-inputs
+     ;; These are all in the Requires field of .pc files.
+     `(("gtk+" ,gtk+)
+       ("libical" ,libical)
+       ("libsecret" ,libsecret)
+       ("libsoup" ,libsoup)
+       ("nss" ,nss)
+       ("sqlite" ,sqlite)))
+    (inputs
+     `(("bdb" ,bdb)
+       ("gcr" ,gcr)
+       ("gnome-online-accounts" ,gnome-online-accounts)
+       ("libgweather" ,libgweather)))
+    (synopsis "Libraries and services for storing addressbooks and calendars")
+    (home-page "https://wiki.gnome.org/Apps/Evolution")
+    (description
+     "This package provides a unified backend for programs that work with
+contacts, tasks, and calendar information.  It was originally developed for
+Evolution (hence the name), but is now used by other packages as well.")
+    (license license:lgpl2.0)))
-- 
2.5.0

Re: [PATCH 2/5] gnu: Add evolution-data-server.

[Alex Kost]

宋文武 (2015-11-10 15:51 +0300) wrote:

[...]
> +(define-public evolution-data-server
> +  (package
> +    (name "evolution-data-server")
> +    (version "3.18.2")
> +    (source (origin
> +              (method url-fetch)
> +              (uri (string-append "mirror://gnome/sources/" name "/"
> +                                  (version-major+minor version) "/"
> +                                  name "-" version ".tar.xz"))
> +              (sha256
> +               (base32
> +                "16yfd2a00xqxikyf6pi2awfd0qfq4hwdhfar88axrb4mycfgqhjr"))))
> +    (build-system gnu-build-system)
> +    (arguments
> +     '(;; XXX: fails with:
> +       ;;   /Fixture/Calendar0: cleaning up pid xxxx
> +       ;;   t status: 139)
> +       #:tests? #f
> +       #:configure-flags
> +       (let ((nss  (assoc-ref %build-inputs "nss"))
> +             (nspr (assoc-ref %build-inputs "nspr")))
> +         (list "--disable-uoa"    ; disable Ubuntu Online Accounts support
> +               "--disable-google" ; disable Google Contacts support
> +             (string-append "--with-nspr-includes=" nspr "/include/nspr")
> +             (string-append "--with-nss-includes=" nss "/include/nss")
> +             (string-append "--with-nss-libs=" nss "/lib/nss")))
                ^^
Please indent (string-append ...) clauses inside list properly.

> +       #:phases
> +       (modify-phases %standard-phases
> +         (add-before
> +          'check 'pre-check
> +          (lambda _
> +            (substitute* "tests/test-server-utils/e-test-server-utils.c"

I would make it:

         (add-before 'check 'pre-check
           (lambda _
             (substitute* "tests/test-server-utils/e-test-server-utils.c"

but it probably doesn't matter.

> +              (("/bin/rm") (which "rm")))
> +            #t)))))
> +    (native-inputs
> +     `(("glib:bin" ,glib "bin") ; for glib-mkenums, etc.
> +       ("gobject-introspection" ,gobject-introspection)
> +       ("gperf" ,gperf)
> +       ("intltool" ,intltool)
> +       ("pkg-config" ,pkg-config)
> +       ("python" ,python)))
> +    (propagated-inputs
> +     ;; These are all in the Requires field of .pc files.
> +     `(("gtk+" ,gtk+)
> +       ("libical" ,libical)
> +       ("libsecret" ,libsecret)
> +       ("libsoup" ,libsoup)
> +       ("nss" ,nss)
> +       ("sqlite" ,sqlite)))
> +    (inputs
> +     `(("bdb" ,bdb)
> +       ("gcr" ,gcr)
> +       ("gnome-online-accounts" ,gnome-online-accounts)
> +       ("libgweather" ,libgweather)))
> +    (synopsis "Libraries and services for storing addressbooks and calendars")

I think it's better to use "address books".

-- 
Alex

Re: [PATCH 2/5] gnu: Add evolution-data-server.

[Ludovic Courtès]

Alex Kost <alezost@gmail.com> skribis:

>> +    (synopsis "Libraries and services for storing addressbooks and calendars")
>
> I think it's better to use "address books".

Yes.  It could even be simply: “Store address books and calendars.”

Ludo’.

[PATCH 3/5] gnu: Add caribou.

[宋文武]

* gnu/packages/gnome.scm (caribou): New variable.
---
 gnu/packages/gnome.scm | 66 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

diff --git a/gnu/packages/gnome.scm b/gnu/packages/gnome.scm
index 9e018d6..9f7b01f 100644
--- a/gnu/packages/gnome.scm
+++ b/gnu/packages/gnome.scm
@@ -4003,3 +4003,69 @@ Exchange, Last.fm, IMAP/SMTP, Jabber, SIP and Kerberos.")
 contacts, tasks, and calendar information.  It was originally developed for
 Evolution (hence the name), but is now used by other packages as well.")
     (license license:lgpl2.0)))
+
+(define-public caribou
+  (package
+    (name "caribou")
+    (version "0.4.19")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "mirror://gnome/sources/" name "/"
+                                  (version-major+minor version) "/"
+                                  name "-" version ".tar.xz"))
+              (sha256
+               (base32
+                "0i2s2xy9ami3wslam15cajhggpcsj4c70qm7qddcz52z9k0x02rg"))))
+    (build-system glib-or-gtk-build-system)
+    (arguments
+     '(#:phases
+       (modify-phases %standard-phases
+         (add-before
+          'build 'pre-build
+          (lambda* (#:key outputs #:allow-other-keys)
+            (let ((out (assoc-ref outputs "out")))
+              ;; Use absolute shared library path in Caribou-1.0.typelib.
+              (substitute* "libcaribou/Makefile"
+                (("--shared-library=libcaribou.so")
+                 (string-append "--shared-library="
+                                out "/lib/libcaribou.so")))
+              #t)))
+         (add-after
+          'install 'wrap-programs
+          (lambda* (#:key outputs #:allow-other-keys)
+            (let* ((out (assoc-ref outputs "out"))
+                   (python-path (getenv "PYTHONPATH"))
+                   (gi-typelib-path (getenv "GI_TYPELIB_PATH")))
+              (for-each
+               (lambda (prog)
+                 (wrap-program prog
+                   `("PYTHONPATH"      ":" prefix (,python-path))
+                   `("GI_TYPELIB_PATH" ":" prefix (,gi-typelib-path))))
+               (list (string-append out "/bin/caribou-preferences")
+                     (string-append out "/libexec/antler-keyboard"))))
+            #t)))))
+    (native-inputs
+     `(("glib:bin" ,glib "bin") ; for glib-compile-schemas, etc.
+       ("gobject-introspection" ,gobject-introspection)
+       ("intltool" ,intltool)
+       ("pkg-config" ,pkg-config)
+       ("python" ,python-2) ; incompatible with Python 3 (print syntax)
+       ("vala" ,vala)
+       ("xsltproc" ,libxslt)))
+    (propagated-inputs
+     ;; caribou-1.0.pc refers to all these.
+     `(("libgee" ,libgee)
+       ("libxklavier" ,libxklavier)
+       ("libxtst" ,libxtst)
+       ("gtk+" ,gtk+)))
+    (inputs
+     `(("clutter" ,clutter)
+       ("dconf" ,dconf)
+       ("gtk+-2" ,gtk+-2)
+       ("python-pygobject" ,python2-pygobject)))
+    (synopsis "Text entry and UI navigation application")
+    (home-page "https://wiki.gnome.org/Projects/Caribou")
+    (description
+     "Caribou is an input assistive technology intended for switch and pointer
+users.")
+    (license license:lgpl2.1)))
-- 
2.5.0

Re: [PATCH 3/5] gnu: Add caribou.

[Ludovic Courtès]

宋文武 <iyzsong@gmail.com> skribis:

> * gnu/packages/gnome.scm (caribou): New variable.

LGTM, thanks.

Ludo’.

[PATCH 4/5] gnu: Add gdm.

[宋文武]

* gnu/packages/gnome.scm (gdm): New variable.
---
 gnu/packages/gnome.scm | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/gnu/packages/gnome.scm b/gnu/packages/gnome.scm
index 9f7b01f..5863be1 100644
--- a/gnu/packages/gnome.scm
+++ b/gnu/packages/gnome.scm
@@ -40,6 +40,7 @@
   #:use-module (gnu packages base)
   #:use-module (gnu packages bison)
   #:use-module (gnu packages calendar)
+  #:use-module (gnu packages check)
   #:use-module (gnu packages cups)
   #:use-module (gnu packages curl)
   #:use-module (gnu packages databases)
@@ -4069,3 +4070,62 @@ Evolution (hence the name), but is now used by other packages as well.")
      "Caribou is an input assistive technology intended for switch and pointer
 users.")
     (license license:lgpl2.1)))
+
+(define-public gdm
+  (package
+    (name "gdm")
+    (version "3.18.0")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "mirror://gnome/sources/" name "/"
+                                  (version-major+minor version) "/"
+                                  name "-" version ".tar.xz"))
+              (sha256
+               (base32
+                "0ivaniic5cxfz417bvdpsp7xz1hg6mfb7shrsb72qgm746lygyy9"))))
+    (build-system gnu-build-system)
+    (arguments
+     '(#:configure-flags
+       '("--without-plymouth")
+       #:phases
+       (modify-phases %standard-phases
+         (add-before
+          'configure 'pre-configure
+          (lambda _
+            ;; We don't have <systemd/sd-daemon.h>.
+            (substitute* '("common/gdm-log.c"
+                           "daemon/gdm-server.c"
+                           "daemon/gdm-session-worker.c"
+                           "daemon/gdm-session-worker-job.c")
+              (("#include <systemd/sd-daemon\\.h>") ""))
+            ;; Use elogind for sd-login.
+            (substitute* '("common/gdm-common.c"
+                           "daemon/gdm-manager.c"
+                           "libgdm/gdm-user-switching.c")
+              (("#include <systemd/sd-login\\.h>")
+               "#include <elogind/sd-login.h>"))
+            ;; Avoid checking SYSTEMD using pkg-config.
+            (setenv "SYSTEMD_CFLAGS" " ")
+            (setenv "SYSTEMD_LIBS" "-lelogind")
+            #t)))))
+    (native-inputs
+     `(("dconf" ,dconf)
+       ("glib:bin" ,glib "bin") ; for glib-compile-schemas, etc.
+       ("gobject-introspection" ,gobject-introspection)
+       ("intltool" ,intltool)
+       ("itstool" ,itstool)
+       ("pkg-config" ,pkg-config)
+       ("xmllint" ,libxml2)))
+    (inputs
+     `(("accountsservice" ,accountsservice)
+       ("check" ,check) ; for testing
+       ("elogind" ,elogind)
+       ("gtk+" ,gtk+)
+       ("libcanberra" ,libcanberra)
+       ("linux-pam" ,linux-pam)))
+    (synopsis "Display manager for GNOME")
+    (home-page "http://wiki.gnome.org/Projects/GDM/")
+    (description
+     "GNOME Display Manager is a system service that is responsible for
+providing graphical log-ins and managing local and remote displays.")
+    (license license:gpl2+)))
-- 
2.5.0

Re: [PATCH 4/5] gnu: Add gdm.

[Ludovic Courtès]

宋文武 <iyzsong@gmail.com> skribis:

> * gnu/packages/gnome.scm (gdm): New variable.

[...]

> +     '(#:configure-flags
> +       '("--without-plymouth")

Should be on a single line.

> +       (modify-phases %standard-phases
> +         (add-before
> +          'configure 'pre-configure

Could use the indentation suggested by Alex, but no big deal.

> +            ;; Use elogind for sd-login.
> +            (substitute* '("common/gdm-common.c"
> +                           "daemon/gdm-manager.c"
> +                           "libgdm/gdm-user-switching.c")
> +              (("#include <systemd/sd-login\\.h>")
> +               "#include <elogind/sd-login.h>"))
> +            ;; Avoid checking SYSTEMD using pkg-config.

That’s cool.

The rest LGTM.

So…  Next step is to have a GDM service in GuixSD.  :-)

Thanks,
Ludo’.

[PATCH 5/5] gnu: Add gnome-shell.

[宋文武]

* gnu/packages/gnome.scm (gnome-shell): New variable.
---
 gnu/packages/gnome.scm | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/gnu/packages/gnome.scm b/gnu/packages/gnome.scm
index 5863be1..4382f81 100644
--- a/gnu/packages/gnome.scm
+++ b/gnu/packages/gnome.scm
@@ -4129,3 +4129,63 @@ users.")
      "GNOME Display Manager is a system service that is responsible for
 providing graphical log-ins and managing local and remote displays.")
     (license license:gpl2+)))
+
+(define-public gnome-shell
+  (package
+    (name "gnome-shell")
+    (version "3.18.1")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "mirror://gnome/sources/" name "/"
+                                  (version-major+minor version) "/"
+                                  name "-" version ".tar.xz"))
+              (sha256
+               (base32
+                "0i9qpxr83xvaj0mj9jmib4icpa73cmjqmib99ywjb6p2ncam588l"))))
+    (build-system glib-or-gtk-build-system)
+    (arguments
+     '(#:phases
+       (modify-phases %standard-phases
+         (add-after
+          'install 'wrap-programs
+          (lambda* (#:key outputs #:allow-other-keys)
+            (let ((out              (assoc-ref outputs "out"))
+                  (gi-typelib-path  (getenv "GI_TYPELIB_PATH")))
+              (wrap-program (string-append out "/bin/gnome-shell")
+                `("GI_TYPELIB_PATH" ":" prefix (,gi-typelib-path)))))))))
+    (native-inputs
+     `(("glib:bin" ,glib "bin") ; for glib-compile-schemas, etc.
+       ("gobject-introspection" ,gobject-introspection)
+       ("intltool" ,intltool)
+       ("pkg-config" ,pkg-config)
+       ("python" ,python)
+       ("xsltproc" ,libxslt)))
+    (inputs
+     `(("accountsservice" ,accountsservice)
+       ("caribou" ,caribou)
+       ("docbook-xsl" ,docbook-xsl)
+       ("evolution-data-server" ,evolution-data-server)
+       ("gcr" ,gcr)
+       ("gdm" ,gdm)
+       ("gjs" ,gjs)
+       ("gnome-desktop" ,gnome-desktop)
+       ("gnome-settings-daemon" ,gnome-settings-daemon)
+       ("gst-plugins-base" ,gst-plugins-base)
+       ("libcanberra" ,libcanberra)
+       ("libcroco" ,libcroco)
+       ("libgweather" ,libgweather)
+       ("libsoup" ,libsoup)
+       ("mesa-headers" ,mesa-headers)
+       ("mutter" ,mutter)
+       ("polkit" ,polkit)
+       ("pulseaudio" ,pulseaudio)
+       ("startup-notification" ,startup-notification)
+       ("telepathy-glib" ,telepathy-glib)
+       ;; XXX: required by libgjs.la.
+       ("readline" ,readline)))
+    (synopsis "Desktop shell for GNOME")
+    (home-page "https://wiki.gnome.org/Projects/GnomeShell")
+    (description
+     "GNOME Shell provides core user interface functions for the GNOME desktop,
+like switching to windows and launching applications.")
+    (license license:gpl2+)))
-- 
2.5.0

Re: [PATCH 5/5] gnu: Add gnome-shell.

[宋文武]

WIP, gdm and gnome-shell won't start.

I haven't look much about gdm.

gnome-shell still missing some runtime depends (as typelib) like
network-manager, etc.

I post those patches to ML to track the process, let's package GNOME :-)

Re: [PATCH 5/5] gnu: Add gnome-shell.

[Thompson, David]

On Tue, Nov 10, 2015 at 8:10 AM, 宋文武 <iyzsong@member.fsf.org> wrote:
> WIP, gdm and gnome-shell won't start.
>
> I haven't look much about gdm.
>
> gnome-shell still missing some runtime depends (as typelib) like
> network-manager, etc.
>
> I post those patches to ML to track the process, let's package GNOME :-)

Wow!!!  Awesome progress!

- Dave

Re: [PATCH 5/5] gnu: Add gnome-shell.

[Daniel Pimentel]

I wait for it :)

Thanks!

-- 
Daniel Pimentel (d4n1 3:)

Re: [PATCH 5/5] gnu: Add gnome-shell.

[Ludovic Courtès]

iyzsong@member.fsf.org (宋文武) skribis:

> WIP, gdm and gnome-shell won't start.
>
> I haven't look much about gdm.
>
> gnome-shell still missing some runtime depends (as typelib) like
> network-manager, etc.
>
> I post those patches to ML to track the process, let's package GNOME :-)

Ah OK, makes sense.  :-)

Thanks for working on it!

Ludo’.

Re: [PATCH 1/5] gnu: Add gnome-online-accounts.

[Ludovic Courtès]

宋文武 <iyzsong@gmail.com> skribis:

> * gnu/packages/gnome.scm (gnome-online-accounts): New variable.

LGTM.

Ludo'.