[PATCH 0/2] Add a cmake build system.

[PATCH 0/2] Add a cmake build system.

[Cyril Roelandt]

Hello!

The first patch adds a cmake build system. The second one is not ready to be
pushed, but it can be used to test the first one.

Regards,
Cyril.

---
Cyril Roelandt (2):
  Add (guix build-system cmake).
  gnu: Add libopenjpeg.

 Makefile.am                       |    3 +
 gnu/packages/libopenjpeg.scm      |   56 +++++++++++++++++
 guix/build-system/cmake.scm       |  123 +++++++++++++++++++++++++++++++++++++
 guix/build/cmake-build-system.scm |   65 ++++++++++++++++++++
 4 files changed, 247 insertions(+)
 create mode 100644 gnu/packages/libopenjpeg.scm
 create mode 100644 guix/build-system/cmake.scm
 create mode 100644 guix/build/cmake-build-system.scm

-- 
1.7.10.4

[PATCH 1/2] Add (guix build-system cmake).

[Cyril Roelandt]

* guix/build/cmake-build-system.scm, guix/build-system/cmake.scm: New files.
* Makefile.am (MODULES): Add them.
---
 Makefile.am                       |    2 +
 guix/build-system/cmake.scm       |  123 +++++++++++++++++++++++++++++++++++++
 guix/build/cmake-build-system.scm |   65 ++++++++++++++++++++
 3 files changed, 190 insertions(+)
 create mode 100644 guix/build-system/cmake.scm
 create mode 100644 guix/build/cmake-build-system.scm

diff --git a/Makefile.am b/Makefile.am
index 3229f16..3cda470 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -38,6 +38,7 @@ MODULES =					\
   guix/gnu-maintenance.scm			\
   guix/licenses.scm				\
   guix/build-system.scm				\
+  guix/build-system/cmake.scm			\
   guix/build-system/gnu.scm			\
   guix/build-system/perl.scm			\
   guix/build-system/trivial.scm			\
@@ -45,6 +46,7 @@ MODULES =					\
   guix/store.scm				\
   guix/ui.scm					\
   guix/build/download.scm			\
+  guix/build/cmake-build-system.scm		\
   guix/build/gnu-build-system.scm		\
   guix/build/perl-build-system.scm		\
   guix/build/utils.scm				\
