;;; guix-emacs.el --- Autoload Emacs packages installed with Guix

;; Copyright © 2014, 2015, 2016, 2017 Alex Kost <alezost@gmail.com>
;; Copyright © 2017 Kyle Meyer <kyle@kyleam.com>
;; Copyright © 2019, 2020 Maxim Cournoyer <maxim.cournoyer@gmail.com>

;; This file is part of GNU Guix.

;; GNU Guix is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Guix is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; This file provides auxiliary code to initialize the Emacs packages
;; installed with Guix.

;;; Code:
(require 'package)
(require 'seq)

(defvar guix-emacs-autoloads-regexp
  (rx (* any) "-autoloads.el" (zero-or-one "c") string-end)
  "Regexp to match 'autoloads' file.")

(defun guix-emacs-find-autoloads (directory)
  "Return a list of 'autoloads' files in DIRECTORY.
The files in the list do not have extensions (.el, .elc)."
  ;; `directory-files' doesn't honor group in regexp.
  (delete-dups (mapcar #'file-name-sans-extension
                       (directory-files directory 'full-name
                                        guix-emacs-autoloads-regexp))))

(defvar guix-emacs-package-initialize-ran-p nil
  "Non-nil if `guix-emacs-package-initialize' has run.")

;;;###autoload
(defun guix-emacs-package-initialize ()
  "Initialize the Emacs packages.

Load the autoloads files of the packages, and add their directory
to the Emacs load path if they aren't already."
  (interactive)
  (let* (;; Filter out core Elisp directories, which have already been
         ;; autoloaded by Emacs.
         (load-path* (seq-filter (lambda (f)
                                   (string-match-p "/share/emacs/site-lisp" f))
                                 load-path))
         (autoloads (mapcan #'guix-emacs-find-autoloads load-path*))
         (package-directory-list* (mapcar (lambda (f)
                                            (expand-file-name "guix" f))
                                          load-path*))
         (user-emacs-directory-warning nil) ;squelch extraneous warnings
         (package-user-dir ""))      ;do not activate package.el user packages

    ;; Autoload packages installed without using 'emacs-build-system'; these
    ;; are found directly under the site-lisp directory (flat hierarchy).
    (mapc (lambda (f)
            (with-demoted-errors "Error loading autoloads: %s"
              (load f nil t)))
          autoloads)

    ;; Set the package-directory-list variable to a meaningful default value
    ;; on Guix, which for 'package.el' is akin to system packages.  It's
    ;; important that this variable contains the correct value to see the
    ;; Guix packages listed (as 'external') in M-x package-list.
    (setq-default package-directory-list package-directory-list*)

    ;; Initialize the Guix-installed Emacs packages.
    (package-initialize)

    (unless guix-emacs-package-initialize-ran-p
      ;; If this is running the first time, hide the fact that
      ;; `'package-initialization' has run in order to leave the default
      ;; behavior of package.el unchanged for its users (that is, to run
      ;; automatically after the early-init.el file but before the user init
      ;; file -- this can be useful if they configured their `'package-user-dir'
      ;; variable).
      (setq package--initialized nil)
      (setq package--activated nil))

    (setq guix-emacs-package-initialize-ran-p t)))

;;;###autoload
(defalias 'guix-package-initialize #'guix-emacs-package-initialize)

;;;###autoload
(define-obsolete-function-alias
  'guix-emacs-autoload-packages 'guix-package-initialize "20201218")

;;; The symbol name is suffixed by -emacs to avoid a name clash with
;;; Emacs-Guix's guix.el.
(provide 'guix-emacs)

;;; guix-emacs.el ends here