diff --git a/guix/build-system/cmake.scm b/guix/build-system/cmake.scm
new file mode 100644
index 0000000..b9fd843
--- /dev/null
+++ b/guix/build-system/cmake.scm
@@ -0,0 +1,123 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2013 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2013 Cyril Roelandt <tipecaml@gmail.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build-system cmake)
+  #:use-module (guix store)
+  #:use-module (guix utils)
+  #:use-module (guix derivations)
+  #:use-module (guix build-system)
+  #:use-module (guix build-system gnu)
+  #:use-module (guix packages)
+  #:use-module (ice-9 match)
+  #:export (cmake-build
+            cmake-build-system))
+
+;; Commentary:
+;;
+;; Standard build procedure for packages using cmake. This is implemented as an
+;; extension of `gnu-build-system'.
+;;
+;; Code:
+
+(define* (cmake-build store name source inputs
+                     #:key (guile #f)
+                     (outputs '("out")) (configure-flags ''())
+                     (make-flags ''())
+                     (patches ''()) (patch-flags ''("--batch" "-p1"))
+                     (cmake (@ (gnu packages cmake) cmake))
+                     (out-of-source? #f)
+                     (path-exclusions ''())
+                     (tests? #t)
+                     (test-target "test")
+                     (parallel-build? #t) (parallel-tests? #f)
+                     (patch-shebangs? #t)
+                     (strip-binaries? #t)
+                     (strip-flags ''("--strip-debug"))
+                     (strip-directories ''("lib" "lib64" "libexec"
+                                           "bin" "sbin"))
+                     (phases '(@ (guix build cmake-build-system)
+                                 %standard-phases))
+                     (system (%current-system))
+                     (imported-modules '((guix build cmake-build-system)
+                                         (guix build gnu-build-system)
+                                         (guix build utils)))
+                     (modules '((guix build cmake-build-system)
+                                (guix build gnu-build-system)
+                                (guix build utils))))
+  "Build SOURCE using CMAKE, and with INPUTS. This assumes that SOURCE
+provides a 'CMakeLists.txt' file as its build system."
+  (define builder
+    `(begin
+       (use-modules ,@modules)
+       (cmake-build #:source ,(if (and source (derivation-path? source))
+                                 (derivation-path->output-path source)
+                                 source)
+                    #:system ,system
+                    #:outputs %outputs
+                    #:inputs %build-inputs
+                    #:patches ,patches
+                    #:patch-flags ,patch-flags
+                    #:phases ,phases
+                    #:configure-flags ,configure-flags
+                    #:make-flags ,make-flags
+                    #:out-of-source? ,out-of-source?
+                    #:path-exclusions ,path-exclusions
+                    #:tests? ,tests?
+                    #:test-target ,test-target
+                    #:parallel-build? ,parallel-build?
+                    #:parallel-tests? ,parallel-tests?
+                    #:patch-shebangs? ,patch-shebangs?
+                    #:strip-binaries? ,strip-binaries?
+                    #:strip-flags ,strip-flags
+                    #:strip-directories ,strip-directories)))
+
+  (define guile-for-build
+    (match guile
+      ((? package?)
+       (package-derivation store guile system))
+      ((and (? string?) (? derivation-path?))
+       guile)
+      (#f                                         ; the default
+       (let* ((distro (resolve-interface '(gnu packages base)))
+              (guile  (module-ref distro 'guile-final)))
+         (package-derivation store guile system)))))
+
+  (let ((cmake (package-derivation store cmake system)))
+    (build-expression->derivation store name system
+                                  builder
+                                  `(,@(if source
+                                          `(("source" ,source))
+                                          '())
+                                    ("cmake" ,cmake)
+                                    ,@inputs
+
+                                    ;; Keep the standard inputs of
+                                    ;; `gnu-build-system'.
+                                    ,@(standard-inputs system))
+
+                                  #:modules imported-modules
+                                  #:outputs outputs
+                                  #:guile-for-build guile-for-build)))
+
+(define cmake-build-system
+  (build-system (name 'cmake)
+                (description "The standard cmake build system")
+                (build cmake-build)))
+
+;;; cmake.scm ends here
diff --git a/guix/build/cmake-build-system.scm b/guix/build/cmake-build-system.scm
new file mode 100644
index 0000000..3bfaa00
--- /dev/null
+++ b/guix/build/cmake-build-system.scm
@@ -0,0 +1,65 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2013 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2013 Cyril Roelandt <tipecaml@gmail.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build cmake-build-system)
+  #:use-module ((guix build gnu-build-system)
+                #:renamer (symbol-prefix-proc 'gnu:))
+  #:use-module (guix build utils)
+  #:use-module (ice-9 match)
+  #:export (%standard-phases
+            cmake-build))
+
+;; Commentary:
+;;
+;; Builder-side code of the standard cmake build procedure.
+;;
+;; Code:
+
+(define* (configure #:key outputs (configure-flags '())
+                    #:allow-other-keys)
+  "Configure the given package."
+  (let ((out (assoc-ref outputs "out")))
+    (if (file-exists? "CMakeLists.txt")
+        (let ((args `(,(string-append "-DCMAKE_INSTALL_PREFIX=" out)
+                      ,@configure-flags)))
+          (format #t "running 'cmake' with arguments ~s~%" args)
+          (zero? (apply system* "cmake" args)))
+        (error "no CMakeLists.txt found"))))
+
+;; XXX Parallel tests are disabled by default because I have no idea how they
+;; work in cmake.
+(define* (check #:key (tests? #t) (parallel-tests? #f) (test-target "test")
+                #:allow-other-keys)
+  (let ((gnucheck (assoc-ref gnu:%standard-phases 'check)))
+    (gnucheck #:tests? tests? #:test-target test-target
+              #:parallel-tests? parallel-tests?)))
+
+(define %standard-phases
+  ;; Everything is as with the GNU Build System except for the `configure'
+  ;; and 'check' phases.
+  (alist-replace 'configure configure
+    (alist-replace 'check check
+                   gnu:%standard-phases)))
+
+(define* (cmake-build #:key inputs (phases %standard-phases)
+                      #:allow-other-keys #:rest args)
+  "Build the given package, applying all of PHASES in order."
+  (apply gnu:gnu-build #:inputs inputs #:phases phases args))
+
+;;; cmake-build-system.scm ends here
-- 
1.7.10.4

[PATCH 2/2] gnu: Add libopenjpeg.

[Cyril Roelandt]

This is quite a dummy commit: the tests are disabled because they fail. This
package is not ready to be pushed, but it allows us to try the new cmake build
system.

* gnu/packages/libopenjpeg.scm: New file.
* Makefile.am: Add it.
---
 Makefile.am                  |    1 +
 gnu/packages/libopenjpeg.scm |   56 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 gnu/packages/libopenjpeg.scm

diff --git a/Makefile.am b/Makefile.am
index 3cda470..1973657 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -110,6 +110,7 @@ MODULES =					\
   gnu/packages/libffi.scm			\
   gnu/packages/libidn.scm			\
   gnu/packages/libjpeg.scm			\
+  gnu/packages/libopenjpeg.scm			\
   gnu/packages/libpng.scm			\
   gnu/packages/libsigsegv.scm			\
   gnu/packages/libtiff.scm			\
diff --git a/gnu/packages/libopenjpeg.scm b/gnu/packages/libopenjpeg.scm
new file mode 100644
index 0000000..778860b
--- /dev/null
+++ b/gnu/packages/libopenjpeg.scm
@@ -0,0 +1,56 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2013 Cyril Roelandt <tipecaml@gmail.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages libopenjpeg)
+  #:use-module (guix licenses)
+  #:use-module (guix packages)
+  #:use-module (guix download)
+  #:use-module (guix build-system cmake)
+  #:use-module (gnu packages)
+  #:use-module (gnu packages autotools)
+  #:use-module (gnu packages base)
+  #:use-module (gnu packages ncurses))
+
+(define-public libopenjpeg
+  (package
+    (name "libopenjpeg")
+    (version "2.0.0")
+    (source (origin
+             (method url-fetch)
+             (uri (string-append
+                    "http://openjpeg.googlecode.com/files/openjpeg-"
+                    version ".tar.gz"))
+             (sha256
+              (base32 "1n05yrmscpgksrh2kfh12h18l0lw9j03mgmvwcg3hm8m0lwgak9k"))))
+    (build-system cmake-build-system)
+    (arguments
+     `(#:tests? #f
+       #:configure-flags
+        '("-DBUILD_DOC:BOOL=ON"
+          "-DBUILD_TESTING:BOOL=ON")))
+    (home-page "http://www.openjpeg.org/")
+    (synopsis "A JPEG 2000 codec")
+    (description
+      "The OpenJPEG library is an open-source JPEG 2000 codec written in C
+language.  It has been developed in order to promote the use of JPEG 2000, the
+new still-image compression standard from the Joint Photographic Experts Group
+(JPEG). In addition to the basic codec, various other features are under
+development, among them the JP2 and MJ2 (Motion JPEG 2000) file formats, an
+indexing tool useful for the JPIP protocol, JPWL-tools for error-resilience, a
+Java-viewer for j2k-images, ... ")
+    (license bsd-2)))
-- 
1.7.10.4

Re: [PATCH 1/2] Add (guix build-system cmake).

[Ludovic Courtès]

Cyril Roelandt <tipecaml@gmail.com> skribis:

> * guix/build/cmake-build-system.scm, guix/build-system/cmake.scm: New files.
> * Makefile.am (MODULES): Add them.

Overall looks good to me, nice!

> +;; Standard build procedure for packages using cmake. This is implemented as an

Please spell it as “CMake”.  Also, two spaces after a period ending a
sentence.

> +(define* (cmake-build store name source inputs

Admittedly these bits look like copy/pasting, but I’m not sure how to
factorize more.

> +                (description "The standard cmake build system")

“CMake”.

> +;; XXX Parallel tests are disabled by default because I have no idea how they
> +;; work in cmake.

CMake generates a Makefile, so running ‘make -jX’ just works.  Thus you
can leave #:parallel-{build,tests}? to #t by default.

> +(define* (check #:key (tests? #t) (parallel-tests? #f) (test-target "test")
> +                #:allow-other-keys)
> +  (let ((gnucheck (assoc-ref gnu:%standard-phases 'check)))

s/gnucheck/gnu-check/

Cool!

Please push after fixing these.

Ludo’.

Re: [PATCH 2/2] gnu: Add libopenjpeg.

[Ludovic Courtès]

Cyril Roelandt <tipecaml@gmail.com> skribis:

> This is quite a dummy commit: the tests are disabled because they fail. This
> package is not ready to be pushed, but it allows us to try the new cmake build
> system.

Better investigate the failure, of course, but it’s OK to push it
before, if you prefer.

> +  #:use-module (gnu packages)
> +  #:use-module (gnu packages autotools)
> +  #:use-module (gnu packages base)
> +  #:use-module (gnu packages ncurses))

These 4 modules are not needed AFAICS.

Thanks,
Ludo’.

Re: [PATCH 2/2] gnu: Add libopenjpeg.

[Nikita Karetnikov]

[-- Attachment #1: Type: text/plain, Size: 355 bytes --]

> +      "The OpenJPEG library is an open-source JPEG 2000 codec written
> in C

I suggest to replace "open-source" with "free software."  If you think
that it's not ethical to replace (it's possible that OpenJPEG people
don't care about freedom-related issues), you can just remove it.

For example:

The OpenJPEG library is a JPEG 2000 codec written...

[-- Attachment #2: Type: application/pgp-signature, Size: 835 bytes --]

Re: [PATCH 2/2] gnu: Add libopenjpeg.

[Andreas Enge]

Am Dienstag, 26. März 2013 schrieb Nikita Karetnikov:
> I suggest to replace "open-source" with "free software."

I do it all the time, I think we do not want to mention "open source" in 
guix...

> The OpenJPEG library is a JPEG 2000 codec written...

... and this is often better, I would say, since by definition we only 
package free software anyway.

Andreas

Re: [PATCH 2/2] gnu: Add libopenjpeg.

[Andreas Enge]

Am Dienstag, 26. März 2013 schrieb Cyril Roelandt:
>  gnu/packages/libopenjpeg.scm |   56

There is already a file libjpeg.scm. How about putting the packages in the 
same file, named jpeg.scm, for instance?

Andreas

Re: [PATCH 1/2] Add (guix build-system cmake).

[Cyril Roelandt]

On 03/26/2013 11:09 PM, Ludovic Courtès wrote:
> Cool!
>
> Please push after fixing these.

Thanks for your quick review! I've just pushed the patch.

Cyril.

Re: [PATCH 2/2] gnu: Add libopenjpeg.

[Cyril Roelandt]

On 03/27/2013 09:47 AM, Andreas Enge wrote:
> Am Dienstag, 26. März 2013 schrieb Cyril Roelandt:
>>   gnu/packages/libopenjpeg.scm |   56
>
> There is already a file libjpeg.scm. How about putting the packages in the
> same file, named jpeg.scm, for instance?
>

This file does not exist on the 'master' branch. Plus, I really did not 
want to push libopenjpeg, it was just a simple example to test my cmake 
build-system. It makes sense to put libopenjpeg in jpeg.scm, we'll have 
to do that once we get it to work.

Cyril.

Re: [PATCH 2/2] gnu: Add libopenjpeg.

[Cyril Roelandt]

On 03/26/2013 11:40 PM, Nikita Karetnikov wrote:
>> +      "The OpenJPEG library is an open-source JPEG 2000 codec written
>> in C
>
> I suggest to replace "open-source" with "free software."  If you think
> that it's not ethical to replace (it's possible that OpenJPEG people
> don't care about freedom-related issues), you can just remove it.
>
> For example:
>
> The OpenJPEG library is a JPEG 2000 codec written...

Looks reasonable.

Cyril.